arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 PHDRS {
  17         text PT_LOAD FLAGS(5);  /* R_E */
  18         data PT_LOAD FLAGS(7);  /* RWE */
  19         user PT_LOAD FLAGS(7);  /* RWE */
  20         note PT_NOTE FLAGS(4);  /* R__ */
  21 }
  22 SECTIONS
  23 {
  24   . = __START_KERNEL;
  25   phys_startup_64 = startup_64 - LOAD_OFFSET;
  26   _text = .;                    /* Text and read-only data */
  27   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  28         /* First the code that has to be first for bootstrapping */
  29         *(.bootstrap.text)
  30         /* Then all the functions that are "hot" in profiles, to group them
  31            onto the same hugetlb entry */
  32         #include "functionlist"
  33         /* Then the rest */
  34         *(.text)
  35         SCHED_TEXT
  36         LOCK_TEXT
  37         KPROBES_TEXT
  38         *(.fixup)
  39         *(.gnu.warning)
  40         } :text = 0x9090
  41                                 /* out-of-line lock text */
  42   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  43
  44   _etext = .;                   /* End of text section */
  45
  46   . = ALIGN(16);                /* Exception table */
  47   __start___ex_table = .;
  48   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  49   __stop___ex_table = .;
  50
  51   RODATA
  52
  53 #ifdef CONFIG_STACK_UNWIND
  54   . = ALIGN(8);
  55   .eh_frame : AT(ADDR(.eh_frame) - LOAD_OFFSET) {
  56         __start_unwind = .;
  57         *(.eh_frame)
  58         __end_unwind = .;
  59   }
  60 #endif
  61
  62                                 /* Data */
  63   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  64         *(.data)
  65         CONSTRUCTORS
  66         } :data
  67
  68   _edata = .;                   /* End of data section */
  69
  70   __bss_start = .;              /* BSS */
  71   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
  72         *(.bss.page_aligned)
  73         *(.bss)
  74         }
  75   __bss_stop = .;
  76
  77   . = ALIGN(PAGE_SIZE);
  78   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  79   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  80         *(.data.cacheline_aligned)
  81   }
  82   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  83   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  84         *(.data.read_mostly)
  85   }
  86
  87 #define VSYSCALL_ADDR (-10*1024*1024)
  88 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  89 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  90
  91 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  92 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  93
  94 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  95 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  96
  97   . = VSYSCALL_ADDR;
  98   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  99   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
 100
 101   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 102   .xtime_lock : AT(VLOAD(.xtime_lock)) { *(.xtime_lock) }
 103   xtime_lock = VVIRT(.xtime_lock);
 104
 105   .vxtime : AT(VLOAD(.vxtime)) { *(.vxtime) }
 106   vxtime = VVIRT(.vxtime);
 107
 108   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
 109   vgetcpu_mode = VVIRT(.vgetcpu_mode);
 110
 111   .wall_jiffies : AT(VLOAD(.wall_jiffies)) { *(.wall_jiffies) }
 112   wall_jiffies = VVIRT(.wall_jiffies);
 113
 114   .sys_tz : AT(VLOAD(.sys_tz)) { *(.sys_tz) }
 115   sys_tz = VVIRT(.sys_tz);
 116
 117   .sysctl_vsyscall : AT(VLOAD(.sysctl_vsyscall)) { *(.sysctl_vsyscall) }
 118   sysctl_vsyscall = VVIRT(.sysctl_vsyscall);
 119
 120   .xtime : AT(VLOAD(.xtime)) { *(.xtime) }
 121   xtime = VVIRT(.xtime);
 122
 123   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 124   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 125   jiffies = VVIRT(.jiffies);
 126
 127   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) { *(.vsyscall_1) }
 128   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) { *(.vsyscall_2) }
 129   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) { *(.vsyscall_3) }
 130
 131   . = VSYSCALL_VIRT_ADDR + 4096;
 132
 133 #undef VSYSCALL_ADDR
 134 #undef VSYSCALL_PHYS_ADDR
 135 #undef VSYSCALL_VIRT_ADDR
 136 #undef VLOAD_OFFSET
 137 #undef VLOAD
 138 #undef VVIRT_OFFSET
 139 #undef VVIRT
 140
 141   . = ALIGN(8192);              /* init_task */
 142   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 143         *(.data.init_task)
 144   } :data
 145
 146   . = ALIGN(4096);
 147   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 148         *(.data.page_aligned)
 149   }
 150
 151   /* might get freed after init */
 152   . = ALIGN(4096);
 153   __smp_alt_begin = .;
 154   __smp_alt_instructions = .;
 155   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
 156         *(.smp_altinstructions)
 157   }
 158   __smp_alt_instructions_end = .;
 159   . = ALIGN(8);
 160   __smp_locks = .;
 161   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 162         *(.smp_locks)
 163   }
 164   __smp_locks_end = .;
 165   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 166         *(.smp_altinstr_replacement)
 167   }
 168   . = ALIGN(4096);
 169   __smp_alt_end = .;
 170
 171   . = ALIGN(4096);              /* Init code and data */
 172   __init_begin = .;
 173   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 174         _sinittext = .;
 175         *(.init.text)
 176         _einittext = .;
 177   }
 178   __initdata_begin = .;
 179   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 180   __initdata_end = .;
 181   . = ALIGN(16);
 182   __setup_start = .;
 183   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 184   __setup_end = .;
 185   __initcall_start = .;
 186   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 187         *(.initcall1.init)
 188         *(.initcall2.init)
 189         *(.initcall3.init)
 190         *(.initcall4.init)
 191         *(.initcall5.init)
 192         *(.initcall6.init)
 193         *(.initcall7.init)
 194   }
 195   __initcall_end = .;
 196   __con_initcall_start = .;
 197   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 198         *(.con_initcall.init)
 199   }
 200   __con_initcall_end = .;
 201   SECURITY_INIT
 202   . = ALIGN(8);
 203   __alt_instructions = .;
 204   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 205         *(.altinstructions)
 206   }
 207   __alt_instructions_end = .;
 208   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 209         *(.altinstr_replacement)
 210   }
 211   /* .exit.text is discard at runtime, not link time, to deal with references
 212      from .altinstructions and .eh_frame */
 213   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 214   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 215   . = ALIGN(4096);
 216   __initramfs_start = .;
 217   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 218   __initramfs_end = .;
 219     . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 220   __per_cpu_start = .;
 221   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 222   __per_cpu_end = .;
 223   . = ALIGN(4096);
 224   __init_end = .;
 225
 226   . = ALIGN(4096);
 227   __nosave_begin = .;
 228   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 229   . = ALIGN(4096);
 230   __nosave_end = .;
 231
 232   _end = . ;
 233
 234   /* Sections to be discarded */
 235   /DISCARD/ : {
 236         *(.exitcall.exit)
 237 #ifndef CONFIG_UNWIND_INFO
 238         *(.eh_frame)
 239 #endif
 240         }
 241
 242   STABS_DEBUG
 243
 244   DWARF_DEBUG
 245 }