arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9
  10 #undef i386     /* in case the preprocessor is a 32bit one */
  11
  12 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  13 OUTPUT_ARCH(i386:x86-64)
  14 ENTRY(phys_startup_64)
  15 jiffies_64 = jiffies;
  16 _proxy_pda = 1;
  17 PHDRS {
  18         text PT_LOAD FLAGS(5);  /* R_E */
  19         data PT_LOAD FLAGS(7);  /* RWE */
  20         user PT_LOAD FLAGS(7);  /* RWE */
  21         data.init PT_LOAD FLAGS(7);     /* RWE */
  22         note PT_NOTE FLAGS(4);  /* R__ */
  23 }
  24 SECTIONS
  25 {
  26   . = __START_KERNEL;
  27   phys_startup_64 = startup_64 - LOAD_OFFSET;
  28   _text = .;                    /* Text and read-only data */
  29   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  30         /* First the code that has to be first for bootstrapping */
  31         *(.bootstrap.text)
  32         _stext = .;
  33         /* Then the rest */
  34         TEXT_TEXT
  35         SCHED_TEXT
  36         LOCK_TEXT
  37         KPROBES_TEXT
  38         *(.fixup)
  39         *(.gnu.warning)
  40         } :text = 0x9090
  41                                 /* out-of-line lock text */
  42   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  43
  44   _etext = .;                   /* End of text section */
  45
  46   . = ALIGN(16);                /* Exception table */
  47   __start___ex_table = .;
  48   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  49   __stop___ex_table = .;
  50
  51   NOTES :text :note
  52
  53   BUG_TABLE :text
  54
  55   RODATA
  56
  57   . = ALIGN(PAGE_SIZE);        /* Align data segment to page size boundary */
  58                                 /* Data */
  59   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  60         DATA_DATA
  61         CONSTRUCTORS
  62         } :data
  63
  64   _edata = .;                   /* End of data section */
  65
  66   . = ALIGN(PAGE_SIZE);
  67   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  68   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  69         *(.data.cacheline_aligned)
  70   }
  71   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  72   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  73         *(.data.read_mostly)
  74   }
  75
  76 #define VSYSCALL_ADDR (-10*1024*1024)
  77 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  78 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  79
  80 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  81 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  82
  83 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  84 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  85
  86   . = VSYSCALL_ADDR;
  87   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) } :user
  88   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  89
  90   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  91   .vsyscall_fn : AT(VLOAD(.vsyscall_fn)) { *(.vsyscall_fn) }
  92   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  93   .vsyscall_gtod_data : AT(VLOAD(.vsyscall_gtod_data))
  94                 { *(.vsyscall_gtod_data) }
  95   vsyscall_gtod_data = VVIRT(.vsyscall_gtod_data);
  96   .vsyscall_clock : AT(VLOAD(.vsyscall_clock))
  97                 { *(.vsyscall_clock) }
  98   vsyscall_clock = VVIRT(.vsyscall_clock);
  99
 100
 101   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1))
 102                 { *(.vsyscall_1) }
 103   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2))
 104                 { *(.vsyscall_2) }
 105
 106   .vgetcpu_mode : AT(VLOAD(.vgetcpu_mode)) { *(.vgetcpu_mode) }
 107   vgetcpu_mode = VVIRT(.vgetcpu_mode);
 108
 109   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 110   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 111   jiffies = VVIRT(.jiffies);
 112
 113   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3))
 114                 { *(.vsyscall_3) }
 115
 116   . = VSYSCALL_VIRT_ADDR + 4096;
 117
 118 #undef VSYSCALL_ADDR
 119 #undef VSYSCALL_PHYS_ADDR
 120 #undef VSYSCALL_VIRT_ADDR
 121 #undef VLOAD_OFFSET
 122 #undef VLOAD
 123 #undef VVIRT_OFFSET
 124 #undef VVIRT
 125
 126   . = ALIGN(8192);              /* init_task */
 127   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 128         *(.data.init_task)
 129   }:data.init
 130
 131   . = ALIGN(4096);
 132   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 133         *(.data.page_aligned)
 134   }
 135
 136   /* might get freed after init */
 137   . = ALIGN(4096);
 138   __smp_alt_begin = .;
 139   __smp_alt_instructions = .;
 140   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
 141         *(.smp_altinstructions)
 142   }
 143   __smp_alt_instructions_end = .;
 144   . = ALIGN(8);
 145   __smp_locks = .;
 146   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 147         *(.smp_locks)
 148   }
 149   __smp_locks_end = .;
 150   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 151         *(.smp_altinstr_replacement)
 152   }
 153   . = ALIGN(4096);
 154   __smp_alt_end = .;
 155
 156   . = ALIGN(4096);              /* Init code and data */
 157   __init_begin = .;
 158   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 159         _sinittext = .;
 160         *(.init.text)
 161         _einittext = .;
 162   }
 163   __initdata_begin = .;
 164   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 165   __initdata_end = .;
 166   . = ALIGN(16);
 167   __setup_start = .;
 168   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 169   __setup_end = .;
 170   __initcall_start = .;
 171   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 172         INITCALLS
 173   }
 174   __initcall_end = .;
 175   __con_initcall_start = .;
 176   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 177         *(.con_initcall.init)
 178   }
 179   __con_initcall_end = .;
 180   SECURITY_INIT
 181   . = ALIGN(8);
 182   __alt_instructions = .;
 183   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 184         *(.altinstructions)
 185   }
 186   __alt_instructions_end = .;
 187   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 188         *(.altinstr_replacement)
 189   }
 190   /* .exit.text is discard at runtime, not link time, to deal with references
 191      from .altinstructions and .eh_frame */
 192   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 193   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 194
 195 /* vdso blob that is mapped into user space */
 196   vdso_start = . ;
 197   .vdso  : AT(ADDR(.vdso) - LOAD_OFFSET) { *(.vdso) }
 198   . = ALIGN(4096);
 199   vdso_end = .;
 200
 201 #ifdef CONFIG_BLK_DEV_INITRD
 202   . = ALIGN(4096);
 203   __initramfs_start = .;
 204   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 205   __initramfs_end = .;
 206 #endif
 207
 208   PERCPU(4096)
 209
 210   . = ALIGN(4096);
 211   __init_end = .;
 212
 213   . = ALIGN(4096);
 214   __nosave_begin = .;
 215   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 216   . = ALIGN(4096);
 217   __nosave_end = .;
 218
 219   __bss_start = .;              /* BSS */
 220   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 221         *(.bss.page_aligned)
 222         *(.bss)
 223         }
 224   __bss_stop = .;
 225
 226   _end = . ;
 227
 228   /* Sections to be discarded */
 229   /DISCARD/ : {
 230         *(.exitcall.exit)
 231         *(.eh_frame)
 232         }
 233
 234   STABS_DEBUG
 235
 236   DWARF_DEBUG
 237 }