arch/x86_64/kernel/vmlinux.lds.S

   1 /* ld script to make x86-64 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __START_KERNEL_map
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/page.h>
   9 #include <linux/config.h>
  10
  11 #undef i386     /* in case the preprocessor is a 32bit one */
  12
  13 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
  14 OUTPUT_ARCH(i386:x86-64)
  15 ENTRY(phys_startup_64)
  16 jiffies_64 = jiffies;
  17 SECTIONS
  18 {
  19   . = __START_KERNEL;
  20   phys_startup_64 = startup_64 - LOAD_OFFSET;
  21   _text = .;                    /* Text and read-only data */
  22   .text :  AT(ADDR(.text) - LOAD_OFFSET) {
  23         /* First the code that has to be first for bootstrapping */
  24         *(.bootstrap.text)
  25         /* Then all the functions that are "hot" in profiles, to group them
  26            onto the same hugetlb entry */
  27         #include "functionlist"
  28         /* Then the rest */
  29         *(.text)
  30         SCHED_TEXT
  31         LOCK_TEXT
  32         KPROBES_TEXT
  33         *(.fixup)
  34         *(.gnu.warning)
  35         } = 0x9090
  36                                 /* out-of-line lock text */
  37   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET) { *(.text.lock) }
  38
  39   _etext = .;                   /* End of text section */
  40
  41   . = ALIGN(16);                /* Exception table */
  42   __start___ex_table = .;
  43   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  44   __stop___ex_table = .;
  45
  46   RODATA
  47
  48 #ifdef CONFIG_STACK_UNWIND
  49   . = ALIGN(8);
  50   .eh_frame : AT(ADDR(.eh_frame) - LOAD_OFFSET) {
  51         __start_unwind = .;
  52         *(.eh_frame)
  53         __end_unwind = .;
  54   }
  55 #endif
  56
  57                                 /* Data */
  58   .data : AT(ADDR(.data) - LOAD_OFFSET) {
  59         *(.data)
  60         CONSTRUCTORS
  61         }
  62
  63   _edata = .;                   /* End of data section */
  64
  65   __bss_start = .;              /* BSS */
  66   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
  67         *(.bss.page_aligned)
  68         *(.bss)
  69         }
  70   __bss_stop = .;
  71
  72   . = ALIGN(PAGE_SIZE);
  73   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  74   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  75         *(.data.cacheline_aligned)
  76   }
  77   . = ALIGN(CONFIG_X86_INTERNODE_CACHE_BYTES);
  78   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
  79         *(.data.read_mostly)
  80   }
  81
  82 #define VSYSCALL_ADDR (-10*1024*1024)
  83 #define VSYSCALL_PHYS_ADDR ((LOADADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  84 #define VSYSCALL_VIRT_ADDR ((ADDR(.data.read_mostly) + SIZEOF(.data.read_mostly) + 4095) & ~(4095))
  85
  86 #define VLOAD_OFFSET (VSYSCALL_ADDR - VSYSCALL_PHYS_ADDR)
  87 #define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
  88
  89 #define VVIRT_OFFSET (VSYSCALL_ADDR - VSYSCALL_VIRT_ADDR)
  90 #define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
  91
  92   . = VSYSCALL_ADDR;
  93   .vsyscall_0 :  AT(VSYSCALL_PHYS_ADDR) { *(.vsyscall_0) }
  94   __vsyscall_0 = VSYSCALL_VIRT_ADDR;
  95
  96   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
  97   .xtime_lock : AT(VLOAD(.xtime_lock)) { *(.xtime_lock) }
  98   xtime_lock = VVIRT(.xtime_lock);
  99
 100   .vxtime : AT(VLOAD(.vxtime)) { *(.vxtime) }
 101   vxtime = VVIRT(.vxtime);
 102
 103   .wall_jiffies : AT(VLOAD(.wall_jiffies)) { *(.wall_jiffies) }
 104   wall_jiffies = VVIRT(.wall_jiffies);
 105
 106   .sys_tz : AT(VLOAD(.sys_tz)) { *(.sys_tz) }
 107   sys_tz = VVIRT(.sys_tz);
 108
 109   .sysctl_vsyscall : AT(VLOAD(.sysctl_vsyscall)) { *(.sysctl_vsyscall) }
 110   sysctl_vsyscall = VVIRT(.sysctl_vsyscall);
 111
 112   .xtime : AT(VLOAD(.xtime)) { *(.xtime) }
 113   xtime = VVIRT(.xtime);
 114
 115   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 116   .jiffies : AT(VLOAD(.jiffies)) { *(.jiffies) }
 117   jiffies = VVIRT(.jiffies);
 118
 119   .vsyscall_1 ADDR(.vsyscall_0) + 1024: AT(VLOAD(.vsyscall_1)) { *(.vsyscall_1) }
 120   .vsyscall_2 ADDR(.vsyscall_0) + 2048: AT(VLOAD(.vsyscall_2)) { *(.vsyscall_2) }
 121   .vsyscall_3 ADDR(.vsyscall_0) + 3072: AT(VLOAD(.vsyscall_3)) { *(.vsyscall_3) }
 122
 123   . = VSYSCALL_VIRT_ADDR + 4096;
 124
 125 #undef VSYSCALL_ADDR
 126 #undef VSYSCALL_PHYS_ADDR
 127 #undef VSYSCALL_VIRT_ADDR
 128 #undef VLOAD_OFFSET
 129 #undef VLOAD
 130 #undef VVIRT_OFFSET
 131 #undef VVIRT
 132
 133   . = ALIGN(8192);              /* init_task */
 134   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 135         *(.data.init_task)
 136   }
 137
 138   . = ALIGN(4096);
 139   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
 140         *(.data.page_aligned)
 141   }
 142
 143   /* might get freed after init */
 144   . = ALIGN(4096);
 145   __smp_alt_begin = .;
 146   __smp_alt_instructions = .;
 147   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
 148         *(.smp_altinstructions)
 149   }
 150   __smp_alt_instructions_end = .;
 151   . = ALIGN(8);
 152   __smp_locks = .;
 153   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 154         *(.smp_locks)
 155   }
 156   __smp_locks_end = .;
 157   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
 158         *(.smp_altinstr_replacement)
 159   }
 160   . = ALIGN(4096);
 161   __smp_alt_end = .;
 162
 163   . = ALIGN(4096);              /* Init code and data */
 164   __init_begin = .;
 165   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 166         _sinittext = .;
 167         *(.init.text)
 168         _einittext = .;
 169   }
 170   __initdata_begin = .;
 171   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 172   __initdata_end = .;
 173   . = ALIGN(16);
 174   __setup_start = .;
 175   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 176   __setup_end = .;
 177   __initcall_start = .;
 178   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 179         *(.initcall1.init)
 180         *(.initcall2.init)
 181         *(.initcall3.init)
 182         *(.initcall4.init)
 183         *(.initcall5.init)
 184         *(.initcall6.init)
 185         *(.initcall7.init)
 186   }
 187   __initcall_end = .;
 188   __con_initcall_start = .;
 189   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 190         *(.con_initcall.init)
 191   }
 192   __con_initcall_end = .;
 193   SECURITY_INIT
 194   . = ALIGN(8);
 195   __alt_instructions = .;
 196   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 197         *(.altinstructions)
 198   }
 199   __alt_instructions_end = .;
 200   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 201         *(.altinstr_replacement)
 202   }
 203   /* .exit.text is discard at runtime, not link time, to deal with references
 204      from .altinstructions and .eh_frame */
 205   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 206   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 207   . = ALIGN(4096);
 208   __initramfs_start = .;
 209   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 210   __initramfs_end = .;
 211   /* temporary here to work around NR_CPUS. If you see this comment in 2.6.17+
 212    complain */
 213   . = ALIGN(4096);
 214   __init_end = .;
 215   . = ALIGN(CONFIG_X86_L1_CACHE_BYTES);
 216   __per_cpu_start = .;
 217   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 218   __per_cpu_end = .;
 219
 220   . = ALIGN(4096);
 221   __nosave_begin = .;
 222   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
 223   . = ALIGN(4096);
 224   __nosave_end = .;
 225
 226   _end = . ;
 227
 228   /* Sections to be discarded */
 229   /DISCARD/ : {
 230         *(.exitcall.exit)
 231 #ifndef CONFIG_UNWIND_INFO
 232         *(.eh_frame)
 233 #endif
 234         }
 235
 236   STABS_DEBUG
 237
 238   DWARF_DEBUG
 239 }