arch/x86/kernel/head_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  *
   5  *  Enhanced CPU detection and feature setting code by Mike Jagdis
   6  *  and Martin Mares, November 1997.
   7  */
   8
   9 .text
  10 #include <linux/threads.h>
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13 #include <asm/segment.h>
  14 #include <asm/page_types.h>
  15 #include <asm/pgtable_types.h>
  16 #include <asm/cache.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/setup.h>
  20 #include <asm/processor-flags.h>
  21 #include <asm/msr-index.h>
  22 #include <asm/cpufeature.h>
  23 #include <asm/percpu.h>
  24
  25 /* Physical address */
  26 #define pa(X) ((X) - __PAGE_OFFSET)
  27
  28 /*
  29  * References to members of the new_cpu_data structure.
  30  */
  31
  32 #define X86             new_cpu_data+CPUINFO_x86
  33 #define X86_VENDOR      new_cpu_data+CPUINFO_x86_vendor
  34 #define X86_MODEL       new_cpu_data+CPUINFO_x86_model
  35 #define X86_MASK        new_cpu_data+CPUINFO_x86_mask
  36 #define X86_HARD_MATH   new_cpu_data+CPUINFO_hard_math
  37 #define X86_CPUID       new_cpu_data+CPUINFO_cpuid_level
  38 #define X86_CAPABILITY  new_cpu_data+CPUINFO_x86_capability
  39 #define X86_VENDOR_ID   new_cpu_data+CPUINFO_x86_vendor_id
  40
  41 /*
  42  * This is how much memory in addition to the memory covered up to
  43  * and including _end we need mapped initially.
  44  * We need:
  45  *     (KERNEL_IMAGE_SIZE/4096) / 1024 pages (worst case, non PAE)
  46  *     (KERNEL_IMAGE_SIZE/4096) / 512 + 4 pages (worst case for PAE)
  47  *
  48  * Modulo rounding, each megabyte assigned here requires a kilobyte of
  49  * memory, which is currently unreclaimed.
  50  *
  51  * This should be a multiple of a page.
  52  *
  53  * KERNEL_IMAGE_SIZE should be greater than pa(_end)
  54  * and small than max_low_pfn, otherwise will waste some page table entries
  55  */
  56
  57 #if PTRS_PER_PMD > 1
  58 #define PAGE_TABLE_SIZE(pages) (((pages) / PTRS_PER_PMD) + PTRS_PER_PGD)
  59 #else
  60 #define PAGE_TABLE_SIZE(pages) ((pages) / PTRS_PER_PGD)
  61 #endif
  62
  63 /* Enough space to fit pagetables for the low memory linear map */
  64 MAPPING_BEYOND_END = \
  65         PAGE_TABLE_SIZE(((1<<32) - __PAGE_OFFSET) >> PAGE_SHIFT) << PAGE_SHIFT
  66
  67 /*
  68  * Worst-case size of the kernel mapping we need to make:
  69  * the worst-case size of the kernel itself, plus the extra we need
  70  * to map for the linear map.
  71  */
  72 KERNEL_PAGES = (KERNEL_IMAGE_SIZE + MAPPING_BEYOND_END)>>PAGE_SHIFT
  73
  74 INIT_MAP_SIZE = PAGE_TABLE_SIZE(KERNEL_PAGES) * PAGE_SIZE_asm
  75 RESERVE_BRK(pagetables, INIT_MAP_SIZE)
  76
  77 /*
  78  * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
  79  * %esi points to the real-mode code as a 32-bit pointer.
  80  * CS and DS must be 4 GB flat segments, but we don't depend on
  81  * any particular GDT layout, because we load our own as soon as we
  82  * can.
  83  */
  84 __HEAD
  85 ENTRY(startup_32)
  86         /* test KEEP_SEGMENTS flag to see if the bootloader is asking
  87                 us to not reload segments */
  88         testb $(1<<6), BP_loadflags(%esi)
  89         jnz 2f
  90
  91 /*
  92  * Set segments to known values.
  93  */
  94         lgdt pa(boot_gdt_descr)
  95         movl $(__BOOT_DS),%eax
  96         movl %eax,%ds
  97         movl %eax,%es
  98         movl %eax,%fs
  99         movl %eax,%gs
 100 2:
 101
 102 /*
 103  * Clear BSS first so that there are no surprises...
 104  */
 105         cld
 106         xorl %eax,%eax
 107         movl $pa(__bss_start),%edi
 108         movl $pa(__bss_stop),%ecx
 109         subl %edi,%ecx
 110         shrl $2,%ecx
 111         rep ; stosl
 112 /*
 113  * Copy bootup parameters out of the way.
 114  * Note: %esi still has the pointer to the real-mode data.
 115  * With the kexec as boot loader, parameter segment might be loaded beyond
 116  * kernel image and might not even be addressable by early boot page tables.
 117  * (kexec on panic case). Hence copy out the parameters before initializing
 118  * page tables.
 119  */
 120         movl $pa(boot_params),%edi
 121         movl $(PARAM_SIZE/4),%ecx
 122         cld
 123         rep
 124         movsl
 125         movl pa(boot_params) + NEW_CL_POINTER,%esi
 126         andl %esi,%esi
 127         jz 1f                   # No comand line
 128         movl $pa(boot_command_line),%edi
 129         movl $(COMMAND_LINE_SIZE/4),%ecx
 130         rep
 131         movsl
 132 1:
 133
 134 #ifdef CONFIG_OLPC_OPENFIRMWARE
 135         /* save OFW's pgdir table for later use when calling into OFW */
 136         movl %cr3, %eax
 137         movl %eax, pa(olpc_ofw_pgd)
 138 #endif
 139
 140 #ifdef CONFIG_PARAVIRT
 141         /* This is can only trip for a broken bootloader... */
 142         cmpw $0x207, pa(boot_params + BP_version)
 143         jb default_entry
 144
 145         /* Paravirt-compatible boot parameters.  Look to see what architecture
 146                 we're booting under. */
 147         movl pa(boot_params + BP_hardware_subarch), %eax
 148         cmpl $num_subarch_entries, %eax
 149         jae bad_subarch
 150
 151         movl pa(subarch_entries)(,%eax,4), %eax
 152         subl $__PAGE_OFFSET, %eax
 153         jmp *%eax
 154
 155 bad_subarch:
 156 WEAK(lguest_entry)
 157 WEAK(xen_entry)
 158         /* Unknown implementation; there's really
 159            nothing we can do at this point. */
 160         ud2a
 161
 162         __INITDATA
 163
 164 subarch_entries:
 165         .long default_entry             /* normal x86/PC */
 166         .long lguest_entry              /* lguest hypervisor */
 167         .long xen_entry                 /* Xen hypervisor */
 168         .long default_entry             /* Moorestown MID */
 169 num_subarch_entries = (. - subarch_entries) / 4
 170 .previous
 171 #endif /* CONFIG_PARAVIRT */
 172
 173 /*
 174  * Initialize page tables.  This creates a PDE and a set of page
 175  * tables, which are located immediately beyond __brk_base.  The variable
 176  * _brk_end is set up to point to the first "safe" location.
 177  * Mappings are created both at virtual address 0 (identity mapping)
 178  * and PAGE_OFFSET for up to _end.
 179  *
 180  * Note that the stack is not yet set up!
 181  */
 182 default_entry:
 183 #ifdef CONFIG_X86_PAE
 184
 185         /*
 186          * In PAE mode initial_page_table is statically defined to contain
 187          * enough entries to cover the VMSPLIT option (that is the top 1, 2 or 3
 188          * entries). The identity mapping is handled by pointing two PGD entries
 189          * to the first kernel PMD.
 190          *
 191          * Note the upper half of each PMD or PTE are always zero at this stage.
 192          */
 193
 194 #define KPMDS (((-__PAGE_OFFSET) >> 30) & 3) /* Number of kernel PMDs */
 195
 196         xorl %ebx,%ebx                          /* %ebx is kept at zero */
 197
 198         movl $pa(__brk_base), %edi
 199         movl $pa(initial_pg_pmd), %edx
 200         movl $PTE_IDENT_ATTR, %eax
 201 10:
 202         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PMD entry */
 203         movl %ecx,(%edx)                        /* Store PMD entry */
 204                                                 /* Upper half already zero */
 205         addl $8,%edx
 206         movl $512,%ecx
 207 11:
 208         stosl
 209         xchgl %eax,%ebx
 210         stosl
 211         xchgl %eax,%ebx
 212         addl $0x1000,%eax
 213         loop 11b
 214
 215         /*
 216          * End condition: we must map up to the end + MAPPING_BEYOND_END.
 217          */
 218         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
 219         cmpl %ebp,%eax
 220         jb 10b
 221 1:
 222         addl $__PAGE_OFFSET, %edi
 223         movl %edi, pa(_brk_end)
 224         shrl $12, %eax
 225         movl %eax, pa(max_pfn_mapped)
 226
 227         /* Do early initialization of the fixmap area */
 228         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
 229         movl %eax,pa(initial_pg_pmd+0x1000*KPMDS-8)
 230 #else   /* Not PAE */
 231
 232 page_pde_offset = (__PAGE_OFFSET >> 20);
 233
 234         movl $pa(__brk_base), %edi
 235         movl $pa(initial_page_table), %edx
 236         movl $PTE_IDENT_ATTR, %eax
 237 10:
 238         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PDE entry */
 239         movl %ecx,(%edx)                        /* Store identity PDE entry */
 240         movl %ecx,page_pde_offset(%edx)         /* Store kernel PDE entry */
 241         addl $4,%edx
 242         movl $1024, %ecx
 243 11:
 244         stosl
 245         addl $0x1000,%eax
 246         loop 11b
 247         /*
 248          * End condition: we must map up to the end + MAPPING_BEYOND_END.
 249          */
 250         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
 251         cmpl %ebp,%eax
 252         jb 10b
 253         addl $__PAGE_OFFSET, %edi
 254         movl %edi, pa(_brk_end)
 255         shrl $12, %eax
 256         movl %eax, pa(max_pfn_mapped)
 257
 258         /* Do early initialization of the fixmap area */
 259         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
 260         movl %eax,pa(initial_page_table+0xffc)
 261 #endif
 262         jmp 3f
 263 /*
 264  * Non-boot CPU entry point; entered from trampoline.S
 265  * We can't lgdt here, because lgdt itself uses a data segment, but
 266  * we know the trampoline has already loaded the boot_gdt for us.
 267  *
 268  * If cpu hotplug is not supported then this code can go in init section
 269  * which will be freed later
 270  */
 271
 272 __CPUINIT
 273
 274 #ifdef CONFIG_SMP
 275 ENTRY(startup_32_smp)
 276         cld
 277         movl $(__BOOT_DS),%eax
 278         movl %eax,%ds
 279         movl %eax,%es
 280         movl %eax,%fs
 281         movl %eax,%gs
 282 #endif /* CONFIG_SMP */
 283 3:
 284
 285 /*
 286  *      New page tables may be in 4Mbyte page mode and may
 287  *      be using the global pages.
 288  *
 289  *      NOTE! If we are on a 486 we may have no cr4 at all!
 290  *      So we do not try to touch it unless we really have
 291  *      some bits in it to set.  This won't work if the BSP
 292  *      implements cr4 but this AP does not -- very unlikely
 293  *      but be warned!  The same applies to the pse feature
 294  *      if not equally supported. --macro
 295  *
 296  *      NOTE! We have to correct for the fact that we're
 297  *      not yet offset PAGE_OFFSET..
 298  */
 299 #define cr4_bits pa(mmu_cr4_features)
 300         movl cr4_bits,%edx
 301         andl %edx,%edx
 302         jz 6f
 303         movl %cr4,%eax          # Turn on paging options (PSE,PAE,..)
 304         orl %edx,%eax
 305         movl %eax,%cr4
 306
 307         testb $X86_CR4_PAE, %al         # check if PAE is enabled
 308         jz 6f
 309
 310         /* Check if extended functions are implemented */
 311         movl $0x80000000, %eax
 312         cpuid
 313         /* Value must be in the range 0x80000001 to 0x8000ffff */
 314         subl $0x80000001, %eax
 315         cmpl $(0x8000ffff-0x80000001), %eax
 316         ja 6f
 317
 318         /* Clear bogus XD_DISABLE bits */
 319         call verify_cpu
 320
 321         mov $0x80000001, %eax
 322         cpuid
 323         /* Execute Disable bit supported? */
 324         btl $(X86_FEATURE_NX & 31), %edx
 325         jnc 6f
 326
 327         /* Setup EFER (Extended Feature Enable Register) */
 328         movl $MSR_EFER, %ecx
 329         rdmsr
 330
 331         btsl $_EFER_NX, %eax
 332         /* Make changes effective */
 333         wrmsr
 334
 335 6:
 336
 337 /*
 338  * Enable paging
 339  */
 340         movl $pa(initial_page_table), %eax
 341         movl %eax,%cr3          /* set the page table pointer.. */
 342         movl %cr0,%eax
 343         orl  $X86_CR0_PG,%eax
 344         movl %eax,%cr0          /* ..and set paging (PG) bit */
 345         ljmp $__BOOT_CS,$1f     /* Clear prefetch and normalize %eip */
 346 1:
 347         /* Set up the stack pointer */
 348         lss stack_start,%esp
 349
 350 /*
 351  * Initialize eflags.  Some BIOS's leave bits like NT set.  This would
 352  * confuse the debugger if this code is traced.
 353  * XXX - best to initialize before switching to protected mode.
 354  */
 355         pushl $0
 356         popfl
 357
 358 #ifdef CONFIG_SMP
 359         cmpb $0, ready
 360         jz  1f                          /* Initial CPU cleans BSS */
 361         jmp checkCPUtype
 362 1:
 363 #endif /* CONFIG_SMP */
 364
 365 /*
 366  * start system 32-bit setup. We need to re-do some of the things done
 367  * in 16-bit mode for the "real" operations.
 368  */
 369         call setup_idt
 370
 371 checkCPUtype:
 372
 373         movl $-1,X86_CPUID              #  -1 for no CPUID initially
 374
 375 /* check if it is 486 or 386. */
 376 /*
 377  * XXX - this does a lot of unnecessary setup.  Alignment checks don't
 378  * apply at our cpl of 0 and the stack ought to be aligned already, and
 379  * we don't need to preserve eflags.
 380  */
 381
 382         movb $3,X86             # at least 386
 383         pushfl                  # push EFLAGS
 384         popl %eax               # get EFLAGS
 385         movl %eax,%ecx          # save original EFLAGS
 386         xorl $0x240000,%eax     # flip AC and ID bits in EFLAGS
 387         pushl %eax              # copy to EFLAGS
 388         popfl                   # set EFLAGS
 389         pushfl                  # get new EFLAGS
 390         popl %eax               # put it in eax
 391         xorl %ecx,%eax          # change in flags
 392         pushl %ecx              # restore original EFLAGS
 393         popfl
 394         testl $0x40000,%eax     # check if AC bit changed
 395         je is386
 396
 397         movb $4,X86             # at least 486
 398         testl $0x200000,%eax    # check if ID bit changed
 399         je is486
 400
 401         /* get vendor info */
 402         xorl %eax,%eax                  # call CPUID with 0 -> return vendor ID
 403         cpuid
 404         movl %eax,X86_CPUID             # save CPUID level
 405         movl %ebx,X86_VENDOR_ID         # lo 4 chars
 406         movl %edx,X86_VENDOR_ID+4       # next 4 chars
 407         movl %ecx,X86_VENDOR_ID+8       # last 4 chars
 408
 409         orl %eax,%eax                   # do we have processor info as well?
 410         je is486
 411
 412         movl $1,%eax            # Use the CPUID instruction to get CPU type
 413         cpuid
 414         movb %al,%cl            # save reg for future use
 415         andb $0x0f,%ah          # mask processor family
 416         movb %ah,X86
 417         andb $0xf0,%al          # mask model
 418         shrb $4,%al
 419         movb %al,X86_MODEL
 420         andb $0x0f,%cl          # mask mask revision
 421         movb %cl,X86_MASK
 422         movl %edx,X86_CAPABILITY
 423
 424 is486:  movl $0x50022,%ecx      # set AM, WP, NE and MP
 425         jmp 2f
 426
 427 is386:  movl $2,%ecx            # set MP
 428 2:      movl %cr0,%eax
 429         andl $0x80000011,%eax   # Save PG,PE,ET
 430         orl %ecx,%eax
 431         movl %eax,%cr0
 432
 433         call check_x87
 434         lgdt early_gdt_descr
 435         lidt idt_descr
 436         ljmp $(__KERNEL_CS),$1f
 437 1:      movl $(__KERNEL_DS),%eax        # reload all the segment registers
 438         movl %eax,%ss                   # after changing gdt.
 439
 440         movl $(__USER_DS),%eax          # DS/ES contains default USER segment
 441         movl %eax,%ds
 442         movl %eax,%es
 443
 444         movl $(__KERNEL_PERCPU), %eax
 445         movl %eax,%fs                   # set this cpu's percpu
 446
 447 #ifdef CONFIG_CC_STACKPROTECTOR
 448         /*
 449          * The linker can't handle this by relocation.  Manually set
 450          * base address in stack canary segment descriptor.
 451          */
 452         cmpb $0,ready
 453         jne 1f
 454         movl $gdt_page,%eax
 455         movl $stack_canary,%ecx
 456         movw %cx, 8 * GDT_ENTRY_STACK_CANARY + 2(%eax)
 457         shrl $16, %ecx
 458         movb %cl, 8 * GDT_ENTRY_STACK_CANARY + 4(%eax)
 459         movb %ch, 8 * GDT_ENTRY_STACK_CANARY + 7(%eax)
 460 1:
 461 #endif
 462         movl $(__KERNEL_STACK_CANARY),%eax
 463         movl %eax,%gs
 464
 465         xorl %eax,%eax                  # Clear LDT
 466         lldt %ax
 467
 468         cld                     # gcc2 wants the direction flag cleared at all times
 469         pushl $0                # fake return address for unwinder
 470 #ifdef CONFIG_SMP
 471         movb ready, %cl
 472         movb $1, ready
 473         cmpb $0,%cl             # the first CPU calls start_kernel
 474         je   1f
 475         movl (stack_start), %esp
 476 1:
 477 #endif /* CONFIG_SMP */
 478         jmp *(initial_code)
 479
 480 /*
 481  * We depend on ET to be correct. This checks for 287/387.
 482  */
 483 check_x87:
 484         movb $0,X86_HARD_MATH
 485         clts
 486         fninit
 487         fstsw %ax
 488         cmpb $0,%al
 489         je 1f
 490         movl %cr0,%eax          /* no coprocessor: have to set bits */
 491         xorl $4,%eax            /* set EM */
 492         movl %eax,%cr0
 493         ret
 494         ALIGN
 495 1:      movb $1,X86_HARD_MATH
 496         .byte 0xDB,0xE4         /* fsetpm for 287, ignored by 387 */
 497         ret
 498
 499 /*
 500  *  setup_idt
 501  *
 502  *  sets up a idt with 256 entries pointing to
 503  *  ignore_int, interrupt gates. It doesn't actually load
 504  *  idt - that can be done only after paging has been enabled
 505  *  and the kernel moved to PAGE_OFFSET. Interrupts
 506  *  are enabled elsewhere, when we can be relatively
 507  *  sure everything is ok.
 508  *
 509  *  Warning: %esi is live across this function.
 510  */
 511 setup_idt:
 512         lea ignore_int,%edx
 513         movl $(__KERNEL_CS << 16),%eax
 514         movw %dx,%ax            /* selector = 0x0010 = cs */
 515         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
 516
 517         lea idt_table,%edi
 518         mov $256,%ecx
 519 rp_sidt:
 520         movl %eax,(%edi)
 521         movl %edx,4(%edi)
 522         addl $8,%edi
 523         dec %ecx
 524         jne rp_sidt
 525
 526 .macro  set_early_handler handler,trapno
 527         lea \handler,%edx
 528         movl $(__KERNEL_CS << 16),%eax
 529         movw %dx,%ax
 530         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
 531         lea idt_table,%edi
 532         movl %eax,8*\trapno(%edi)
 533         movl %edx,8*\trapno+4(%edi)
 534 .endm
 535
 536         set_early_handler handler=early_divide_err,trapno=0
 537         set_early_handler handler=early_illegal_opcode,trapno=6
 538         set_early_handler handler=early_protection_fault,trapno=13
 539         set_early_handler handler=early_page_fault,trapno=14
 540
 541         ret
 542
 543 early_divide_err:
 544         xor %edx,%edx
 545         pushl $0        /* fake errcode */
 546         jmp early_fault
 547
 548 early_illegal_opcode:
 549         movl $6,%edx
 550         pushl $0        /* fake errcode */
 551         jmp early_fault
 552
 553 early_protection_fault:
 554         movl $13,%edx
 555         jmp early_fault
 556
 557 early_page_fault:
 558         movl $14,%edx
 559         jmp early_fault
 560
 561 early_fault:
 562         cld
 563 #ifdef CONFIG_PRINTK
 564         pusha
 565         movl $(__KERNEL_DS),%eax
 566         movl %eax,%ds
 567         movl %eax,%es
 568         cmpl $2,early_recursion_flag
 569         je hlt_loop
 570         incl early_recursion_flag
 571         movl %cr2,%eax
 572         pushl %eax
 573         pushl %edx              /* trapno */
 574         pushl $fault_msg
 575         call printk
 576 #endif
 577         call dump_stack
 578 hlt_loop:
 579         hlt
 580         jmp hlt_loop
 581
 582 /* This is the default interrupt "handler" :-) */
 583         ALIGN
 584 ignore_int:
 585         cld
 586 #ifdef CONFIG_PRINTK
 587         pushl %eax
 588         pushl %ecx
 589         pushl %edx
 590         pushl %es
 591         pushl %ds
 592         movl $(__KERNEL_DS),%eax
 593         movl %eax,%ds
 594         movl %eax,%es
 595         cmpl $2,early_recursion_flag
 596         je hlt_loop
 597         incl early_recursion_flag
 598         pushl 16(%esp)
 599         pushl 24(%esp)
 600         pushl 32(%esp)
 601         pushl 40(%esp)
 602         pushl $int_msg
 603         call printk
 604
 605         call dump_stack
 606
 607         addl $(5*4),%esp
 608         popl %ds
 609         popl %es
 610         popl %edx
 611         popl %ecx
 612         popl %eax
 613 #endif
 614         iret
 615
 616 #include "verify_cpu.S"
 617
 618         __REFDATA
 619 .align 4
 620 ENTRY(initial_code)
 621         .long i386_start_kernel
 622
 623 /*
 624  * BSS section
 625  */
 626 __PAGE_ALIGNED_BSS
 627         .align PAGE_SIZE_asm
 628 #ifdef CONFIG_X86_PAE
 629 initial_pg_pmd:
 630         .fill 1024*KPMDS,4,0
 631 #else
 632 ENTRY(initial_page_table)
 633         .fill 1024,4,0
 634 #endif
 635 initial_pg_fixmap:
 636         .fill 1024,4,0
 637 ENTRY(empty_zero_page)
 638         .fill 4096,1,0
 639 ENTRY(swapper_pg_dir)
 640         .fill 1024,4,0
 641
 642 /*
 643  * This starts the data section.
 644  */
 645 #ifdef CONFIG_X86_PAE
 646 __PAGE_ALIGNED_DATA
 647         /* Page-aligned for the benefit of paravirt? */
 648         .align PAGE_SIZE_asm
 649 ENTRY(initial_page_table)
 650         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0     /* low identity map */
 651 # if KPMDS == 3
 652         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 653         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
 654         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x2000),0
 655 # elif KPMDS == 2
 656         .long   0,0
 657         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 658         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
 659 # elif KPMDS == 1
 660         .long   0,0
 661         .long   0,0
 662         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 663 # else
 664 #  error "Kernel PMDs should be 1, 2 or 3"
 665 # endif
 666         .align PAGE_SIZE_asm            /* needs to be page-sized too */
 667 #endif
 668
 669 .data
 670 ENTRY(stack_start)
 671         .long init_thread_union+THREAD_SIZE
 672         .long __BOOT_DS
 673
 674 ready:  .byte 0
 675
 676 early_recursion_flag:
 677         .long 0
 678
 679 int_msg:
 680         .asciz "Unknown interrupt or fault at: %p %p %p\n"
 681
 682 fault_msg:
 683 /* fault info: */
 684         .ascii "BUG: Int %d: CR2 %p\n"
 685 /* pusha regs: */
 686         .ascii "     EDI %p  ESI %p  EBP %p  ESP %p\n"
 687         .ascii "     EBX %p  EDX %p  ECX %p  EAX %p\n"
 688 /* fault frame: */
 689         .ascii "     err %p  EIP %p   CS %p  flg %p\n"
 690         .ascii "Stack: %p %p %p %p %p %p %p %p\n"
 691         .ascii "       %p %p %p %p %p %p %p %p\n"
 692         .asciz "       %p %p %p %p %p %p %p %p\n"
 693
 694 #include "../../x86/xen/xen-head.S"
 695
 696 /*
 697  * The IDT and GDT 'descriptors' are a strange 48-bit object
 698  * only used by the lidt and lgdt instructions. They are not
 699  * like usual segment descriptors - they consist of a 16-bit
 700  * segment size, and 32-bit linear address value:
 701  */
 702
 703 .globl boot_gdt_descr
 704 .globl idt_descr
 705
 706         ALIGN
 707 # early boot GDT descriptor (must use 1:1 address mapping)
 708         .word 0                         # 32 bit align gdt_desc.address
 709 boot_gdt_descr:
 710         .word __BOOT_DS+7
 711         .long boot_gdt - __PAGE_OFFSET
 712
 713         .word 0                         # 32-bit align idt_desc.address
 714 idt_descr:
 715         .word IDT_ENTRIES*8-1           # idt contains 256 entries
 716         .long idt_table
 717
 718 # boot GDT descriptor (later on used by CPU#0):
 719         .word 0                         # 32 bit align gdt_desc.address
 720 ENTRY(early_gdt_descr)
 721         .word GDT_ENTRIES*8-1
 722         .long gdt_page                  /* Overwritten for secondary CPUs */
 723
 724 /*
 725  * The boot_gdt must mirror the equivalent in setup.S and is
 726  * used only for booting.
 727  */
 728         .align L1_CACHE_BYTES
 729 ENTRY(boot_gdt)
 730         .fill GDT_ENTRY_BOOT_CS,8,0
 731         .quad 0x00cf9a000000ffff        /* kernel 4GB code at 0x00000000 */
 732         .quad 0x00cf92000000ffff        /* kernel 4GB data at 0x00000000 */