arch/x86/kernel/head_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  *
   5  *  Enhanced CPU detection and feature setting code by Mike Jagdis
   6  *  and Martin Mares, November 1997.
   7  */
   8
   9 .text
  10 #include <linux/threads.h>
  11 #include <linux/init.h>
  12 #include <linux/linkage.h>
  13 #include <asm/segment.h>
  14 #include <asm/page_types.h>
  15 #include <asm/pgtable_types.h>
  16 #include <asm/cache.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/asm-offsets.h>
  19 #include <asm/setup.h>
  20 #include <asm/processor-flags.h>
  21 #include <asm/msr-index.h>
  22 #include <asm/cpufeature.h>
  23 #include <asm/percpu.h>
  24
  25 /* Physical address */
  26 #define pa(X) ((X) - __PAGE_OFFSET)
  27
  28 /*
  29  * References to members of the new_cpu_data structure.
  30  */
  31
  32 #define X86             new_cpu_data+CPUINFO_x86
  33 #define X86_VENDOR      new_cpu_data+CPUINFO_x86_vendor
  34 #define X86_MODEL       new_cpu_data+CPUINFO_x86_model
  35 #define X86_MASK        new_cpu_data+CPUINFO_x86_mask
  36 #define X86_HARD_MATH   new_cpu_data+CPUINFO_hard_math
  37 #define X86_CPUID       new_cpu_data+CPUINFO_cpuid_level
  38 #define X86_CAPABILITY  new_cpu_data+CPUINFO_x86_capability
  39 #define X86_VENDOR_ID   new_cpu_data+CPUINFO_x86_vendor_id
  40
  41 /*
  42  * This is how much memory in addition to the memory covered up to
  43  * and including _end we need mapped initially.
  44  * We need:
  45  *     (KERNEL_IMAGE_SIZE/4096) / 1024 pages (worst case, non PAE)
  46  *     (KERNEL_IMAGE_SIZE/4096) / 512 + 4 pages (worst case for PAE)
  47  *
  48  * Modulo rounding, each megabyte assigned here requires a kilobyte of
  49  * memory, which is currently unreclaimed.
  50  *
  51  * This should be a multiple of a page.
  52  *
  53  * KERNEL_IMAGE_SIZE should be greater than pa(_end)
  54  * and small than max_low_pfn, otherwise will waste some page table entries
  55  */
  56
  57 #if PTRS_PER_PMD > 1
  58 #define PAGE_TABLE_SIZE(pages) (((pages) / PTRS_PER_PMD) + PTRS_PER_PGD)
  59 #else
  60 #define PAGE_TABLE_SIZE(pages) ((pages) / PTRS_PER_PGD)
  61 #endif
  62
  63 /* Number of possible pages in the lowmem region */
  64 LOWMEM_PAGES = (((1<<32) - __PAGE_OFFSET) >> PAGE_SHIFT)
  65
  66 /* Enough space to fit pagetables for the low memory linear map */
  67 MAPPING_BEYOND_END = PAGE_TABLE_SIZE(LOWMEM_PAGES) << PAGE_SHIFT
  68
  69 /*
  70  * Worst-case size of the kernel mapping we need to make:
  71  * a relocatable kernel can live anywhere in lowmem, so we need to be able
  72  * to map all of lowmem.
  73  */
  74 KERNEL_PAGES = LOWMEM_PAGES
  75
  76 INIT_MAP_SIZE = PAGE_TABLE_SIZE(KERNEL_PAGES) * PAGE_SIZE_asm
  77 RESERVE_BRK(pagetables, INIT_MAP_SIZE)
  78
  79 /*
  80  * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
  81  * %esi points to the real-mode code as a 32-bit pointer.
  82  * CS and DS must be 4 GB flat segments, but we don't depend on
  83  * any particular GDT layout, because we load our own as soon as we
  84  * can.
  85  */
  86 __HEAD
  87 ENTRY(startup_32)
  88         /* test KEEP_SEGMENTS flag to see if the bootloader is asking
  89                 us to not reload segments */
  90         testb $(1<<6), BP_loadflags(%esi)
  91         jnz 2f
  92
  93 /*
  94  * Set segments to known values.
  95  */
  96         lgdt pa(boot_gdt_descr)
  97         movl $(__BOOT_DS),%eax
  98         movl %eax,%ds
  99         movl %eax,%es
 100         movl %eax,%fs
 101         movl %eax,%gs
 102 2:
 103
 104 /*
 105  * Clear BSS first so that there are no surprises...
 106  */
 107         cld
 108         xorl %eax,%eax
 109         movl $pa(__bss_start),%edi
 110         movl $pa(__bss_stop),%ecx
 111         subl %edi,%ecx
 112         shrl $2,%ecx
 113         rep ; stosl
 114 /*
 115  * Copy bootup parameters out of the way.
 116  * Note: %esi still has the pointer to the real-mode data.
 117  * With the kexec as boot loader, parameter segment might be loaded beyond
 118  * kernel image and might not even be addressable by early boot page tables.
 119  * (kexec on panic case). Hence copy out the parameters before initializing
 120  * page tables.
 121  */
 122         movl $pa(boot_params),%edi
 123         movl $(PARAM_SIZE/4),%ecx
 124         cld
 125         rep
 126         movsl
 127         movl pa(boot_params) + NEW_CL_POINTER,%esi
 128         andl %esi,%esi
 129         jz 1f                   # No comand line
 130         movl $pa(boot_command_line),%edi
 131         movl $(COMMAND_LINE_SIZE/4),%ecx
 132         rep
 133         movsl
 134 1:
 135
 136 #ifdef CONFIG_OLPC_OPENFIRMWARE
 137         /* save OFW's pgdir table for later use when calling into OFW */
 138         movl %cr3, %eax
 139         movl %eax, pa(olpc_ofw_pgd)
 140 #endif
 141
 142 #ifdef CONFIG_PARAVIRT
 143         /* This is can only trip for a broken bootloader... */
 144         cmpw $0x207, pa(boot_params + BP_version)
 145         jb default_entry
 146
 147         /* Paravirt-compatible boot parameters.  Look to see what architecture
 148                 we're booting under. */
 149         movl pa(boot_params + BP_hardware_subarch), %eax
 150         cmpl $num_subarch_entries, %eax
 151         jae bad_subarch
 152
 153         movl pa(subarch_entries)(,%eax,4), %eax
 154         subl $__PAGE_OFFSET, %eax
 155         jmp *%eax
 156
 157 bad_subarch:
 158 WEAK(lguest_entry)
 159 WEAK(xen_entry)
 160         /* Unknown implementation; there's really
 161            nothing we can do at this point. */
 162         ud2a
 163
 164         __INITDATA
 165
 166 subarch_entries:
 167         .long default_entry             /* normal x86/PC */
 168         .long lguest_entry              /* lguest hypervisor */
 169         .long xen_entry                 /* Xen hypervisor */
 170         .long default_entry             /* Moorestown MID */
 171 num_subarch_entries = (. - subarch_entries) / 4
 172 .previous
 173 #endif /* CONFIG_PARAVIRT */
 174
 175 /*
 176  * Initialize page tables.  This creates a PDE and a set of page
 177  * tables, which are located immediately beyond __brk_base.  The variable
 178  * _brk_end is set up to point to the first "safe" location.
 179  * Mappings are created both at virtual address 0 (identity mapping)
 180  * and PAGE_OFFSET for up to _end.
 181  *
 182  * Note that the stack is not yet set up!
 183  */
 184 default_entry:
 185 #ifdef CONFIG_X86_PAE
 186
 187         /*
 188          * In PAE mode initial_page_table is statically defined to contain
 189          * enough entries to cover the VMSPLIT option (that is the top 1, 2 or 3
 190          * entries). The identity mapping is handled by pointing two PGD entries
 191          * to the first kernel PMD.
 192          *
 193          * Note the upper half of each PMD or PTE are always zero at this stage.
 194          */
 195
 196 #define KPMDS (((-__PAGE_OFFSET) >> 30) & 3) /* Number of kernel PMDs */
 197
 198         xorl %ebx,%ebx                          /* %ebx is kept at zero */
 199
 200         movl $pa(__brk_base), %edi
 201         movl $pa(initial_pg_pmd), %edx
 202         movl $PTE_IDENT_ATTR, %eax
 203 10:
 204         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PMD entry */
 205         movl %ecx,(%edx)                        /* Store PMD entry */
 206                                                 /* Upper half already zero */
 207         addl $8,%edx
 208         movl $512,%ecx
 209 11:
 210         stosl
 211         xchgl %eax,%ebx
 212         stosl
 213         xchgl %eax,%ebx
 214         addl $0x1000,%eax
 215         loop 11b
 216
 217         /*
 218          * End condition: we must map up to the end + MAPPING_BEYOND_END.
 219          */
 220         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
 221         cmpl %ebp,%eax
 222         jb 10b
 223 1:
 224         addl $__PAGE_OFFSET, %edi
 225         movl %edi, pa(_brk_end)
 226         shrl $12, %eax
 227         movl %eax, pa(max_pfn_mapped)
 228
 229         /* Do early initialization of the fixmap area */
 230         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
 231         movl %eax,pa(initial_pg_pmd+0x1000*KPMDS-8)
 232 #else   /* Not PAE */
 233
 234 page_pde_offset = (__PAGE_OFFSET >> 20);
 235
 236         movl $pa(__brk_base), %edi
 237         movl $pa(initial_page_table), %edx
 238         movl $PTE_IDENT_ATTR, %eax
 239 10:
 240         leal PDE_IDENT_ATTR(%edi),%ecx          /* Create PDE entry */
 241         movl %ecx,(%edx)                        /* Store identity PDE entry */
 242         movl %ecx,page_pde_offset(%edx)         /* Store kernel PDE entry */
 243         addl $4,%edx
 244         movl $1024, %ecx
 245 11:
 246         stosl
 247         addl $0x1000,%eax
 248         loop 11b
 249         /*
 250          * End condition: we must map up to the end + MAPPING_BEYOND_END.
 251          */
 252         movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
 253         cmpl %ebp,%eax
 254         jb 10b
 255         addl $__PAGE_OFFSET, %edi
 256         movl %edi, pa(_brk_end)
 257         shrl $12, %eax
 258         movl %eax, pa(max_pfn_mapped)
 259
 260         /* Do early initialization of the fixmap area */
 261         movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
 262         movl %eax,pa(initial_page_table+0xffc)
 263 #endif
 264         jmp 3f
 265 /*
 266  * Non-boot CPU entry point; entered from trampoline.S
 267  * We can't lgdt here, because lgdt itself uses a data segment, but
 268  * we know the trampoline has already loaded the boot_gdt for us.
 269  *
 270  * If cpu hotplug is not supported then this code can go in init section
 271  * which will be freed later
 272  */
 273
 274 __CPUINIT
 275
 276 #ifdef CONFIG_SMP
 277 ENTRY(startup_32_smp)
 278         cld
 279         movl $(__BOOT_DS),%eax
 280         movl %eax,%ds
 281         movl %eax,%es
 282         movl %eax,%fs
 283         movl %eax,%gs
 284 #endif /* CONFIG_SMP */
 285 3:
 286
 287 /*
 288  *      New page tables may be in 4Mbyte page mode and may
 289  *      be using the global pages.
 290  *
 291  *      NOTE! If we are on a 486 we may have no cr4 at all!
 292  *      So we do not try to touch it unless we really have
 293  *      some bits in it to set.  This won't work if the BSP
 294  *      implements cr4 but this AP does not -- very unlikely
 295  *      but be warned!  The same applies to the pse feature
 296  *      if not equally supported. --macro
 297  *
 298  *      NOTE! We have to correct for the fact that we're
 299  *      not yet offset PAGE_OFFSET..
 300  */
 301 #define cr4_bits pa(mmu_cr4_features)
 302         movl cr4_bits,%edx
 303         andl %edx,%edx
 304         jz 6f
 305         movl %cr4,%eax          # Turn on paging options (PSE,PAE,..)
 306         orl %edx,%eax
 307         movl %eax,%cr4
 308
 309         testb $X86_CR4_PAE, %al         # check if PAE is enabled
 310         jz 6f
 311
 312         /* Check if extended functions are implemented */
 313         movl $0x80000000, %eax
 314         cpuid
 315         /* Value must be in the range 0x80000001 to 0x8000ffff */
 316         subl $0x80000001, %eax
 317         cmpl $(0x8000ffff-0x80000001), %eax
 318         ja 6f
 319         mov $0x80000001, %eax
 320         cpuid
 321         /* Execute Disable bit supported? */
 322         btl $(X86_FEATURE_NX & 31), %edx
 323         jnc 6f
 324
 325         /* Setup EFER (Extended Feature Enable Register) */
 326         movl $MSR_EFER, %ecx
 327         rdmsr
 328
 329         btsl $_EFER_NX, %eax
 330         /* Make changes effective */
 331         wrmsr
 332
 333 6:
 334
 335 /*
 336  * Enable paging
 337  */
 338         movl $pa(initial_page_table), %eax
 339         movl %eax,%cr3          /* set the page table pointer.. */
 340         movl %cr0,%eax
 341         orl  $X86_CR0_PG,%eax
 342         movl %eax,%cr0          /* ..and set paging (PG) bit */
 343         ljmp $__BOOT_CS,$1f     /* Clear prefetch and normalize %eip */
 344 1:
 345         /* Set up the stack pointer */
 346         lss stack_start,%esp
 347
 348 /*
 349  * Initialize eflags.  Some BIOS's leave bits like NT set.  This would
 350  * confuse the debugger if this code is traced.
 351  * XXX - best to initialize before switching to protected mode.
 352  */
 353         pushl $0
 354         popfl
 355
 356 #ifdef CONFIG_SMP
 357         cmpb $0, ready
 358         jz  1f                          /* Initial CPU cleans BSS */
 359         jmp checkCPUtype
 360 1:
 361 #endif /* CONFIG_SMP */
 362
 363 /*
 364  * start system 32-bit setup. We need to re-do some of the things done
 365  * in 16-bit mode for the "real" operations.
 366  */
 367         call setup_idt
 368
 369 checkCPUtype:
 370
 371         movl $-1,X86_CPUID              #  -1 for no CPUID initially
 372
 373 /* check if it is 486 or 386. */
 374 /*
 375  * XXX - this does a lot of unnecessary setup.  Alignment checks don't
 376  * apply at our cpl of 0 and the stack ought to be aligned already, and
 377  * we don't need to preserve eflags.
 378  */
 379
 380         movb $3,X86             # at least 386
 381         pushfl                  # push EFLAGS
 382         popl %eax               # get EFLAGS
 383         movl %eax,%ecx          # save original EFLAGS
 384         xorl $0x240000,%eax     # flip AC and ID bits in EFLAGS
 385         pushl %eax              # copy to EFLAGS
 386         popfl                   # set EFLAGS
 387         pushfl                  # get new EFLAGS
 388         popl %eax               # put it in eax
 389         xorl %ecx,%eax          # change in flags
 390         pushl %ecx              # restore original EFLAGS
 391         popfl
 392         testl $0x40000,%eax     # check if AC bit changed
 393         je is386
 394
 395         movb $4,X86             # at least 486
 396         testl $0x200000,%eax    # check if ID bit changed
 397         je is486
 398
 399         /* get vendor info */
 400         xorl %eax,%eax                  # call CPUID with 0 -> return vendor ID
 401         cpuid
 402         movl %eax,X86_CPUID             # save CPUID level
 403         movl %ebx,X86_VENDOR_ID         # lo 4 chars
 404         movl %edx,X86_VENDOR_ID+4       # next 4 chars
 405         movl %ecx,X86_VENDOR_ID+8       # last 4 chars
 406
 407         orl %eax,%eax                   # do we have processor info as well?
 408         je is486
 409
 410         movl $1,%eax            # Use the CPUID instruction to get CPU type
 411         cpuid
 412         movb %al,%cl            # save reg for future use
 413         andb $0x0f,%ah          # mask processor family
 414         movb %ah,X86
 415         andb $0xf0,%al          # mask model
 416         shrb $4,%al
 417         movb %al,X86_MODEL
 418         andb $0x0f,%cl          # mask mask revision
 419         movb %cl,X86_MASK
 420         movl %edx,X86_CAPABILITY
 421
 422 is486:  movl $0x50022,%ecx      # set AM, WP, NE and MP
 423         jmp 2f
 424
 425 is386:  movl $2,%ecx            # set MP
 426 2:      movl %cr0,%eax
 427         andl $0x80000011,%eax   # Save PG,PE,ET
 428         orl %ecx,%eax
 429         movl %eax,%cr0
 430
 431         call check_x87
 432         lgdt early_gdt_descr
 433         lidt idt_descr
 434         ljmp $(__KERNEL_CS),$1f
 435 1:      movl $(__KERNEL_DS),%eax        # reload all the segment registers
 436         movl %eax,%ss                   # after changing gdt.
 437
 438         movl $(__USER_DS),%eax          # DS/ES contains default USER segment
 439         movl %eax,%ds
 440         movl %eax,%es
 441
 442         movl $(__KERNEL_PERCPU), %eax
 443         movl %eax,%fs                   # set this cpu's percpu
 444
 445 #ifdef CONFIG_CC_STACKPROTECTOR
 446         /*
 447          * The linker can't handle this by relocation.  Manually set
 448          * base address in stack canary segment descriptor.
 449          */
 450         cmpb $0,ready
 451         jne 1f
 452         movl $gdt_page,%eax
 453         movl $stack_canary,%ecx
 454         movw %cx, 8 * GDT_ENTRY_STACK_CANARY + 2(%eax)
 455         shrl $16, %ecx
 456         movb %cl, 8 * GDT_ENTRY_STACK_CANARY + 4(%eax)
 457         movb %ch, 8 * GDT_ENTRY_STACK_CANARY + 7(%eax)
 458 1:
 459 #endif
 460         movl $(__KERNEL_STACK_CANARY),%eax
 461         movl %eax,%gs
 462
 463         xorl %eax,%eax                  # Clear LDT
 464         lldt %ax
 465
 466         cld                     # gcc2 wants the direction flag cleared at all times
 467         pushl $0                # fake return address for unwinder
 468 #ifdef CONFIG_SMP
 469         movb ready, %cl
 470         movb $1, ready
 471         cmpb $0,%cl             # the first CPU calls start_kernel
 472         je   1f
 473         movl (stack_start), %esp
 474 1:
 475 #endif /* CONFIG_SMP */
 476         jmp *(initial_code)
 477
 478 /*
 479  * We depend on ET to be correct. This checks for 287/387.
 480  */
 481 check_x87:
 482         movb $0,X86_HARD_MATH
 483         clts
 484         fninit
 485         fstsw %ax
 486         cmpb $0,%al
 487         je 1f
 488         movl %cr0,%eax          /* no coprocessor: have to set bits */
 489         xorl $4,%eax            /* set EM */
 490         movl %eax,%cr0
 491         ret
 492         ALIGN
 493 1:      movb $1,X86_HARD_MATH
 494         .byte 0xDB,0xE4         /* fsetpm for 287, ignored by 387 */
 495         ret
 496
 497 /*
 498  *  setup_idt
 499  *
 500  *  sets up a idt with 256 entries pointing to
 501  *  ignore_int, interrupt gates. It doesn't actually load
 502  *  idt - that can be done only after paging has been enabled
 503  *  and the kernel moved to PAGE_OFFSET. Interrupts
 504  *  are enabled elsewhere, when we can be relatively
 505  *  sure everything is ok.
 506  *
 507  *  Warning: %esi is live across this function.
 508  */
 509 setup_idt:
 510         lea ignore_int,%edx
 511         movl $(__KERNEL_CS << 16),%eax
 512         movw %dx,%ax            /* selector = 0x0010 = cs */
 513         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
 514
 515         lea idt_table,%edi
 516         mov $256,%ecx
 517 rp_sidt:
 518         movl %eax,(%edi)
 519         movl %edx,4(%edi)
 520         addl $8,%edi
 521         dec %ecx
 522         jne rp_sidt
 523
 524 .macro  set_early_handler handler,trapno
 525         lea \handler,%edx
 526         movl $(__KERNEL_CS << 16),%eax
 527         movw %dx,%ax
 528         movw $0x8E00,%dx        /* interrupt gate - dpl=0, present */
 529         lea idt_table,%edi
 530         movl %eax,8*\trapno(%edi)
 531         movl %edx,8*\trapno+4(%edi)
 532 .endm
 533
 534         set_early_handler handler=early_divide_err,trapno=0
 535         set_early_handler handler=early_illegal_opcode,trapno=6
 536         set_early_handler handler=early_protection_fault,trapno=13
 537         set_early_handler handler=early_page_fault,trapno=14
 538
 539         ret
 540
 541 early_divide_err:
 542         xor %edx,%edx
 543         pushl $0        /* fake errcode */
 544         jmp early_fault
 545
 546 early_illegal_opcode:
 547         movl $6,%edx
 548         pushl $0        /* fake errcode */
 549         jmp early_fault
 550
 551 early_protection_fault:
 552         movl $13,%edx
 553         jmp early_fault
 554
 555 early_page_fault:
 556         movl $14,%edx
 557         jmp early_fault
 558
 559 early_fault:
 560         cld
 561 #ifdef CONFIG_PRINTK
 562         pusha
 563         movl $(__KERNEL_DS),%eax
 564         movl %eax,%ds
 565         movl %eax,%es
 566         cmpl $2,early_recursion_flag
 567         je hlt_loop
 568         incl early_recursion_flag
 569         movl %cr2,%eax
 570         pushl %eax
 571         pushl %edx              /* trapno */
 572         pushl $fault_msg
 573         call printk
 574 #endif
 575         call dump_stack
 576 hlt_loop:
 577         hlt
 578         jmp hlt_loop
 579
 580 /* This is the default interrupt "handler" :-) */
 581         ALIGN
 582 ignore_int:
 583         cld
 584 #ifdef CONFIG_PRINTK
 585         pushl %eax
 586         pushl %ecx
 587         pushl %edx
 588         pushl %es
 589         pushl %ds
 590         movl $(__KERNEL_DS),%eax
 591         movl %eax,%ds
 592         movl %eax,%es
 593         cmpl $2,early_recursion_flag
 594         je hlt_loop
 595         incl early_recursion_flag
 596         pushl 16(%esp)
 597         pushl 24(%esp)
 598         pushl 32(%esp)
 599         pushl 40(%esp)
 600         pushl $int_msg
 601         call printk
 602
 603         call dump_stack
 604
 605         addl $(5*4),%esp
 606         popl %ds
 607         popl %es
 608         popl %edx
 609         popl %ecx
 610         popl %eax
 611 #endif
 612         iret
 613
 614         __REFDATA
 615 .align 4
 616 ENTRY(initial_code)
 617         .long i386_start_kernel
 618
 619 /*
 620  * BSS section
 621  */
 622 __PAGE_ALIGNED_BSS
 623         .align PAGE_SIZE_asm
 624 #ifdef CONFIG_X86_PAE
 625 ENTRY(initial_pg_pmd)
 626         .fill 1024*KPMDS,4,0
 627 #else
 628 ENTRY(initial_page_table)
 629         .fill 1024,4,0
 630 #endif
 631 ENTRY(initial_pg_fixmap)
 632         .fill 1024,4,0
 633 ENTRY(empty_zero_page)
 634         .fill 4096,1,0
 635 ENTRY(swapper_pg_dir)
 636         .fill 1024,4,0
 637
 638 /*
 639  * This starts the data section.
 640  */
 641 #ifdef CONFIG_X86_PAE
 642 __PAGE_ALIGNED_DATA
 643         /* Page-aligned for the benefit of paravirt? */
 644         .align PAGE_SIZE_asm
 645 ENTRY(initial_page_table)
 646         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0     /* low identity map */
 647 # if KPMDS == 3
 648         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 649         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
 650         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x2000),0
 651 # elif KPMDS == 2
 652         .long   0,0
 653         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 654         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
 655 # elif KPMDS == 1
 656         .long   0,0
 657         .long   0,0
 658         .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 659 # else
 660 #  error "Kernel PMDs should be 1, 2 or 3"
 661 # endif
 662         .align PAGE_SIZE_asm            /* needs to be page-sized too */
 663 #endif
 664
 665 .data
 666 ENTRY(stack_start)
 667         .long init_thread_union+THREAD_SIZE
 668         .long __BOOT_DS
 669
 670 ready:  .byte 0
 671
 672 early_recursion_flag:
 673         .long 0
 674
 675 int_msg:
 676         .asciz "Unknown interrupt or fault at: %p %p %p\n"
 677
 678 fault_msg:
 679 /* fault info: */
 680         .ascii "BUG: Int %d: CR2 %p\n"
 681 /* pusha regs: */
 682         .ascii "     EDI %p  ESI %p  EBP %p  ESP %p\n"
 683         .ascii "     EBX %p  EDX %p  ECX %p  EAX %p\n"
 684 /* fault frame: */
 685         .ascii "     err %p  EIP %p   CS %p  flg %p\n"
 686         .ascii "Stack: %p %p %p %p %p %p %p %p\n"
 687         .ascii "       %p %p %p %p %p %p %p %p\n"
 688         .asciz "       %p %p %p %p %p %p %p %p\n"
 689
 690 #include "../../x86/xen/xen-head.S"
 691
 692 /*
 693  * The IDT and GDT 'descriptors' are a strange 48-bit object
 694  * only used by the lidt and lgdt instructions. They are not
 695  * like usual segment descriptors - they consist of a 16-bit
 696  * segment size, and 32-bit linear address value:
 697  */
 698
 699 .globl boot_gdt_descr
 700 .globl idt_descr
 701
 702         ALIGN
 703 # early boot GDT descriptor (must use 1:1 address mapping)
 704         .word 0                         # 32 bit align gdt_desc.address
 705 boot_gdt_descr:
 706         .word __BOOT_DS+7
 707         .long boot_gdt - __PAGE_OFFSET
 708
 709         .word 0                         # 32-bit align idt_desc.address
 710 idt_descr:
 711         .word IDT_ENTRIES*8-1           # idt contains 256 entries
 712         .long idt_table
 713
 714 # boot GDT descriptor (later on used by CPU#0):
 715         .word 0                         # 32 bit align gdt_desc.address
 716 ENTRY(early_gdt_descr)
 717         .word GDT_ENTRIES*8-1
 718         .long gdt_page                  /* Overwritten for secondary CPUs */
 719
 720 /*
 721  * The boot_gdt must mirror the equivalent in setup.S and is
 722  * used only for booting.
 723  */
 724         .align L1_CACHE_BYTES
 725 ENTRY(boot_gdt)
 726         .fill GDT_ENTRY_BOOT_CS,8,0
 727         .quad 0x00cf9a000000ffff        /* kernel 4GB code at 0x00000000 */
 728         .quad 0x00cf92000000ffff        /* kernel 4GB data at 0x00000000 */