arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/asm.h>
  59 #include <asm/context_tracking.h>
  60 #include <asm/smap.h>
  61 #include <asm/pgtable_types.h>
  62 #include <linux/err.h>
  63
  64 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  65 #include <linux/elf-em.h>
  66 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  67 #define __AUDIT_ARCH_64BIT 0x80000000
  68 #define __AUDIT_ARCH_LE    0x40000000
  69
  70         .code64
  71         .section .entry.text, "ax"
  72
  73 #ifdef CONFIG_FUNCTION_TRACER
  74
  75 #ifdef CC_USING_FENTRY
  76 # define function_hook  __fentry__
  77 #else
  78 # define function_hook  mcount
  79 #endif
  80
  81 #ifdef CONFIG_DYNAMIC_FTRACE
  82
  83 ENTRY(function_hook)
  84         retq
  85 END(function_hook)
  86
  87 /* skip is set if stack has been adjusted */
  88 .macro ftrace_caller_setup skip=0
  89         MCOUNT_SAVE_FRAME \skip
  90
  91         /* Load the ftrace_ops into the 3rd parameter */
  92         movq function_trace_op(%rip), %rdx
  93
  94         /* Load ip into the first parameter */
  95         movq RIP(%rsp), %rdi
  96         subq $MCOUNT_INSN_SIZE, %rdi
  97         /* Load the parent_ip into the second parameter */
  98 #ifdef CC_USING_FENTRY
  99         movq SS+16(%rsp), %rsi
 100 #else
 101         movq 8(%rbp), %rsi
 102 #endif
 103 .endm
 104
 105 ENTRY(ftrace_caller)
 106         /* Check if tracing was disabled (quick check) */
 107         cmpl $0, function_trace_stop
 108         jne  ftrace_stub
 109
 110         ftrace_caller_setup
 111         /* regs go into 4th parameter (but make it NULL) */
 112         movq $0, %rcx
 113
 114 GLOBAL(ftrace_call)
 115         call ftrace_stub
 116
 117         MCOUNT_RESTORE_FRAME
 118 ftrace_return:
 119
 120 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 121 GLOBAL(ftrace_graph_call)
 122         jmp ftrace_stub
 123 #endif
 124
 125 GLOBAL(ftrace_stub)
 126         retq
 127 END(ftrace_caller)
 128
 129 ENTRY(ftrace_regs_caller)
 130         /* Save the current flags before compare (in SS location)*/
 131         pushfq
 132
 133         /* Check if tracing was disabled (quick check) */
 134         cmpl $0, function_trace_stop
 135         jne  ftrace_restore_flags
 136
 137         /* skip=8 to skip flags saved in SS */
 138         ftrace_caller_setup 8
 139
 140         /* Save the rest of pt_regs */
 141         movq %r15, R15(%rsp)
 142         movq %r14, R14(%rsp)
 143         movq %r13, R13(%rsp)
 144         movq %r12, R12(%rsp)
 145         movq %r11, R11(%rsp)
 146         movq %r10, R10(%rsp)
 147         movq %rbp, RBP(%rsp)
 148         movq %rbx, RBX(%rsp)
 149         /* Copy saved flags */
 150         movq SS(%rsp), %rcx
 151         movq %rcx, EFLAGS(%rsp)
 152         /* Kernel segments */
 153         movq $__KERNEL_DS, %rcx
 154         movq %rcx, SS(%rsp)
 155         movq $__KERNEL_CS, %rcx
 156         movq %rcx, CS(%rsp)
 157         /* Stack - skipping return address */
 158         leaq SS+16(%rsp), %rcx
 159         movq %rcx, RSP(%rsp)
 160
 161         /* regs go into 4th parameter */
 162         leaq (%rsp), %rcx
 163
 164 GLOBAL(ftrace_regs_call)
 165         call ftrace_stub
 166
 167         /* Copy flags back to SS, to restore them */
 168         movq EFLAGS(%rsp), %rax
 169         movq %rax, SS(%rsp)
 170
 171         /* Handlers can change the RIP */
 172         movq RIP(%rsp), %rax
 173         movq %rax, SS+8(%rsp)
 174
 175         /* restore the rest of pt_regs */
 176         movq R15(%rsp), %r15
 177         movq R14(%rsp), %r14
 178         movq R13(%rsp), %r13
 179         movq R12(%rsp), %r12
 180         movq R10(%rsp), %r10
 181         movq RBP(%rsp), %rbp
 182         movq RBX(%rsp), %rbx
 183
 184         /* skip=8 to skip flags saved in SS */
 185         MCOUNT_RESTORE_FRAME 8
 186
 187         /* Restore flags */
 188         popfq
 189
 190         jmp ftrace_return
 191 ftrace_restore_flags:
 192         popfq
 193         jmp  ftrace_stub
 194
 195 END(ftrace_regs_caller)
 196
 197
 198 #else /* ! CONFIG_DYNAMIC_FTRACE */
 199
 200 ENTRY(function_hook)
 201         cmpl $0, function_trace_stop
 202         jne  ftrace_stub
 203
 204         cmpq $ftrace_stub, ftrace_trace_function
 205         jnz trace
 206
 207 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 208         cmpq $ftrace_stub, ftrace_graph_return
 209         jnz ftrace_graph_caller
 210
 211         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 212         jnz ftrace_graph_caller
 213 #endif
 214
 215 GLOBAL(ftrace_stub)
 216         retq
 217
 218 trace:
 219         MCOUNT_SAVE_FRAME
 220
 221         movq RIP(%rsp), %rdi
 222 #ifdef CC_USING_FENTRY
 223         movq SS+16(%rsp), %rsi
 224 #else
 225         movq 8(%rbp), %rsi
 226 #endif
 227         subq $MCOUNT_INSN_SIZE, %rdi
 228
 229         call   *ftrace_trace_function
 230
 231         MCOUNT_RESTORE_FRAME
 232
 233         jmp ftrace_stub
 234 END(function_hook)
 235 #endif /* CONFIG_DYNAMIC_FTRACE */
 236 #endif /* CONFIG_FUNCTION_TRACER */
 237
 238 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 239 ENTRY(ftrace_graph_caller)
 240         MCOUNT_SAVE_FRAME
 241
 242 #ifdef CC_USING_FENTRY
 243         leaq SS+16(%rsp), %rdi
 244         movq $0, %rdx   /* No framepointers needed */
 245 #else
 246         leaq 8(%rbp), %rdi
 247         movq (%rbp), %rdx
 248 #endif
 249         movq RIP(%rsp), %rsi
 250         subq $MCOUNT_INSN_SIZE, %rsi
 251
 252         call    prepare_ftrace_return
 253
 254         MCOUNT_RESTORE_FRAME
 255
 256         retq
 257 END(ftrace_graph_caller)
 258
 259 GLOBAL(return_to_handler)
 260         subq  $24, %rsp
 261
 262         /* Save the return values */
 263         movq %rax, (%rsp)
 264         movq %rdx, 8(%rsp)
 265         movq %rbp, %rdi
 266
 267         call ftrace_return_to_handler
 268
 269         movq %rax, %rdi
 270         movq 8(%rsp), %rdx
 271         movq (%rsp), %rax
 272         addq $24, %rsp
 273         jmp *%rdi
 274 #endif
 275
 276
 277 #ifndef CONFIG_PREEMPT
 278 #define retint_kernel retint_restore_args
 279 #endif
 280
 281 #ifdef CONFIG_PARAVIRT
 282 ENTRY(native_usergs_sysret64)
 283         swapgs
 284         sysretq
 285 ENDPROC(native_usergs_sysret64)
 286 #endif /* CONFIG_PARAVIRT */
 287
 288
 289 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 290 #ifdef CONFIG_TRACE_IRQFLAGS
 291         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 292         jnc  1f
 293         TRACE_IRQS_ON
 294 1:
 295 #endif
 296 .endm
 297
 298 /*
 299  * When dynamic function tracer is enabled it will add a breakpoint
 300  * to all locations that it is about to modify, sync CPUs, update
 301  * all the code, sync CPUs, then remove the breakpoints. In this time
 302  * if lockdep is enabled, it might jump back into the debug handler
 303  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 304  *
 305  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 306  * make sure the stack pointer does not get reset back to the top
 307  * of the debug stack, and instead just reuses the current stack.
 308  */
 309 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 310
 311 .macro TRACE_IRQS_OFF_DEBUG
 312         call debug_stack_set_zero
 313         TRACE_IRQS_OFF
 314         call debug_stack_reset
 315 .endm
 316
 317 .macro TRACE_IRQS_ON_DEBUG
 318         call debug_stack_set_zero
 319         TRACE_IRQS_ON
 320         call debug_stack_reset
 321 .endm
 322
 323 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 324         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 325         jnc  1f
 326         TRACE_IRQS_ON_DEBUG
 327 1:
 328 .endm
 329
 330 #else
 331 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 332 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 333 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 334 #endif
 335
 336 /*
 337  * C code is not supposed to know about undefined top of stack. Every time
 338  * a C function with an pt_regs argument is called from the SYSCALL based
 339  * fast path FIXUP_TOP_OF_STACK is needed.
 340  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 341  * manipulation.
 342  */
 343
 344         /* %rsp:at FRAMEEND */
 345         .macro FIXUP_TOP_OF_STACK tmp offset=0
 346         movq PER_CPU_VAR(old_rsp),\tmp
 347         movq \tmp,RSP+\offset(%rsp)
 348         movq $__USER_DS,SS+\offset(%rsp)
 349         movq $__USER_CS,CS+\offset(%rsp)
 350         movq $-1,RCX+\offset(%rsp)
 351         movq R11+\offset(%rsp),\tmp  /* get eflags */
 352         movq \tmp,EFLAGS+\offset(%rsp)
 353         .endm
 354
 355         .macro RESTORE_TOP_OF_STACK tmp offset=0
 356         movq RSP+\offset(%rsp),\tmp
 357         movq \tmp,PER_CPU_VAR(old_rsp)
 358         movq EFLAGS+\offset(%rsp),\tmp
 359         movq \tmp,R11+\offset(%rsp)
 360         .endm
 361
 362         .macro FAKE_STACK_FRAME child_rip
 363         /* push in order ss, rsp, eflags, cs, rip */
 364         xorl %eax, %eax
 365         pushq_cfi $__KERNEL_DS /* ss */
 366         /*CFI_REL_OFFSET        ss,0*/
 367         pushq_cfi %rax /* rsp */
 368         CFI_REL_OFFSET  rsp,0
 369         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_FIXED) /* eflags - interrupts on */
 370         /*CFI_REL_OFFSET        rflags,0*/
 371         pushq_cfi $__KERNEL_CS /* cs */
 372         /*CFI_REL_OFFSET        cs,0*/
 373         pushq_cfi \child_rip /* rip */
 374         CFI_REL_OFFSET  rip,0
 375         pushq_cfi %rax /* orig rax */
 376         .endm
 377
 378         .macro UNFAKE_STACK_FRAME
 379         addq $8*6, %rsp
 380         CFI_ADJUST_CFA_OFFSET   -(6*8)
 381         .endm
 382
 383 /*
 384  * initial frame state for interrupts (and exceptions without error code)
 385  */
 386         .macro EMPTY_FRAME start=1 offset=0
 387         .if \start
 388         CFI_STARTPROC simple
 389         CFI_SIGNAL_FRAME
 390         CFI_DEF_CFA rsp,8+\offset
 391         .else
 392         CFI_DEF_CFA_OFFSET 8+\offset
 393         .endif
 394         .endm
 395
 396 /*
 397  * initial frame state for interrupts (and exceptions without error code)
 398  */
 399         .macro INTR_FRAME start=1 offset=0
 400         EMPTY_FRAME \start, SS+8+\offset-RIP
 401         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 402         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 403         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 404         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 405         CFI_REL_OFFSET rip, RIP+\offset-RIP
 406         .endm
 407
 408 /*
 409  * initial frame state for exceptions with error code (and interrupts
 410  * with vector already pushed)
 411  */
 412         .macro XCPT_FRAME start=1 offset=0
 413         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 414         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 415         .endm
 416
 417 /*
 418  * frame that enables calling into C.
 419  */
 420         .macro PARTIAL_FRAME start=1 offset=0
 421         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 422         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 423         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 424         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 425         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 426         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 427         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 428         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 429         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 430         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 431         .endm
 432
 433 /*
 434  * frame that enables passing a complete pt_regs to a C function.
 435  */
 436         .macro DEFAULT_FRAME start=1 offset=0
 437         PARTIAL_FRAME \start, R11+\offset-R15
 438         CFI_REL_OFFSET rbx, RBX+\offset
 439         CFI_REL_OFFSET rbp, RBP+\offset
 440         CFI_REL_OFFSET r12, R12+\offset
 441         CFI_REL_OFFSET r13, R13+\offset
 442         CFI_REL_OFFSET r14, R14+\offset
 443         CFI_REL_OFFSET r15, R15+\offset
 444         .endm
 445
 446 /* save partial stack frame */
 447         .macro SAVE_ARGS_IRQ
 448         cld
 449         /* start from rbp in pt_regs and jump over */
 450         movq_cfi rdi, (RDI-RBP)
 451         movq_cfi rsi, (RSI-RBP)
 452         movq_cfi rdx, (RDX-RBP)
 453         movq_cfi rcx, (RCX-RBP)
 454         movq_cfi rax, (RAX-RBP)
 455         movq_cfi  r8,  (R8-RBP)
 456         movq_cfi  r9,  (R9-RBP)
 457         movq_cfi r10, (R10-RBP)
 458         movq_cfi r11, (R11-RBP)
 459
 460         /* Save rbp so that we can unwind from get_irq_regs() */
 461         movq_cfi rbp, 0
 462
 463         /* Save previous stack value */
 464         movq %rsp, %rsi
 465
 466         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 467         testl $3, CS-RBP(%rsi)
 468         je 1f
 469         SWAPGS
 470         /*
 471          * irq_count is used to check if a CPU is already on an interrupt stack
 472          * or not. While this is essentially redundant with preempt_count it is
 473          * a little cheaper to use a separate counter in the PDA (short of
 474          * moving irq_enter into assembly, which would be too much work)
 475          */
 476 1:      incl PER_CPU_VAR(irq_count)
 477         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 478         CFI_DEF_CFA_REGISTER    rsi
 479
 480         /* Store previous stack value */
 481         pushq %rsi
 482         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 483                         0x77 /* DW_OP_breg7 */, 0, \
 484                         0x06 /* DW_OP_deref */, \
 485                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 486                         0x22 /* DW_OP_plus */
 487         /* We entered an interrupt context - irqs are off: */
 488         TRACE_IRQS_OFF
 489         .endm
 490
 491 /* save complete stack frame */
 492         .pushsection .kprobes.text, "ax"
 493 ENTRY(save_paranoid)
 494         XCPT_FRAME 1 RDI+8
 495         cld
 496         movq_cfi rdi, RDI+8
 497         movq_cfi rsi, RSI+8
 498         movq_cfi rdx, RDX+8
 499         movq_cfi rcx, RCX+8
 500         movq_cfi rax, RAX+8
 501         movq_cfi r8, R8+8
 502         movq_cfi r9, R9+8
 503         movq_cfi r10, R10+8
 504         movq_cfi r11, R11+8
 505         movq_cfi rbx, RBX+8
 506         movq_cfi rbp, RBP+8
 507         movq_cfi r12, R12+8
 508         movq_cfi r13, R13+8
 509         movq_cfi r14, R14+8
 510         movq_cfi r15, R15+8
 511         movl $1,%ebx
 512         movl $MSR_GS_BASE,%ecx
 513         rdmsr
 514         testl %edx,%edx
 515         js 1f   /* negative -> in kernel */
 516         SWAPGS
 517         xorl %ebx,%ebx
 518 1:      ret
 519         CFI_ENDPROC
 520 END(save_paranoid)
 521         .popsection
 522
 523 /*
 524  * A newly forked process directly context switches into this address.
 525  *
 526  * rdi: prev task we switched from
 527  */
 528 ENTRY(ret_from_fork)
 529         DEFAULT_FRAME
 530
 531         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 532
 533         pushq_cfi $0x0002
 534         popfq_cfi                               # reset kernel eflags
 535
 536         call schedule_tail                      # rdi: 'prev' task parameter
 537
 538         GET_THREAD_INFO(%rcx)
 539
 540         RESTORE_REST
 541
 542         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 543         jz   1f
 544
 545         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 546         jnz  int_ret_from_sys_call
 547
 548         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 549         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 550
 551 1:
 552         subq $REST_SKIP, %rsp   # leave space for volatiles
 553         CFI_ADJUST_CFA_OFFSET   REST_SKIP
 554         movq %rbp, %rdi
 555         call *%rbx
 556         movl $0, RAX(%rsp)
 557         RESTORE_REST
 558         jmp int_ret_from_sys_call
 559         CFI_ENDPROC
 560 END(ret_from_fork)
 561
 562 /*
 563  * System call entry. Up to 6 arguments in registers are supported.
 564  *
 565  * SYSCALL does not save anything on the stack and does not change the
 566  * stack pointer.  However, it does mask the flags register for us, so
 567  * CLD and CLAC are not needed.
 568  */
 569
 570 /*
 571  * Register setup:
 572  * rax  system call number
 573  * rdi  arg0
 574  * rcx  return address for syscall/sysret, C arg3
 575  * rsi  arg1
 576  * rdx  arg2
 577  * r10  arg3    (--> moved to rcx for C)
 578  * r8   arg4
 579  * r9   arg5
 580  * r11  eflags for syscall/sysret, temporary for C
 581  * r12-r15,rbp,rbx saved by C code, not touched.
 582  *
 583  * Interrupts are off on entry.
 584  * Only called from user space.
 585  *
 586  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 587  *      and report it properly in ps. Unfortunately we haven't.
 588  *
 589  * When user can change the frames always force IRET. That is because
 590  * it deals with uncanonical addresses better. SYSRET has trouble
 591  * with them due to bugs in both AMD and Intel CPUs.
 592  */
 593
 594 ENTRY(system_call)
 595         CFI_STARTPROC   simple
 596         CFI_SIGNAL_FRAME
 597         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 598         CFI_REGISTER    rip,rcx
 599         /*CFI_REGISTER  rflags,r11*/
 600         SWAPGS_UNSAFE_STACK
 601         /*
 602          * A hypervisor implementation might want to use a label
 603          * after the swapgs, so that it can do the swapgs
 604          * for the guest and jump here on syscall.
 605          */
 606 GLOBAL(system_call_after_swapgs)
 607
 608         movq    %rsp,PER_CPU_VAR(old_rsp)
 609         movq    PER_CPU_VAR(kernel_stack),%rsp
 610         /*
 611          * No need to follow this irqs off/on section - it's straight
 612          * and short:
 613          */
 614         ENABLE_INTERRUPTS(CLBR_NONE)
 615         SAVE_ARGS 8,0
 616         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 617         movq  %rcx,RIP-ARGOFFSET(%rsp)
 618         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 619         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 620         jnz tracesys
 621 system_call_fastpath:
 622 #if __SYSCALL_MASK == ~0
 623         cmpq $__NR_syscall_max,%rax
 624 #else
 625         andl $__SYSCALL_MASK,%eax
 626         cmpl $__NR_syscall_max,%eax
 627 #endif
 628         ja badsys
 629         movq %r10,%rcx
 630         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 631         movq %rax,RAX-ARGOFFSET(%rsp)
 632 /*
 633  * Syscall return path ending with SYSRET (fast path)
 634  * Has incomplete stack frame and undefined top of stack.
 635  */
 636 ret_from_sys_call:
 637         movl $_TIF_ALLWORK_MASK,%edi
 638         /* edi: flagmask */
 639 sysret_check:
 640         LOCKDEP_SYS_EXIT
 641         DISABLE_INTERRUPTS(CLBR_NONE)
 642         TRACE_IRQS_OFF
 643         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 644         andl %edi,%edx
 645         jnz  sysret_careful
 646         CFI_REMEMBER_STATE
 647         /*
 648          * sysretq will re-enable interrupts:
 649          */
 650         TRACE_IRQS_ON
 651         movq RIP-ARGOFFSET(%rsp),%rcx
 652         CFI_REGISTER    rip,rcx
 653         RESTORE_ARGS 1,-ARG_SKIP,0
 654         /*CFI_REGISTER  rflags,r11*/
 655         movq    PER_CPU_VAR(old_rsp), %rsp
 656         USERGS_SYSRET64
 657
 658         CFI_RESTORE_STATE
 659         /* Handle reschedules */
 660         /* edx: work, edi: workmask */
 661 sysret_careful:
 662         bt $TIF_NEED_RESCHED,%edx
 663         jnc sysret_signal
 664         TRACE_IRQS_ON
 665         ENABLE_INTERRUPTS(CLBR_NONE)
 666         pushq_cfi %rdi
 667         SCHEDULE_USER
 668         popq_cfi %rdi
 669         jmp sysret_check
 670
 671         /* Handle a signal */
 672 sysret_signal:
 673         TRACE_IRQS_ON
 674         ENABLE_INTERRUPTS(CLBR_NONE)
 675 #ifdef CONFIG_AUDITSYSCALL
 676         bt $TIF_SYSCALL_AUDIT,%edx
 677         jc sysret_audit
 678 #endif
 679         /*
 680          * We have a signal, or exit tracing or single-step.
 681          * These all wind up with the iret return path anyway,
 682          * so just join that path right now.
 683          */
 684         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 685         jmp int_check_syscall_exit_work
 686
 687 badsys:
 688         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 689         jmp ret_from_sys_call
 690
 691 #ifdef CONFIG_AUDITSYSCALL
 692         /*
 693          * Fast path for syscall audit without full syscall trace.
 694          * We just call __audit_syscall_entry() directly, and then
 695          * jump back to the normal fast path.
 696          */
 697 auditsys:
 698         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 699         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 700         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 701         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 702         movq %rax,%rsi                  /* 2nd arg: syscall number */
 703         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 704         call __audit_syscall_entry
 705         LOAD_ARGS 0             /* reload call-clobbered registers */
 706         jmp system_call_fastpath
 707
 708         /*
 709          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 710          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 711          * masked off.
 712          */
 713 sysret_audit:
 714         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 715         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 716         setbe %al               /* 1 if so, 0 if not */
 717         movzbl %al,%edi         /* zero-extend that into %edi */
 718         call __audit_syscall_exit
 719         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 720         jmp sysret_check
 721 #endif  /* CONFIG_AUDITSYSCALL */
 722
 723         /* Do syscall tracing */
 724 tracesys:
 725 #ifdef CONFIG_AUDITSYSCALL
 726         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 727         jz auditsys
 728 #endif
 729         SAVE_REST
 730         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 731         FIXUP_TOP_OF_STACK %rdi
 732         movq %rsp,%rdi
 733         call syscall_trace_enter
 734         /*
 735          * Reload arg registers from stack in case ptrace changed them.
 736          * We don't reload %rax because syscall_trace_enter() returned
 737          * the value it wants us to use in the table lookup.
 738          */
 739         LOAD_ARGS ARGOFFSET, 1
 740         RESTORE_REST
 741 #if __SYSCALL_MASK == ~0
 742         cmpq $__NR_syscall_max,%rax
 743 #else
 744         andl $__SYSCALL_MASK,%eax
 745         cmpl $__NR_syscall_max,%eax
 746 #endif
 747         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 748         movq %r10,%rcx  /* fixup for C */
 749         call *sys_call_table(,%rax,8)
 750         movq %rax,RAX-ARGOFFSET(%rsp)
 751         /* Use IRET because user could have changed frame */
 752
 753 /*
 754  * Syscall return path ending with IRET.
 755  * Has correct top of stack, but partial stack frame.
 756  */
 757 GLOBAL(int_ret_from_sys_call)
 758         DISABLE_INTERRUPTS(CLBR_NONE)
 759         TRACE_IRQS_OFF
 760         movl $_TIF_ALLWORK_MASK,%edi
 761         /* edi: mask to check */
 762 GLOBAL(int_with_check)
 763         LOCKDEP_SYS_EXIT_IRQ
 764         GET_THREAD_INFO(%rcx)
 765         movl TI_flags(%rcx),%edx
 766         andl %edi,%edx
 767         jnz   int_careful
 768         andl    $~TS_COMPAT,TI_status(%rcx)
 769         jmp   retint_swapgs
 770
 771         /* Either reschedule or signal or syscall exit tracking needed. */
 772         /* First do a reschedule test. */
 773         /* edx: work, edi: workmask */
 774 int_careful:
 775         bt $TIF_NEED_RESCHED,%edx
 776         jnc  int_very_careful
 777         TRACE_IRQS_ON
 778         ENABLE_INTERRUPTS(CLBR_NONE)
 779         pushq_cfi %rdi
 780         SCHEDULE_USER
 781         popq_cfi %rdi
 782         DISABLE_INTERRUPTS(CLBR_NONE)
 783         TRACE_IRQS_OFF
 784         jmp int_with_check
 785
 786         /* handle signals and tracing -- both require a full stack frame */
 787 int_very_careful:
 788         TRACE_IRQS_ON
 789         ENABLE_INTERRUPTS(CLBR_NONE)
 790 int_check_syscall_exit_work:
 791         SAVE_REST
 792         /* Check for syscall exit trace */
 793         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 794         jz int_signal
 795         pushq_cfi %rdi
 796         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 797         call syscall_trace_leave
 798         popq_cfi %rdi
 799         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 800         jmp int_restore_rest
 801
 802 int_signal:
 803         testl $_TIF_DO_NOTIFY_MASK,%edx
 804         jz 1f
 805         movq %rsp,%rdi          # &ptregs -> arg1
 806         xorl %esi,%esi          # oldset -> arg2
 807         call do_notify_resume
 808 1:      movl $_TIF_WORK_MASK,%edi
 809 int_restore_rest:
 810         RESTORE_REST
 811         DISABLE_INTERRUPTS(CLBR_NONE)
 812         TRACE_IRQS_OFF
 813         jmp int_with_check
 814         CFI_ENDPROC
 815 END(system_call)
 816
 817         .macro FORK_LIKE func
 818 ENTRY(stub_\func)
 819         CFI_STARTPROC
 820         popq    %r11                    /* save return address */
 821         PARTIAL_FRAME 0
 822         SAVE_REST
 823         pushq   %r11                    /* put it back on stack */
 824         FIXUP_TOP_OF_STACK %r11, 8
 825         DEFAULT_FRAME 0 8               /* offset 8: return address */
 826         call sys_\func
 827         RESTORE_TOP_OF_STACK %r11, 8
 828         ret $REST_SKIP          /* pop extended registers */
 829         CFI_ENDPROC
 830 END(stub_\func)
 831         .endm
 832
 833         .macro FIXED_FRAME label,func
 834 ENTRY(\label)
 835         CFI_STARTPROC
 836         PARTIAL_FRAME 0 8               /* offset 8: return address */
 837         FIXUP_TOP_OF_STACK %r11, 8-ARGOFFSET
 838         call \func
 839         RESTORE_TOP_OF_STACK %r11, 8-ARGOFFSET
 840         ret
 841         CFI_ENDPROC
 842 END(\label)
 843         .endm
 844
 845         FORK_LIKE  clone
 846         FORK_LIKE  fork
 847         FORK_LIKE  vfork
 848         FIXED_FRAME stub_iopl, sys_iopl
 849
 850 ENTRY(ptregscall_common)
 851         DEFAULT_FRAME 1 8       /* offset 8: return address */
 852         RESTORE_TOP_OF_STACK %r11, 8
 853         movq_cfi_restore R15+8, r15
 854         movq_cfi_restore R14+8, r14
 855         movq_cfi_restore R13+8, r13
 856         movq_cfi_restore R12+8, r12
 857         movq_cfi_restore RBP+8, rbp
 858         movq_cfi_restore RBX+8, rbx
 859         ret $REST_SKIP          /* pop extended registers */
 860         CFI_ENDPROC
 861 END(ptregscall_common)
 862
 863 ENTRY(stub_execve)
 864         CFI_STARTPROC
 865         addq $8, %rsp
 866         PARTIAL_FRAME 0
 867         SAVE_REST
 868         FIXUP_TOP_OF_STACK %r11
 869         call sys_execve
 870         movq %rax,RAX(%rsp)
 871         RESTORE_REST
 872         jmp int_ret_from_sys_call
 873         CFI_ENDPROC
 874 END(stub_execve)
 875
 876 /*
 877  * sigreturn is special because it needs to restore all registers on return.
 878  * This cannot be done with SYSRET, so use the IRET return path instead.
 879  */
 880 ENTRY(stub_rt_sigreturn)
 881         CFI_STARTPROC
 882         addq $8, %rsp
 883         PARTIAL_FRAME 0
 884         SAVE_REST
 885         FIXUP_TOP_OF_STACK %r11
 886         call sys_rt_sigreturn
 887         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 888         RESTORE_REST
 889         jmp int_ret_from_sys_call
 890         CFI_ENDPROC
 891 END(stub_rt_sigreturn)
 892
 893 #ifdef CONFIG_X86_X32_ABI
 894 ENTRY(stub_x32_rt_sigreturn)
 895         CFI_STARTPROC
 896         addq $8, %rsp
 897         PARTIAL_FRAME 0
 898         SAVE_REST
 899         FIXUP_TOP_OF_STACK %r11
 900         call sys32_x32_rt_sigreturn
 901         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 902         RESTORE_REST
 903         jmp int_ret_from_sys_call
 904         CFI_ENDPROC
 905 END(stub_x32_rt_sigreturn)
 906
 907 ENTRY(stub_x32_execve)
 908         CFI_STARTPROC
 909         addq $8, %rsp
 910         PARTIAL_FRAME 0
 911         SAVE_REST
 912         FIXUP_TOP_OF_STACK %r11
 913         call compat_sys_execve
 914         RESTORE_TOP_OF_STACK %r11
 915         movq %rax,RAX(%rsp)
 916         RESTORE_REST
 917         jmp int_ret_from_sys_call
 918         CFI_ENDPROC
 919 END(stub_x32_execve)
 920
 921 #endif
 922
 923 /*
 924  * Build the entry stubs and pointer table with some assembler magic.
 925  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 926  * single cache line on all modern x86 implementations.
 927  */
 928         .section .init.rodata,"a"
 929 ENTRY(interrupt)
 930         .section .entry.text
 931         .p2align 5
 932         .p2align CONFIG_X86_L1_CACHE_SHIFT
 933 ENTRY(irq_entries_start)
 934         INTR_FRAME
 935 vector=FIRST_EXTERNAL_VECTOR
 936 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 937         .balign 32
 938   .rept 7
 939     .if vector < NR_VECTORS
 940       .if vector <> FIRST_EXTERNAL_VECTOR
 941         CFI_ADJUST_CFA_OFFSET -8
 942       .endif
 943 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 944       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 945         jmp 2f
 946       .endif
 947       .previous
 948         .quad 1b
 949       .section .entry.text
 950 vector=vector+1
 951     .endif
 952   .endr
 953 2:      jmp common_interrupt
 954 .endr
 955         CFI_ENDPROC
 956 END(irq_entries_start)
 957
 958 .previous
 959 END(interrupt)
 960 .previous
 961
 962 /*
 963  * Interrupt entry/exit.
 964  *
 965  * Interrupt entry points save only callee clobbered registers in fast path.
 966  *
 967  * Entry runs with interrupts off.
 968  */
 969
 970 /* 0(%rsp): ~(interrupt number) */
 971         .macro interrupt func
 972         /* reserve pt_regs for scratch regs and rbp */
 973         subq $ORIG_RAX-RBP, %rsp
 974         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 975         SAVE_ARGS_IRQ
 976         call \func
 977         .endm
 978
 979 /*
 980  * Interrupt entry/exit should be protected against kprobes
 981  */
 982         .pushsection .kprobes.text, "ax"
 983         /*
 984          * The interrupt stubs push (~vector+0x80) onto the stack and
 985          * then jump to common_interrupt.
 986          */
 987         .p2align CONFIG_X86_L1_CACHE_SHIFT
 988 common_interrupt:
 989         XCPT_FRAME
 990         ASM_CLAC
 991         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 992         interrupt do_IRQ
 993         /* 0(%rsp): old_rsp-ARGOFFSET */
 994 ret_from_intr:
 995         DISABLE_INTERRUPTS(CLBR_NONE)
 996         TRACE_IRQS_OFF
 997         decl PER_CPU_VAR(irq_count)
 998
 999         /* Restore saved previous stack */
1000         popq %rsi
1001         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
1002         leaq ARGOFFSET-RBP(%rsi), %rsp
1003         CFI_DEF_CFA_REGISTER    rsp
1004         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
1005
1006 exit_intr:
1007         GET_THREAD_INFO(%rcx)
1008         testl $3,CS-ARGOFFSET(%rsp)
1009         je retint_kernel
1010
1011         /* Interrupt came from user space */
1012         /*
1013          * Has a correct top of stack, but a partial stack frame
1014          * %rcx: thread info. Interrupts off.
1015          */
1016 retint_with_reschedule:
1017         movl $_TIF_WORK_MASK,%edi
1018 retint_check:
1019         LOCKDEP_SYS_EXIT_IRQ
1020         movl TI_flags(%rcx),%edx
1021         andl %edi,%edx
1022         CFI_REMEMBER_STATE
1023         jnz  retint_careful
1024
1025 retint_swapgs:          /* return to user-space */
1026         /*
1027          * The iretq could re-enable interrupts:
1028          */
1029         DISABLE_INTERRUPTS(CLBR_ANY)
1030         TRACE_IRQS_IRETQ
1031         SWAPGS
1032         jmp restore_args
1033
1034 retint_restore_args:    /* return to kernel space */
1035         DISABLE_INTERRUPTS(CLBR_ANY)
1036         /*
1037          * The iretq could re-enable interrupts:
1038          */
1039         TRACE_IRQS_IRETQ
1040 restore_args:
1041         RESTORE_ARGS 1,8,1
1042
1043 irq_return:
1044         /*
1045          * Are we returning to a stack segment from the LDT?  Note: in
1046          * 64-bit mode SS:RSP on the exception stack is always valid.
1047          */
1048 #ifdef CONFIG_X86_ESPFIX64
1049         testb $4,(SS-RIP)(%rsp)
1050         jnz irq_return_ldt
1051 #endif
1052
1053 irq_return_iret:
1054         INTERRUPT_RETURN
1055         _ASM_EXTABLE(irq_return_iret, bad_iret)
1056
1057 #ifdef CONFIG_PARAVIRT
1058 ENTRY(native_iret)
1059         iretq
1060         _ASM_EXTABLE(native_iret, bad_iret)
1061 #endif
1062
1063 #ifdef CONFIG_X86_ESPFIX64
1064 irq_return_ldt:
1065         pushq_cfi %rax
1066         pushq_cfi %rdi
1067         SWAPGS
1068         movq PER_CPU_VAR(espfix_waddr),%rdi
1069         movq %rax,(0*8)(%rdi)   /* RAX */
1070         movq (2*8)(%rsp),%rax   /* RIP */
1071         movq %rax,(1*8)(%rdi)
1072         movq (3*8)(%rsp),%rax   /* CS */
1073         movq %rax,(2*8)(%rdi)
1074         movq (4*8)(%rsp),%rax   /* RFLAGS */
1075         movq %rax,(3*8)(%rdi)
1076         movq (6*8)(%rsp),%rax   /* SS */
1077         movq %rax,(5*8)(%rdi)
1078         movq (5*8)(%rsp),%rax   /* RSP */
1079         movq %rax,(4*8)(%rdi)
1080         andl $0xffff0000,%eax
1081         popq_cfi %rdi
1082         orq PER_CPU_VAR(espfix_stack),%rax
1083         SWAPGS
1084         movq %rax,%rsp
1085         popq_cfi %rax
1086         jmp irq_return_iret
1087 #endif
1088
1089         .section .fixup,"ax"
1090 bad_iret:
1091         /*
1092          * The iret traps when the %cs or %ss being restored is bogus.
1093          * We've lost the original trap vector and error code.
1094          * #GPF is the most likely one to get for an invalid selector.
1095          * So pretend we completed the iret and took the #GPF in user mode.
1096          *
1097          * We are now running with the kernel GS after exception recovery.
1098          * But error_entry expects us to have user GS to match the user %cs,
1099          * so swap back.
1100          */
1101         pushq $0
1102
1103         SWAPGS
1104         jmp general_protection
1105
1106         .previous
1107
1108         /* edi: workmask, edx: work */
1109 retint_careful:
1110         CFI_RESTORE_STATE
1111         bt    $TIF_NEED_RESCHED,%edx
1112         jnc   retint_signal
1113         TRACE_IRQS_ON
1114         ENABLE_INTERRUPTS(CLBR_NONE)
1115         pushq_cfi %rdi
1116         SCHEDULE_USER
1117         popq_cfi %rdi
1118         GET_THREAD_INFO(%rcx)
1119         DISABLE_INTERRUPTS(CLBR_NONE)
1120         TRACE_IRQS_OFF
1121         jmp retint_check
1122
1123 retint_signal:
1124         testl $_TIF_DO_NOTIFY_MASK,%edx
1125         jz    retint_swapgs
1126         TRACE_IRQS_ON
1127         ENABLE_INTERRUPTS(CLBR_NONE)
1128         SAVE_REST
1129         movq $-1,ORIG_RAX(%rsp)
1130         xorl %esi,%esi          # oldset
1131         movq %rsp,%rdi          # &pt_regs
1132         call do_notify_resume
1133         RESTORE_REST
1134         DISABLE_INTERRUPTS(CLBR_NONE)
1135         TRACE_IRQS_OFF
1136         GET_THREAD_INFO(%rcx)
1137         jmp retint_with_reschedule
1138
1139 #ifdef CONFIG_PREEMPT
1140         /* Returning to kernel space. Check if we need preemption */
1141         /* rcx:  threadinfo. interrupts off. */
1142 ENTRY(retint_kernel)
1143         cmpl $0,PER_CPU_VAR(__preempt_count)
1144         jnz  retint_restore_args
1145         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1146         jnc  retint_restore_args
1147         call preempt_schedule_irq
1148         jmp exit_intr
1149 #endif
1150         CFI_ENDPROC
1151 END(common_interrupt)
1152
1153         /*
1154          * If IRET takes a fault on the espfix stack, then we
1155          * end up promoting it to a doublefault.  In that case,
1156          * modify the stack to make it look like we just entered
1157          * the #GP handler from user space, similar to bad_iret.
1158          */
1159 #ifdef CONFIG_X86_ESPFIX64
1160         ALIGN
1161 __do_double_fault:
1162         XCPT_FRAME 1 RDI+8
1163         movq RSP(%rdi),%rax             /* Trap on the espfix stack? */
1164         sarq $PGDIR_SHIFT,%rax
1165         cmpl $ESPFIX_PGD_ENTRY,%eax
1166         jne do_double_fault             /* No, just deliver the fault */
1167         cmpl $__KERNEL_CS,CS(%rdi)
1168         jne do_double_fault
1169         movq RIP(%rdi),%rax
1170         cmpq $irq_return_iret,%rax
1171 #ifdef CONFIG_PARAVIRT
1172         je 1f
1173         cmpq $native_iret,%rax
1174 #endif
1175         jne do_double_fault             /* This shouldn't happen... */
1176 1:
1177         movq PER_CPU_VAR(kernel_stack),%rax
1178         subq $(6*8-KERNEL_STACK_OFFSET),%rax    /* Reset to original stack */
1179         movq %rax,RSP(%rdi)
1180         movq $0,(%rax)                  /* Missing (lost) #GP error code */
1181         movq $general_protection,RIP(%rdi)
1182         retq
1183         CFI_ENDPROC
1184 END(__do_double_fault)
1185 #else
1186 # define __do_double_fault do_double_fault
1187 #endif
1188
1189 /*
1190  * End of kprobes section
1191  */
1192        .popsection
1193
1194 /*
1195  * APIC interrupts.
1196  */
1197 .macro apicinterrupt3 num sym do_sym
1198 ENTRY(\sym)
1199         INTR_FRAME
1200         ASM_CLAC
1201         pushq_cfi $~(\num)
1202 .Lcommon_\sym:
1203         interrupt \do_sym
1204         jmp ret_from_intr
1205         CFI_ENDPROC
1206 END(\sym)
1207 .endm
1208
1209 #ifdef CONFIG_TRACING
1210 #define trace(sym) trace_##sym
1211 #define smp_trace(sym) smp_trace_##sym
1212
1213 .macro trace_apicinterrupt num sym
1214 apicinterrupt3 \num trace(\sym) smp_trace(\sym)
1215 .endm
1216 #else
1217 .macro trace_apicinterrupt num sym do_sym
1218 .endm
1219 #endif
1220
1221 .macro apicinterrupt num sym do_sym
1222 apicinterrupt3 \num \sym \do_sym
1223 trace_apicinterrupt \num \sym
1224 .endm
1225
1226 #ifdef CONFIG_SMP
1227 apicinterrupt3 IRQ_MOVE_CLEANUP_VECTOR \
1228         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1229 apicinterrupt3 REBOOT_VECTOR \
1230         reboot_interrupt smp_reboot_interrupt
1231 #endif
1232
1233 #ifdef CONFIG_X86_UV
1234 apicinterrupt3 UV_BAU_MESSAGE \
1235         uv_bau_message_intr1 uv_bau_message_interrupt
1236 #endif
1237 apicinterrupt LOCAL_TIMER_VECTOR \
1238         apic_timer_interrupt smp_apic_timer_interrupt
1239 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1240         x86_platform_ipi smp_x86_platform_ipi
1241
1242 #ifdef CONFIG_HAVE_KVM
1243 apicinterrupt3 POSTED_INTR_VECTOR \
1244         kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
1245 #endif
1246
1247 #ifdef CONFIG_X86_MCE_THRESHOLD
1248 apicinterrupt THRESHOLD_APIC_VECTOR \
1249         threshold_interrupt smp_threshold_interrupt
1250 #endif
1251
1252 #ifdef CONFIG_X86_THERMAL_VECTOR
1253 apicinterrupt THERMAL_APIC_VECTOR \
1254         thermal_interrupt smp_thermal_interrupt
1255 #endif
1256
1257 #ifdef CONFIG_SMP
1258 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1259         call_function_single_interrupt smp_call_function_single_interrupt
1260 apicinterrupt CALL_FUNCTION_VECTOR \
1261         call_function_interrupt smp_call_function_interrupt
1262 apicinterrupt RESCHEDULE_VECTOR \
1263         reschedule_interrupt smp_reschedule_interrupt
1264 #endif
1265
1266 apicinterrupt ERROR_APIC_VECTOR \
1267         error_interrupt smp_error_interrupt
1268 apicinterrupt SPURIOUS_APIC_VECTOR \
1269         spurious_interrupt smp_spurious_interrupt
1270
1271 #ifdef CONFIG_IRQ_WORK
1272 apicinterrupt IRQ_WORK_VECTOR \
1273         irq_work_interrupt smp_irq_work_interrupt
1274 #endif
1275
1276 /*
1277  * Exception entry points.
1278  */
1279 .macro zeroentry sym do_sym
1280 ENTRY(\sym)
1281         INTR_FRAME
1282         ASM_CLAC
1283         PARAVIRT_ADJUST_EXCEPTION_FRAME
1284         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1285         subq $ORIG_RAX-R15, %rsp
1286         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1287         call error_entry
1288         DEFAULT_FRAME 0
1289         movq %rsp,%rdi          /* pt_regs pointer */
1290         xorl %esi,%esi          /* no error code */
1291         call \do_sym
1292         jmp error_exit          /* %ebx: no swapgs flag */
1293         CFI_ENDPROC
1294 END(\sym)
1295 .endm
1296
1297 .macro paranoidzeroentry sym do_sym
1298 ENTRY(\sym)
1299         INTR_FRAME
1300         ASM_CLAC
1301         PARAVIRT_ADJUST_EXCEPTION_FRAME
1302         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1303         subq $ORIG_RAX-R15, %rsp
1304         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1305         call save_paranoid
1306         TRACE_IRQS_OFF
1307         movq %rsp,%rdi          /* pt_regs pointer */
1308         xorl %esi,%esi          /* no error code */
1309         call \do_sym
1310         jmp paranoid_exit       /* %ebx: no swapgs flag */
1311         CFI_ENDPROC
1312 END(\sym)
1313 .endm
1314
1315 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1316 .macro paranoidzeroentry_ist sym do_sym ist
1317 ENTRY(\sym)
1318         INTR_FRAME
1319         ASM_CLAC
1320         PARAVIRT_ADJUST_EXCEPTION_FRAME
1321         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1322         subq $ORIG_RAX-R15, %rsp
1323         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1324         call save_paranoid
1325         TRACE_IRQS_OFF_DEBUG
1326         movq %rsp,%rdi          /* pt_regs pointer */
1327         xorl %esi,%esi          /* no error code */
1328         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1329         call \do_sym
1330         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1331         jmp paranoid_exit       /* %ebx: no swapgs flag */
1332         CFI_ENDPROC
1333 END(\sym)
1334 .endm
1335
1336 .macro errorentry sym do_sym
1337 ENTRY(\sym)
1338         XCPT_FRAME
1339         ASM_CLAC
1340         PARAVIRT_ADJUST_EXCEPTION_FRAME
1341         subq $ORIG_RAX-R15, %rsp
1342         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1343         call error_entry
1344         DEFAULT_FRAME 0
1345         movq %rsp,%rdi                  /* pt_regs pointer */
1346         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1347         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1348         call \do_sym
1349         jmp error_exit                  /* %ebx: no swapgs flag */
1350         CFI_ENDPROC
1351 END(\sym)
1352 .endm
1353
1354 #ifdef CONFIG_TRACING
1355 .macro trace_errorentry sym do_sym
1356 errorentry trace(\sym) trace(\do_sym)
1357 errorentry \sym \do_sym
1358 .endm
1359 #else
1360 .macro trace_errorentry sym do_sym
1361 errorentry \sym \do_sym
1362 .endm
1363 #endif
1364
1365         /* error code is on the stack already */
1366 .macro paranoiderrorentry sym do_sym
1367 ENTRY(\sym)
1368         XCPT_FRAME
1369         ASM_CLAC
1370         PARAVIRT_ADJUST_EXCEPTION_FRAME
1371         subq $ORIG_RAX-R15, %rsp
1372         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1373         call save_paranoid
1374         DEFAULT_FRAME 0
1375         TRACE_IRQS_OFF
1376         movq %rsp,%rdi                  /* pt_regs pointer */
1377         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1378         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1379         call \do_sym
1380         jmp paranoid_exit               /* %ebx: no swapgs flag */
1381         CFI_ENDPROC
1382 END(\sym)
1383 .endm
1384
1385 zeroentry divide_error do_divide_error
1386 zeroentry overflow do_overflow
1387 zeroentry bounds do_bounds
1388 zeroentry invalid_op do_invalid_op
1389 zeroentry device_not_available do_device_not_available
1390 paranoiderrorentry double_fault __do_double_fault
1391 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1392 errorentry invalid_TSS do_invalid_TSS
1393 errorentry segment_not_present do_segment_not_present
1394 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1395 zeroentry coprocessor_error do_coprocessor_error
1396 errorentry alignment_check do_alignment_check
1397 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1398
1399
1400         /* Reload gs selector with exception handling */
1401         /* edi:  new selector */
1402 ENTRY(native_load_gs_index)
1403         CFI_STARTPROC
1404         pushfq_cfi
1405         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1406         SWAPGS
1407 gs_change:
1408         movl %edi,%gs
1409 2:      mfence          /* workaround */
1410         SWAPGS
1411         popfq_cfi
1412         ret
1413         CFI_ENDPROC
1414 END(native_load_gs_index)
1415
1416         _ASM_EXTABLE(gs_change,bad_gs)
1417         .section .fixup,"ax"
1418         /* running with kernelgs */
1419 bad_gs:
1420         SWAPGS                  /* switch back to user gs */
1421         xorl %eax,%eax
1422         movl %eax,%gs
1423         jmp  2b
1424         .previous
1425
1426 /* Call softirq on interrupt stack. Interrupts are off. */
1427 ENTRY(do_softirq_own_stack)
1428         CFI_STARTPROC
1429         pushq_cfi %rbp
1430         CFI_REL_OFFSET rbp,0
1431         mov  %rsp,%rbp
1432         CFI_DEF_CFA_REGISTER rbp
1433         incl PER_CPU_VAR(irq_count)
1434         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1435         push  %rbp                      # backlink for old unwinder
1436         call __do_softirq
1437         leaveq
1438         CFI_RESTORE             rbp
1439         CFI_DEF_CFA_REGISTER    rsp
1440         CFI_ADJUST_CFA_OFFSET   -8
1441         decl PER_CPU_VAR(irq_count)
1442         ret
1443         CFI_ENDPROC
1444 END(do_softirq_own_stack)
1445
1446 #ifdef CONFIG_XEN
1447 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1448
1449 /*
1450  * A note on the "critical region" in our callback handler.
1451  * We want to avoid stacking callback handlers due to events occurring
1452  * during handling of the last event. To do this, we keep events disabled
1453  * until we've done all processing. HOWEVER, we must enable events before
1454  * popping the stack frame (can't be done atomically) and so it would still
1455  * be possible to get enough handler activations to overflow the stack.
1456  * Although unlikely, bugs of that kind are hard to track down, so we'd
1457  * like to avoid the possibility.
1458  * So, on entry to the handler we detect whether we interrupted an
1459  * existing activation in its critical region -- if so, we pop the current
1460  * activation and restart the handler using the previous one.
1461  */
1462 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1463         CFI_STARTPROC
1464 /*
1465  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1466  * see the correct pointer to the pt_regs
1467  */
1468         movq %rdi, %rsp            # we don't return, adjust the stack frame
1469         CFI_ENDPROC
1470         DEFAULT_FRAME
1471 11:     incl PER_CPU_VAR(irq_count)
1472         movq %rsp,%rbp
1473         CFI_DEF_CFA_REGISTER rbp
1474         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1475         pushq %rbp                      # backlink for old unwinder
1476         call xen_evtchn_do_upcall
1477         popq %rsp
1478         CFI_DEF_CFA_REGISTER rsp
1479         decl PER_CPU_VAR(irq_count)
1480         jmp  error_exit
1481         CFI_ENDPROC
1482 END(xen_do_hypervisor_callback)
1483
1484 /*
1485  * Hypervisor uses this for application faults while it executes.
1486  * We get here for two reasons:
1487  *  1. Fault while reloading DS, ES, FS or GS
1488  *  2. Fault while executing IRET
1489  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1490  * registers that could be reloaded and zeroed the others.
1491  * Category 2 we fix up by killing the current process. We cannot use the
1492  * normal Linux return path in this case because if we use the IRET hypercall
1493  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1494  * We distinguish between categories by comparing each saved segment register
1495  * with its current contents: any discrepancy means we in category 1.
1496  */
1497 ENTRY(xen_failsafe_callback)
1498         INTR_FRAME 1 (6*8)
1499         /*CFI_REL_OFFSET gs,GS*/
1500         /*CFI_REL_OFFSET fs,FS*/
1501         /*CFI_REL_OFFSET es,ES*/
1502         /*CFI_REL_OFFSET ds,DS*/
1503         CFI_REL_OFFSET r11,8
1504         CFI_REL_OFFSET rcx,0
1505         movw %ds,%cx
1506         cmpw %cx,0x10(%rsp)
1507         CFI_REMEMBER_STATE
1508         jne 1f
1509         movw %es,%cx
1510         cmpw %cx,0x18(%rsp)
1511         jne 1f
1512         movw %fs,%cx
1513         cmpw %cx,0x20(%rsp)
1514         jne 1f
1515         movw %gs,%cx
1516         cmpw %cx,0x28(%rsp)
1517         jne 1f
1518         /* All segments match their saved values => Category 2 (Bad IRET). */
1519         movq (%rsp),%rcx
1520         CFI_RESTORE rcx
1521         movq 8(%rsp),%r11
1522         CFI_RESTORE r11
1523         addq $0x30,%rsp
1524         CFI_ADJUST_CFA_OFFSET -0x30
1525         pushq_cfi $0    /* RIP */
1526         pushq_cfi %r11
1527         pushq_cfi %rcx
1528         jmp general_protection
1529         CFI_RESTORE_STATE
1530 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1531         movq (%rsp),%rcx
1532         CFI_RESTORE rcx
1533         movq 8(%rsp),%r11
1534         CFI_RESTORE r11
1535         addq $0x30,%rsp
1536         CFI_ADJUST_CFA_OFFSET -0x30
1537         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1538         SAVE_ALL
1539         jmp error_exit
1540         CFI_ENDPROC
1541 END(xen_failsafe_callback)
1542
1543 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1544         xen_hvm_callback_vector xen_evtchn_do_upcall
1545
1546 #endif /* CONFIG_XEN */
1547
1548 #if IS_ENABLED(CONFIG_HYPERV)
1549 apicinterrupt3 HYPERVISOR_CALLBACK_VECTOR \
1550         hyperv_callback_vector hyperv_vector_handler
1551 #endif /* CONFIG_HYPERV */
1552
1553 /*
1554  * Some functions should be protected against kprobes
1555  */
1556         .pushsection .kprobes.text, "ax"
1557
1558 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1559 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1560 paranoiderrorentry stack_segment do_stack_segment
1561 #ifdef CONFIG_XEN
1562 zeroentry xen_debug do_debug
1563 zeroentry xen_int3 do_int3
1564 errorentry xen_stack_segment do_stack_segment
1565 #endif
1566 errorentry general_protection do_general_protection
1567 trace_errorentry page_fault do_page_fault
1568 #ifdef CONFIG_KVM_GUEST
1569 errorentry async_page_fault do_async_page_fault
1570 #endif
1571 #ifdef CONFIG_X86_MCE
1572 paranoidzeroentry machine_check *machine_check_vector(%rip)
1573 #endif
1574
1575         /*
1576          * "Paranoid" exit path from exception stack.
1577          * Paranoid because this is used by NMIs and cannot take
1578          * any kernel state for granted.
1579          * We don't do kernel preemption checks here, because only
1580          * NMI should be common and it does not enable IRQs and
1581          * cannot get reschedule ticks.
1582          *
1583          * "trace" is 0 for the NMI handler only, because irq-tracing
1584          * is fundamentally NMI-unsafe. (we cannot change the soft and
1585          * hard flags at once, atomically)
1586          */
1587
1588         /* ebx: no swapgs flag */
1589 ENTRY(paranoid_exit)
1590         DEFAULT_FRAME
1591         DISABLE_INTERRUPTS(CLBR_NONE)
1592         TRACE_IRQS_OFF_DEBUG
1593         testl %ebx,%ebx                         /* swapgs needed? */
1594         jnz paranoid_restore
1595         testl $3,CS(%rsp)
1596         jnz   paranoid_userspace
1597 paranoid_swapgs:
1598         TRACE_IRQS_IRETQ 0
1599         SWAPGS_UNSAFE_STACK
1600         RESTORE_ALL 8
1601         jmp irq_return
1602 paranoid_restore:
1603         TRACE_IRQS_IRETQ_DEBUG 0
1604         RESTORE_ALL 8
1605         jmp irq_return
1606 paranoid_userspace:
1607         GET_THREAD_INFO(%rcx)
1608         movl TI_flags(%rcx),%ebx
1609         andl $_TIF_WORK_MASK,%ebx
1610         jz paranoid_swapgs
1611         movq %rsp,%rdi                  /* &pt_regs */
1612         call sync_regs
1613         movq %rax,%rsp                  /* switch stack for scheduling */
1614         testl $_TIF_NEED_RESCHED,%ebx
1615         jnz paranoid_schedule
1616         movl %ebx,%edx                  /* arg3: thread flags */
1617         TRACE_IRQS_ON
1618         ENABLE_INTERRUPTS(CLBR_NONE)
1619         xorl %esi,%esi                  /* arg2: oldset */
1620         movq %rsp,%rdi                  /* arg1: &pt_regs */
1621         call do_notify_resume
1622         DISABLE_INTERRUPTS(CLBR_NONE)
1623         TRACE_IRQS_OFF
1624         jmp paranoid_userspace
1625 paranoid_schedule:
1626         TRACE_IRQS_ON
1627         ENABLE_INTERRUPTS(CLBR_ANY)
1628         SCHEDULE_USER
1629         DISABLE_INTERRUPTS(CLBR_ANY)
1630         TRACE_IRQS_OFF
1631         jmp paranoid_userspace
1632         CFI_ENDPROC
1633 END(paranoid_exit)
1634
1635 /*
1636  * Exception entry point. This expects an error code/orig_rax on the stack.
1637  * returns in "no swapgs flag" in %ebx.
1638  */
1639 ENTRY(error_entry)
1640         XCPT_FRAME
1641         CFI_ADJUST_CFA_OFFSET 15*8
1642         /* oldrax contains error code */
1643         cld
1644         movq_cfi rdi, RDI+8
1645         movq_cfi rsi, RSI+8
1646         movq_cfi rdx, RDX+8
1647         movq_cfi rcx, RCX+8
1648         movq_cfi rax, RAX+8
1649         movq_cfi  r8,  R8+8
1650         movq_cfi  r9,  R9+8
1651         movq_cfi r10, R10+8
1652         movq_cfi r11, R11+8
1653         movq_cfi rbx, RBX+8
1654         movq_cfi rbp, RBP+8
1655         movq_cfi r12, R12+8
1656         movq_cfi r13, R13+8
1657         movq_cfi r14, R14+8
1658         movq_cfi r15, R15+8
1659         xorl %ebx,%ebx
1660         testl $3,CS+8(%rsp)
1661         je error_kernelspace
1662 error_swapgs:
1663         SWAPGS
1664 error_sti:
1665         TRACE_IRQS_OFF
1666         ret
1667
1668 /*
1669  * There are two places in the kernel that can potentially fault with
1670  * usergs. Handle them here. The exception handlers after iret run with
1671  * kernel gs again, so don't set the user space flag. B stepping K8s
1672  * sometimes report an truncated RIP for IRET exceptions returning to
1673  * compat mode. Check for these here too.
1674  */
1675 error_kernelspace:
1676         incl %ebx
1677         leaq irq_return_iret(%rip),%rcx
1678         cmpq %rcx,RIP+8(%rsp)
1679         je error_swapgs
1680         movl %ecx,%eax  /* zero extend */
1681         cmpq %rax,RIP+8(%rsp)
1682         je bstep_iret
1683         cmpq $gs_change,RIP+8(%rsp)
1684         je error_swapgs
1685         jmp error_sti
1686
1687 bstep_iret:
1688         /* Fix truncated RIP */
1689         movq %rcx,RIP+8(%rsp)
1690         jmp error_swapgs
1691         CFI_ENDPROC
1692 END(error_entry)
1693
1694
1695 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1696 ENTRY(error_exit)
1697         DEFAULT_FRAME
1698         movl %ebx,%eax
1699         RESTORE_REST
1700         DISABLE_INTERRUPTS(CLBR_NONE)
1701         TRACE_IRQS_OFF
1702         GET_THREAD_INFO(%rcx)
1703         testl %eax,%eax
1704         jne retint_kernel
1705         LOCKDEP_SYS_EXIT_IRQ
1706         movl TI_flags(%rcx),%edx
1707         movl $_TIF_WORK_MASK,%edi
1708         andl %edi,%edx
1709         jnz retint_careful
1710         jmp retint_swapgs
1711         CFI_ENDPROC
1712 END(error_exit)
1713
1714 /*
1715  * Test if a given stack is an NMI stack or not.
1716  */
1717         .macro test_in_nmi reg stack nmi_ret normal_ret
1718         cmpq %\reg, \stack
1719         ja \normal_ret
1720         subq $EXCEPTION_STKSZ, %\reg
1721         cmpq %\reg, \stack
1722         jb \normal_ret
1723         jmp \nmi_ret
1724         .endm
1725
1726         /* runs on exception stack */
1727 ENTRY(nmi)
1728         INTR_FRAME
1729         PARAVIRT_ADJUST_EXCEPTION_FRAME
1730         /*
1731          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1732          * the iretq it performs will take us out of NMI context.
1733          * This means that we can have nested NMIs where the next
1734          * NMI is using the top of the stack of the previous NMI. We
1735          * can't let it execute because the nested NMI will corrupt the
1736          * stack of the previous NMI. NMI handlers are not re-entrant
1737          * anyway.
1738          *
1739          * To handle this case we do the following:
1740          *  Check the a special location on the stack that contains
1741          *  a variable that is set when NMIs are executing.
1742          *  The interrupted task's stack is also checked to see if it
1743          *  is an NMI stack.
1744          *  If the variable is not set and the stack is not the NMI
1745          *  stack then:
1746          *    o Set the special variable on the stack
1747          *    o Copy the interrupt frame into a "saved" location on the stack
1748          *    o Copy the interrupt frame into a "copy" location on the stack
1749          *    o Continue processing the NMI
1750          *  If the variable is set or the previous stack is the NMI stack:
1751          *    o Modify the "copy" location to jump to the repeate_nmi
1752          *    o return back to the first NMI
1753          *
1754          * Now on exit of the first NMI, we first clear the stack variable
1755          * The NMI stack will tell any nested NMIs at that point that it is
1756          * nested. Then we pop the stack normally with iret, and if there was
1757          * a nested NMI that updated the copy interrupt stack frame, a
1758          * jump will be made to the repeat_nmi code that will handle the second
1759          * NMI.
1760          */
1761
1762         /* Use %rdx as out temp variable throughout */
1763         pushq_cfi %rdx
1764         CFI_REL_OFFSET rdx, 0
1765
1766         /*
1767          * If %cs was not the kernel segment, then the NMI triggered in user
1768          * space, which means it is definitely not nested.
1769          */
1770         cmpl $__KERNEL_CS, 16(%rsp)
1771         jne first_nmi
1772
1773         /*
1774          * Check the special variable on the stack to see if NMIs are
1775          * executing.
1776          */
1777         cmpl $1, -8(%rsp)
1778         je nested_nmi
1779
1780         /*
1781          * Now test if the previous stack was an NMI stack.
1782          * We need the double check. We check the NMI stack to satisfy the
1783          * race when the first NMI clears the variable before returning.
1784          * We check the variable because the first NMI could be in a
1785          * breakpoint routine using a breakpoint stack.
1786          */
1787         lea 6*8(%rsp), %rdx
1788         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1789         CFI_REMEMBER_STATE
1790
1791 nested_nmi:
1792         /*
1793          * Do nothing if we interrupted the fixup in repeat_nmi.
1794          * It's about to repeat the NMI handler, so we are fine
1795          * with ignoring this one.
1796          */
1797         movq $repeat_nmi, %rdx
1798         cmpq 8(%rsp), %rdx
1799         ja 1f
1800         movq $end_repeat_nmi, %rdx
1801         cmpq 8(%rsp), %rdx
1802         ja nested_nmi_out
1803
1804 1:
1805         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1806         leaq -1*8(%rsp), %rdx
1807         movq %rdx, %rsp
1808         CFI_ADJUST_CFA_OFFSET 1*8
1809         leaq -10*8(%rsp), %rdx
1810         pushq_cfi $__KERNEL_DS
1811         pushq_cfi %rdx
1812         pushfq_cfi
1813         pushq_cfi $__KERNEL_CS
1814         pushq_cfi $repeat_nmi
1815
1816         /* Put stack back */
1817         addq $(6*8), %rsp
1818         CFI_ADJUST_CFA_OFFSET -6*8
1819
1820 nested_nmi_out:
1821         popq_cfi %rdx
1822         CFI_RESTORE rdx
1823
1824         /* No need to check faults here */
1825         INTERRUPT_RETURN
1826
1827         CFI_RESTORE_STATE
1828 first_nmi:
1829         /*
1830          * Because nested NMIs will use the pushed location that we
1831          * stored in rdx, we must keep that space available.
1832          * Here's what our stack frame will look like:
1833          * +-------------------------+
1834          * | original SS             |
1835          * | original Return RSP     |
1836          * | original RFLAGS         |
1837          * | original CS             |
1838          * | original RIP            |
1839          * +-------------------------+
1840          * | temp storage for rdx    |
1841          * +-------------------------+
1842          * | NMI executing variable  |
1843          * +-------------------------+
1844          * | copied SS               |
1845          * | copied Return RSP       |
1846          * | copied RFLAGS           |
1847          * | copied CS               |
1848          * | copied RIP              |
1849          * +-------------------------+
1850          * | Saved SS                |
1851          * | Saved Return RSP        |
1852          * | Saved RFLAGS            |
1853          * | Saved CS                |
1854          * | Saved RIP               |
1855          * +-------------------------+
1856          * | pt_regs                 |
1857          * +-------------------------+
1858          *
1859          * The saved stack frame is used to fix up the copied stack frame
1860          * that a nested NMI may change to make the interrupted NMI iret jump
1861          * to the repeat_nmi. The original stack frame and the temp storage
1862          * is also used by nested NMIs and can not be trusted on exit.
1863          */
1864         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1865         movq (%rsp), %rdx
1866         CFI_RESTORE rdx
1867
1868         /* Set the NMI executing variable on the stack. */
1869         pushq_cfi $1
1870
1871         /*
1872          * Leave room for the "copied" frame
1873          */
1874         subq $(5*8), %rsp
1875         CFI_ADJUST_CFA_OFFSET 5*8
1876
1877         /* Copy the stack frame to the Saved frame */
1878         .rept 5
1879         pushq_cfi 11*8(%rsp)
1880         .endr
1881         CFI_DEF_CFA_OFFSET SS+8-RIP
1882
1883         /* Everything up to here is safe from nested NMIs */
1884
1885         /*
1886          * If there was a nested NMI, the first NMI's iret will return
1887          * here. But NMIs are still enabled and we can take another
1888          * nested NMI. The nested NMI checks the interrupted RIP to see
1889          * if it is between repeat_nmi and end_repeat_nmi, and if so
1890          * it will just return, as we are about to repeat an NMI anyway.
1891          * This makes it safe to copy to the stack frame that a nested
1892          * NMI will update.
1893          */
1894 repeat_nmi:
1895         /*
1896          * Update the stack variable to say we are still in NMI (the update
1897          * is benign for the non-repeat case, where 1 was pushed just above
1898          * to this very stack slot).
1899          */
1900         movq $1, 10*8(%rsp)
1901
1902         /* Make another copy, this one may be modified by nested NMIs */
1903         addq $(10*8), %rsp
1904         CFI_ADJUST_CFA_OFFSET -10*8
1905         .rept 5
1906         pushq_cfi -6*8(%rsp)
1907         .endr
1908         subq $(5*8), %rsp
1909         CFI_DEF_CFA_OFFSET SS+8-RIP
1910 end_repeat_nmi:
1911
1912         /*
1913          * Everything below this point can be preempted by a nested
1914          * NMI if the first NMI took an exception and reset our iret stack
1915          * so that we repeat another NMI.
1916          */
1917         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1918         subq $ORIG_RAX-R15, %rsp
1919         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1920         /*
1921          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1922          * as we should not be calling schedule in NMI context.
1923          * Even with normal interrupts enabled. An NMI should not be
1924          * setting NEED_RESCHED or anything that normal interrupts and
1925          * exceptions might do.
1926          */
1927         call save_paranoid
1928         DEFAULT_FRAME 0
1929
1930         /*
1931          * Save off the CR2 register. If we take a page fault in the NMI then
1932          * it could corrupt the CR2 value. If the NMI preempts a page fault
1933          * handler before it was able to read the CR2 register, and then the
1934          * NMI itself takes a page fault, the page fault that was preempted
1935          * will read the information from the NMI page fault and not the
1936          * origin fault. Save it off and restore it if it changes.
1937          * Use the r12 callee-saved register.
1938          */
1939         movq %cr2, %r12
1940
1941         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1942         movq %rsp,%rdi
1943         movq $-1,%rsi
1944         call do_nmi
1945
1946         /* Did the NMI take a page fault? Restore cr2 if it did */
1947         movq %cr2, %rcx
1948         cmpq %rcx, %r12
1949         je 1f
1950         movq %r12, %cr2
1951 1:
1952
1953         testl %ebx,%ebx                         /* swapgs needed? */
1954         jnz nmi_restore
1955 nmi_swapgs:
1956         SWAPGS_UNSAFE_STACK
1957 nmi_restore:
1958         /* Pop the extra iret frame at once */
1959         RESTORE_ALL 6*8
1960
1961         /* Clear the NMI executing stack variable */
1962         movq $0, 5*8(%rsp)
1963         jmp irq_return
1964         CFI_ENDPROC
1965 END(nmi)
1966
1967 ENTRY(ignore_sysret)
1968         CFI_STARTPROC
1969         mov $-ENOSYS,%eax
1970         sysret
1971         CFI_ENDPROC
1972 END(ignore_sysret)
1973
1974 /*
1975  * End of kprobes section
1976  */
1977         .popsection