arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/pgtable_types.h>
  59
  60 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  61 #include <linux/elf-em.h>
  62 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  63 #define __AUDIT_ARCH_64BIT 0x80000000
  64 #define __AUDIT_ARCH_LE    0x40000000
  65
  66         .code64
  67         .section .entry.text, "ax"
  68
  69 #ifdef CONFIG_FUNCTION_TRACER
  70 #ifdef CONFIG_DYNAMIC_FTRACE
  71 ENTRY(mcount)
  72         retq
  73 END(mcount)
  74
  75 ENTRY(ftrace_caller)
  76         cmpl $0, function_trace_stop
  77         jne  ftrace_stub
  78
  79         MCOUNT_SAVE_FRAME
  80
  81         movq 0x38(%rsp), %rdi
  82         movq 8(%rbp), %rsi
  83         subq $MCOUNT_INSN_SIZE, %rdi
  84
  85 GLOBAL(ftrace_call)
  86         call ftrace_stub
  87
  88         MCOUNT_RESTORE_FRAME
  89
  90 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  91 GLOBAL(ftrace_graph_call)
  92         jmp ftrace_stub
  93 #endif
  94
  95 GLOBAL(ftrace_stub)
  96         retq
  97 END(ftrace_caller)
  98
  99 #else /* ! CONFIG_DYNAMIC_FTRACE */
 100 ENTRY(mcount)
 101         cmpl $0, function_trace_stop
 102         jne  ftrace_stub
 103
 104         cmpq $ftrace_stub, ftrace_trace_function
 105         jnz trace
 106
 107 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 108         cmpq $ftrace_stub, ftrace_graph_return
 109         jnz ftrace_graph_caller
 110
 111         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 112         jnz ftrace_graph_caller
 113 #endif
 114
 115 GLOBAL(ftrace_stub)
 116         retq
 117
 118 trace:
 119         MCOUNT_SAVE_FRAME
 120
 121         movq 0x38(%rsp), %rdi
 122         movq 8(%rbp), %rsi
 123         subq $MCOUNT_INSN_SIZE, %rdi
 124
 125         call   *ftrace_trace_function
 126
 127         MCOUNT_RESTORE_FRAME
 128
 129         jmp ftrace_stub
 130 END(mcount)
 131 #endif /* CONFIG_DYNAMIC_FTRACE */
 132 #endif /* CONFIG_FUNCTION_TRACER */
 133
 134 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 135 ENTRY(ftrace_graph_caller)
 136         cmpl $0, function_trace_stop
 137         jne ftrace_stub
 138
 139         MCOUNT_SAVE_FRAME
 140
 141         leaq 8(%rbp), %rdi
 142         movq 0x38(%rsp), %rsi
 143         movq (%rbp), %rdx
 144         subq $MCOUNT_INSN_SIZE, %rsi
 145
 146         call    prepare_ftrace_return
 147
 148         MCOUNT_RESTORE_FRAME
 149
 150         retq
 151 END(ftrace_graph_caller)
 152
 153 GLOBAL(return_to_handler)
 154         subq  $24, %rsp
 155
 156         /* Save the return values */
 157         movq %rax, (%rsp)
 158         movq %rdx, 8(%rsp)
 159         movq %rbp, %rdi
 160
 161         call ftrace_return_to_handler
 162
 163         movq %rax, %rdi
 164         movq 8(%rsp), %rdx
 165         movq (%rsp), %rax
 166         addq $24, %rsp
 167         jmp *%rdi
 168 #endif
 169
 170
 171 #ifndef CONFIG_PREEMPT
 172 #define retint_kernel retint_restore_args
 173 #endif
 174
 175 #ifdef CONFIG_PARAVIRT
 176 ENTRY(native_usergs_sysret64)
 177         swapgs
 178         sysretq
 179 ENDPROC(native_usergs_sysret64)
 180 #endif /* CONFIG_PARAVIRT */
 181
 182
 183 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 184 #ifdef CONFIG_TRACE_IRQFLAGS
 185         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 186         jnc  1f
 187         TRACE_IRQS_ON
 188 1:
 189 #endif
 190 .endm
 191
 192 /*
 193  * C code is not supposed to know about undefined top of stack. Every time
 194  * a C function with an pt_regs argument is called from the SYSCALL based
 195  * fast path FIXUP_TOP_OF_STACK is needed.
 196  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 197  * manipulation.
 198  */
 199
 200         /* %rsp:at FRAMEEND */
 201         .macro FIXUP_TOP_OF_STACK tmp offset=0
 202         movq PER_CPU_VAR(old_rsp),\tmp
 203         movq \tmp,RSP+\offset(%rsp)
 204         movq $__USER_DS,SS+\offset(%rsp)
 205         movq $__USER_CS,CS+\offset(%rsp)
 206         movq $-1,RCX+\offset(%rsp)
 207         movq R11+\offset(%rsp),\tmp  /* get eflags */
 208         movq \tmp,EFLAGS+\offset(%rsp)
 209         .endm
 210
 211         .macro RESTORE_TOP_OF_STACK tmp offset=0
 212         movq RSP+\offset(%rsp),\tmp
 213         movq \tmp,PER_CPU_VAR(old_rsp)
 214         movq EFLAGS+\offset(%rsp),\tmp
 215         movq \tmp,R11+\offset(%rsp)
 216         .endm
 217
 218         .macro FAKE_STACK_FRAME child_rip
 219         /* push in order ss, rsp, eflags, cs, rip */
 220         xorl %eax, %eax
 221         pushq_cfi $__KERNEL_DS /* ss */
 222         /*CFI_REL_OFFSET        ss,0*/
 223         pushq_cfi %rax /* rsp */
 224         CFI_REL_OFFSET  rsp,0
 225         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 226         /*CFI_REL_OFFSET        rflags,0*/
 227         pushq_cfi $__KERNEL_CS /* cs */
 228         /*CFI_REL_OFFSET        cs,0*/
 229         pushq_cfi \child_rip /* rip */
 230         CFI_REL_OFFSET  rip,0
 231         pushq_cfi %rax /* orig rax */
 232         .endm
 233
 234         .macro UNFAKE_STACK_FRAME
 235         addq $8*6, %rsp
 236         CFI_ADJUST_CFA_OFFSET   -(6*8)
 237         .endm
 238
 239 /*
 240  * initial frame state for interrupts (and exceptions without error code)
 241  */
 242         .macro EMPTY_FRAME start=1 offset=0
 243         .if \start
 244         CFI_STARTPROC simple
 245         CFI_SIGNAL_FRAME
 246         CFI_DEF_CFA rsp,8+\offset
 247         .else
 248         CFI_DEF_CFA_OFFSET 8+\offset
 249         .endif
 250         .endm
 251
 252 /*
 253  * initial frame state for interrupts (and exceptions without error code)
 254  */
 255         .macro INTR_FRAME start=1 offset=0
 256         EMPTY_FRAME \start, SS+8+\offset-RIP
 257         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 258         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 259         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 260         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 261         CFI_REL_OFFSET rip, RIP+\offset-RIP
 262         .endm
 263
 264 /*
 265  * initial frame state for exceptions with error code (and interrupts
 266  * with vector already pushed)
 267  */
 268         .macro XCPT_FRAME start=1 offset=0
 269         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 270         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 271         .endm
 272
 273 /*
 274  * frame that enables calling into C.
 275  */
 276         .macro PARTIAL_FRAME start=1 offset=0
 277         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 278         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 283         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 286         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 287         .endm
 288
 289 /*
 290  * frame that enables passing a complete pt_regs to a C function.
 291  */
 292         .macro DEFAULT_FRAME start=1 offset=0
 293         PARTIAL_FRAME \start, R11+\offset-R15
 294         CFI_REL_OFFSET rbx, RBX+\offset
 295         CFI_REL_OFFSET rbp, RBP+\offset
 296         CFI_REL_OFFSET r12, R12+\offset
 297         CFI_REL_OFFSET r13, R13+\offset
 298         CFI_REL_OFFSET r14, R14+\offset
 299         CFI_REL_OFFSET r15, R15+\offset
 300         .endm
 301
 302 /* save partial stack frame */
 303         .macro SAVE_ARGS_IRQ
 304         cld
 305         /* start from rbp in pt_regs and jump over */
 306         movq_cfi rdi, RDI-RBP
 307         movq_cfi rsi, RSI-RBP
 308         movq_cfi rdx, RDX-RBP
 309         movq_cfi rcx, RCX-RBP
 310         movq_cfi rax, RAX-RBP
 311         movq_cfi  r8,  R8-RBP
 312         movq_cfi  r9,  R9-RBP
 313         movq_cfi r10, R10-RBP
 314         movq_cfi r11, R11-RBP
 315
 316         /* Save rbp so that we can unwind from get_irq_regs() */
 317         movq_cfi rbp, 0
 318
 319         /* Save previous stack value */
 320         movq %rsp, %rsi
 321
 322         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 323         testl $3, CS(%rdi)
 324         je 1f
 325         SWAPGS
 326         /*
 327          * irq_count is used to check if a CPU is already on an interrupt stack
 328          * or not. While this is essentially redundant with preempt_count it is
 329          * a little cheaper to use a separate counter in the PDA (short of
 330          * moving irq_enter into assembly, which would be too much work)
 331          */
 332 1:      incl PER_CPU_VAR(irq_count)
 333         jne 2f
 334         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 335         CFI_DEF_CFA_REGISTER    rsi
 336
 337 2:      /* Store previous stack value */
 338         pushq %rsi
 339         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 340                         0x77 /* DW_OP_breg7 */, 0, \
 341                         0x06 /* DW_OP_deref */, \
 342                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 343                         0x22 /* DW_OP_plus */
 344         /* We entered an interrupt context - irqs are off: */
 345         TRACE_IRQS_OFF
 346         .endm
 347
 348 ENTRY(save_rest)
 349         PARTIAL_FRAME 1 REST_SKIP+8
 350         movq 5*8+16(%rsp), %r11 /* save return address */
 351         movq_cfi rbx, RBX+16
 352         movq_cfi rbp, RBP+16
 353         movq_cfi r12, R12+16
 354         movq_cfi r13, R13+16
 355         movq_cfi r14, R14+16
 356         movq_cfi r15, R15+16
 357         movq %r11, 8(%rsp)      /* return address */
 358         FIXUP_TOP_OF_STACK %r11, 16
 359         ret
 360         CFI_ENDPROC
 361 END(save_rest)
 362
 363 /* save complete stack frame */
 364         .pushsection .kprobes.text, "ax"
 365 ENTRY(save_paranoid)
 366         XCPT_FRAME 1 RDI+8
 367         cld
 368         movq_cfi rdi, RDI+8
 369         movq_cfi rsi, RSI+8
 370         movq_cfi rdx, RDX+8
 371         movq_cfi rcx, RCX+8
 372         movq_cfi rax, RAX+8
 373         movq_cfi r8, R8+8
 374         movq_cfi r9, R9+8
 375         movq_cfi r10, R10+8
 376         movq_cfi r11, R11+8
 377         movq_cfi rbx, RBX+8
 378         movq_cfi rbp, RBP+8
 379         movq_cfi r12, R12+8
 380         movq_cfi r13, R13+8
 381         movq_cfi r14, R14+8
 382         movq_cfi r15, R15+8
 383         movl $1,%ebx
 384         movl $MSR_GS_BASE,%ecx
 385         rdmsr
 386         testl %edx,%edx
 387         js 1f   /* negative -> in kernel */
 388         SWAPGS
 389         xorl %ebx,%ebx
 390 1:      ret
 391         CFI_ENDPROC
 392 END(save_paranoid)
 393         .popsection
 394
 395 /*
 396  * A newly forked process directly context switches into this address.
 397  *
 398  * rdi: prev task we switched from
 399  */
 400 ENTRY(ret_from_fork)
 401         DEFAULT_FRAME
 402
 403         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 404
 405         pushq_cfi kernel_eflags(%rip)
 406         popfq_cfi                               # reset kernel eflags
 407
 408         call schedule_tail                      # rdi: 'prev' task parameter
 409
 410         GET_THREAD_INFO(%rcx)
 411
 412         RESTORE_REST
 413
 414         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 415         je   int_ret_from_sys_call
 416
 417         /*
 418          * By the time we get here, we have no idea whether our pt_regs,
 419          * ti flags, and ti status came from the 64-bit SYSCALL fast path,
 420          * the slow path, or one of the ia32entry paths.
 421          * Use int_ret_from_sys_call to return, since it can safely handle
 422          * all of the above.
 423          */
 424         jmp  int_ret_from_sys_call
 425
 426         CFI_ENDPROC
 427 END(ret_from_fork)
 428
 429 /*
 430  * System call entry. Up to 6 arguments in registers are supported.
 431  *
 432  * SYSCALL does not save anything on the stack and does not change the
 433  * stack pointer.
 434  */
 435
 436 /*
 437  * Register setup:
 438  * rax  system call number
 439  * rdi  arg0
 440  * rcx  return address for syscall/sysret, C arg3
 441  * rsi  arg1
 442  * rdx  arg2
 443  * r10  arg3    (--> moved to rcx for C)
 444  * r8   arg4
 445  * r9   arg5
 446  * r11  eflags for syscall/sysret, temporary for C
 447  * r12-r15,rbp,rbx saved by C code, not touched.
 448  *
 449  * Interrupts are off on entry.
 450  * Only called from user space.
 451  *
 452  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 453  *      and report it properly in ps. Unfortunately we haven't.
 454  *
 455  * When user can change the frames always force IRET. That is because
 456  * it deals with uncanonical addresses better. SYSRET has trouble
 457  * with them due to bugs in both AMD and Intel CPUs.
 458  */
 459
 460 ENTRY(system_call)
 461         CFI_STARTPROC   simple
 462         CFI_SIGNAL_FRAME
 463         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 464         CFI_REGISTER    rip,rcx
 465         /*CFI_REGISTER  rflags,r11*/
 466         SWAPGS_UNSAFE_STACK
 467         /*
 468          * A hypervisor implementation might want to use a label
 469          * after the swapgs, so that it can do the swapgs
 470          * for the guest and jump here on syscall.
 471          */
 472 ENTRY(system_call_after_swapgs)
 473
 474         movq    %rsp,PER_CPU_VAR(old_rsp)
 475         movq    PER_CPU_VAR(kernel_stack),%rsp
 476         /*
 477          * No need to follow this irqs off/on section - it's straight
 478          * and short:
 479          */
 480         ENABLE_INTERRUPTS(CLBR_NONE)
 481         SAVE_ARGS 8,0
 482         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 483         movq  %rcx,RIP-ARGOFFSET(%rsp)
 484         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 485         GET_THREAD_INFO(%rcx)
 486         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 487         jnz tracesys
 488 system_call_fastpath:
 489         cmpq $__NR_syscall_max,%rax
 490         ja badsys
 491         movq %r10,%rcx
 492         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 493         movq %rax,RAX-ARGOFFSET(%rsp)
 494 /*
 495  * Syscall return path ending with SYSRET (fast path)
 496  * Has incomplete stack frame and undefined top of stack.
 497  */
 498 ret_from_sys_call:
 499         movl $_TIF_ALLWORK_MASK,%edi
 500         /* edi: flagmask */
 501 sysret_check:
 502         LOCKDEP_SYS_EXIT
 503         GET_THREAD_INFO(%rcx)
 504         DISABLE_INTERRUPTS(CLBR_NONE)
 505         TRACE_IRQS_OFF
 506         movl TI_flags(%rcx),%edx
 507         andl %edi,%edx
 508         jnz  sysret_careful
 509         CFI_REMEMBER_STATE
 510         /*
 511          * sysretq will re-enable interrupts:
 512          */
 513         TRACE_IRQS_ON
 514         movq RIP-ARGOFFSET(%rsp),%rcx
 515         CFI_REGISTER    rip,rcx
 516         RESTORE_ARGS 1,-ARG_SKIP,0
 517         /*CFI_REGISTER  rflags,r11*/
 518         movq    PER_CPU_VAR(old_rsp), %rsp
 519         USERGS_SYSRET64
 520
 521         CFI_RESTORE_STATE
 522         /* Handle reschedules */
 523         /* edx: work, edi: workmask */
 524 sysret_careful:
 525         bt $TIF_NEED_RESCHED,%edx
 526         jnc sysret_signal
 527         TRACE_IRQS_ON
 528         ENABLE_INTERRUPTS(CLBR_NONE)
 529         pushq_cfi %rdi
 530         call schedule
 531         popq_cfi %rdi
 532         jmp sysret_check
 533
 534         /* Handle a signal */
 535 sysret_signal:
 536         TRACE_IRQS_ON
 537         ENABLE_INTERRUPTS(CLBR_NONE)
 538 #ifdef CONFIG_AUDITSYSCALL
 539         bt $TIF_SYSCALL_AUDIT,%edx
 540         jc sysret_audit
 541 #endif
 542         /*
 543          * We have a signal, or exit tracing or single-step.
 544          * These all wind up with the iret return path anyway,
 545          * so just join that path right now.
 546          */
 547         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 548         jmp int_check_syscall_exit_work
 549
 550 badsys:
 551         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 552         jmp ret_from_sys_call
 553
 554 #ifdef CONFIG_AUDITSYSCALL
 555         /*
 556          * Fast path for syscall audit without full syscall trace.
 557          * We just call audit_syscall_entry() directly, and then
 558          * jump back to the normal fast path.
 559          */
 560 auditsys:
 561         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 562         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 563         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 564         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 565         movq %rax,%rsi                  /* 2nd arg: syscall number */
 566         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 567         call audit_syscall_entry
 568         LOAD_ARGS 0             /* reload call-clobbered registers */
 569         jmp system_call_fastpath
 570
 571         /*
 572          * Return fast path for syscall audit.  Call audit_syscall_exit()
 573          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 574          * masked off.
 575          */
 576 sysret_audit:
 577         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 578         cmpq $0,%rsi            /* is it < 0? */
 579         setl %al                /* 1 if so, 0 if not */
 580         movzbl %al,%edi         /* zero-extend that into %edi */
 581         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 582         call audit_syscall_exit
 583         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 584         jmp sysret_check
 585 #endif  /* CONFIG_AUDITSYSCALL */
 586
 587         /* Do syscall tracing */
 588 tracesys:
 589 #ifdef CONFIG_AUDITSYSCALL
 590         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 591         jz auditsys
 592 #endif
 593         SAVE_REST
 594         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 595         FIXUP_TOP_OF_STACK %rdi
 596         movq %rsp,%rdi
 597         call syscall_trace_enter
 598         /*
 599          * Reload arg registers from stack in case ptrace changed them.
 600          * We don't reload %rax because syscall_trace_enter() returned
 601          * the value it wants us to use in the table lookup.
 602          */
 603         LOAD_ARGS ARGOFFSET, 1
 604         RESTORE_REST
 605         cmpq $__NR_syscall_max,%rax
 606         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 607         movq %r10,%rcx  /* fixup for C */
 608         call *sys_call_table(,%rax,8)
 609         movq %rax,RAX-ARGOFFSET(%rsp)
 610         /* Use IRET because user could have changed frame */
 611
 612 /*
 613  * Syscall return path ending with IRET.
 614  * Has correct top of stack, but partial stack frame.
 615  */
 616 GLOBAL(int_ret_from_sys_call)
 617         DISABLE_INTERRUPTS(CLBR_NONE)
 618         TRACE_IRQS_OFF
 619         testl $3,CS-ARGOFFSET(%rsp)
 620         je retint_restore_args
 621         movl $_TIF_ALLWORK_MASK,%edi
 622         /* edi: mask to check */
 623 GLOBAL(int_with_check)
 624         LOCKDEP_SYS_EXIT_IRQ
 625         GET_THREAD_INFO(%rcx)
 626         movl TI_flags(%rcx),%edx
 627         andl %edi,%edx
 628         jnz   int_careful
 629         andl    $~TS_COMPAT,TI_status(%rcx)
 630         jmp   retint_swapgs
 631
 632         /* Either reschedule or signal or syscall exit tracking needed. */
 633         /* First do a reschedule test. */
 634         /* edx: work, edi: workmask */
 635 int_careful:
 636         bt $TIF_NEED_RESCHED,%edx
 637         jnc  int_very_careful
 638         TRACE_IRQS_ON
 639         ENABLE_INTERRUPTS(CLBR_NONE)
 640         pushq_cfi %rdi
 641         call schedule
 642         popq_cfi %rdi
 643         DISABLE_INTERRUPTS(CLBR_NONE)
 644         TRACE_IRQS_OFF
 645         jmp int_with_check
 646
 647         /* handle signals and tracing -- both require a full stack frame */
 648 int_very_careful:
 649         TRACE_IRQS_ON
 650         ENABLE_INTERRUPTS(CLBR_NONE)
 651 int_check_syscall_exit_work:
 652         SAVE_REST
 653         /* Check for syscall exit trace */
 654         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 655         jz int_signal
 656         pushq_cfi %rdi
 657         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 658         call syscall_trace_leave
 659         popq_cfi %rdi
 660         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 661         jmp int_restore_rest
 662
 663 int_signal:
 664         testl $_TIF_DO_NOTIFY_MASK,%edx
 665         jz 1f
 666         movq %rsp,%rdi          # &ptregs -> arg1
 667         xorl %esi,%esi          # oldset -> arg2
 668         call do_notify_resume
 669 1:      movl $_TIF_WORK_MASK,%edi
 670 int_restore_rest:
 671         RESTORE_REST
 672         DISABLE_INTERRUPTS(CLBR_NONE)
 673         TRACE_IRQS_OFF
 674         jmp int_with_check
 675         CFI_ENDPROC
 676 END(system_call)
 677
 678 /*
 679  * Certain special system calls that need to save a complete full stack frame.
 680  */
 681         .macro PTREGSCALL label,func,arg
 682 ENTRY(\label)
 683         PARTIAL_FRAME 1 8               /* offset 8: return address */
 684         subq $REST_SKIP, %rsp
 685         CFI_ADJUST_CFA_OFFSET REST_SKIP
 686         call save_rest
 687         DEFAULT_FRAME 0 8               /* offset 8: return address */
 688         leaq 8(%rsp), \arg      /* pt_regs pointer */
 689         call \func
 690         jmp ptregscall_common
 691         CFI_ENDPROC
 692 END(\label)
 693         .endm
 694
 695         PTREGSCALL stub_clone, sys_clone, %r8
 696         PTREGSCALL stub_fork, sys_fork, %rdi
 697         PTREGSCALL stub_vfork, sys_vfork, %rdi
 698         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 699         PTREGSCALL stub_iopl, sys_iopl, %rsi
 700
 701 ENTRY(ptregscall_common)
 702         DEFAULT_FRAME 1 8       /* offset 8: return address */
 703         RESTORE_TOP_OF_STACK %r11, 8
 704         movq_cfi_restore R15+8, r15
 705         movq_cfi_restore R14+8, r14
 706         movq_cfi_restore R13+8, r13
 707         movq_cfi_restore R12+8, r12
 708         movq_cfi_restore RBP+8, rbp
 709         movq_cfi_restore RBX+8, rbx
 710         ret $REST_SKIP          /* pop extended registers */
 711         CFI_ENDPROC
 712 END(ptregscall_common)
 713
 714 ENTRY(stub_execve)
 715         CFI_STARTPROC
 716         addq $8, %rsp
 717         PARTIAL_FRAME 0
 718         SAVE_REST
 719         FIXUP_TOP_OF_STACK %r11
 720         movq %rsp, %rcx
 721         call sys_execve
 722         RESTORE_TOP_OF_STACK %r11
 723         movq %rax,RAX(%rsp)
 724         RESTORE_REST
 725         jmp int_ret_from_sys_call
 726         CFI_ENDPROC
 727 END(stub_execve)
 728
 729 /*
 730  * sigreturn is special because it needs to restore all registers on return.
 731  * This cannot be done with SYSRET, so use the IRET return path instead.
 732  */
 733 ENTRY(stub_rt_sigreturn)
 734         CFI_STARTPROC
 735         addq $8, %rsp
 736         PARTIAL_FRAME 0
 737         SAVE_REST
 738         movq %rsp,%rdi
 739         FIXUP_TOP_OF_STACK %r11
 740         call sys_rt_sigreturn
 741         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 742         RESTORE_REST
 743         jmp int_ret_from_sys_call
 744         CFI_ENDPROC
 745 END(stub_rt_sigreturn)
 746
 747 /*
 748  * Build the entry stubs and pointer table with some assembler magic.
 749  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 750  * single cache line on all modern x86 implementations.
 751  */
 752         .section .init.rodata,"a"
 753 ENTRY(interrupt)
 754         .section .entry.text
 755         .p2align 5
 756         .p2align CONFIG_X86_L1_CACHE_SHIFT
 757 ENTRY(irq_entries_start)
 758         INTR_FRAME
 759 vector=FIRST_EXTERNAL_VECTOR
 760 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 761         .balign 32
 762   .rept 7
 763     .if vector < NR_VECTORS
 764       .if vector <> FIRST_EXTERNAL_VECTOR
 765         CFI_ADJUST_CFA_OFFSET -8
 766       .endif
 767 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 768       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 769         jmp 2f
 770       .endif
 771       .previous
 772         .quad 1b
 773       .section .entry.text
 774 vector=vector+1
 775     .endif
 776   .endr
 777 2:      jmp common_interrupt
 778 .endr
 779         CFI_ENDPROC
 780 END(irq_entries_start)
 781
 782 .previous
 783 END(interrupt)
 784 .previous
 785
 786 /*
 787  * Interrupt entry/exit.
 788  *
 789  * Interrupt entry points save only callee clobbered registers in fast path.
 790  *
 791  * Entry runs with interrupts off.
 792  */
 793
 794 /* 0(%rsp): ~(interrupt number) */
 795         .macro interrupt func
 796         /* reserve pt_regs for scratch regs and rbp */
 797         subq $ORIG_RAX-RBP, %rsp
 798         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 799         SAVE_ARGS_IRQ
 800         call \func
 801         .endm
 802
 803 /*
 804  * Interrupt entry/exit should be protected against kprobes
 805  */
 806         .pushsection .kprobes.text, "ax"
 807         /*
 808          * The interrupt stubs push (~vector+0x80) onto the stack and
 809          * then jump to common_interrupt.
 810          */
 811         .p2align CONFIG_X86_L1_CACHE_SHIFT
 812 common_interrupt:
 813         XCPT_FRAME
 814         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 815         interrupt do_IRQ
 816         /* 0(%rsp): old_rsp-ARGOFFSET */
 817 ret_from_intr:
 818         DISABLE_INTERRUPTS(CLBR_NONE)
 819         TRACE_IRQS_OFF
 820         decl PER_CPU_VAR(irq_count)
 821
 822         /* Restore saved previous stack */
 823         popq %rsi
 824         CFI_DEF_CFA_REGISTER    rsi
 825         leaq ARGOFFSET-RBP(%rsi), %rsp
 826         CFI_DEF_CFA_REGISTER    rsp
 827         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 828
 829 exit_intr:
 830         GET_THREAD_INFO(%rcx)
 831         testl $3,CS-ARGOFFSET(%rsp)
 832         je retint_kernel
 833
 834         /* Interrupt came from user space */
 835         /*
 836          * Has a correct top of stack, but a partial stack frame
 837          * %rcx: thread info. Interrupts off.
 838          */
 839 retint_with_reschedule:
 840         movl $_TIF_WORK_MASK,%edi
 841 retint_check:
 842         LOCKDEP_SYS_EXIT_IRQ
 843         movl TI_flags(%rcx),%edx
 844         andl %edi,%edx
 845         CFI_REMEMBER_STATE
 846         jnz  retint_careful
 847
 848 retint_swapgs:          /* return to user-space */
 849         /*
 850          * The iretq could re-enable interrupts:
 851          */
 852         DISABLE_INTERRUPTS(CLBR_ANY)
 853         TRACE_IRQS_IRETQ
 854         SWAPGS
 855         jmp restore_args
 856
 857 retint_restore_args:    /* return to kernel space */
 858         DISABLE_INTERRUPTS(CLBR_ANY)
 859         /*
 860          * The iretq could re-enable interrupts:
 861          */
 862         TRACE_IRQS_IRETQ
 863 restore_args:
 864         RESTORE_ARGS 1,8,1
 865
 866 irq_return:
 867         INTERRUPT_RETURN
 868
 869 ENTRY(native_iret)
 870         /*
 871          * Are we returning to a stack segment from the LDT?  Note: in
 872          * 64-bit mode SS:RSP on the exception stack is always valid.
 873          */
 874 #ifdef CONFIG_X86_ESPFIX64
 875         testb $4,(SS-RIP)(%rsp)
 876         jnz native_irq_return_ldt
 877 #endif
 878
 879 .global native_irq_return_iret
 880 native_irq_return_iret:
 881         /*
 882          * This may fault.  Non-paranoid faults on return to userspace are
 883          * handled by fixup_bad_iret.  These include #SS, #GP, and #NP.
 884          * Double-faults due to espfix64 are handled in do_double_fault.
 885          * Other faults here are fatal.
 886          */
 887         iretq
 888
 889 #ifdef CONFIG_X86_ESPFIX64
 890 native_irq_return_ldt:
 891         pushq_cfi %rax
 892         pushq_cfi %rdi
 893         SWAPGS
 894         movq PER_CPU_VAR(espfix_waddr),%rdi
 895         movq %rax,(0*8)(%rdi)   /* RAX */
 896         movq (2*8)(%rsp),%rax   /* RIP */
 897         movq %rax,(1*8)(%rdi)
 898         movq (3*8)(%rsp),%rax   /* CS */
 899         movq %rax,(2*8)(%rdi)
 900         movq (4*8)(%rsp),%rax   /* RFLAGS */
 901         movq %rax,(3*8)(%rdi)
 902         movq (6*8)(%rsp),%rax   /* SS */
 903         movq %rax,(5*8)(%rdi)
 904         movq (5*8)(%rsp),%rax   /* RSP */
 905         movq %rax,(4*8)(%rdi)
 906         andl $0xffff0000,%eax
 907         popq_cfi %rdi
 908         orq PER_CPU_VAR(espfix_stack),%rax
 909         SWAPGS
 910         movq %rax,%rsp
 911         popq_cfi %rax
 912         jmp native_irq_return_iret
 913 #endif
 914
 915         /* edi: workmask, edx: work */
 916 retint_careful:
 917         CFI_RESTORE_STATE
 918         bt    $TIF_NEED_RESCHED,%edx
 919         jnc   retint_signal
 920         TRACE_IRQS_ON
 921         ENABLE_INTERRUPTS(CLBR_NONE)
 922         pushq_cfi %rdi
 923         call  schedule
 924         popq_cfi %rdi
 925         GET_THREAD_INFO(%rcx)
 926         DISABLE_INTERRUPTS(CLBR_NONE)
 927         TRACE_IRQS_OFF
 928         jmp retint_check
 929
 930 retint_signal:
 931         testl $_TIF_DO_NOTIFY_MASK,%edx
 932         jz    retint_swapgs
 933         TRACE_IRQS_ON
 934         ENABLE_INTERRUPTS(CLBR_NONE)
 935         SAVE_REST
 936         movq $-1,ORIG_RAX(%rsp)
 937         xorl %esi,%esi          # oldset
 938         movq %rsp,%rdi          # &pt_regs
 939         call do_notify_resume
 940         RESTORE_REST
 941         DISABLE_INTERRUPTS(CLBR_NONE)
 942         TRACE_IRQS_OFF
 943         GET_THREAD_INFO(%rcx)
 944         jmp retint_with_reschedule
 945
 946 #ifdef CONFIG_PREEMPT
 947         /* Returning to kernel space. Check if we need preemption */
 948         /* rcx:  threadinfo. interrupts off. */
 949 ENTRY(retint_kernel)
 950         cmpl $0,TI_preempt_count(%rcx)
 951         jnz  retint_restore_args
 952         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 953         jnc  retint_restore_args
 954         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 955         jnc  retint_restore_args
 956         call preempt_schedule_irq
 957         jmp exit_intr
 958 #endif
 959         CFI_ENDPROC
 960 END(common_interrupt)
 961
 962 /*
 963  * End of kprobes section
 964  */
 965        .popsection
 966
 967 /*
 968  * APIC interrupts.
 969  */
 970 .macro apicinterrupt num sym do_sym
 971 ENTRY(\sym)
 972         INTR_FRAME
 973         pushq_cfi $~(\num)
 974         interrupt \do_sym
 975         jmp ret_from_intr
 976         CFI_ENDPROC
 977 END(\sym)
 978 .endm
 979
 980 #ifdef CONFIG_SMP
 981 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 982         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 983 apicinterrupt REBOOT_VECTOR \
 984         reboot_interrupt smp_reboot_interrupt
 985 #endif
 986
 987 #ifdef CONFIG_X86_UV
 988 apicinterrupt UV_BAU_MESSAGE \
 989         uv_bau_message_intr1 uv_bau_message_interrupt
 990 #endif
 991 apicinterrupt LOCAL_TIMER_VECTOR \
 992         apic_timer_interrupt smp_apic_timer_interrupt
 993 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 994         x86_platform_ipi smp_x86_platform_ipi
 995
 996 #ifdef CONFIG_SMP
 997 .irp idx,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
 998         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
 999 .if NUM_INVALIDATE_TLB_VECTORS > \idx
1000 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
1001         invalidate_interrupt\idx smp_invalidate_interrupt
1002 .endif
1003 .endr
1004 #endif
1005
1006 apicinterrupt THRESHOLD_APIC_VECTOR \
1007         threshold_interrupt smp_threshold_interrupt
1008 apicinterrupt THERMAL_APIC_VECTOR \
1009         thermal_interrupt smp_thermal_interrupt
1010
1011 #ifdef CONFIG_SMP
1012 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1013         call_function_single_interrupt smp_call_function_single_interrupt
1014 apicinterrupt CALL_FUNCTION_VECTOR \
1015         call_function_interrupt smp_call_function_interrupt
1016 apicinterrupt RESCHEDULE_VECTOR \
1017         reschedule_interrupt smp_reschedule_interrupt
1018 #endif
1019
1020 apicinterrupt ERROR_APIC_VECTOR \
1021         error_interrupt smp_error_interrupt
1022 apicinterrupt SPURIOUS_APIC_VECTOR \
1023         spurious_interrupt smp_spurious_interrupt
1024
1025 #ifdef CONFIG_IRQ_WORK
1026 apicinterrupt IRQ_WORK_VECTOR \
1027         irq_work_interrupt smp_irq_work_interrupt
1028 #endif
1029
1030 /*
1031  * Exception entry points.
1032  */
1033 .macro zeroentry sym do_sym
1034 ENTRY(\sym)
1035         INTR_FRAME
1036         PARAVIRT_ADJUST_EXCEPTION_FRAME
1037         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1038         subq $ORIG_RAX-R15, %rsp
1039         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1040         call error_entry
1041         DEFAULT_FRAME 0
1042         movq %rsp,%rdi          /* pt_regs pointer */
1043         xorl %esi,%esi          /* no error code */
1044         call \do_sym
1045         jmp error_exit          /* %ebx: no swapgs flag */
1046         CFI_ENDPROC
1047 END(\sym)
1048 .endm
1049
1050 .macro paranoidzeroentry sym do_sym
1051 ENTRY(\sym)
1052         INTR_FRAME
1053         PARAVIRT_ADJUST_EXCEPTION_FRAME
1054         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1055         subq $ORIG_RAX-R15, %rsp
1056         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1057         call save_paranoid
1058         TRACE_IRQS_OFF
1059         movq %rsp,%rdi          /* pt_regs pointer */
1060         xorl %esi,%esi          /* no error code */
1061         call \do_sym
1062         jmp paranoid_exit       /* %ebx: no swapgs flag */
1063         CFI_ENDPROC
1064 END(\sym)
1065 .endm
1066
1067 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1068 .macro paranoidzeroentry_ist sym do_sym ist
1069 ENTRY(\sym)
1070         INTR_FRAME
1071         PARAVIRT_ADJUST_EXCEPTION_FRAME
1072         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1073         subq $ORIG_RAX-R15, %rsp
1074         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1075         call save_paranoid
1076         TRACE_IRQS_OFF
1077         movq %rsp,%rdi          /* pt_regs pointer */
1078         xorl %esi,%esi          /* no error code */
1079         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1080         call \do_sym
1081         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1082         jmp paranoid_exit       /* %ebx: no swapgs flag */
1083         CFI_ENDPROC
1084 END(\sym)
1085 .endm
1086
1087 .macro errorentry sym do_sym
1088 ENTRY(\sym)
1089         XCPT_FRAME
1090         PARAVIRT_ADJUST_EXCEPTION_FRAME
1091         subq $ORIG_RAX-R15, %rsp
1092         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1093         call error_entry
1094         DEFAULT_FRAME 0
1095         movq %rsp,%rdi                  /* pt_regs pointer */
1096         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1097         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1098         call \do_sym
1099         jmp error_exit                  /* %ebx: no swapgs flag */
1100         CFI_ENDPROC
1101 END(\sym)
1102 .endm
1103
1104         /* error code is on the stack already */
1105 .macro paranoiderrorentry sym do_sym
1106 ENTRY(\sym)
1107         XCPT_FRAME
1108         PARAVIRT_ADJUST_EXCEPTION_FRAME
1109         subq $ORIG_RAX-R15, %rsp
1110         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1111         call save_paranoid
1112         DEFAULT_FRAME 0
1113         TRACE_IRQS_OFF
1114         movq %rsp,%rdi                  /* pt_regs pointer */
1115         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1116         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1117         call \do_sym
1118         jmp paranoid_exit               /* %ebx: no swapgs flag */
1119         CFI_ENDPROC
1120 END(\sym)
1121 .endm
1122
1123 zeroentry divide_error do_divide_error
1124 zeroentry overflow do_overflow
1125 zeroentry bounds do_bounds
1126 zeroentry invalid_op do_invalid_op
1127 zeroentry device_not_available do_device_not_available
1128 paranoiderrorentry double_fault do_double_fault
1129 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1130 errorentry invalid_TSS do_invalid_TSS
1131 errorentry segment_not_present do_segment_not_present
1132 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1133 zeroentry coprocessor_error do_coprocessor_error
1134 errorentry alignment_check do_alignment_check
1135 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1136
1137
1138         /* Reload gs selector with exception handling */
1139         /* edi:  new selector */
1140 ENTRY(native_load_gs_index)
1141         CFI_STARTPROC
1142         pushfq_cfi
1143         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1144         SWAPGS
1145 gs_change:
1146         movl %edi,%gs
1147 2:      mfence          /* workaround */
1148         SWAPGS
1149         popfq_cfi
1150         ret
1151         CFI_ENDPROC
1152 END(native_load_gs_index)
1153
1154         .section __ex_table,"a"
1155         .align 8
1156         .quad gs_change,bad_gs
1157         .previous
1158         .section .fixup,"ax"
1159         /* running with kernelgs */
1160 bad_gs:
1161         SWAPGS                  /* switch back to user gs */
1162         xorl %eax,%eax
1163         movl %eax,%gs
1164         jmp  2b
1165         .previous
1166
1167 ENTRY(kernel_thread_helper)
1168         pushq $0                # fake return address
1169         CFI_STARTPROC
1170         /*
1171          * Here we are in the child and the registers are set as they were
1172          * at kernel_thread() invocation in the parent.
1173          */
1174         call *%rsi
1175         # exit
1176         mov %eax, %edi
1177         call do_exit
1178         ud2                     # padding for call trace
1179         CFI_ENDPROC
1180 END(kernel_thread_helper)
1181
1182 /*
1183  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1184  *
1185  * C extern interface:
1186  *       extern long execve(const char *name, char **argv, char **envp)
1187  *
1188  * asm input arguments:
1189  *      rdi: name, rsi: argv, rdx: envp
1190  *
1191  * We want to fallback into:
1192  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1193  *
1194  * do_sys_execve asm fallback arguments:
1195  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1196  */
1197 ENTRY(kernel_execve)
1198         CFI_STARTPROC
1199         FAKE_STACK_FRAME $0
1200         SAVE_ALL
1201         movq %rsp,%rcx
1202         call sys_execve
1203         movq %rax, RAX(%rsp)
1204         RESTORE_REST
1205         testq %rax,%rax
1206         je int_ret_from_sys_call
1207         RESTORE_ARGS
1208         UNFAKE_STACK_FRAME
1209         ret
1210         CFI_ENDPROC
1211 END(kernel_execve)
1212
1213 /* Call softirq on interrupt stack. Interrupts are off. */
1214 ENTRY(call_softirq)
1215         CFI_STARTPROC
1216         pushq_cfi %rbp
1217         CFI_REL_OFFSET rbp,0
1218         mov  %rsp,%rbp
1219         CFI_DEF_CFA_REGISTER rbp
1220         incl PER_CPU_VAR(irq_count)
1221         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1222         push  %rbp                      # backlink for old unwinder
1223         call __do_softirq
1224         leaveq
1225         CFI_RESTORE             rbp
1226         CFI_DEF_CFA_REGISTER    rsp
1227         CFI_ADJUST_CFA_OFFSET   -8
1228         decl PER_CPU_VAR(irq_count)
1229         ret
1230         CFI_ENDPROC
1231 END(call_softirq)
1232
1233 #ifdef CONFIG_XEN
1234 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1235
1236 /*
1237  * A note on the "critical region" in our callback handler.
1238  * We want to avoid stacking callback handlers due to events occurring
1239  * during handling of the last event. To do this, we keep events disabled
1240  * until we've done all processing. HOWEVER, we must enable events before
1241  * popping the stack frame (can't be done atomically) and so it would still
1242  * be possible to get enough handler activations to overflow the stack.
1243  * Although unlikely, bugs of that kind are hard to track down, so we'd
1244  * like to avoid the possibility.
1245  * So, on entry to the handler we detect whether we interrupted an
1246  * existing activation in its critical region -- if so, we pop the current
1247  * activation and restart the handler using the previous one.
1248  */
1249 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1250         CFI_STARTPROC
1251 /*
1252  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1253  * see the correct pointer to the pt_regs
1254  */
1255         movq %rdi, %rsp            # we don't return, adjust the stack frame
1256         CFI_ENDPROC
1257         DEFAULT_FRAME
1258 11:     incl PER_CPU_VAR(irq_count)
1259         movq %rsp,%rbp
1260         CFI_DEF_CFA_REGISTER rbp
1261         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1262         pushq %rbp                      # backlink for old unwinder
1263         call xen_evtchn_do_upcall
1264         popq %rsp
1265         CFI_DEF_CFA_REGISTER rsp
1266         decl PER_CPU_VAR(irq_count)
1267         jmp  error_exit
1268         CFI_ENDPROC
1269 END(xen_do_hypervisor_callback)
1270
1271 /*
1272  * Hypervisor uses this for application faults while it executes.
1273  * We get here for two reasons:
1274  *  1. Fault while reloading DS, ES, FS or GS
1275  *  2. Fault while executing IRET
1276  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1277  * registers that could be reloaded and zeroed the others.
1278  * Category 2 we fix up by killing the current process. We cannot use the
1279  * normal Linux return path in this case because if we use the IRET hypercall
1280  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1281  * We distinguish between categories by comparing each saved segment register
1282  * with its current contents: any discrepancy means we in category 1.
1283  */
1284 ENTRY(xen_failsafe_callback)
1285         INTR_FRAME 1 (6*8)
1286         /*CFI_REL_OFFSET gs,GS*/
1287         /*CFI_REL_OFFSET fs,FS*/
1288         /*CFI_REL_OFFSET es,ES*/
1289         /*CFI_REL_OFFSET ds,DS*/
1290         CFI_REL_OFFSET r11,8
1291         CFI_REL_OFFSET rcx,0
1292         movw %ds,%cx
1293         cmpw %cx,0x10(%rsp)
1294         CFI_REMEMBER_STATE
1295         jne 1f
1296         movw %es,%cx
1297         cmpw %cx,0x18(%rsp)
1298         jne 1f
1299         movw %fs,%cx
1300         cmpw %cx,0x20(%rsp)
1301         jne 1f
1302         movw %gs,%cx
1303         cmpw %cx,0x28(%rsp)
1304         jne 1f
1305         /* All segments match their saved values => Category 2 (Bad IRET). */
1306         movq (%rsp),%rcx
1307         CFI_RESTORE rcx
1308         movq 8(%rsp),%r11
1309         CFI_RESTORE r11
1310         addq $0x30,%rsp
1311         CFI_ADJUST_CFA_OFFSET -0x30
1312         pushq_cfi $0    /* RIP */
1313         pushq_cfi %r11
1314         pushq_cfi %rcx
1315         jmp general_protection
1316         CFI_RESTORE_STATE
1317 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1318         movq (%rsp),%rcx
1319         CFI_RESTORE rcx
1320         movq 8(%rsp),%r11
1321         CFI_RESTORE r11
1322         addq $0x30,%rsp
1323         CFI_ADJUST_CFA_OFFSET -0x30
1324         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1325         SAVE_ALL
1326         jmp error_exit
1327         CFI_ENDPROC
1328 END(xen_failsafe_callback)
1329
1330 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1331         xen_hvm_callback_vector xen_evtchn_do_upcall
1332
1333 #endif /* CONFIG_XEN */
1334
1335 /*
1336  * Some functions should be protected against kprobes
1337  */
1338         .pushsection .kprobes.text, "ax"
1339
1340 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1341 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1342 errorentry stack_segment do_stack_segment
1343 #ifdef CONFIG_XEN
1344 zeroentry xen_debug do_debug
1345 zeroentry xen_int3 do_int3
1346 errorentry xen_stack_segment do_stack_segment
1347 #endif
1348 errorentry general_protection do_general_protection
1349 errorentry page_fault do_page_fault
1350 #ifdef CONFIG_KVM_GUEST
1351 errorentry async_page_fault do_async_page_fault
1352 #endif
1353 #ifdef CONFIG_X86_MCE
1354 paranoidzeroentry machine_check *machine_check_vector(%rip)
1355 #endif
1356
1357         /*
1358          * "Paranoid" exit path from exception stack.
1359          * Paranoid because this is used by NMIs and cannot take
1360          * any kernel state for granted.
1361          * We don't do kernel preemption checks here, because only
1362          * NMI should be common and it does not enable IRQs and
1363          * cannot get reschedule ticks.
1364          *
1365          * "trace" is 0 for the NMI handler only, because irq-tracing
1366          * is fundamentally NMI-unsafe. (we cannot change the soft and
1367          * hard flags at once, atomically)
1368          */
1369
1370         /* ebx: no swapgs flag */
1371 ENTRY(paranoid_exit)
1372         DEFAULT_FRAME
1373         DISABLE_INTERRUPTS(CLBR_NONE)
1374         TRACE_IRQS_OFF
1375         testl %ebx,%ebx                         /* swapgs needed? */
1376         jnz paranoid_restore
1377         testl $3,CS(%rsp)
1378         jnz   paranoid_userspace
1379 paranoid_swapgs:
1380         TRACE_IRQS_IRETQ 0
1381         SWAPGS_UNSAFE_STACK
1382         RESTORE_ALL 8
1383         jmp irq_return
1384 paranoid_restore:
1385         TRACE_IRQS_IRETQ 0
1386         RESTORE_ALL 8
1387         jmp irq_return
1388 paranoid_userspace:
1389         GET_THREAD_INFO(%rcx)
1390         movl TI_flags(%rcx),%ebx
1391         andl $_TIF_WORK_MASK,%ebx
1392         jz paranoid_swapgs
1393         movq %rsp,%rdi                  /* &pt_regs */
1394         call sync_regs
1395         movq %rax,%rsp                  /* switch stack for scheduling */
1396         testl $_TIF_NEED_RESCHED,%ebx
1397         jnz paranoid_schedule
1398         movl %ebx,%edx                  /* arg3: thread flags */
1399         TRACE_IRQS_ON
1400         ENABLE_INTERRUPTS(CLBR_NONE)
1401         xorl %esi,%esi                  /* arg2: oldset */
1402         movq %rsp,%rdi                  /* arg1: &pt_regs */
1403         call do_notify_resume
1404         DISABLE_INTERRUPTS(CLBR_NONE)
1405         TRACE_IRQS_OFF
1406         jmp paranoid_userspace
1407 paranoid_schedule:
1408         TRACE_IRQS_ON
1409         ENABLE_INTERRUPTS(CLBR_ANY)
1410         call schedule
1411         DISABLE_INTERRUPTS(CLBR_ANY)
1412         TRACE_IRQS_OFF
1413         jmp paranoid_userspace
1414         CFI_ENDPROC
1415 END(paranoid_exit)
1416
1417 /*
1418  * Exception entry point. This expects an error code/orig_rax on the stack.
1419  * returns in "no swapgs flag" in %ebx.
1420  */
1421 ENTRY(error_entry)
1422         XCPT_FRAME
1423         CFI_ADJUST_CFA_OFFSET 15*8
1424         /* oldrax contains error code */
1425         cld
1426         movq_cfi rdi, RDI+8
1427         movq_cfi rsi, RSI+8
1428         movq_cfi rdx, RDX+8
1429         movq_cfi rcx, RCX+8
1430         movq_cfi rax, RAX+8
1431         movq_cfi  r8,  R8+8
1432         movq_cfi  r9,  R9+8
1433         movq_cfi r10, R10+8
1434         movq_cfi r11, R11+8
1435         movq_cfi rbx, RBX+8
1436         movq_cfi rbp, RBP+8
1437         movq_cfi r12, R12+8
1438         movq_cfi r13, R13+8
1439         movq_cfi r14, R14+8
1440         movq_cfi r15, R15+8
1441         xorl %ebx,%ebx
1442         testl $3,CS+8(%rsp)
1443         je error_kernelspace
1444 error_swapgs:
1445         SWAPGS
1446 error_sti:
1447         TRACE_IRQS_OFF
1448         ret
1449
1450 /*
1451  * There are two places in the kernel that can potentially fault with
1452  * usergs. Handle them here.  B stepping K8s sometimes report a
1453  * truncated RIP for IRET exceptions returning to compat mode. Check
1454  * for these here too.
1455  */
1456 error_kernelspace:
1457         incl %ebx
1458         leaq native_irq_return_iret(%rip),%rcx
1459         cmpq %rcx,RIP+8(%rsp)
1460         je error_bad_iret
1461         movl %ecx,%eax  /* zero extend */
1462         cmpq %rax,RIP+8(%rsp)
1463         je bstep_iret
1464         cmpq $gs_change,RIP+8(%rsp)
1465         je error_swapgs
1466         jmp error_sti
1467
1468 bstep_iret:
1469         /* Fix truncated RIP */
1470         movq %rcx,RIP+8(%rsp)
1471         /* fall through */
1472
1473 error_bad_iret:
1474         SWAPGS
1475         mov %rsp,%rdi
1476         call fixup_bad_iret
1477         mov %rax,%rsp
1478         decl %ebx       /* Return to usergs */
1479         jmp error_sti
1480         CFI_ENDPROC
1481 END(error_entry)
1482
1483
1484 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1485 ENTRY(error_exit)
1486         DEFAULT_FRAME
1487         movl %ebx,%eax
1488         RESTORE_REST
1489         DISABLE_INTERRUPTS(CLBR_NONE)
1490         TRACE_IRQS_OFF
1491         GET_THREAD_INFO(%rcx)
1492         testl %eax,%eax
1493         jne retint_kernel
1494         LOCKDEP_SYS_EXIT_IRQ
1495         movl TI_flags(%rcx),%edx
1496         movl $_TIF_WORK_MASK,%edi
1497         andl %edi,%edx
1498         jnz retint_careful
1499         jmp retint_swapgs
1500         CFI_ENDPROC
1501 END(error_exit)
1502
1503
1504         /* runs on exception stack */
1505 ENTRY(nmi)
1506         INTR_FRAME
1507         PARAVIRT_ADJUST_EXCEPTION_FRAME
1508         pushq_cfi $-1
1509         subq $ORIG_RAX-R15, %rsp
1510         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1511         call save_paranoid
1512         DEFAULT_FRAME 0
1513         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1514         movq %rsp,%rdi
1515         movq $-1,%rsi
1516         call do_nmi
1517 #ifdef CONFIG_TRACE_IRQFLAGS
1518         /* paranoidexit; without TRACE_IRQS_OFF */
1519         /* ebx: no swapgs flag */
1520         DISABLE_INTERRUPTS(CLBR_NONE)
1521         testl %ebx,%ebx                         /* swapgs needed? */
1522         jnz nmi_restore
1523         testl $3,CS(%rsp)
1524         jnz nmi_userspace
1525 nmi_swapgs:
1526         SWAPGS_UNSAFE_STACK
1527 nmi_restore:
1528         RESTORE_ALL 8
1529         jmp irq_return
1530 nmi_userspace:
1531         GET_THREAD_INFO(%rcx)
1532         movl TI_flags(%rcx),%ebx
1533         andl $_TIF_WORK_MASK,%ebx
1534         jz nmi_swapgs
1535         movq %rsp,%rdi                  /* &pt_regs */
1536         call sync_regs
1537         movq %rax,%rsp                  /* switch stack for scheduling */
1538         testl $_TIF_NEED_RESCHED,%ebx
1539         jnz nmi_schedule
1540         movl %ebx,%edx                  /* arg3: thread flags */
1541         ENABLE_INTERRUPTS(CLBR_NONE)
1542         xorl %esi,%esi                  /* arg2: oldset */
1543         movq %rsp,%rdi                  /* arg1: &pt_regs */
1544         call do_notify_resume
1545         DISABLE_INTERRUPTS(CLBR_NONE)
1546         jmp nmi_userspace
1547 nmi_schedule:
1548         ENABLE_INTERRUPTS(CLBR_ANY)
1549         call schedule
1550         DISABLE_INTERRUPTS(CLBR_ANY)
1551         jmp nmi_userspace
1552         CFI_ENDPROC
1553 #else
1554         jmp paranoid_exit
1555         CFI_ENDPROC
1556 #endif
1557 END(nmi)
1558
1559 ENTRY(ignore_sysret)
1560         CFI_STARTPROC
1561         mov $-ENOSYS,%eax
1562         sysret
1563         CFI_ENDPROC
1564 END(ignore_sysret)
1565
1566 /*
1567  * End of kprobes section
1568  */
1569         .popsection