arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * NOTE: This code handles signal-recognition, which happens every time
  13  * after an interrupt and after each system call.
  14  *
  15  * Normal syscalls and interrupts don't save a full stack frame, this is
  16  * only done for syscall tracing, signals or fork/exec et.al.
  17  *
  18  * A note on terminology:
  19  * - top of stack: Architecture defined interrupt frame from SS to RIP
  20  * at the top of the kernel process stack.
  21  * - partial stack frame: partially saved registers upto R11.
  22  * - full stack frame: Like partial stack frame, but all register saved.
  23  *
  24  * Some macro usage:
  25  * - CFI macros are used to generate dwarf2 unwind information for better
  26  * backtraces. They don't change any code.
  27  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  28  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  29  * There are unfortunately lots of special cases where some registers
  30  * not touched. The macro is a big mess that should be cleaned up.
  31  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  32  * Gives a full stack frame.
  33  * - ENTRY/END Define functions in the symbol table.
  34  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  35  * frame that is otherwise undefined after a SYSCALL
  36  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  37  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  38  */
  39
  40 #include <linux/linkage.h>
  41 #include <asm/segment.h>
  42 #include <asm/cache.h>
  43 #include <asm/errno.h>
  44 #include <asm/dwarf2.h>
  45 #include <asm/calling.h>
  46 #include <asm/asm-offsets.h>
  47 #include <asm/msr.h>
  48 #include <asm/unistd.h>
  49 #include <asm/thread_info.h>
  50 #include <asm/hw_irq.h>
  51 #include <asm/page.h>
  52 #include <asm/irqflags.h>
  53 #include <asm/paravirt.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/percpu.h>
  56
  57 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  58 #include <linux/elf-em.h>
  59 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  60 #define __AUDIT_ARCH_64BIT 0x80000000
  61 #define __AUDIT_ARCH_LE    0x40000000
  62
  63         .code64
  64 #ifdef CONFIG_FUNCTION_TRACER
  65 #ifdef CONFIG_DYNAMIC_FTRACE
  66 ENTRY(mcount)
  67         retq
  68 END(mcount)
  69
  70 ENTRY(ftrace_caller)
  71         cmpl $0, function_trace_stop
  72         jne  ftrace_stub
  73
  74         MCOUNT_SAVE_FRAME
  75
  76         movq 0x38(%rsp), %rdi
  77         movq 8(%rbp), %rsi
  78         subq $MCOUNT_INSN_SIZE, %rdi
  79
  80 .globl ftrace_call
  81 ftrace_call:
  82         call ftrace_stub
  83
  84         MCOUNT_RESTORE_FRAME
  85
  86 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  87 .globl ftrace_graph_call
  88 ftrace_graph_call:
  89         jmp ftrace_stub
  90 #endif
  91
  92 .globl ftrace_stub
  93 ftrace_stub:
  94         retq
  95 END(ftrace_caller)
  96
  97 #else /* ! CONFIG_DYNAMIC_FTRACE */
  98 ENTRY(mcount)
  99         cmpl $0, function_trace_stop
 100         jne  ftrace_stub
 101
 102         cmpq $ftrace_stub, ftrace_trace_function
 103         jnz trace
 104
 105 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 106         cmpq $ftrace_stub, ftrace_graph_return
 107         jnz ftrace_graph_caller
 108
 109         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 110         jnz ftrace_graph_caller
 111 #endif
 112
 113 .globl ftrace_stub
 114 ftrace_stub:
 115         retq
 116
 117 trace:
 118         MCOUNT_SAVE_FRAME
 119
 120         movq 0x38(%rsp), %rdi
 121         movq 8(%rbp), %rsi
 122         subq $MCOUNT_INSN_SIZE, %rdi
 123
 124         call   *ftrace_trace_function
 125
 126         MCOUNT_RESTORE_FRAME
 127
 128         jmp ftrace_stub
 129 END(mcount)
 130 #endif /* CONFIG_DYNAMIC_FTRACE */
 131 #endif /* CONFIG_FUNCTION_TRACER */
 132
 133 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 134 ENTRY(ftrace_graph_caller)
 135         cmpl $0, function_trace_stop
 136         jne ftrace_stub
 137
 138         MCOUNT_SAVE_FRAME
 139
 140         leaq 8(%rbp), %rdi
 141         movq 0x38(%rsp), %rsi
 142         subq $MCOUNT_INSN_SIZE, %rsi
 143
 144         call    prepare_ftrace_return
 145
 146         MCOUNT_RESTORE_FRAME
 147
 148         retq
 149 END(ftrace_graph_caller)
 150
 151
 152 .globl return_to_handler
 153 return_to_handler:
 154         subq  $80, %rsp
 155
 156         movq %rax, (%rsp)
 157         movq %rcx, 8(%rsp)
 158         movq %rdx, 16(%rsp)
 159         movq %rsi, 24(%rsp)
 160         movq %rdi, 32(%rsp)
 161         movq %r8, 40(%rsp)
 162         movq %r9, 48(%rsp)
 163         movq %r10, 56(%rsp)
 164         movq %r11, 64(%rsp)
 165
 166         call ftrace_return_to_handler
 167
 168         movq %rax, 72(%rsp)
 169         movq 64(%rsp), %r11
 170         movq 56(%rsp), %r10
 171         movq 48(%rsp), %r9
 172         movq 40(%rsp), %r8
 173         movq 32(%rsp), %rdi
 174         movq 24(%rsp), %rsi
 175         movq 16(%rsp), %rdx
 176         movq 8(%rsp), %rcx
 177         movq (%rsp), %rax
 178         addq $72, %rsp
 179         retq
 180 #endif
 181
 182
 183 #ifndef CONFIG_PREEMPT
 184 #define retint_kernel retint_restore_args
 185 #endif
 186
 187 #ifdef CONFIG_PARAVIRT
 188 ENTRY(native_usergs_sysret64)
 189         swapgs
 190         sysretq
 191 #endif /* CONFIG_PARAVIRT */
 192
 193
 194 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 195 #ifdef CONFIG_TRACE_IRQFLAGS
 196         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 197         jnc  1f
 198         TRACE_IRQS_ON
 199 1:
 200 #endif
 201 .endm
 202
 203 /*
 204  * C code is not supposed to know about undefined top of stack. Every time
 205  * a C function with an pt_regs argument is called from the SYSCALL based
 206  * fast path FIXUP_TOP_OF_STACK is needed.
 207  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 208  * manipulation.
 209  */
 210
 211         /* %rsp:at FRAMEEND */
 212         .macro FIXUP_TOP_OF_STACK tmp offset=0
 213         movq PER_CPU_VAR(old_rsp),\tmp
 214         movq \tmp,RSP+\offset(%rsp)
 215         movq $__USER_DS,SS+\offset(%rsp)
 216         movq $__USER_CS,CS+\offset(%rsp)
 217         movq $-1,RCX+\offset(%rsp)
 218         movq R11+\offset(%rsp),\tmp  /* get eflags */
 219         movq \tmp,EFLAGS+\offset(%rsp)
 220         .endm
 221
 222         .macro RESTORE_TOP_OF_STACK tmp offset=0
 223         movq RSP+\offset(%rsp),\tmp
 224         movq \tmp,PER_CPU_VAR(old_rsp)
 225         movq EFLAGS+\offset(%rsp),\tmp
 226         movq \tmp,R11+\offset(%rsp)
 227         .endm
 228
 229         .macro FAKE_STACK_FRAME child_rip
 230         /* push in order ss, rsp, eflags, cs, rip */
 231         xorl %eax, %eax
 232         pushq $__KERNEL_DS /* ss */
 233         CFI_ADJUST_CFA_OFFSET   8
 234         /*CFI_REL_OFFSET        ss,0*/
 235         pushq %rax /* rsp */
 236         CFI_ADJUST_CFA_OFFSET   8
 237         CFI_REL_OFFSET  rsp,0
 238         pushq $X86_EFLAGS_IF /* eflags - interrupts on */
 239         CFI_ADJUST_CFA_OFFSET   8
 240         /*CFI_REL_OFFSET        rflags,0*/
 241         pushq $__KERNEL_CS /* cs */
 242         CFI_ADJUST_CFA_OFFSET   8
 243         /*CFI_REL_OFFSET        cs,0*/
 244         pushq \child_rip /* rip */
 245         CFI_ADJUST_CFA_OFFSET   8
 246         CFI_REL_OFFSET  rip,0
 247         pushq   %rax /* orig rax */
 248         CFI_ADJUST_CFA_OFFSET   8
 249         .endm
 250
 251         .macro UNFAKE_STACK_FRAME
 252         addq $8*6, %rsp
 253         CFI_ADJUST_CFA_OFFSET   -(6*8)
 254         .endm
 255
 256 /*
 257  * initial frame state for interrupts (and exceptions without error code)
 258  */
 259         .macro EMPTY_FRAME start=1 offset=0
 260         .if \start
 261         CFI_STARTPROC simple
 262         CFI_SIGNAL_FRAME
 263         CFI_DEF_CFA rsp,8+\offset
 264         .else
 265         CFI_DEF_CFA_OFFSET 8+\offset
 266         .endif
 267         .endm
 268
 269 /*
 270  * initial frame state for interrupts (and exceptions without error code)
 271  */
 272         .macro INTR_FRAME start=1 offset=0
 273         EMPTY_FRAME \start, SS+8+\offset-RIP
 274         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 275         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 276         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 277         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 278         CFI_REL_OFFSET rip, RIP+\offset-RIP
 279         .endm
 280
 281 /*
 282  * initial frame state for exceptions with error code (and interrupts
 283  * with vector already pushed)
 284  */
 285         .macro XCPT_FRAME start=1 offset=0
 286         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 287         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 288         .endm
 289
 290 /*
 291  * frame that enables calling into C.
 292  */
 293         .macro PARTIAL_FRAME start=1 offset=0
 294         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 295         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 296         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 297         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 298         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 299         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 300         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 301         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 302         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 303         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 304         .endm
 305
 306 /*
 307  * frame that enables passing a complete pt_regs to a C function.
 308  */
 309         .macro DEFAULT_FRAME start=1 offset=0
 310         PARTIAL_FRAME \start, R11+\offset-R15
 311         CFI_REL_OFFSET rbx, RBX+\offset
 312         CFI_REL_OFFSET rbp, RBP+\offset
 313         CFI_REL_OFFSET r12, R12+\offset
 314         CFI_REL_OFFSET r13, R13+\offset
 315         CFI_REL_OFFSET r14, R14+\offset
 316         CFI_REL_OFFSET r15, R15+\offset
 317         .endm
 318
 319 /* save partial stack frame */
 320 ENTRY(save_args)
 321         XCPT_FRAME
 322         cld
 323         movq_cfi rdi, RDI+16-ARGOFFSET
 324         movq_cfi rsi, RSI+16-ARGOFFSET
 325         movq_cfi rdx, RDX+16-ARGOFFSET
 326         movq_cfi rcx, RCX+16-ARGOFFSET
 327         movq_cfi rax, RAX+16-ARGOFFSET
 328         movq_cfi  r8,  R8+16-ARGOFFSET
 329         movq_cfi  r9,  R9+16-ARGOFFSET
 330         movq_cfi r10, R10+16-ARGOFFSET
 331         movq_cfi r11, R11+16-ARGOFFSET
 332
 333         leaq -ARGOFFSET+16(%rsp),%rdi   /* arg1 for handler */
 334         movq_cfi rbp, 8         /* push %rbp */
 335         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 336         testl $3, CS(%rdi)
 337         je 1f
 338         SWAPGS
 339         /*
 340          * irq_count is used to check if a CPU is already on an interrupt stack
 341          * or not. While this is essentially redundant with preempt_count it is
 342          * a little cheaper to use a separate counter in the PDA (short of
 343          * moving irq_enter into assembly, which would be too much work)
 344          */
 345 1:      incl PER_CPU_VAR(irq_count)
 346         jne 2f
 347         popq_cfi %rax                   /* move return address... */
 348         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 349         EMPTY_FRAME 0
 350         pushq_cfi %rbp                  /* backlink for unwinder */
 351         pushq_cfi %rax                  /* ... to the new stack */
 352         /*
 353          * We entered an interrupt context - irqs are off:
 354          */
 355 2:      TRACE_IRQS_OFF
 356         ret
 357         CFI_ENDPROC
 358 END(save_args)
 359
 360 ENTRY(save_rest)
 361         PARTIAL_FRAME 1 REST_SKIP+8
 362         movq 5*8+16(%rsp), %r11 /* save return address */
 363         movq_cfi rbx, RBX+16
 364         movq_cfi rbp, RBP+16
 365         movq_cfi r12, R12+16
 366         movq_cfi r13, R13+16
 367         movq_cfi r14, R14+16
 368         movq_cfi r15, R15+16
 369         movq %r11, 8(%rsp)      /* return address */
 370         FIXUP_TOP_OF_STACK %r11, 16
 371         ret
 372         CFI_ENDPROC
 373 END(save_rest)
 374
 375 /* save complete stack frame */
 376 ENTRY(save_paranoid)
 377         XCPT_FRAME 1 RDI+8
 378         cld
 379         movq_cfi rdi, RDI+8
 380         movq_cfi rsi, RSI+8
 381         movq_cfi rdx, RDX+8
 382         movq_cfi rcx, RCX+8
 383         movq_cfi rax, RAX+8
 384         movq_cfi r8, R8+8
 385         movq_cfi r9, R9+8
 386         movq_cfi r10, R10+8
 387         movq_cfi r11, R11+8
 388         movq_cfi rbx, RBX+8
 389         movq_cfi rbp, RBP+8
 390         movq_cfi r12, R12+8
 391         movq_cfi r13, R13+8
 392         movq_cfi r14, R14+8
 393         movq_cfi r15, R15+8
 394         movl $1,%ebx
 395         movl $MSR_GS_BASE,%ecx
 396         rdmsr
 397         testl %edx,%edx
 398         js 1f   /* negative -> in kernel */
 399         SWAPGS
 400         xorl %ebx,%ebx
 401 1:      ret
 402         CFI_ENDPROC
 403 END(save_paranoid)
 404
 405 /*
 406  * A newly forked process directly context switches into this address.
 407  *
 408  * rdi: prev task we switched from
 409  */
 410 ENTRY(ret_from_fork)
 411         DEFAULT_FRAME
 412
 413         push kernel_eflags(%rip)
 414         CFI_ADJUST_CFA_OFFSET 8
 415         popf                                    # reset kernel eflags
 416         CFI_ADJUST_CFA_OFFSET -8
 417
 418         call schedule_tail                      # rdi: 'prev' task parameter
 419
 420         GET_THREAD_INFO(%rcx)
 421
 422         CFI_REMEMBER_STATE
 423         RESTORE_REST
 424
 425         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 426         je   int_ret_from_sys_call
 427
 428         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 429         jnz  int_ret_from_sys_call
 430
 431         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 432         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 433
 434         CFI_RESTORE_STATE
 435         CFI_ENDPROC
 436 END(ret_from_fork)
 437
 438 /*
 439  * System call entry. Upto 6 arguments in registers are supported.
 440  *
 441  * SYSCALL does not save anything on the stack and does not change the
 442  * stack pointer.
 443  */
 444
 445 /*
 446  * Register setup:
 447  * rax  system call number
 448  * rdi  arg0
 449  * rcx  return address for syscall/sysret, C arg3
 450  * rsi  arg1
 451  * rdx  arg2
 452  * r10  arg3    (--> moved to rcx for C)
 453  * r8   arg4
 454  * r9   arg5
 455  * r11  eflags for syscall/sysret, temporary for C
 456  * r12-r15,rbp,rbx saved by C code, not touched.
 457  *
 458  * Interrupts are off on entry.
 459  * Only called from user space.
 460  *
 461  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 462  *      and report it properly in ps. Unfortunately we haven't.
 463  *
 464  * When user can change the frames always force IRET. That is because
 465  * it deals with uncanonical addresses better. SYSRET has trouble
 466  * with them due to bugs in both AMD and Intel CPUs.
 467  */
 468
 469 ENTRY(system_call)
 470         CFI_STARTPROC   simple
 471         CFI_SIGNAL_FRAME
 472         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 473         CFI_REGISTER    rip,rcx
 474         /*CFI_REGISTER  rflags,r11*/
 475         SWAPGS_UNSAFE_STACK
 476         /*
 477          * A hypervisor implementation might want to use a label
 478          * after the swapgs, so that it can do the swapgs
 479          * for the guest and jump here on syscall.
 480          */
 481 ENTRY(system_call_after_swapgs)
 482
 483         movq    %rsp,PER_CPU_VAR(old_rsp)
 484         movq    PER_CPU_VAR(kernel_stack),%rsp
 485         /*
 486          * No need to follow this irqs off/on section - it's straight
 487          * and short:
 488          */
 489         ENABLE_INTERRUPTS(CLBR_NONE)
 490         SAVE_ARGS 8,1
 491         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 492         movq  %rcx,RIP-ARGOFFSET(%rsp)
 493         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 494         GET_THREAD_INFO(%rcx)
 495         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 496         jnz tracesys
 497 system_call_fastpath:
 498         cmpq $__NR_syscall_max,%rax
 499         ja badsys
 500         movq %r10,%rcx
 501         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 502         movq %rax,RAX-ARGOFFSET(%rsp)
 503 /*
 504  * Syscall return path ending with SYSRET (fast path)
 505  * Has incomplete stack frame and undefined top of stack.
 506  */
 507 ret_from_sys_call:
 508         movl $_TIF_ALLWORK_MASK,%edi
 509         /* edi: flagmask */
 510 sysret_check:
 511         LOCKDEP_SYS_EXIT
 512         GET_THREAD_INFO(%rcx)
 513         DISABLE_INTERRUPTS(CLBR_NONE)
 514         TRACE_IRQS_OFF
 515         movl TI_flags(%rcx),%edx
 516         andl %edi,%edx
 517         jnz  sysret_careful
 518         CFI_REMEMBER_STATE
 519         /*
 520          * sysretq will re-enable interrupts:
 521          */
 522         TRACE_IRQS_ON
 523         movq RIP-ARGOFFSET(%rsp),%rcx
 524         CFI_REGISTER    rip,rcx
 525         RESTORE_ARGS 0,-ARG_SKIP,1
 526         /*CFI_REGISTER  rflags,r11*/
 527         movq    PER_CPU_VAR(old_rsp), %rsp
 528         USERGS_SYSRET64
 529
 530         CFI_RESTORE_STATE
 531         /* Handle reschedules */
 532         /* edx: work, edi: workmask */
 533 sysret_careful:
 534         bt $TIF_NEED_RESCHED,%edx
 535         jnc sysret_signal
 536         TRACE_IRQS_ON
 537         ENABLE_INTERRUPTS(CLBR_NONE)
 538         pushq %rdi
 539         CFI_ADJUST_CFA_OFFSET 8
 540         call schedule
 541         popq  %rdi
 542         CFI_ADJUST_CFA_OFFSET -8
 543         jmp sysret_check
 544
 545         /* Handle a signal */
 546 sysret_signal:
 547         TRACE_IRQS_ON
 548         ENABLE_INTERRUPTS(CLBR_NONE)
 549 #ifdef CONFIG_AUDITSYSCALL
 550         bt $TIF_SYSCALL_AUDIT,%edx
 551         jc sysret_audit
 552 #endif
 553         /* edx: work flags (arg3) */
 554         leaq -ARGOFFSET(%rsp),%rdi # &pt_regs -> arg1
 555         xorl %esi,%esi # oldset -> arg2
 556         SAVE_REST
 557         FIXUP_TOP_OF_STACK %r11
 558         call do_notify_resume
 559         RESTORE_TOP_OF_STACK %r11
 560         RESTORE_REST
 561         movl $_TIF_WORK_MASK,%edi
 562         /* Use IRET because user could have changed frame. This
 563            works because ptregscall_common has called FIXUP_TOP_OF_STACK. */
 564         DISABLE_INTERRUPTS(CLBR_NONE)
 565         TRACE_IRQS_OFF
 566         jmp int_with_check
 567
 568 badsys:
 569         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 570         jmp ret_from_sys_call
 571
 572 #ifdef CONFIG_AUDITSYSCALL
 573         /*
 574          * Fast path for syscall audit without full syscall trace.
 575          * We just call audit_syscall_entry() directly, and then
 576          * jump back to the normal fast path.
 577          */
 578 auditsys:
 579         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 580         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 581         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 582         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 583         movq %rax,%rsi                  /* 2nd arg: syscall number */
 584         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 585         call audit_syscall_entry
 586         LOAD_ARGS 0             /* reload call-clobbered registers */
 587         jmp system_call_fastpath
 588
 589         /*
 590          * Return fast path for syscall audit.  Call audit_syscall_exit()
 591          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 592          * masked off.
 593          */
 594 sysret_audit:
 595         movq %rax,%rsi          /* second arg, syscall return value */
 596         cmpq $0,%rax            /* is it < 0? */
 597         setl %al                /* 1 if so, 0 if not */
 598         movzbl %al,%edi         /* zero-extend that into %edi */
 599         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 600         call audit_syscall_exit
 601         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 602         jmp sysret_check
 603 #endif  /* CONFIG_AUDITSYSCALL */
 604
 605         /* Do syscall tracing */
 606 tracesys:
 607 #ifdef CONFIG_AUDITSYSCALL
 608         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 609         jz auditsys
 610 #endif
 611         SAVE_REST
 612         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 613         FIXUP_TOP_OF_STACK %rdi
 614         movq %rsp,%rdi
 615         call syscall_trace_enter
 616         /*
 617          * Reload arg registers from stack in case ptrace changed them.
 618          * We don't reload %rax because syscall_trace_enter() returned
 619          * the value it wants us to use in the table lookup.
 620          */
 621         LOAD_ARGS ARGOFFSET, 1
 622         RESTORE_REST
 623         cmpq $__NR_syscall_max,%rax
 624         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 625         movq %r10,%rcx  /* fixup for C */
 626         call *sys_call_table(,%rax,8)
 627         movq %rax,RAX-ARGOFFSET(%rsp)
 628         /* Use IRET because user could have changed frame */
 629
 630 /*
 631  * Syscall return path ending with IRET.
 632  * Has correct top of stack, but partial stack frame.
 633  */
 634         .globl int_ret_from_sys_call
 635         .globl int_with_check
 636 int_ret_from_sys_call:
 637         DISABLE_INTERRUPTS(CLBR_NONE)
 638         TRACE_IRQS_OFF
 639         testl $3,CS-ARGOFFSET(%rsp)
 640         je retint_restore_args
 641         movl $_TIF_ALLWORK_MASK,%edi
 642         /* edi: mask to check */
 643 int_with_check:
 644         LOCKDEP_SYS_EXIT_IRQ
 645         GET_THREAD_INFO(%rcx)
 646         movl TI_flags(%rcx),%edx
 647         andl %edi,%edx
 648         jnz   int_careful
 649         andl    $~TS_COMPAT,TI_status(%rcx)
 650         jmp   retint_swapgs
 651
 652         /* Either reschedule or signal or syscall exit tracking needed. */
 653         /* First do a reschedule test. */
 654         /* edx: work, edi: workmask */
 655 int_careful:
 656         bt $TIF_NEED_RESCHED,%edx
 657         jnc  int_very_careful
 658         TRACE_IRQS_ON
 659         ENABLE_INTERRUPTS(CLBR_NONE)
 660         pushq %rdi
 661         CFI_ADJUST_CFA_OFFSET 8
 662         call schedule
 663         popq %rdi
 664         CFI_ADJUST_CFA_OFFSET -8
 665         DISABLE_INTERRUPTS(CLBR_NONE)
 666         TRACE_IRQS_OFF
 667         jmp int_with_check
 668
 669         /* handle signals and tracing -- both require a full stack frame */
 670 int_very_careful:
 671         TRACE_IRQS_ON
 672         ENABLE_INTERRUPTS(CLBR_NONE)
 673         SAVE_REST
 674         /* Check for syscall exit trace */
 675         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 676         jz int_signal
 677         pushq %rdi
 678         CFI_ADJUST_CFA_OFFSET 8
 679         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 680         call syscall_trace_leave
 681         popq %rdi
 682         CFI_ADJUST_CFA_OFFSET -8
 683         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 684         jmp int_restore_rest
 685
 686 int_signal:
 687         testl $_TIF_DO_NOTIFY_MASK,%edx
 688         jz 1f
 689         movq %rsp,%rdi          # &ptregs -> arg1
 690         xorl %esi,%esi          # oldset -> arg2
 691         call do_notify_resume
 692 1:      movl $_TIF_WORK_MASK,%edi
 693 int_restore_rest:
 694         RESTORE_REST
 695         DISABLE_INTERRUPTS(CLBR_NONE)
 696         TRACE_IRQS_OFF
 697         jmp int_with_check
 698         CFI_ENDPROC
 699 END(system_call)
 700
 701 /*
 702  * Certain special system calls that need to save a complete full stack frame.
 703  */
 704         .macro PTREGSCALL label,func,arg
 705 ENTRY(\label)
 706         PARTIAL_FRAME 1 8               /* offset 8: return address */
 707         subq $REST_SKIP, %rsp
 708         CFI_ADJUST_CFA_OFFSET REST_SKIP
 709         call save_rest
 710         DEFAULT_FRAME 0 8               /* offset 8: return address */
 711         leaq 8(%rsp), \arg      /* pt_regs pointer */
 712         call \func
 713         jmp ptregscall_common
 714         CFI_ENDPROC
 715 END(\label)
 716         .endm
 717
 718         PTREGSCALL stub_clone, sys_clone, %r8
 719         PTREGSCALL stub_fork, sys_fork, %rdi
 720         PTREGSCALL stub_vfork, sys_vfork, %rdi
 721         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 722         PTREGSCALL stub_iopl, sys_iopl, %rsi
 723
 724 ENTRY(ptregscall_common)
 725         DEFAULT_FRAME 1 8       /* offset 8: return address */
 726         RESTORE_TOP_OF_STACK %r11, 8
 727         movq_cfi_restore R15+8, r15
 728         movq_cfi_restore R14+8, r14
 729         movq_cfi_restore R13+8, r13
 730         movq_cfi_restore R12+8, r12
 731         movq_cfi_restore RBP+8, rbp
 732         movq_cfi_restore RBX+8, rbx
 733         ret $REST_SKIP          /* pop extended registers */
 734         CFI_ENDPROC
 735 END(ptregscall_common)
 736
 737 ENTRY(stub_execve)
 738         CFI_STARTPROC
 739         popq %r11
 740         CFI_ADJUST_CFA_OFFSET -8
 741         CFI_REGISTER rip, r11
 742         SAVE_REST
 743         FIXUP_TOP_OF_STACK %r11
 744         movq %rsp, %rcx
 745         call sys_execve
 746         RESTORE_TOP_OF_STACK %r11
 747         movq %rax,RAX(%rsp)
 748         RESTORE_REST
 749         jmp int_ret_from_sys_call
 750         CFI_ENDPROC
 751 END(stub_execve)
 752
 753 /*
 754  * sigreturn is special because it needs to restore all registers on return.
 755  * This cannot be done with SYSRET, so use the IRET return path instead.
 756  */
 757 ENTRY(stub_rt_sigreturn)
 758         CFI_STARTPROC
 759         addq $8, %rsp
 760         CFI_ADJUST_CFA_OFFSET   -8
 761         SAVE_REST
 762         movq %rsp,%rdi
 763         FIXUP_TOP_OF_STACK %r11
 764         call sys_rt_sigreturn
 765         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 766         RESTORE_REST
 767         jmp int_ret_from_sys_call
 768         CFI_ENDPROC
 769 END(stub_rt_sigreturn)
 770
 771 /*
 772  * Build the entry stubs and pointer table with some assembler magic.
 773  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 774  * single cache line on all modern x86 implementations.
 775  */
 776         .section .init.rodata,"a"
 777 ENTRY(interrupt)
 778         .text
 779         .p2align 5
 780         .p2align CONFIG_X86_L1_CACHE_SHIFT
 781 ENTRY(irq_entries_start)
 782         INTR_FRAME
 783 vector=FIRST_EXTERNAL_VECTOR
 784 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 785         .balign 32
 786   .rept 7
 787     .if vector < NR_VECTORS
 788       .if vector <> FIRST_EXTERNAL_VECTOR
 789         CFI_ADJUST_CFA_OFFSET -8
 790       .endif
 791 1:      pushq $(~vector+0x80)   /* Note: always in signed byte range */
 792         CFI_ADJUST_CFA_OFFSET 8
 793       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 794         jmp 2f
 795       .endif
 796       .previous
 797         .quad 1b
 798       .text
 799 vector=vector+1
 800     .endif
 801   .endr
 802 2:      jmp common_interrupt
 803 .endr
 804         CFI_ENDPROC
 805 END(irq_entries_start)
 806
 807 .previous
 808 END(interrupt)
 809 .previous
 810
 811 /*
 812  * Interrupt entry/exit.
 813  *
 814  * Interrupt entry points save only callee clobbered registers in fast path.
 815  *
 816  * Entry runs with interrupts off.
 817  */
 818
 819 /* 0(%rsp): ~(interrupt number) */
 820         .macro interrupt func
 821         subq $10*8, %rsp
 822         CFI_ADJUST_CFA_OFFSET 10*8
 823         call save_args
 824         PARTIAL_FRAME 0
 825         call \func
 826         .endm
 827
 828         /*
 829          * The interrupt stubs push (~vector+0x80) onto the stack and
 830          * then jump to common_interrupt.
 831          */
 832         .p2align CONFIG_X86_L1_CACHE_SHIFT
 833 common_interrupt:
 834         XCPT_FRAME
 835         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 836         interrupt do_IRQ
 837         /* 0(%rsp): old_rsp-ARGOFFSET */
 838 ret_from_intr:
 839         DISABLE_INTERRUPTS(CLBR_NONE)
 840         TRACE_IRQS_OFF
 841         decl PER_CPU_VAR(irq_count)
 842         leaveq
 843         CFI_DEF_CFA_REGISTER    rsp
 844         CFI_ADJUST_CFA_OFFSET   -8
 845 exit_intr:
 846         GET_THREAD_INFO(%rcx)
 847         testl $3,CS-ARGOFFSET(%rsp)
 848         je retint_kernel
 849
 850         /* Interrupt came from user space */
 851         /*
 852          * Has a correct top of stack, but a partial stack frame
 853          * %rcx: thread info. Interrupts off.
 854          */
 855 retint_with_reschedule:
 856         movl $_TIF_WORK_MASK,%edi
 857 retint_check:
 858         LOCKDEP_SYS_EXIT_IRQ
 859         movl TI_flags(%rcx),%edx
 860         andl %edi,%edx
 861         CFI_REMEMBER_STATE
 862         jnz  retint_careful
 863
 864 retint_swapgs:          /* return to user-space */
 865         /*
 866          * The iretq could re-enable interrupts:
 867          */
 868         DISABLE_INTERRUPTS(CLBR_ANY)
 869         TRACE_IRQS_IRETQ
 870         SWAPGS
 871         jmp restore_args
 872
 873 retint_restore_args:    /* return to kernel space */
 874         DISABLE_INTERRUPTS(CLBR_ANY)
 875         /*
 876          * The iretq could re-enable interrupts:
 877          */
 878         TRACE_IRQS_IRETQ
 879 restore_args:
 880         RESTORE_ARGS 0,8,0
 881
 882 irq_return:
 883         INTERRUPT_RETURN
 884
 885         .section __ex_table, "a"
 886         .quad irq_return, bad_iret
 887         .previous
 888
 889 #ifdef CONFIG_PARAVIRT
 890 ENTRY(native_iret)
 891         iretq
 892
 893         .section __ex_table,"a"
 894         .quad native_iret, bad_iret
 895         .previous
 896 #endif
 897
 898         .section .fixup,"ax"
 899 bad_iret:
 900         /*
 901          * The iret traps when the %cs or %ss being restored is bogus.
 902          * We've lost the original trap vector and error code.
 903          * #GPF is the most likely one to get for an invalid selector.
 904          * So pretend we completed the iret and took the #GPF in user mode.
 905          *
 906          * We are now running with the kernel GS after exception recovery.
 907          * But error_entry expects us to have user GS to match the user %cs,
 908          * so swap back.
 909          */
 910         pushq $0
 911
 912         SWAPGS
 913         jmp general_protection
 914
 915         .previous
 916
 917         /* edi: workmask, edx: work */
 918 retint_careful:
 919         CFI_RESTORE_STATE
 920         bt    $TIF_NEED_RESCHED,%edx
 921         jnc   retint_signal
 922         TRACE_IRQS_ON
 923         ENABLE_INTERRUPTS(CLBR_NONE)
 924         pushq %rdi
 925         CFI_ADJUST_CFA_OFFSET   8
 926         call  schedule
 927         popq %rdi
 928         CFI_ADJUST_CFA_OFFSET   -8
 929         GET_THREAD_INFO(%rcx)
 930         DISABLE_INTERRUPTS(CLBR_NONE)
 931         TRACE_IRQS_OFF
 932         jmp retint_check
 933
 934 retint_signal:
 935         testl $_TIF_DO_NOTIFY_MASK,%edx
 936         jz    retint_swapgs
 937         TRACE_IRQS_ON
 938         ENABLE_INTERRUPTS(CLBR_NONE)
 939         SAVE_REST
 940         movq $-1,ORIG_RAX(%rsp)
 941         xorl %esi,%esi          # oldset
 942         movq %rsp,%rdi          # &pt_regs
 943         call do_notify_resume
 944         RESTORE_REST
 945         DISABLE_INTERRUPTS(CLBR_NONE)
 946         TRACE_IRQS_OFF
 947         GET_THREAD_INFO(%rcx)
 948         jmp retint_with_reschedule
 949
 950 #ifdef CONFIG_PREEMPT
 951         /* Returning to kernel space. Check if we need preemption */
 952         /* rcx:  threadinfo. interrupts off. */
 953 ENTRY(retint_kernel)
 954         cmpl $0,TI_preempt_count(%rcx)
 955         jnz  retint_restore_args
 956         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 957         jnc  retint_restore_args
 958         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 959         jnc  retint_restore_args
 960         call preempt_schedule_irq
 961         jmp exit_intr
 962 #endif
 963
 964         CFI_ENDPROC
 965 END(common_interrupt)
 966
 967 /*
 968  * APIC interrupts.
 969  */
 970 .macro apicinterrupt num sym do_sym
 971 ENTRY(\sym)
 972         INTR_FRAME
 973         pushq $~(\num)
 974         CFI_ADJUST_CFA_OFFSET 8
 975         interrupt \do_sym
 976         jmp ret_from_intr
 977         CFI_ENDPROC
 978 END(\sym)
 979 .endm
 980
 981 #ifdef CONFIG_SMP
 982 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 983         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 984 #endif
 985
 986 #ifdef CONFIG_X86_UV
 987 apicinterrupt UV_BAU_MESSAGE \
 988         uv_bau_message_intr1 uv_bau_message_interrupt
 989 #endif
 990 apicinterrupt LOCAL_TIMER_VECTOR \
 991         apic_timer_interrupt smp_apic_timer_interrupt
 992
 993 #ifdef CONFIG_SMP
 994 apicinterrupt INVALIDATE_TLB_VECTOR_START+0 \
 995         invalidate_interrupt0 smp_invalidate_interrupt
 996 apicinterrupt INVALIDATE_TLB_VECTOR_START+1 \
 997         invalidate_interrupt1 smp_invalidate_interrupt
 998 apicinterrupt INVALIDATE_TLB_VECTOR_START+2 \
 999         invalidate_interrupt2 smp_invalidate_interrupt
1000 apicinterrupt INVALIDATE_TLB_VECTOR_START+3 \
1001         invalidate_interrupt3 smp_invalidate_interrupt
1002 apicinterrupt INVALIDATE_TLB_VECTOR_START+4 \
1003         invalidate_interrupt4 smp_invalidate_interrupt
1004 apicinterrupt INVALIDATE_TLB_VECTOR_START+5 \
1005         invalidate_interrupt5 smp_invalidate_interrupt
1006 apicinterrupt INVALIDATE_TLB_VECTOR_START+6 \
1007         invalidate_interrupt6 smp_invalidate_interrupt
1008 apicinterrupt INVALIDATE_TLB_VECTOR_START+7 \
1009         invalidate_interrupt7 smp_invalidate_interrupt
1010 #endif
1011
1012 apicinterrupt THRESHOLD_APIC_VECTOR \
1013         threshold_interrupt mce_threshold_interrupt
1014 apicinterrupt THERMAL_APIC_VECTOR \
1015         thermal_interrupt smp_thermal_interrupt
1016
1017 #ifdef CONFIG_SMP
1018 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1019         call_function_single_interrupt smp_call_function_single_interrupt
1020 apicinterrupt CALL_FUNCTION_VECTOR \
1021         call_function_interrupt smp_call_function_interrupt
1022 apicinterrupt RESCHEDULE_VECTOR \
1023         reschedule_interrupt smp_reschedule_interrupt
1024 #endif
1025
1026 apicinterrupt ERROR_APIC_VECTOR \
1027         error_interrupt smp_error_interrupt
1028 apicinterrupt SPURIOUS_APIC_VECTOR \
1029         spurious_interrupt smp_spurious_interrupt
1030
1031 /*
1032  * Exception entry points.
1033  */
1034 .macro zeroentry sym do_sym
1035 ENTRY(\sym)
1036         INTR_FRAME
1037         PARAVIRT_ADJUST_EXCEPTION_FRAME
1038         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1039         subq $15*8,%rsp
1040         CFI_ADJUST_CFA_OFFSET 15*8
1041         call error_entry
1042         DEFAULT_FRAME 0
1043         movq %rsp,%rdi          /* pt_regs pointer */
1044         xorl %esi,%esi          /* no error code */
1045         call \do_sym
1046         jmp error_exit          /* %ebx: no swapgs flag */
1047         CFI_ENDPROC
1048 END(\sym)
1049 .endm
1050
1051 .macro paranoidzeroentry sym do_sym
1052 ENTRY(\sym)
1053         INTR_FRAME
1054         PARAVIRT_ADJUST_EXCEPTION_FRAME
1055         pushq $-1               /* ORIG_RAX: no syscall to restart */
1056         CFI_ADJUST_CFA_OFFSET 8
1057         subq $15*8, %rsp
1058         call save_paranoid
1059         TRACE_IRQS_OFF
1060         movq %rsp,%rdi          /* pt_regs pointer */
1061         xorl %esi,%esi          /* no error code */
1062         call \do_sym
1063         jmp paranoid_exit       /* %ebx: no swapgs flag */
1064         CFI_ENDPROC
1065 END(\sym)
1066 .endm
1067
1068 .macro paranoidzeroentry_ist sym do_sym ist
1069 ENTRY(\sym)
1070         INTR_FRAME
1071         PARAVIRT_ADJUST_EXCEPTION_FRAME
1072         pushq $-1               /* ORIG_RAX: no syscall to restart */
1073         CFI_ADJUST_CFA_OFFSET 8
1074         subq $15*8, %rsp
1075         call save_paranoid
1076         TRACE_IRQS_OFF
1077         movq %rsp,%rdi          /* pt_regs pointer */
1078         xorl %esi,%esi          /* no error code */
1079         PER_CPU(init_tss, %rbp)
1080         subq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1081         call \do_sym
1082         addq $EXCEPTION_STKSZ, TSS_ist + (\ist - 1) * 8(%rbp)
1083         jmp paranoid_exit       /* %ebx: no swapgs flag */
1084         CFI_ENDPROC
1085 END(\sym)
1086 .endm
1087
1088 .macro errorentry sym do_sym
1089 ENTRY(\sym)
1090         XCPT_FRAME
1091         PARAVIRT_ADJUST_EXCEPTION_FRAME
1092         subq $15*8,%rsp
1093         CFI_ADJUST_CFA_OFFSET 15*8
1094         call error_entry
1095         DEFAULT_FRAME 0
1096         movq %rsp,%rdi                  /* pt_regs pointer */
1097         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1098         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1099         call \do_sym
1100         jmp error_exit                  /* %ebx: no swapgs flag */
1101         CFI_ENDPROC
1102 END(\sym)
1103 .endm
1104
1105         /* error code is on the stack already */
1106 .macro paranoiderrorentry sym do_sym
1107 ENTRY(\sym)
1108         XCPT_FRAME
1109         PARAVIRT_ADJUST_EXCEPTION_FRAME
1110         subq $15*8,%rsp
1111         CFI_ADJUST_CFA_OFFSET 15*8
1112         call save_paranoid
1113         DEFAULT_FRAME 0
1114         TRACE_IRQS_OFF
1115         movq %rsp,%rdi                  /* pt_regs pointer */
1116         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1117         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1118         call \do_sym
1119         jmp paranoid_exit               /* %ebx: no swapgs flag */
1120         CFI_ENDPROC
1121 END(\sym)
1122 .endm
1123
1124 zeroentry divide_error do_divide_error
1125 zeroentry overflow do_overflow
1126 zeroentry bounds do_bounds
1127 zeroentry invalid_op do_invalid_op
1128 zeroentry device_not_available do_device_not_available
1129 paranoiderrorentry double_fault do_double_fault
1130 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1131 errorentry invalid_TSS do_invalid_TSS
1132 errorentry segment_not_present do_segment_not_present
1133 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1134 zeroentry coprocessor_error do_coprocessor_error
1135 errorentry alignment_check do_alignment_check
1136 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1137
1138         /* Reload gs selector with exception handling */
1139         /* edi:  new selector */
1140 ENTRY(native_load_gs_index)
1141         CFI_STARTPROC
1142         pushf
1143         CFI_ADJUST_CFA_OFFSET 8
1144         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1145         SWAPGS
1146 gs_change:
1147         movl %edi,%gs
1148 2:      mfence          /* workaround */
1149         SWAPGS
1150         popf
1151         CFI_ADJUST_CFA_OFFSET -8
1152         ret
1153         CFI_ENDPROC
1154 END(native_load_gs_index)
1155
1156         .section __ex_table,"a"
1157         .align 8
1158         .quad gs_change,bad_gs
1159         .previous
1160         .section .fixup,"ax"
1161         /* running with kernelgs */
1162 bad_gs:
1163         SWAPGS                  /* switch back to user gs */
1164         xorl %eax,%eax
1165         movl %eax,%gs
1166         jmp  2b
1167         .previous
1168
1169 /*
1170  * Create a kernel thread.
1171  *
1172  * C extern interface:
1173  *      extern long kernel_thread(int (*fn)(void *), void * arg, unsigned long flags)
1174  *
1175  * asm input arguments:
1176  *      rdi: fn, rsi: arg, rdx: flags
1177  */
1178 ENTRY(kernel_thread)
1179         CFI_STARTPROC
1180         FAKE_STACK_FRAME $child_rip
1181         SAVE_ALL
1182
1183         # rdi: flags, rsi: usp, rdx: will be &pt_regs
1184         movq %rdx,%rdi
1185         orq  kernel_thread_flags(%rip),%rdi
1186         movq $-1, %rsi
1187         movq %rsp, %rdx
1188
1189         xorl %r8d,%r8d
1190         xorl %r9d,%r9d
1191
1192         # clone now
1193         call do_fork
1194         movq %rax,RAX(%rsp)
1195         xorl %edi,%edi
1196
1197         /*
1198          * It isn't worth to check for reschedule here,
1199          * so internally to the x86_64 port you can rely on kernel_thread()
1200          * not to reschedule the child before returning, this avoids the need
1201          * of hacks for example to fork off the per-CPU idle tasks.
1202          * [Hopefully no generic code relies on the reschedule -AK]
1203          */
1204         RESTORE_ALL
1205         UNFAKE_STACK_FRAME
1206         ret
1207         CFI_ENDPROC
1208 END(kernel_thread)
1209
1210 ENTRY(child_rip)
1211         pushq $0                # fake return address
1212         CFI_STARTPROC
1213         /*
1214          * Here we are in the child and the registers are set as they were
1215          * at kernel_thread() invocation in the parent.
1216          */
1217         movq %rdi, %rax
1218         movq %rsi, %rdi
1219         call *%rax
1220         # exit
1221         mov %eax, %edi
1222         call do_exit
1223         ud2                     # padding for call trace
1224         CFI_ENDPROC
1225 END(child_rip)
1226
1227 /*
1228  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1229  *
1230  * C extern interface:
1231  *       extern long execve(char *name, char **argv, char **envp)
1232  *
1233  * asm input arguments:
1234  *      rdi: name, rsi: argv, rdx: envp
1235  *
1236  * We want to fallback into:
1237  *      extern long sys_execve(char *name, char **argv,char **envp, struct pt_regs *regs)
1238  *
1239  * do_sys_execve asm fallback arguments:
1240  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1241  */
1242 ENTRY(kernel_execve)
1243         CFI_STARTPROC
1244         FAKE_STACK_FRAME $0
1245         SAVE_ALL
1246         movq %rsp,%rcx
1247         call sys_execve
1248         movq %rax, RAX(%rsp)
1249         RESTORE_REST
1250         testq %rax,%rax
1251         je int_ret_from_sys_call
1252         RESTORE_ARGS
1253         UNFAKE_STACK_FRAME
1254         ret
1255         CFI_ENDPROC
1256 END(kernel_execve)
1257
1258 /* Call softirq on interrupt stack. Interrupts are off. */
1259 ENTRY(call_softirq)
1260         CFI_STARTPROC
1261         push %rbp
1262         CFI_ADJUST_CFA_OFFSET   8
1263         CFI_REL_OFFSET rbp,0
1264         mov  %rsp,%rbp
1265         CFI_DEF_CFA_REGISTER rbp
1266         incl PER_CPU_VAR(irq_count)
1267         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1268         push  %rbp                      # backlink for old unwinder
1269         call __do_softirq
1270         leaveq
1271         CFI_DEF_CFA_REGISTER    rsp
1272         CFI_ADJUST_CFA_OFFSET   -8
1273         decl PER_CPU_VAR(irq_count)
1274         ret
1275         CFI_ENDPROC
1276 END(call_softirq)
1277
1278 #ifdef CONFIG_XEN
1279 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1280
1281 /*
1282  * A note on the "critical region" in our callback handler.
1283  * We want to avoid stacking callback handlers due to events occurring
1284  * during handling of the last event. To do this, we keep events disabled
1285  * until we've done all processing. HOWEVER, we must enable events before
1286  * popping the stack frame (can't be done atomically) and so it would still
1287  * be possible to get enough handler activations to overflow the stack.
1288  * Although unlikely, bugs of that kind are hard to track down, so we'd
1289  * like to avoid the possibility.
1290  * So, on entry to the handler we detect whether we interrupted an
1291  * existing activation in its critical region -- if so, we pop the current
1292  * activation and restart the handler using the previous one.
1293  */
1294 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1295         CFI_STARTPROC
1296 /*
1297  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1298  * see the correct pointer to the pt_regs
1299  */
1300         movq %rdi, %rsp            # we don't return, adjust the stack frame
1301         CFI_ENDPROC
1302         DEFAULT_FRAME
1303 11:     incl PER_CPU_VAR(irq_count)
1304         movq %rsp,%rbp
1305         CFI_DEF_CFA_REGISTER rbp
1306         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1307         pushq %rbp                      # backlink for old unwinder
1308         call xen_evtchn_do_upcall
1309         popq %rsp
1310         CFI_DEF_CFA_REGISTER rsp
1311         decl PER_CPU_VAR(irq_count)
1312         jmp  error_exit
1313         CFI_ENDPROC
1314 END(do_hypervisor_callback)
1315
1316 /*
1317  * Hypervisor uses this for application faults while it executes.
1318  * We get here for two reasons:
1319  *  1. Fault while reloading DS, ES, FS or GS
1320  *  2. Fault while executing IRET
1321  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1322  * registers that could be reloaded and zeroed the others.
1323  * Category 2 we fix up by killing the current process. We cannot use the
1324  * normal Linux return path in this case because if we use the IRET hypercall
1325  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1326  * We distinguish between categories by comparing each saved segment register
1327  * with its current contents: any discrepancy means we in category 1.
1328  */
1329 ENTRY(xen_failsafe_callback)
1330         INTR_FRAME 1 (6*8)
1331         /*CFI_REL_OFFSET gs,GS*/
1332         /*CFI_REL_OFFSET fs,FS*/
1333         /*CFI_REL_OFFSET es,ES*/
1334         /*CFI_REL_OFFSET ds,DS*/
1335         CFI_REL_OFFSET r11,8
1336         CFI_REL_OFFSET rcx,0
1337         movw %ds,%cx
1338         cmpw %cx,0x10(%rsp)
1339         CFI_REMEMBER_STATE
1340         jne 1f
1341         movw %es,%cx
1342         cmpw %cx,0x18(%rsp)
1343         jne 1f
1344         movw %fs,%cx
1345         cmpw %cx,0x20(%rsp)
1346         jne 1f
1347         movw %gs,%cx
1348         cmpw %cx,0x28(%rsp)
1349         jne 1f
1350         /* All segments match their saved values => Category 2 (Bad IRET). */
1351         movq (%rsp),%rcx
1352         CFI_RESTORE rcx
1353         movq 8(%rsp),%r11
1354         CFI_RESTORE r11
1355         addq $0x30,%rsp
1356         CFI_ADJUST_CFA_OFFSET -0x30
1357         pushq_cfi $0    /* RIP */
1358         pushq_cfi %r11
1359         pushq_cfi %rcx
1360         jmp general_protection
1361         CFI_RESTORE_STATE
1362 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1363         movq (%rsp),%rcx
1364         CFI_RESTORE rcx
1365         movq 8(%rsp),%r11
1366         CFI_RESTORE r11
1367         addq $0x30,%rsp
1368         CFI_ADJUST_CFA_OFFSET -0x30
1369         pushq_cfi $0
1370         SAVE_ALL
1371         jmp error_exit
1372         CFI_ENDPROC
1373 END(xen_failsafe_callback)
1374
1375 #endif /* CONFIG_XEN */
1376
1377 /*
1378  * Some functions should be protected against kprobes
1379  */
1380         .pushsection .kprobes.text, "ax"
1381
1382 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1383 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1384 paranoiderrorentry stack_segment do_stack_segment
1385 errorentry general_protection do_general_protection
1386 errorentry page_fault do_page_fault
1387 #ifdef CONFIG_X86_MCE
1388 paranoidzeroentry machine_check do_machine_check
1389 #endif
1390
1391         /*
1392          * "Paranoid" exit path from exception stack.
1393          * Paranoid because this is used by NMIs and cannot take
1394          * any kernel state for granted.
1395          * We don't do kernel preemption checks here, because only
1396          * NMI should be common and it does not enable IRQs and
1397          * cannot get reschedule ticks.
1398          *
1399          * "trace" is 0 for the NMI handler only, because irq-tracing
1400          * is fundamentally NMI-unsafe. (we cannot change the soft and
1401          * hard flags at once, atomically)
1402          */
1403
1404         /* ebx: no swapgs flag */
1405 ENTRY(paranoid_exit)
1406         INTR_FRAME
1407         DISABLE_INTERRUPTS(CLBR_NONE)
1408         TRACE_IRQS_OFF
1409         testl %ebx,%ebx                         /* swapgs needed? */
1410         jnz paranoid_restore
1411         testl $3,CS(%rsp)
1412         jnz   paranoid_userspace
1413 paranoid_swapgs:
1414         TRACE_IRQS_IRETQ 0
1415         SWAPGS_UNSAFE_STACK
1416 paranoid_restore:
1417         RESTORE_ALL 8
1418         jmp irq_return
1419 paranoid_userspace:
1420         GET_THREAD_INFO(%rcx)
1421         movl TI_flags(%rcx),%ebx
1422         andl $_TIF_WORK_MASK,%ebx
1423         jz paranoid_swapgs
1424         movq %rsp,%rdi                  /* &pt_regs */
1425         call sync_regs
1426         movq %rax,%rsp                  /* switch stack for scheduling */
1427         testl $_TIF_NEED_RESCHED,%ebx
1428         jnz paranoid_schedule
1429         movl %ebx,%edx                  /* arg3: thread flags */
1430         TRACE_IRQS_ON
1431         ENABLE_INTERRUPTS(CLBR_NONE)
1432         xorl %esi,%esi                  /* arg2: oldset */
1433         movq %rsp,%rdi                  /* arg1: &pt_regs */
1434         call do_notify_resume
1435         DISABLE_INTERRUPTS(CLBR_NONE)
1436         TRACE_IRQS_OFF
1437         jmp paranoid_userspace
1438 paranoid_schedule:
1439         TRACE_IRQS_ON
1440         ENABLE_INTERRUPTS(CLBR_ANY)
1441         call schedule
1442         DISABLE_INTERRUPTS(CLBR_ANY)
1443         TRACE_IRQS_OFF
1444         jmp paranoid_userspace
1445         CFI_ENDPROC
1446 END(paranoid_exit)
1447
1448 /*
1449  * Exception entry point. This expects an error code/orig_rax on the stack.
1450  * returns in "no swapgs flag" in %ebx.
1451  */
1452 ENTRY(error_entry)
1453         XCPT_FRAME
1454         CFI_ADJUST_CFA_OFFSET 15*8
1455         /* oldrax contains error code */
1456         cld
1457         movq_cfi rdi, RDI+8
1458         movq_cfi rsi, RSI+8
1459         movq_cfi rdx, RDX+8
1460         movq_cfi rcx, RCX+8
1461         movq_cfi rax, RAX+8
1462         movq_cfi  r8,  R8+8
1463         movq_cfi  r9,  R9+8
1464         movq_cfi r10, R10+8
1465         movq_cfi r11, R11+8
1466         movq_cfi rbx, RBX+8
1467         movq_cfi rbp, RBP+8
1468         movq_cfi r12, R12+8
1469         movq_cfi r13, R13+8
1470         movq_cfi r14, R14+8
1471         movq_cfi r15, R15+8
1472         xorl %ebx,%ebx
1473         testl $3,CS+8(%rsp)
1474         je error_kernelspace
1475 error_swapgs:
1476         SWAPGS
1477 error_sti:
1478         TRACE_IRQS_OFF
1479         ret
1480         CFI_ENDPROC
1481
1482 /*
1483  * There are two places in the kernel that can potentially fault with
1484  * usergs. Handle them here. The exception handlers after iret run with
1485  * kernel gs again, so don't set the user space flag. B stepping K8s
1486  * sometimes report an truncated RIP for IRET exceptions returning to
1487  * compat mode. Check for these here too.
1488  */
1489 error_kernelspace:
1490         incl %ebx
1491         leaq irq_return(%rip),%rcx
1492         cmpq %rcx,RIP+8(%rsp)
1493         je error_swapgs
1494         movl %ecx,%ecx  /* zero extend */
1495         cmpq %rcx,RIP+8(%rsp)
1496         je error_swapgs
1497         cmpq $gs_change,RIP+8(%rsp)
1498         je error_swapgs
1499         jmp error_sti
1500 END(error_entry)
1501
1502
1503 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1504 ENTRY(error_exit)
1505         DEFAULT_FRAME
1506         movl %ebx,%eax
1507         RESTORE_REST
1508         DISABLE_INTERRUPTS(CLBR_NONE)
1509         TRACE_IRQS_OFF
1510         GET_THREAD_INFO(%rcx)
1511         testl %eax,%eax
1512         jne retint_kernel
1513         LOCKDEP_SYS_EXIT_IRQ
1514         movl TI_flags(%rcx),%edx
1515         movl $_TIF_WORK_MASK,%edi
1516         andl %edi,%edx
1517         jnz retint_careful
1518         jmp retint_swapgs
1519         CFI_ENDPROC
1520 END(error_exit)
1521
1522
1523         /* runs on exception stack */
1524 ENTRY(nmi)
1525         INTR_FRAME
1526         PARAVIRT_ADJUST_EXCEPTION_FRAME
1527         pushq_cfi $-1
1528         subq $15*8, %rsp
1529         CFI_ADJUST_CFA_OFFSET 15*8
1530         call save_paranoid
1531         DEFAULT_FRAME 0
1532         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1533         movq %rsp,%rdi
1534         movq $-1,%rsi
1535         call do_nmi
1536 #ifdef CONFIG_TRACE_IRQFLAGS
1537         /* paranoidexit; without TRACE_IRQS_OFF */
1538         /* ebx: no swapgs flag */
1539         DISABLE_INTERRUPTS(CLBR_NONE)
1540         testl %ebx,%ebx                         /* swapgs needed? */
1541         jnz nmi_restore
1542         testl $3,CS(%rsp)
1543         jnz nmi_userspace
1544 nmi_swapgs:
1545         SWAPGS_UNSAFE_STACK
1546 nmi_restore:
1547         RESTORE_ALL 8
1548         jmp irq_return
1549 nmi_userspace:
1550         GET_THREAD_INFO(%rcx)
1551         movl TI_flags(%rcx),%ebx
1552         andl $_TIF_WORK_MASK,%ebx
1553         jz nmi_swapgs
1554         movq %rsp,%rdi                  /* &pt_regs */
1555         call sync_regs
1556         movq %rax,%rsp                  /* switch stack for scheduling */
1557         testl $_TIF_NEED_RESCHED,%ebx
1558         jnz nmi_schedule
1559         movl %ebx,%edx                  /* arg3: thread flags */
1560         ENABLE_INTERRUPTS(CLBR_NONE)
1561         xorl %esi,%esi                  /* arg2: oldset */
1562         movq %rsp,%rdi                  /* arg1: &pt_regs */
1563         call do_notify_resume
1564         DISABLE_INTERRUPTS(CLBR_NONE)
1565         jmp nmi_userspace
1566 nmi_schedule:
1567         ENABLE_INTERRUPTS(CLBR_ANY)
1568         call schedule
1569         DISABLE_INTERRUPTS(CLBR_ANY)
1570         jmp nmi_userspace
1571         CFI_ENDPROC
1572 #else
1573         jmp paranoid_exit
1574         CFI_ENDPROC
1575 #endif
1576 END(nmi)
1577
1578 ENTRY(ignore_sysret)
1579         CFI_STARTPROC
1580         mov $-ENOSYS,%eax
1581         sysret
1582         CFI_ENDPROC
1583 END(ignore_sysret)
1584
1585 /*
1586  * End of kprobes section
1587  */
1588         .popsection