arch/x86/kernel/entry_32.S

   1 /*
   2  *
   3  *  Copyright (C) 1991, 1992  Linus Torvalds
   4  */
   5
   6 /*
   7  * entry.S contains the system-call and fault low-level handling routines.
   8  * This also contains the timer-interrupt handler, as well as all interrupts
   9  * and faults that can result in a task-switch.
  10  *
  11  * NOTE: This code handles signal-recognition, which happens every time
  12  * after a timer-interrupt and after each system call.
  13  *
  14  * I changed all the .align's to 4 (16 byte alignment), as that's faster
  15  * on a 486.
  16  *
  17  * Stack layout in 'syscall_exit':
  18  *      ptrace needs to have all regs on the stack.
  19  *      if the order here is changed, it needs to be
  20  *      updated in fork.c:copy_process, signal.c:do_signal,
  21  *      ptrace.c and ptrace.h
  22  *
  23  *       0(%esp) - %ebx
  24  *       4(%esp) - %ecx
  25  *       8(%esp) - %edx
  26  *       C(%esp) - %esi
  27  *      10(%esp) - %edi
  28  *      14(%esp) - %ebp
  29  *      18(%esp) - %eax
  30  *      1C(%esp) - %ds
  31  *      20(%esp) - %es
  32  *      24(%esp) - %fs
  33  *      28(%esp) - %gs          saved iff !CONFIG_X86_32_LAZY_GS
  34  *      2C(%esp) - orig_eax
  35  *      30(%esp) - %eip
  36  *      34(%esp) - %cs
  37  *      38(%esp) - %eflags
  38  *      3C(%esp) - %oldesp
  39  *      40(%esp) - %oldss
  40  *
  41  * "current" is in register %ebx during any slow entries.
  42  */
  43
  44 #include <linux/linkage.h>
  45 #include <asm/thread_info.h>
  46 #include <asm/irqflags.h>
  47 #include <asm/errno.h>
  48 #include <asm/segment.h>
  49 #include <asm/smp.h>
  50 #include <asm/page_types.h>
  51 #include <asm/percpu.h>
  52 #include <asm/dwarf2.h>
  53 #include <asm/processor-flags.h>
  54 #include <asm/ftrace.h>
  55 #include <asm/irq_vectors.h>
  56 #include <asm/cpufeature.h>
  57 #include <asm/alternative-asm.h>
  58
  59 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  60 #include <linux/elf-em.h>
  61 #define AUDIT_ARCH_I386         (EM_386|__AUDIT_ARCH_LE)
  62 #define __AUDIT_ARCH_LE    0x40000000
  63
  64 #ifndef CONFIG_AUDITSYSCALL
  65 #define sysenter_audit  syscall_trace_entry
  66 #define sysexit_audit   syscall_exit_work
  67 #endif
  68
  69         .section .entry.text, "ax"
  70
  71 /*
  72  * We use macros for low-level operations which need to be overridden
  73  * for paravirtualization.  The following will never clobber any registers:
  74  *   INTERRUPT_RETURN (aka. "iret")
  75  *   GET_CR0_INTO_EAX (aka. "movl %cr0, %eax")
  76  *   ENABLE_INTERRUPTS_SYSEXIT (aka "sti; sysexit").
  77  *
  78  * For DISABLE_INTERRUPTS/ENABLE_INTERRUPTS (aka "cli"/"sti"), you must
  79  * specify what registers can be overwritten (CLBR_NONE, CLBR_EAX/EDX/ECX/ANY).
  80  * Allowing a register to be clobbered can shrink the paravirt replacement
  81  * enough to patch inline, increasing performance.
  82  */
  83
  84 #define nr_syscalls ((syscall_table_size)/4)
  85
  86 #ifdef CONFIG_PREEMPT
  87 #define preempt_stop(clobbers)  DISABLE_INTERRUPTS(clobbers); TRACE_IRQS_OFF
  88 #else
  89 #define preempt_stop(clobbers)
  90 #define resume_kernel           restore_all
  91 #endif
  92
  93 .macro TRACE_IRQS_IRET
  94 #ifdef CONFIG_TRACE_IRQFLAGS
  95         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)     # interrupts off?
  96         jz 1f
  97         TRACE_IRQS_ON
  98 1:
  99 #endif
 100 .endm
 101
 102 /*
 103  * User gs save/restore
 104  *
 105  * %gs is used for userland TLS and kernel only uses it for stack
 106  * canary which is required to be at %gs:20 by gcc.  Read the comment
 107  * at the top of stackprotector.h for more info.
 108  *
 109  * Local labels 98 and 99 are used.
 110  */
 111 #ifdef CONFIG_X86_32_LAZY_GS
 112
 113  /* unfortunately push/pop can't be no-op */
 114 .macro PUSH_GS
 115         pushl_cfi $0
 116 .endm
 117 .macro POP_GS pop=0
 118         addl $(4 + \pop), %esp
 119         CFI_ADJUST_CFA_OFFSET -(4 + \pop)
 120 .endm
 121 .macro POP_GS_EX
 122 .endm
 123
 124  /* all the rest are no-op */
 125 .macro PTGS_TO_GS
 126 .endm
 127 .macro PTGS_TO_GS_EX
 128 .endm
 129 .macro GS_TO_REG reg
 130 .endm
 131 .macro REG_TO_PTGS reg
 132 .endm
 133 .macro SET_KERNEL_GS reg
 134 .endm
 135
 136 #else   /* CONFIG_X86_32_LAZY_GS */
 137
 138 .macro PUSH_GS
 139         pushl_cfi %gs
 140         /*CFI_REL_OFFSET gs, 0*/
 141 .endm
 142
 143 .macro POP_GS pop=0
 144 98:     popl_cfi %gs
 145         /*CFI_RESTORE gs*/
 146   .if \pop <> 0
 147         add $\pop, %esp
 148         CFI_ADJUST_CFA_OFFSET -\pop
 149   .endif
 150 .endm
 151 .macro POP_GS_EX
 152 .pushsection .fixup, "ax"
 153 99:     movl $0, (%esp)
 154         jmp 98b
 155 .section __ex_table, "a"
 156         .align 4
 157         .long 98b, 99b
 158 .popsection
 159 .endm
 160
 161 .macro PTGS_TO_GS
 162 98:     mov PT_GS(%esp), %gs
 163 .endm
 164 .macro PTGS_TO_GS_EX
 165 .pushsection .fixup, "ax"
 166 99:     movl $0, PT_GS(%esp)
 167         jmp 98b
 168 .section __ex_table, "a"
 169         .align 4
 170         .long 98b, 99b
 171 .popsection
 172 .endm
 173
 174 .macro GS_TO_REG reg
 175         movl %gs, \reg
 176         /*CFI_REGISTER gs, \reg*/
 177 .endm
 178 .macro REG_TO_PTGS reg
 179         movl \reg, PT_GS(%esp)
 180         /*CFI_REL_OFFSET gs, PT_GS*/
 181 .endm
 182 .macro SET_KERNEL_GS reg
 183         movl $(__KERNEL_STACK_CANARY), \reg
 184         movl \reg, %gs
 185 .endm
 186
 187 #endif  /* CONFIG_X86_32_LAZY_GS */
 188
 189 .macro SAVE_ALL
 190         cld
 191         PUSH_GS
 192         pushl_cfi %fs
 193         /*CFI_REL_OFFSET fs, 0;*/
 194         pushl_cfi %es
 195         /*CFI_REL_OFFSET es, 0;*/
 196         pushl_cfi %ds
 197         /*CFI_REL_OFFSET ds, 0;*/
 198         pushl_cfi %eax
 199         CFI_REL_OFFSET eax, 0
 200         pushl_cfi %ebp
 201         CFI_REL_OFFSET ebp, 0
 202         pushl_cfi %edi
 203         CFI_REL_OFFSET edi, 0
 204         pushl_cfi %esi
 205         CFI_REL_OFFSET esi, 0
 206         pushl_cfi %edx
 207         CFI_REL_OFFSET edx, 0
 208         pushl_cfi %ecx
 209         CFI_REL_OFFSET ecx, 0
 210         pushl_cfi %ebx
 211         CFI_REL_OFFSET ebx, 0
 212         movl $(__USER_DS), %edx
 213         movl %edx, %ds
 214         movl %edx, %es
 215         movl $(__KERNEL_PERCPU), %edx
 216         movl %edx, %fs
 217         SET_KERNEL_GS %edx
 218 .endm
 219
 220 .macro RESTORE_INT_REGS
 221         popl_cfi %ebx
 222         CFI_RESTORE ebx
 223         popl_cfi %ecx
 224         CFI_RESTORE ecx
 225         popl_cfi %edx
 226         CFI_RESTORE edx
 227         popl_cfi %esi
 228         CFI_RESTORE esi
 229         popl_cfi %edi
 230         CFI_RESTORE edi
 231         popl_cfi %ebp
 232         CFI_RESTORE ebp
 233         popl_cfi %eax
 234         CFI_RESTORE eax
 235 .endm
 236
 237 .macro RESTORE_REGS pop=0
 238         RESTORE_INT_REGS
 239 1:      popl_cfi %ds
 240         /*CFI_RESTORE ds;*/
 241 2:      popl_cfi %es
 242         /*CFI_RESTORE es;*/
 243 3:      popl_cfi %fs
 244         /*CFI_RESTORE fs;*/
 245         POP_GS \pop
 246 .pushsection .fixup, "ax"
 247 4:      movl $0, (%esp)
 248         jmp 1b
 249 5:      movl $0, (%esp)
 250         jmp 2b
 251 6:      movl $0, (%esp)
 252         jmp 3b
 253 .section __ex_table, "a"
 254         .align 4
 255         .long 1b, 4b
 256         .long 2b, 5b
 257         .long 3b, 6b
 258 .popsection
 259         POP_GS_EX
 260 .endm
 261
 262 .macro RING0_INT_FRAME
 263         CFI_STARTPROC simple
 264         CFI_SIGNAL_FRAME
 265         CFI_DEF_CFA esp, 3*4
 266         /*CFI_OFFSET cs, -2*4;*/
 267         CFI_OFFSET eip, -3*4
 268 .endm
 269
 270 .macro RING0_EC_FRAME
 271         CFI_STARTPROC simple
 272         CFI_SIGNAL_FRAME
 273         CFI_DEF_CFA esp, 4*4
 274         /*CFI_OFFSET cs, -2*4;*/
 275         CFI_OFFSET eip, -3*4
 276 .endm
 277
 278 .macro RING0_PTREGS_FRAME
 279         CFI_STARTPROC simple
 280         CFI_SIGNAL_FRAME
 281         CFI_DEF_CFA esp, PT_OLDESP-PT_EBX
 282         /*CFI_OFFSET cs, PT_CS-PT_OLDESP;*/
 283         CFI_OFFSET eip, PT_EIP-PT_OLDESP
 284         /*CFI_OFFSET es, PT_ES-PT_OLDESP;*/
 285         /*CFI_OFFSET ds, PT_DS-PT_OLDESP;*/
 286         CFI_OFFSET eax, PT_EAX-PT_OLDESP
 287         CFI_OFFSET ebp, PT_EBP-PT_OLDESP
 288         CFI_OFFSET edi, PT_EDI-PT_OLDESP
 289         CFI_OFFSET esi, PT_ESI-PT_OLDESP
 290         CFI_OFFSET edx, PT_EDX-PT_OLDESP
 291         CFI_OFFSET ecx, PT_ECX-PT_OLDESP
 292         CFI_OFFSET ebx, PT_EBX-PT_OLDESP
 293 .endm
 294
 295 ENTRY(ret_from_fork)
 296         CFI_STARTPROC
 297         pushl_cfi %eax
 298         call schedule_tail
 299         GET_THREAD_INFO(%ebp)
 300         popl_cfi %eax
 301         pushl_cfi $0x0202               # Reset kernel eflags
 302         popfl_cfi
 303         jmp syscall_exit
 304         CFI_ENDPROC
 305 END(ret_from_fork)
 306
 307 /*
 308  * Interrupt exit functions should be protected against kprobes
 309  */
 310         .pushsection .kprobes.text, "ax"
 311 /*
 312  * Return to user mode is not as complex as all this looks,
 313  * but we want the default path for a system call return to
 314  * go as quickly as possible which is why some of this is
 315  * less clear than it otherwise should be.
 316  */
 317
 318         # userspace resumption stub bypassing syscall exit tracing
 319         ALIGN
 320         RING0_PTREGS_FRAME
 321 ret_from_exception:
 322         preempt_stop(CLBR_ANY)
 323 ret_from_intr:
 324         GET_THREAD_INFO(%ebp)
 325 resume_userspace_sig:
 326 #ifdef CONFIG_VM86
 327         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS and CS
 328         movb PT_CS(%esp), %al
 329         andl $(X86_EFLAGS_VM | SEGMENT_RPL_MASK), %eax
 330 #else
 331         /*
 332          * We can be coming here from a syscall done in the kernel space,
 333          * e.g. a failed kernel_execve().
 334          */
 335         movl PT_CS(%esp), %eax
 336         andl $SEGMENT_RPL_MASK, %eax
 337 #endif
 338         cmpl $USER_RPL, %eax
 339         jb resume_kernel                # not returning to v8086 or userspace
 340
 341 ENTRY(resume_userspace)
 342         LOCKDEP_SYS_EXIT
 343         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 344                                         # setting need_resched or sigpending
 345                                         # between sampling and the iret
 346         TRACE_IRQS_OFF
 347         movl TI_flags(%ebp), %ecx
 348         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done on
 349                                         # int/exception return?
 350         jne work_pending
 351         jmp restore_all
 352 END(ret_from_exception)
 353
 354 #ifdef CONFIG_PREEMPT
 355 ENTRY(resume_kernel)
 356         DISABLE_INTERRUPTS(CLBR_ANY)
 357         cmpl $0,TI_preempt_count(%ebp)  # non-zero preempt_count ?
 358         jnz restore_all
 359 need_resched:
 360         movl TI_flags(%ebp), %ecx       # need_resched set ?
 361         testb $_TIF_NEED_RESCHED, %cl
 362         jz restore_all
 363         testl $X86_EFLAGS_IF,PT_EFLAGS(%esp)    # interrupts off (exception path) ?
 364         jz restore_all
 365         call preempt_schedule_irq
 366         jmp need_resched
 367 END(resume_kernel)
 368 #endif
 369         CFI_ENDPROC
 370 /*
 371  * End of kprobes section
 372  */
 373         .popsection
 374
 375 /* SYSENTER_RETURN points to after the "sysenter" instruction in
 376    the vsyscall page.  See vsyscall-sysentry.S, which defines the symbol.  */
 377
 378         # sysenter call handler stub
 379 ENTRY(ia32_sysenter_target)
 380         CFI_STARTPROC simple
 381         CFI_SIGNAL_FRAME
 382         CFI_DEF_CFA esp, 0
 383         CFI_REGISTER esp, ebp
 384         movl TSS_sysenter_sp0(%esp),%esp
 385 sysenter_past_esp:
 386         /*
 387          * Interrupts are disabled here, but we can't trace it until
 388          * enough kernel state to call TRACE_IRQS_OFF can be called - but
 389          * we immediately enable interrupts at that point anyway.
 390          */
 391         pushl_cfi $__USER_DS
 392         /*CFI_REL_OFFSET ss, 0*/
 393         pushl_cfi %ebp
 394         CFI_REL_OFFSET esp, 0
 395         pushfl_cfi
 396         orl $X86_EFLAGS_IF, (%esp)
 397         pushl_cfi $__USER_CS
 398         /*CFI_REL_OFFSET cs, 0*/
 399         /*
 400          * Push current_thread_info()->sysenter_return to the stack.
 401          * A tiny bit of offset fixup is necessary - 4*4 means the 4 words
 402          * pushed above; +8 corresponds to copy_thread's esp0 setting.
 403          */
 404         pushl_cfi ((TI_sysenter_return)-THREAD_SIZE+8+4*4)(%esp)
 405         CFI_REL_OFFSET eip, 0
 406
 407         pushl_cfi %eax
 408         SAVE_ALL
 409         ENABLE_INTERRUPTS(CLBR_NONE)
 410
 411 /*
 412  * Load the potential sixth argument from user stack.
 413  * Careful about security.
 414  */
 415         cmpl $__PAGE_OFFSET-3,%ebp
 416         jae syscall_fault
 417 1:      movl (%ebp),%ebp
 418         movl %ebp,PT_EBP(%esp)
 419 .section __ex_table,"a"
 420         .align 4
 421         .long 1b,syscall_fault
 422 .previous
 423
 424         GET_THREAD_INFO(%ebp)
 425
 426         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 427         jnz sysenter_audit
 428 sysenter_do_call:
 429         cmpl $(nr_syscalls), %eax
 430         jae sysenter_badsys
 431         call *sys_call_table(,%eax,4)
 432         movl %eax,PT_EAX(%esp)
 433 sysenter_after_call:
 434         LOCKDEP_SYS_EXIT
 435         DISABLE_INTERRUPTS(CLBR_ANY)
 436         TRACE_IRQS_OFF
 437         movl TI_flags(%ebp), %ecx
 438         testl $_TIF_ALLWORK_MASK, %ecx
 439         jne sysexit_audit
 440 sysenter_exit:
 441 /* if something modifies registers it must also disable sysexit */
 442         movl PT_EIP(%esp), %edx
 443         movl PT_OLDESP(%esp), %ecx
 444         xorl %ebp,%ebp
 445         TRACE_IRQS_ON
 446 1:      mov  PT_FS(%esp), %fs
 447         PTGS_TO_GS
 448         ENABLE_INTERRUPTS_SYSEXIT
 449
 450 #ifdef CONFIG_AUDITSYSCALL
 451 sysenter_audit:
 452         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%ebp)
 453         jnz syscall_trace_entry
 454         addl $4,%esp
 455         CFI_ADJUST_CFA_OFFSET -4
 456         /* %esi already in 8(%esp)         6th arg: 4th syscall arg */
 457         /* %edx already in 4(%esp)         5th arg: 3rd syscall arg */
 458         /* %ecx already in 0(%esp)         4th arg: 2nd syscall arg */
 459         movl %ebx,%ecx                  /* 3rd arg: 1st syscall arg */
 460         movl %eax,%edx                  /* 2nd arg: syscall number */
 461         movl $AUDIT_ARCH_I386,%eax      /* 1st arg: audit arch */
 462         call audit_syscall_entry
 463         pushl_cfi %ebx
 464         movl PT_EAX(%esp),%eax          /* reload syscall number */
 465         jmp sysenter_do_call
 466
 467 sysexit_audit:
 468         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 469         jne syscall_exit_work
 470         TRACE_IRQS_ON
 471         ENABLE_INTERRUPTS(CLBR_ANY)
 472         movl %eax,%edx          /* second arg, syscall return value */
 473         cmpl $0,%eax            /* is it < 0? */
 474         setl %al                /* 1 if so, 0 if not */
 475         movzbl %al,%eax         /* zero-extend that */
 476         inc %eax /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 477         call audit_syscall_exit
 478         DISABLE_INTERRUPTS(CLBR_ANY)
 479         TRACE_IRQS_OFF
 480         movl TI_flags(%ebp), %ecx
 481         testl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT), %ecx
 482         jne syscall_exit_work
 483         movl PT_EAX(%esp),%eax  /* reload syscall return value */
 484         jmp sysenter_exit
 485 #endif
 486
 487         CFI_ENDPROC
 488 .pushsection .fixup,"ax"
 489 2:      movl $0,PT_FS(%esp)
 490         jmp 1b
 491 .section __ex_table,"a"
 492         .align 4
 493         .long 1b,2b
 494 .popsection
 495         PTGS_TO_GS_EX
 496 ENDPROC(ia32_sysenter_target)
 497
 498 /*
 499  * syscall stub including irq exit should be protected against kprobes
 500  */
 501         .pushsection .kprobes.text, "ax"
 502         # system call handler stub
 503 ENTRY(system_call)
 504         RING0_INT_FRAME                 # can't unwind into user space anyway
 505         pushl_cfi %eax                  # save orig_eax
 506         SAVE_ALL
 507         GET_THREAD_INFO(%ebp)
 508                                         # system call tracing in operation / emulation
 509         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%ebp)
 510         jnz syscall_trace_entry
 511         cmpl $(nr_syscalls), %eax
 512         jae syscall_badsys
 513 syscall_call:
 514         call *sys_call_table(,%eax,4)
 515         movl %eax,PT_EAX(%esp)          # store the return value
 516 syscall_exit:
 517         LOCKDEP_SYS_EXIT
 518         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 519                                         # setting need_resched or sigpending
 520                                         # between sampling and the iret
 521         TRACE_IRQS_OFF
 522         movl TI_flags(%ebp), %ecx
 523         testl $_TIF_ALLWORK_MASK, %ecx  # current->work
 524         jne syscall_exit_work
 525
 526 restore_all:
 527         TRACE_IRQS_IRET
 528 restore_all_notrace:
 529         movl PT_EFLAGS(%esp), %eax      # mix EFLAGS, SS and CS
 530         # Warning: PT_OLDSS(%esp) contains the wrong/random values if we
 531         # are returning to the kernel.
 532         # See comments in process.c:copy_thread() for details.
 533         movb PT_OLDSS(%esp), %ah
 534         movb PT_CS(%esp), %al
 535         andl $(X86_EFLAGS_VM | (SEGMENT_TI_MASK << 8) | SEGMENT_RPL_MASK), %eax
 536         cmpl $((SEGMENT_LDT << 8) | USER_RPL), %eax
 537         CFI_REMEMBER_STATE
 538         je ldt_ss                       # returning to user-space with LDT SS
 539 restore_nocheck:
 540         RESTORE_REGS 4                  # skip orig_eax/error_code
 541 irq_return:
 542         INTERRUPT_RETURN
 543 .section .fixup,"ax"
 544 ENTRY(iret_exc)
 545         pushl $0                        # no error code
 546         pushl $do_iret_error
 547         jmp error_code
 548 .previous
 549 .section __ex_table,"a"
 550         .align 4
 551         .long irq_return,iret_exc
 552 .previous
 553
 554         CFI_RESTORE_STATE
 555 ldt_ss:
 556         larl PT_OLDSS(%esp), %eax
 557         jnz restore_nocheck
 558         testl $0x00400000, %eax         # returning to 32bit stack?
 559         jnz restore_nocheck             # allright, normal return
 560
 561 #ifdef CONFIG_PARAVIRT
 562         /*
 563          * The kernel can't run on a non-flat stack if paravirt mode
 564          * is active.  Rather than try to fixup the high bits of
 565          * ESP, bypass this code entirely.  This may break DOSemu
 566          * and/or Wine support in a paravirt VM, although the option
 567          * is still available to implement the setting of the high
 568          * 16-bits in the INTERRUPT_RETURN paravirt-op.
 569          */
 570         cmpl $0, pv_info+PARAVIRT_enabled
 571         jne restore_nocheck
 572 #endif
 573
 574 /*
 575  * Setup and switch to ESPFIX stack
 576  *
 577  * We're returning to userspace with a 16 bit stack. The CPU will not
 578  * restore the high word of ESP for us on executing iret... This is an
 579  * "official" bug of all the x86-compatible CPUs, which we can work
 580  * around to make dosemu and wine happy. We do this by preloading the
 581  * high word of ESP with the high word of the userspace ESP while
 582  * compensating for the offset by changing to the ESPFIX segment with
 583  * a base address that matches for the difference.
 584  */
 585 #define GDT_ESPFIX_SS PER_CPU_VAR(gdt_page) + (GDT_ENTRY_ESPFIX_SS * 8)
 586         mov %esp, %edx                  /* load kernel esp */
 587         mov PT_OLDESP(%esp), %eax       /* load userspace esp */
 588         mov %dx, %ax                    /* eax: new kernel esp */
 589         sub %eax, %edx                  /* offset (low word is 0) */
 590         shr $16, %edx
 591         mov %dl, GDT_ESPFIX_SS + 4 /* bits 16..23 */
 592         mov %dh, GDT_ESPFIX_SS + 7 /* bits 24..31 */
 593         pushl_cfi $__ESPFIX_SS
 594         pushl_cfi %eax                  /* new kernel esp */
 595         /* Disable interrupts, but do not irqtrace this section: we
 596          * will soon execute iret and the tracer was already set to
 597          * the irqstate after the iret */
 598         DISABLE_INTERRUPTS(CLBR_EAX)
 599         lss (%esp), %esp                /* switch to espfix segment */
 600         CFI_ADJUST_CFA_OFFSET -8
 601         jmp restore_nocheck
 602         CFI_ENDPROC
 603 ENDPROC(system_call)
 604
 605         # perform work that needs to be done immediately before resumption
 606         ALIGN
 607         RING0_PTREGS_FRAME              # can't unwind into user space anyway
 608 work_pending:
 609         testb $_TIF_NEED_RESCHED, %cl
 610         jz work_notifysig
 611 work_resched:
 612         call schedule
 613         LOCKDEP_SYS_EXIT
 614         DISABLE_INTERRUPTS(CLBR_ANY)    # make sure we don't miss an interrupt
 615                                         # setting need_resched or sigpending
 616                                         # between sampling and the iret
 617         TRACE_IRQS_OFF
 618         movl TI_flags(%ebp), %ecx
 619         andl $_TIF_WORK_MASK, %ecx      # is there any work to be done other
 620                                         # than syscall tracing?
 621         jz restore_all
 622         testb $_TIF_NEED_RESCHED, %cl
 623         jnz work_resched
 624
 625 work_notifysig:                         # deal with pending signals and
 626                                         # notify-resume requests
 627 #ifdef CONFIG_VM86
 628         testl $X86_EFLAGS_VM, PT_EFLAGS(%esp)
 629         movl %esp, %eax
 630         jne work_notifysig_v86          # returning to kernel-space or
 631                                         # vm86-space
 632         xorl %edx, %edx
 633         call do_notify_resume
 634         jmp resume_userspace_sig
 635
 636         ALIGN
 637 work_notifysig_v86:
 638         pushl_cfi %ecx                  # save ti_flags for do_notify_resume
 639         call save_v86_state             # %eax contains pt_regs pointer
 640         popl_cfi %ecx
 641         movl %eax, %esp
 642 #else
 643         movl %esp, %eax
 644 #endif
 645         xorl %edx, %edx
 646         call do_notify_resume
 647         jmp resume_userspace_sig
 648 END(work_pending)
 649
 650         # perform syscall exit tracing
 651         ALIGN
 652 syscall_trace_entry:
 653         movl $-ENOSYS,PT_EAX(%esp)
 654         movl %esp, %eax
 655         call syscall_trace_enter
 656         /* What it returned is what we'll actually use.  */
 657         cmpl $(nr_syscalls), %eax
 658         jnae syscall_call
 659         jmp syscall_exit
 660 END(syscall_trace_entry)
 661
 662         # perform syscall exit tracing
 663         ALIGN
 664 syscall_exit_work:
 665         testl $_TIF_WORK_SYSCALL_EXIT, %ecx
 666         jz work_pending
 667         TRACE_IRQS_ON
 668         ENABLE_INTERRUPTS(CLBR_ANY)     # could let syscall_trace_leave() call
 669                                         # schedule() instead
 670         movl %esp, %eax
 671         call syscall_trace_leave
 672         jmp resume_userspace
 673 END(syscall_exit_work)
 674         CFI_ENDPROC
 675
 676         RING0_INT_FRAME                 # can't unwind into user space anyway
 677 syscall_fault:
 678         GET_THREAD_INFO(%ebp)
 679         movl $-EFAULT,PT_EAX(%esp)
 680         jmp resume_userspace
 681 END(syscall_fault)
 682
 683 syscall_badsys:
 684         movl $-ENOSYS,PT_EAX(%esp)
 685         jmp syscall_exit
 686 END(syscall_badsys)
 687
 688 sysenter_badsys:
 689         movl $-ENOSYS,PT_EAX(%esp)
 690         jmp sysenter_after_call
 691 END(syscall_badsys)
 692         CFI_ENDPROC
 693 /*
 694  * End of kprobes section
 695  */
 696         .popsection
 697
 698 /*
 699  * System calls that need a pt_regs pointer.
 700  */
 701 #define PTREGSCALL0(name) \
 702         ALIGN; \
 703 ptregs_##name: \
 704         leal 4(%esp),%eax; \
 705         jmp sys_##name;
 706
 707 #define PTREGSCALL1(name) \
 708         ALIGN; \
 709 ptregs_##name: \
 710         leal 4(%esp),%edx; \
 711         movl (PT_EBX+4)(%esp),%eax; \
 712         jmp sys_##name;
 713
 714 #define PTREGSCALL2(name) \
 715         ALIGN; \
 716 ptregs_##name: \
 717         leal 4(%esp),%ecx; \
 718         movl (PT_ECX+4)(%esp),%edx; \
 719         movl (PT_EBX+4)(%esp),%eax; \
 720         jmp sys_##name;
 721
 722 #define PTREGSCALL3(name) \
 723         ALIGN; \
 724 ptregs_##name: \
 725         CFI_STARTPROC; \
 726         leal 4(%esp),%eax; \
 727         pushl_cfi %eax; \
 728         movl PT_EDX(%eax),%ecx; \
 729         movl PT_ECX(%eax),%edx; \
 730         movl PT_EBX(%eax),%eax; \
 731         call sys_##name; \
 732         addl $4,%esp; \
 733         CFI_ADJUST_CFA_OFFSET -4; \
 734         ret; \
 735         CFI_ENDPROC; \
 736 ENDPROC(ptregs_##name)
 737
 738 PTREGSCALL1(iopl)
 739 PTREGSCALL0(fork)
 740 PTREGSCALL0(vfork)
 741 PTREGSCALL3(execve)
 742 PTREGSCALL2(sigaltstack)
 743 PTREGSCALL0(sigreturn)
 744 PTREGSCALL0(rt_sigreturn)
 745 PTREGSCALL2(vm86)
 746 PTREGSCALL1(vm86old)
 747
 748 /* Clone is an oddball.  The 4th arg is in %edi */
 749         ALIGN;
 750 ptregs_clone:
 751         CFI_STARTPROC
 752         leal 4(%esp),%eax
 753         pushl_cfi %eax
 754         pushl_cfi PT_EDI(%eax)
 755         movl PT_EDX(%eax),%ecx
 756         movl PT_ECX(%eax),%edx
 757         movl PT_EBX(%eax),%eax
 758         call sys_clone
 759         addl $8,%esp
 760         CFI_ADJUST_CFA_OFFSET -8
 761         ret
 762         CFI_ENDPROC
 763 ENDPROC(ptregs_clone)
 764
 765 .macro FIXUP_ESPFIX_STACK
 766 /*
 767  * Switch back for ESPFIX stack to the normal zerobased stack
 768  *
 769  * We can't call C functions using the ESPFIX stack. This code reads
 770  * the high word of the segment base from the GDT and swiches to the
 771  * normal stack and adjusts ESP with the matching offset.
 772  */
 773         /* fixup the stack */
 774         mov GDT_ESPFIX_SS + 4, %al /* bits 16..23 */
 775         mov GDT_ESPFIX_SS + 7, %ah /* bits 24..31 */
 776         shl $16, %eax
 777         addl %esp, %eax                 /* the adjusted stack pointer */
 778         pushl_cfi $__KERNEL_DS
 779         pushl_cfi %eax
 780         lss (%esp), %esp                /* switch to the normal stack segment */
 781         CFI_ADJUST_CFA_OFFSET -8
 782 .endm
 783 .macro UNWIND_ESPFIX_STACK
 784         movl %ss, %eax
 785         /* see if on espfix stack */
 786         cmpw $__ESPFIX_SS, %ax
 787         jne 27f
 788         movl $__KERNEL_DS, %eax
 789         movl %eax, %ds
 790         movl %eax, %es
 791         /* switch to normal stack */
 792         FIXUP_ESPFIX_STACK
 793 27:
 794 .endm
 795
 796 /*
 797  * Build the entry stubs and pointer table with some assembler magic.
 798  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 799  * single cache line on all modern x86 implementations.
 800  */
 801 .section .init.rodata,"a"
 802 ENTRY(interrupt)
 803 .section .entry.text, "ax"
 804         .p2align 5
 805         .p2align CONFIG_X86_L1_CACHE_SHIFT
 806 ENTRY(irq_entries_start)
 807         RING0_INT_FRAME
 808 vector=FIRST_EXTERNAL_VECTOR
 809 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 810         .balign 32
 811   .rept 7
 812     .if vector < NR_VECTORS
 813       .if vector <> FIRST_EXTERNAL_VECTOR
 814         CFI_ADJUST_CFA_OFFSET -4
 815       .endif
 816 1:      pushl_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 817       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 818         jmp 2f
 819       .endif
 820       .previous
 821         .long 1b
 822       .section .entry.text, "ax"
 823 vector=vector+1
 824     .endif
 825   .endr
 826 2:      jmp common_interrupt
 827 .endr
 828 END(irq_entries_start)
 829
 830 .previous
 831 END(interrupt)
 832 .previous
 833
 834 /*
 835  * the CPU automatically disables interrupts when executing an IRQ vector,
 836  * so IRQ-flags tracing has to follow that:
 837  */
 838         .p2align CONFIG_X86_L1_CACHE_SHIFT
 839 common_interrupt:
 840         addl $-0x80,(%esp)      /* Adjust vector into the [-256,-1] range */
 841         SAVE_ALL
 842         TRACE_IRQS_OFF
 843         movl %esp,%eax
 844         call do_IRQ
 845         jmp ret_from_intr
 846 ENDPROC(common_interrupt)
 847         CFI_ENDPROC
 848
 849 /*
 850  *  Irq entries should be protected against kprobes
 851  */
 852         .pushsection .kprobes.text, "ax"
 853 #define BUILD_INTERRUPT3(name, nr, fn)  \
 854 ENTRY(name)                             \
 855         RING0_INT_FRAME;                \
 856         pushl_cfi $~(nr);               \
 857         SAVE_ALL;                       \
 858         TRACE_IRQS_OFF                  \
 859         movl %esp,%eax;                 \
 860         call fn;                        \
 861         jmp ret_from_intr;              \
 862         CFI_ENDPROC;                    \
 863 ENDPROC(name)
 864
 865 #define BUILD_INTERRUPT(name, nr)       BUILD_INTERRUPT3(name, nr, smp_##name)
 866
 867 /* The include is where all of the SMP etc. interrupts come from */
 868 #include <asm/entry_arch.h>
 869
 870 ENTRY(coprocessor_error)
 871         RING0_INT_FRAME
 872         pushl_cfi $0
 873         pushl_cfi $do_coprocessor_error
 874         jmp error_code
 875         CFI_ENDPROC
 876 END(coprocessor_error)
 877
 878 ENTRY(simd_coprocessor_error)
 879         RING0_INT_FRAME
 880         pushl_cfi $0
 881 #ifdef CONFIG_X86_INVD_BUG
 882         /* AMD 486 bug: invd from userspace calls exception 19 instead of #GP */
 883 661:    pushl_cfi $do_general_protection
 884 662:
 885 .section .altinstructions,"a"
 886         altinstruction_entry 661b, 663f, X86_FEATURE_XMM, 662b-661b, 664f-663f
 887 .previous
 888 .section .altinstr_replacement,"ax"
 889 663:    pushl $do_simd_coprocessor_error
 890 664:
 891 .previous
 892 #else
 893         pushl_cfi $do_simd_coprocessor_error
 894 #endif
 895         jmp error_code
 896         CFI_ENDPROC
 897 END(simd_coprocessor_error)
 898
 899 ENTRY(device_not_available)
 900         RING0_INT_FRAME
 901         pushl_cfi $-1                   # mark this as an int
 902         pushl_cfi $do_device_not_available
 903         jmp error_code
 904         CFI_ENDPROC
 905 END(device_not_available)
 906
 907 #ifdef CONFIG_PARAVIRT
 908 ENTRY(native_iret)
 909         iret
 910 .section __ex_table,"a"
 911         .align 4
 912         .long native_iret, iret_exc
 913 .previous
 914 END(native_iret)
 915
 916 ENTRY(native_irq_enable_sysexit)
 917         sti
 918         sysexit
 919 END(native_irq_enable_sysexit)
 920 #endif
 921
 922 ENTRY(overflow)
 923         RING0_INT_FRAME
 924         pushl_cfi $0
 925         pushl_cfi $do_overflow
 926         jmp error_code
 927         CFI_ENDPROC
 928 END(overflow)
 929
 930 ENTRY(bounds)
 931         RING0_INT_FRAME
 932         pushl_cfi $0
 933         pushl_cfi $do_bounds
 934         jmp error_code
 935         CFI_ENDPROC
 936 END(bounds)
 937
 938 ENTRY(invalid_op)
 939         RING0_INT_FRAME
 940         pushl_cfi $0
 941         pushl_cfi $do_invalid_op
 942         jmp error_code
 943         CFI_ENDPROC
 944 END(invalid_op)
 945
 946 ENTRY(coprocessor_segment_overrun)
 947         RING0_INT_FRAME
 948         pushl_cfi $0
 949         pushl_cfi $do_coprocessor_segment_overrun
 950         jmp error_code
 951         CFI_ENDPROC
 952 END(coprocessor_segment_overrun)
 953
 954 ENTRY(invalid_TSS)
 955         RING0_EC_FRAME
 956         pushl_cfi $do_invalid_TSS
 957         jmp error_code
 958         CFI_ENDPROC
 959 END(invalid_TSS)
 960
 961 ENTRY(segment_not_present)
 962         RING0_EC_FRAME
 963         pushl_cfi $do_segment_not_present
 964         jmp error_code
 965         CFI_ENDPROC
 966 END(segment_not_present)
 967
 968 ENTRY(stack_segment)
 969         RING0_EC_FRAME
 970         pushl_cfi $do_stack_segment
 971         jmp error_code
 972         CFI_ENDPROC
 973 END(stack_segment)
 974
 975 ENTRY(alignment_check)
 976         RING0_EC_FRAME
 977         pushl_cfi $do_alignment_check
 978         jmp error_code
 979         CFI_ENDPROC
 980 END(alignment_check)
 981
 982 ENTRY(divide_error)
 983         RING0_INT_FRAME
 984         pushl_cfi $0                    # no error code
 985         pushl_cfi $do_divide_error
 986         jmp error_code
 987         CFI_ENDPROC
 988 END(divide_error)
 989
 990 #ifdef CONFIG_X86_MCE
 991 ENTRY(machine_check)
 992         RING0_INT_FRAME
 993         pushl_cfi $0
 994         pushl_cfi machine_check_vector
 995         jmp error_code
 996         CFI_ENDPROC
 997 END(machine_check)
 998 #endif
 999
1000 ENTRY(spurious_interrupt_bug)
1001         RING0_INT_FRAME
1002         pushl_cfi $0
1003         pushl_cfi $do_spurious_interrupt_bug
1004         jmp error_code
1005         CFI_ENDPROC
1006 END(spurious_interrupt_bug)
1007 /*
1008  * End of kprobes section
1009  */
1010         .popsection
1011
1012 ENTRY(kernel_thread_helper)
1013         pushl $0                # fake return address for unwinder
1014         CFI_STARTPROC
1015         movl %edi,%eax
1016         call *%esi
1017         call do_exit
1018         ud2                     # padding for call trace
1019         CFI_ENDPROC
1020 ENDPROC(kernel_thread_helper)
1021
1022 #ifdef CONFIG_XEN
1023 /* Xen doesn't set %esp to be precisely what the normal sysenter
1024    entrypoint expects, so fix it up before using the normal path. */
1025 ENTRY(xen_sysenter_target)
1026         RING0_INT_FRAME
1027         addl $5*4, %esp         /* remove xen-provided frame */
1028         CFI_ADJUST_CFA_OFFSET -5*4
1029         jmp sysenter_past_esp
1030         CFI_ENDPROC
1031
1032 ENTRY(xen_hypervisor_callback)
1033         CFI_STARTPROC
1034         pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1035         SAVE_ALL
1036         TRACE_IRQS_OFF
1037
1038         /* Check to see if we got the event in the critical
1039            region in xen_iret_direct, after we've reenabled
1040            events and checked for pending events.  This simulates
1041            iret instruction's behaviour where it delivers a
1042            pending interrupt when enabling interrupts. */
1043         movl PT_EIP(%esp),%eax
1044         cmpl $xen_iret_start_crit,%eax
1045         jb   1f
1046         cmpl $xen_iret_end_crit,%eax
1047         jae  1f
1048
1049         jmp  xen_iret_crit_fixup
1050
1051 ENTRY(xen_do_upcall)
1052 1:      mov %esp, %eax
1053         call xen_evtchn_do_upcall
1054         jmp  ret_from_intr
1055         CFI_ENDPROC
1056 ENDPROC(xen_hypervisor_callback)
1057
1058 # Hypervisor uses this for application faults while it executes.
1059 # We get here for two reasons:
1060 #  1. Fault while reloading DS, ES, FS or GS
1061 #  2. Fault while executing IRET
1062 # Category 1 we fix up by reattempting the load, and zeroing the segment
1063 # register if the load fails.
1064 # Category 2 we fix up by jumping to do_iret_error. We cannot use the
1065 # normal Linux return path in this case because if we use the IRET hypercall
1066 # to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1067 # We distinguish between categories by maintaining a status value in EAX.
1068 ENTRY(xen_failsafe_callback)
1069         CFI_STARTPROC
1070         pushl_cfi %eax
1071         movl $1,%eax
1072 1:      mov 4(%esp),%ds
1073 2:      mov 8(%esp),%es
1074 3:      mov 12(%esp),%fs
1075 4:      mov 16(%esp),%gs
1076         /* EAX == 0 => Category 1 (Bad segment)
1077            EAX != 0 => Category 2 (Bad IRET) */
1078         testl %eax,%eax
1079         popl_cfi %eax
1080         lea 16(%esp),%esp
1081         CFI_ADJUST_CFA_OFFSET -16
1082         jz 5f
1083         jmp iret_exc
1084 5:      pushl_cfi $-1 /* orig_ax = -1 => not a system call */
1085         SAVE_ALL
1086         jmp ret_from_exception
1087         CFI_ENDPROC
1088
1089 .section .fixup,"ax"
1090 6:      xorl %eax,%eax
1091         movl %eax,4(%esp)
1092         jmp 1b
1093 7:      xorl %eax,%eax
1094         movl %eax,8(%esp)
1095         jmp 2b
1096 8:      xorl %eax,%eax
1097         movl %eax,12(%esp)
1098         jmp 3b
1099 9:      xorl %eax,%eax
1100         movl %eax,16(%esp)
1101         jmp 4b
1102 .previous
1103 .section __ex_table,"a"
1104         .align 4
1105         .long 1b,6b
1106         .long 2b,7b
1107         .long 3b,8b
1108         .long 4b,9b
1109 .previous
1110 ENDPROC(xen_failsafe_callback)
1111
1112 BUILD_INTERRUPT3(xen_hvm_callback_vector, XEN_HVM_EVTCHN_CALLBACK,
1113                 xen_evtchn_do_upcall)
1114
1115 #endif  /* CONFIG_XEN */
1116
1117 #ifdef CONFIG_FUNCTION_TRACER
1118 #ifdef CONFIG_DYNAMIC_FTRACE
1119
1120 ENTRY(mcount)
1121         ret
1122 END(mcount)
1123
1124 ENTRY(ftrace_caller)
1125         cmpl $0, function_trace_stop
1126         jne  ftrace_stub
1127
1128         pushl %eax
1129         pushl %ecx
1130         pushl %edx
1131         movl 0xc(%esp), %eax
1132         movl 0x4(%ebp), %edx
1133         subl $MCOUNT_INSN_SIZE, %eax
1134
1135 .globl ftrace_call
1136 ftrace_call:
1137         call ftrace_stub
1138
1139         popl %edx
1140         popl %ecx
1141         popl %eax
1142 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1143 .globl ftrace_graph_call
1144 ftrace_graph_call:
1145         jmp ftrace_stub
1146 #endif
1147
1148 .globl ftrace_stub
1149 ftrace_stub:
1150         ret
1151 END(ftrace_caller)
1152
1153 #else /* ! CONFIG_DYNAMIC_FTRACE */
1154
1155 ENTRY(mcount)
1156         cmpl $0, function_trace_stop
1157         jne  ftrace_stub
1158
1159         cmpl $ftrace_stub, ftrace_trace_function
1160         jnz trace
1161 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1162         cmpl $ftrace_stub, ftrace_graph_return
1163         jnz ftrace_graph_caller
1164
1165         cmpl $ftrace_graph_entry_stub, ftrace_graph_entry
1166         jnz ftrace_graph_caller
1167 #endif
1168 .globl ftrace_stub
1169 ftrace_stub:
1170         ret
1171
1172         /* taken from glibc */
1173 trace:
1174         pushl %eax
1175         pushl %ecx
1176         pushl %edx
1177         movl 0xc(%esp), %eax
1178         movl 0x4(%ebp), %edx
1179         subl $MCOUNT_INSN_SIZE, %eax
1180
1181         call *ftrace_trace_function
1182
1183         popl %edx
1184         popl %ecx
1185         popl %eax
1186         jmp ftrace_stub
1187 END(mcount)
1188 #endif /* CONFIG_DYNAMIC_FTRACE */
1189 #endif /* CONFIG_FUNCTION_TRACER */
1190
1191 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
1192 ENTRY(ftrace_graph_caller)
1193         cmpl $0, function_trace_stop
1194         jne ftrace_stub
1195
1196         pushl %eax
1197         pushl %ecx
1198         pushl %edx
1199         movl 0xc(%esp), %edx
1200         lea 0x4(%ebp), %eax
1201         movl (%ebp), %ecx
1202         subl $MCOUNT_INSN_SIZE, %edx
1203         call prepare_ftrace_return
1204         popl %edx
1205         popl %ecx
1206         popl %eax
1207         ret
1208 END(ftrace_graph_caller)
1209
1210 .globl return_to_handler
1211 return_to_handler:
1212         pushl %eax
1213         pushl %edx
1214         movl %ebp, %eax
1215         call ftrace_return_to_handler
1216         movl %eax, %ecx
1217         popl %edx
1218         popl %eax
1219         jmp *%ecx
1220 #endif
1221
1222 .section .rodata,"a"
1223 #include "syscall_table_32.S"
1224
1225 syscall_table_size=(.-sys_call_table)
1226
1227 /*
1228  * Some functions should be protected against kprobes
1229  */
1230         .pushsection .kprobes.text, "ax"
1231
1232 ENTRY(page_fault)
1233         RING0_EC_FRAME
1234         pushl_cfi $do_page_fault
1235         ALIGN
1236 error_code:
1237         /* the function address is in %gs's slot on the stack */
1238         pushl_cfi %fs
1239         /*CFI_REL_OFFSET fs, 0*/
1240         pushl_cfi %es
1241         /*CFI_REL_OFFSET es, 0*/
1242         pushl_cfi %ds
1243         /*CFI_REL_OFFSET ds, 0*/
1244         pushl_cfi %eax
1245         CFI_REL_OFFSET eax, 0
1246         pushl_cfi %ebp
1247         CFI_REL_OFFSET ebp, 0
1248         pushl_cfi %edi
1249         CFI_REL_OFFSET edi, 0
1250         pushl_cfi %esi
1251         CFI_REL_OFFSET esi, 0
1252         pushl_cfi %edx
1253         CFI_REL_OFFSET edx, 0
1254         pushl_cfi %ecx
1255         CFI_REL_OFFSET ecx, 0
1256         pushl_cfi %ebx
1257         CFI_REL_OFFSET ebx, 0
1258         cld
1259         movl $(__KERNEL_PERCPU), %ecx
1260         movl %ecx, %fs
1261         UNWIND_ESPFIX_STACK
1262         GS_TO_REG %ecx
1263         movl PT_GS(%esp), %edi          # get the function address
1264         movl PT_ORIG_EAX(%esp), %edx    # get the error code
1265         movl $-1, PT_ORIG_EAX(%esp)     # no syscall to restart
1266         REG_TO_PTGS %ecx
1267         SET_KERNEL_GS %ecx
1268         movl $(__USER_DS), %ecx
1269         movl %ecx, %ds
1270         movl %ecx, %es
1271         TRACE_IRQS_OFF
1272         movl %esp,%eax                  # pt_regs pointer
1273         call *%edi
1274         jmp ret_from_exception
1275         CFI_ENDPROC
1276 END(page_fault)
1277
1278 /*
1279  * Debug traps and NMI can happen at the one SYSENTER instruction
1280  * that sets up the real kernel stack. Check here, since we can't
1281  * allow the wrong stack to be used.
1282  *
1283  * "TSS_sysenter_sp0+12" is because the NMI/debug handler will have
1284  * already pushed 3 words if it hits on the sysenter instruction:
1285  * eflags, cs and eip.
1286  *
1287  * We just load the right stack, and push the three (known) values
1288  * by hand onto the new stack - while updating the return eip past
1289  * the instruction that would have done it for sysenter.
1290  */
1291 .macro FIX_STACK offset ok label
1292         cmpw $__KERNEL_CS, 4(%esp)
1293         jne \ok
1294 \label:
1295         movl TSS_sysenter_sp0 + \offset(%esp), %esp
1296         CFI_DEF_CFA esp, 0
1297         CFI_UNDEFINED eip
1298         pushfl_cfi
1299         pushl_cfi $__KERNEL_CS
1300         pushl_cfi $sysenter_past_esp
1301         CFI_REL_OFFSET eip, 0
1302 .endm
1303
1304 ENTRY(debug)
1305         RING0_INT_FRAME
1306         cmpl $ia32_sysenter_target,(%esp)
1307         jne debug_stack_correct
1308         FIX_STACK 12, debug_stack_correct, debug_esp_fix_insn
1309 debug_stack_correct:
1310         pushl_cfi $-1                   # mark this as an int
1311         SAVE_ALL
1312         TRACE_IRQS_OFF
1313         xorl %edx,%edx                  # error code 0
1314         movl %esp,%eax                  # pt_regs pointer
1315         call do_debug
1316         jmp ret_from_exception
1317         CFI_ENDPROC
1318 END(debug)
1319
1320 /*
1321  * NMI is doubly nasty. It can happen _while_ we're handling
1322  * a debug fault, and the debug fault hasn't yet been able to
1323  * clear up the stack. So we first check whether we got  an
1324  * NMI on the sysenter entry path, but after that we need to
1325  * check whether we got an NMI on the debug path where the debug
1326  * fault happened on the sysenter path.
1327  */
1328 ENTRY(nmi)
1329         RING0_INT_FRAME
1330         pushl_cfi %eax
1331         movl %ss, %eax
1332         cmpw $__ESPFIX_SS, %ax
1333         popl_cfi %eax
1334         je nmi_espfix_stack
1335         cmpl $ia32_sysenter_target,(%esp)
1336         je nmi_stack_fixup
1337         pushl_cfi %eax
1338         movl %esp,%eax
1339         /* Do not access memory above the end of our stack page,
1340          * it might not exist.
1341          */
1342         andl $(THREAD_SIZE-1),%eax
1343         cmpl $(THREAD_SIZE-20),%eax
1344         popl_cfi %eax
1345         jae nmi_stack_correct
1346         cmpl $ia32_sysenter_target,12(%esp)
1347         je nmi_debug_stack_check
1348 nmi_stack_correct:
1349         /* We have a RING0_INT_FRAME here */
1350         pushl_cfi %eax
1351         SAVE_ALL
1352         xorl %edx,%edx          # zero error code
1353         movl %esp,%eax          # pt_regs pointer
1354         call do_nmi
1355         jmp restore_all_notrace
1356         CFI_ENDPROC
1357
1358 nmi_stack_fixup:
1359         RING0_INT_FRAME
1360         FIX_STACK 12, nmi_stack_correct, 1
1361         jmp nmi_stack_correct
1362
1363 nmi_debug_stack_check:
1364         /* We have a RING0_INT_FRAME here */
1365         cmpw $__KERNEL_CS,16(%esp)
1366         jne nmi_stack_correct
1367         cmpl $debug,(%esp)
1368         jb nmi_stack_correct
1369         cmpl $debug_esp_fix_insn,(%esp)
1370         ja nmi_stack_correct
1371         FIX_STACK 24, nmi_stack_correct, 1
1372         jmp nmi_stack_correct
1373
1374 nmi_espfix_stack:
1375         /* We have a RING0_INT_FRAME here.
1376          *
1377          * create the pointer to lss back
1378          */
1379         pushl_cfi %ss
1380         pushl_cfi %esp
1381         addl $4, (%esp)
1382         /* copy the iret frame of 12 bytes */
1383         .rept 3
1384         pushl_cfi 16(%esp)
1385         .endr
1386         pushl_cfi %eax
1387         SAVE_ALL
1388         FIXUP_ESPFIX_STACK              # %eax == %esp
1389         xorl %edx,%edx                  # zero error code
1390         call do_nmi
1391         RESTORE_REGS
1392         lss 12+4(%esp), %esp            # back to espfix stack
1393         CFI_ADJUST_CFA_OFFSET -24
1394         jmp irq_return
1395         CFI_ENDPROC
1396 END(nmi)
1397
1398 ENTRY(int3)
1399         RING0_INT_FRAME
1400         pushl_cfi $-1                   # mark this as an int
1401         SAVE_ALL
1402         TRACE_IRQS_OFF
1403         xorl %edx,%edx          # zero error code
1404         movl %esp,%eax          # pt_regs pointer
1405         call do_int3
1406         jmp ret_from_exception
1407         CFI_ENDPROC
1408 END(int3)
1409
1410 ENTRY(general_protection)
1411         RING0_EC_FRAME
1412         pushl_cfi $do_general_protection
1413         jmp error_code
1414         CFI_ENDPROC
1415 END(general_protection)
1416
1417 #ifdef CONFIG_KVM_GUEST
1418 ENTRY(async_page_fault)
1419         RING0_EC_FRAME
1420         pushl_cfi $do_async_page_fault
1421         jmp error_code
1422         CFI_ENDPROC
1423 END(async_page_fault)
1424 #endif
1425
1426 /*
1427  * End of kprobes section
1428  */
1429         .popsection