arch/x86/ia32/ia32entry.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/irqflags.h>
  16 #include <linux/linkage.h>
  17
  18 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
  19
  20         .macro IA32_ARG_FIXUP noebp=0
  21         movl    %edi,%r8d
  22         .if \noebp
  23         .else
  24         movl    %ebp,%r9d
  25         .endif
  26         xchg    %ecx,%esi
  27         movl    %ebx,%edi
  28         movl    %edx,%edx       /* zero extension */
  29         .endm
  30
  31         /* clobbers %eax */
  32         .macro  CLEAR_RREGS
  33         xorl    %eax,%eax
  34         movq    %rax,R11(%rsp)
  35         movq    %rax,R10(%rsp)
  36         movq    %rax,R9(%rsp)
  37         movq    %rax,R8(%rsp)
  38         .endm
  39
  40         /*
  41          * Reload arg registers from stack in case ptrace changed them.
  42          * We don't reload %eax because syscall_trace_enter() returned
  43          * the value it wants us to use in the table lookup.
  44          */
  45         .macro LOAD_ARGS32 offset
  46         movl \offset(%rsp),%r11d
  47         movl \offset+8(%rsp),%r10d
  48         movl \offset+16(%rsp),%r9d
  49         movl \offset+24(%rsp),%r8d
  50         movl \offset+40(%rsp),%ecx
  51         movl \offset+48(%rsp),%edx
  52         movl \offset+56(%rsp),%esi
  53         movl \offset+64(%rsp),%edi
  54         .endm
  55
  56         .macro CFI_STARTPROC32 simple
  57         CFI_STARTPROC   \simple
  58         CFI_UNDEFINED   r8
  59         CFI_UNDEFINED   r9
  60         CFI_UNDEFINED   r10
  61         CFI_UNDEFINED   r11
  62         CFI_UNDEFINED   r12
  63         CFI_UNDEFINED   r13
  64         CFI_UNDEFINED   r14
  65         CFI_UNDEFINED   r15
  66         .endm
  67
  68 #ifdef CONFIG_PARAVIRT
  69 ENTRY(native_usergs_sysret32)
  70         swapgs
  71         sysretl
  72 ENDPROC(native_usergs_sysret32)
  73
  74 ENTRY(native_irq_enable_sysexit)
  75         swapgs
  76         sti
  77         sysexit
  78 ENDPROC(native_irq_enable_sysexit)
  79 #endif
  80
  81 /*
  82  * 32bit SYSENTER instruction entry.
  83  *
  84  * Arguments:
  85  * %eax System call number.
  86  * %ebx Arg1
  87  * %ecx Arg2
  88  * %edx Arg3
  89  * %esi Arg4
  90  * %edi Arg5
  91  * %ebp user stack
  92  * 0(%ebp) Arg6
  93  *
  94  * Interrupts off.
  95  *
  96  * This is purely a fast path. For anything complicated we use the int 0x80
  97  * path below.  Set up a complete hardware stack frame to share code
  98  * with the int 0x80 path.
  99  */
 100 ENTRY(ia32_sysenter_target)
 101         CFI_STARTPROC32 simple
 102         CFI_SIGNAL_FRAME
 103         CFI_DEF_CFA     rsp,0
 104         CFI_REGISTER    rsp,rbp
 105         SWAPGS_UNSAFE_STACK
 106         movq    %gs:pda_kernelstack, %rsp
 107         addq    $(PDA_STACKOFFSET),%rsp
 108         /*
 109          * No need to follow this irqs on/off section: the syscall
 110          * disabled irqs, here we enable it straight after entry:
 111          */
 112         ENABLE_INTERRUPTS(CLBR_NONE)
 113         movl    %ebp,%ebp               /* zero extension */
 114         pushq   $__USER32_DS
 115         CFI_ADJUST_CFA_OFFSET 8
 116         /*CFI_REL_OFFSET ss,0*/
 117         pushq   %rbp
 118         CFI_ADJUST_CFA_OFFSET 8
 119         CFI_REL_OFFSET rsp,0
 120         pushfq
 121         CFI_ADJUST_CFA_OFFSET 8
 122         /*CFI_REL_OFFSET rflags,0*/
 123         movl    8*3-THREAD_SIZE+TI_sysenter_return(%rsp), %r10d
 124         CFI_REGISTER rip,r10
 125         pushq   $__USER32_CS
 126         CFI_ADJUST_CFA_OFFSET 8
 127         /*CFI_REL_OFFSET cs,0*/
 128         movl    %eax, %eax
 129         pushq   %r10
 130         CFI_ADJUST_CFA_OFFSET 8
 131         CFI_REL_OFFSET rip,0
 132         pushq   %rax
 133         CFI_ADJUST_CFA_OFFSET 8
 134         cld
 135         SAVE_ARGS 0,0,1
 136         /* no need to do an access_ok check here because rbp has been
 137            32bit zero extended */
 138 1:      movl    (%rbp),%r9d
 139         .section __ex_table,"a"
 140         .quad 1b,ia32_badarg
 141         .previous
 142         GET_THREAD_INFO(%r10)
 143         orl    $TS_COMPAT,TI_status(%r10)
 144         testl  $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%r10)
 145         CFI_REMEMBER_STATE
 146         jnz  sysenter_tracesys
 147         cmpl    $(IA32_NR_syscalls-1),%eax
 148         ja      ia32_badsys
 149 sysenter_do_call:
 150         IA32_ARG_FIXUP 1
 151         call    *ia32_sys_call_table(,%rax,8)
 152         movq    %rax,RAX-ARGOFFSET(%rsp)
 153         GET_THREAD_INFO(%r10)
 154         DISABLE_INTERRUPTS(CLBR_NONE)
 155         TRACE_IRQS_OFF
 156         testl   $_TIF_ALLWORK_MASK,TI_flags(%r10)
 157         jnz     int_ret_from_sys_call
 158         andl    $~TS_COMPAT,TI_status(%r10)
 159         /* clear IF, that popfq doesn't enable interrupts early */
 160         andl  $~0x200,EFLAGS-R11(%rsp)
 161         movl    RIP-R11(%rsp),%edx              /* User %eip */
 162         CFI_REGISTER rip,rdx
 163         RESTORE_ARGS 1,24,1,1,1,1
 164         popfq
 165         CFI_ADJUST_CFA_OFFSET -8
 166         /*CFI_RESTORE rflags*/
 167         popq    %rcx                            /* User %esp */
 168         CFI_ADJUST_CFA_OFFSET -8
 169         CFI_REGISTER rsp,rcx
 170         TRACE_IRQS_ON
 171         ENABLE_INTERRUPTS_SYSEXIT32
 172
 173 sysenter_tracesys:
 174         CFI_RESTORE_STATE
 175         xchgl   %r9d,%ebp
 176         SAVE_REST
 177         CLEAR_RREGS
 178         movq    %r9,R9(%rsp)
 179         movq    $-ENOSYS,RAX(%rsp)/* ptrace can change this for a bad syscall */
 180         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 181         call    syscall_trace_enter
 182         LOAD_ARGS32 ARGOFFSET  /* reload args from stack in case ptrace changed it */
 183         RESTORE_REST
 184         xchgl   %ebp,%r9d
 185         cmpl    $(IA32_NR_syscalls-1),%eax
 186         ja      int_ret_from_sys_call /* sysenter_tracesys has set RAX(%rsp) */
 187         jmp     sysenter_do_call
 188         CFI_ENDPROC
 189 ENDPROC(ia32_sysenter_target)
 190
 191 /*
 192  * 32bit SYSCALL instruction entry.
 193  *
 194  * Arguments:
 195  * %eax System call number.
 196  * %ebx Arg1
 197  * %ecx return EIP
 198  * %edx Arg3
 199  * %esi Arg4
 200  * %edi Arg5
 201  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 202  * %esp user stack
 203  * 0(%esp) Arg6
 204  *
 205  * Interrupts off.
 206  *
 207  * This is purely a fast path. For anything complicated we use the int 0x80
 208  * path below.  Set up a complete hardware stack frame to share code
 209  * with the int 0x80 path.
 210  */
 211 ENTRY(ia32_cstar_target)
 212         CFI_STARTPROC32 simple
 213         CFI_SIGNAL_FRAME
 214         CFI_DEF_CFA     rsp,PDA_STACKOFFSET
 215         CFI_REGISTER    rip,rcx
 216         /*CFI_REGISTER  rflags,r11*/
 217         SWAPGS_UNSAFE_STACK
 218         movl    %esp,%r8d
 219         CFI_REGISTER    rsp,r8
 220         movq    %gs:pda_kernelstack,%rsp
 221         /*
 222          * No need to follow this irqs on/off section: the syscall
 223          * disabled irqs and here we enable it straight after entry:
 224          */
 225         ENABLE_INTERRUPTS(CLBR_NONE)
 226         SAVE_ARGS 8,1,1
 227         movl    %eax,%eax       /* zero extension */
 228         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 229         movq    %rcx,RIP-ARGOFFSET(%rsp)
 230         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 231         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 232         movl    %ebp,%ecx
 233         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 234         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 235         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 236         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 237         movq    %r8,RSP-ARGOFFSET(%rsp)
 238         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 239         /* no need to do an access_ok check here because r8 has been
 240            32bit zero extended */
 241         /* hardware stack frame is complete now */
 242 1:      movl    (%r8),%r9d
 243         .section __ex_table,"a"
 244         .quad 1b,ia32_badarg
 245         .previous
 246         GET_THREAD_INFO(%r10)
 247         orl   $TS_COMPAT,TI_status(%r10)
 248         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%r10)
 249         CFI_REMEMBER_STATE
 250         jnz   cstar_tracesys
 251 cstar_do_call:
 252         cmpl $IA32_NR_syscalls-1,%eax
 253         ja  ia32_badsys
 254         IA32_ARG_FIXUP 1
 255         call *ia32_sys_call_table(,%rax,8)
 256         movq %rax,RAX-ARGOFFSET(%rsp)
 257         GET_THREAD_INFO(%r10)
 258         DISABLE_INTERRUPTS(CLBR_NONE)
 259         TRACE_IRQS_OFF
 260         testl $_TIF_ALLWORK_MASK,TI_flags(%r10)
 261         jnz  int_ret_from_sys_call
 262         andl $~TS_COMPAT,TI_status(%r10)
 263         RESTORE_ARGS 1,-ARG_SKIP,1,1,1
 264         movl RIP-ARGOFFSET(%rsp),%ecx
 265         CFI_REGISTER rip,rcx
 266         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 267         /*CFI_REGISTER rflags,r11*/
 268         TRACE_IRQS_ON
 269         movl RSP-ARGOFFSET(%rsp),%esp
 270         CFI_RESTORE rsp
 271         USERGS_SYSRET32
 272
 273 cstar_tracesys:
 274         CFI_RESTORE_STATE
 275         xchgl %r9d,%ebp
 276         SAVE_REST
 277         CLEAR_RREGS
 278         movq %r9,R9(%rsp)
 279         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 280         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 281         call syscall_trace_enter
 282         LOAD_ARGS32 ARGOFFSET  /* reload args from stack in case ptrace changed it */
 283         RESTORE_REST
 284         xchgl %ebp,%r9d
 285         movl RSP-ARGOFFSET(%rsp), %r8d
 286         cmpl $(IA32_NR_syscalls-1),%eax
 287         ja int_ret_from_sys_call /* cstar_tracesys has set RAX(%rsp) */
 288         jmp cstar_do_call
 289 END(ia32_cstar_target)
 290
 291 ia32_badarg:
 292         movq $-EFAULT,%rax
 293         jmp ia32_sysret
 294         CFI_ENDPROC
 295
 296 /*
 297  * Emulated IA32 system calls via int 0x80.
 298  *
 299  * Arguments:
 300  * %eax System call number.
 301  * %ebx Arg1
 302  * %ecx Arg2
 303  * %edx Arg3
 304  * %esi Arg4
 305  * %edi Arg5
 306  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 307  *
 308  * Notes:
 309  * Uses the same stack frame as the x86-64 version.
 310  * All registers except %eax must be saved (but ptrace may violate that)
 311  * Arguments are zero extended. For system calls that want sign extension and
 312  * take long arguments a wrapper is needed. Most calls can just be called
 313  * directly.
 314  * Assumes it is only called from user space and entered with interrupts off.
 315  */
 316
 317 ENTRY(ia32_syscall)
 318         CFI_STARTPROC32 simple
 319         CFI_SIGNAL_FRAME
 320         CFI_DEF_CFA     rsp,SS+8-RIP
 321         /*CFI_REL_OFFSET        ss,SS-RIP*/
 322         CFI_REL_OFFSET  rsp,RSP-RIP
 323         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 324         /*CFI_REL_OFFSET        cs,CS-RIP*/
 325         CFI_REL_OFFSET  rip,RIP-RIP
 326         PARAVIRT_ADJUST_EXCEPTION_FRAME
 327         SWAPGS
 328         /*
 329          * No need to follow this irqs on/off section: the syscall
 330          * disabled irqs and here we enable it straight after entry:
 331          */
 332         ENABLE_INTERRUPTS(CLBR_NONE)
 333         movl %eax,%eax
 334         pushq %rax
 335         CFI_ADJUST_CFA_OFFSET 8
 336         cld
 337         /* note the registers are not zero extended to the sf.
 338            this could be a problem. */
 339         SAVE_ARGS 0,0,1
 340         GET_THREAD_INFO(%r10)
 341         orl   $TS_COMPAT,TI_status(%r10)
 342         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%r10)
 343         jnz ia32_tracesys
 344 ia32_do_syscall:
 345         cmpl $(IA32_NR_syscalls-1),%eax
 346         ja  int_ret_from_sys_call       /* ia32_tracesys has set RAX(%rsp) */
 347         IA32_ARG_FIXUP
 348         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 349 ia32_sysret:
 350         movq %rax,RAX-ARGOFFSET(%rsp)
 351         jmp int_ret_from_sys_call
 352
 353 ia32_tracesys:
 354         SAVE_REST
 355         CLEAR_RREGS
 356         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 357         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 358         call syscall_trace_enter
 359         LOAD_ARGS32 ARGOFFSET  /* reload args from stack in case ptrace changed it */
 360         RESTORE_REST
 361         jmp ia32_do_syscall
 362 END(ia32_syscall)
 363
 364 ia32_badsys:
 365         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 366         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 367         jmp int_ret_from_sys_call
 368
 369 quiet_ni_syscall:
 370         movq $-ENOSYS,%rax
 371         ret
 372         CFI_ENDPROC
 373
 374         .macro PTREGSCALL label, func, arg
 375         .globl \label
 376 \label:
 377         leaq \func(%rip),%rax
 378         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 379         jmp  ia32_ptregs_common
 380         .endm
 381
 382         CFI_STARTPROC32
 383
 384         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 385         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 386         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 387         PTREGSCALL stub32_execve, sys32_execve, %rcx
 388         PTREGSCALL stub32_fork, sys_fork, %rdi
 389         PTREGSCALL stub32_clone, sys32_clone, %rdx
 390         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 391         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 392
 393 ENTRY(ia32_ptregs_common)
 394         popq %r11
 395         CFI_ENDPROC
 396         CFI_STARTPROC32 simple
 397         CFI_SIGNAL_FRAME
 398         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 399         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 400         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 401         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 402         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 403         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 404         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 405 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 406 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 407         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 408 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 409         SAVE_REST
 410         call *%rax
 411         RESTORE_REST
 412         jmp  ia32_sysret        /* misbalances the return cache */
 413         CFI_ENDPROC
 414 END(ia32_ptregs_common)
 415
 416         .section .rodata,"a"
 417         .align 8
 418 ia32_sys_call_table:
 419         .quad sys_restart_syscall
 420         .quad sys_exit
 421         .quad stub32_fork
 422         .quad sys_read
 423         .quad sys_write
 424         .quad compat_sys_open           /* 5 */
 425         .quad sys_close
 426         .quad sys32_waitpid
 427         .quad sys_creat
 428         .quad sys_link
 429         .quad sys_unlink                /* 10 */
 430         .quad stub32_execve
 431         .quad sys_chdir
 432         .quad compat_sys_time
 433         .quad sys_mknod
 434         .quad sys_chmod         /* 15 */
 435         .quad sys_lchown16
 436         .quad quiet_ni_syscall                  /* old break syscall holder */
 437         .quad sys_stat
 438         .quad sys32_lseek
 439         .quad sys_getpid                /* 20 */
 440         .quad compat_sys_mount  /* mount  */
 441         .quad sys_oldumount     /* old_umount  */
 442         .quad sys_setuid16
 443         .quad sys_getuid16
 444         .quad compat_sys_stime  /* stime */             /* 25 */
 445         .quad compat_sys_ptrace /* ptrace */
 446         .quad sys_alarm
 447         .quad sys_fstat /* (old)fstat */
 448         .quad sys_pause
 449         .quad compat_sys_utime  /* 30 */
 450         .quad quiet_ni_syscall  /* old stty syscall holder */
 451         .quad quiet_ni_syscall  /* old gtty syscall holder */
 452         .quad sys_access
 453         .quad sys_nice
 454         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 455         .quad sys_sync
 456         .quad sys32_kill
 457         .quad sys_rename
 458         .quad sys_mkdir
 459         .quad sys_rmdir         /* 40 */
 460         .quad sys_dup
 461         .quad sys32_pipe
 462         .quad compat_sys_times
 463         .quad quiet_ni_syscall                  /* old prof syscall holder */
 464         .quad sys_brk           /* 45 */
 465         .quad sys_setgid16
 466         .quad sys_getgid16
 467         .quad sys_signal
 468         .quad sys_geteuid16
 469         .quad sys_getegid16     /* 50 */
 470         .quad sys_acct
 471         .quad sys_umount                        /* new_umount */
 472         .quad quiet_ni_syscall                  /* old lock syscall holder */
 473         .quad compat_sys_ioctl
 474         .quad compat_sys_fcntl64                /* 55 */
 475         .quad quiet_ni_syscall                  /* old mpx syscall holder */
 476         .quad sys_setpgid
 477         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 478         .quad sys32_olduname
 479         .quad sys_umask         /* 60 */
 480         .quad sys_chroot
 481         .quad sys32_ustat
 482         .quad sys_dup2
 483         .quad sys_getppid
 484         .quad sys_getpgrp               /* 65 */
 485         .quad sys_setsid
 486         .quad sys32_sigaction
 487         .quad sys_sgetmask
 488         .quad sys_ssetmask
 489         .quad sys_setreuid16    /* 70 */
 490         .quad sys_setregid16
 491         .quad sys32_sigsuspend
 492         .quad compat_sys_sigpending
 493         .quad sys_sethostname
 494         .quad compat_sys_setrlimit      /* 75 */
 495         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 496         .quad compat_sys_getrusage
 497         .quad sys32_gettimeofday
 498         .quad sys32_settimeofday
 499         .quad sys_getgroups16   /* 80 */
 500         .quad sys_setgroups16
 501         .quad sys32_old_select
 502         .quad sys_symlink
 503         .quad sys_lstat
 504         .quad sys_readlink              /* 85 */
 505         .quad sys_uselib
 506         .quad sys_swapon
 507         .quad sys_reboot
 508         .quad compat_sys_old_readdir
 509         .quad sys32_mmap                /* 90 */
 510         .quad sys_munmap
 511         .quad sys_truncate
 512         .quad sys_ftruncate
 513         .quad sys_fchmod
 514         .quad sys_fchown16              /* 95 */
 515         .quad sys_getpriority
 516         .quad sys_setpriority
 517         .quad quiet_ni_syscall                  /* old profil syscall holder */
 518         .quad compat_sys_statfs
 519         .quad compat_sys_fstatfs                /* 100 */
 520         .quad sys_ioperm
 521         .quad compat_sys_socketcall
 522         .quad sys_syslog
 523         .quad compat_sys_setitimer
 524         .quad compat_sys_getitimer      /* 105 */
 525         .quad compat_sys_newstat
 526         .quad compat_sys_newlstat
 527         .quad compat_sys_newfstat
 528         .quad sys32_uname
 529         .quad stub32_iopl               /* 110 */
 530         .quad sys_vhangup
 531         .quad quiet_ni_syscall  /* old "idle" system call */
 532         .quad sys32_vm86_warning        /* vm86old */
 533         .quad compat_sys_wait4
 534         .quad sys_swapoff               /* 115 */
 535         .quad compat_sys_sysinfo
 536         .quad sys32_ipc
 537         .quad sys_fsync
 538         .quad stub32_sigreturn
 539         .quad stub32_clone              /* 120 */
 540         .quad sys_setdomainname
 541         .quad sys_uname
 542         .quad sys_modify_ldt
 543         .quad compat_sys_adjtimex
 544         .quad sys32_mprotect            /* 125 */
 545         .quad compat_sys_sigprocmask
 546         .quad quiet_ni_syscall          /* create_module */
 547         .quad sys_init_module
 548         .quad sys_delete_module
 549         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 550         .quad sys32_quotactl
 551         .quad sys_getpgid
 552         .quad sys_fchdir
 553         .quad quiet_ni_syscall  /* bdflush */
 554         .quad sys_sysfs         /* 135 */
 555         .quad sys_personality
 556         .quad quiet_ni_syscall  /* for afs_syscall */
 557         .quad sys_setfsuid16
 558         .quad sys_setfsgid16
 559         .quad sys_llseek                /* 140 */
 560         .quad compat_sys_getdents
 561         .quad compat_sys_select
 562         .quad sys_flock
 563         .quad sys_msync
 564         .quad compat_sys_readv          /* 145 */
 565         .quad compat_sys_writev
 566         .quad sys_getsid
 567         .quad sys_fdatasync
 568         .quad sys32_sysctl      /* sysctl */
 569         .quad sys_mlock         /* 150 */
 570         .quad sys_munlock
 571         .quad sys_mlockall
 572         .quad sys_munlockall
 573         .quad sys_sched_setparam
 574         .quad sys_sched_getparam   /* 155 */
 575         .quad sys_sched_setscheduler
 576         .quad sys_sched_getscheduler
 577         .quad sys_sched_yield
 578         .quad sys_sched_get_priority_max
 579         .quad sys_sched_get_priority_min  /* 160 */
 580         .quad sys32_sched_rr_get_interval
 581         .quad compat_sys_nanosleep
 582         .quad sys_mremap
 583         .quad sys_setresuid16
 584         .quad sys_getresuid16   /* 165 */
 585         .quad sys32_vm86_warning        /* vm86 */
 586         .quad quiet_ni_syscall  /* query_module */
 587         .quad sys_poll
 588         .quad compat_sys_nfsservctl
 589         .quad sys_setresgid16   /* 170 */
 590         .quad sys_getresgid16
 591         .quad sys_prctl
 592         .quad stub32_rt_sigreturn
 593         .quad sys32_rt_sigaction
 594         .quad sys32_rt_sigprocmask      /* 175 */
 595         .quad sys32_rt_sigpending
 596         .quad compat_sys_rt_sigtimedwait
 597         .quad sys32_rt_sigqueueinfo
 598         .quad sys_rt_sigsuspend
 599         .quad sys32_pread               /* 180 */
 600         .quad sys32_pwrite
 601         .quad sys_chown16
 602         .quad sys_getcwd
 603         .quad sys_capget
 604         .quad sys_capset
 605         .quad stub32_sigaltstack
 606         .quad sys32_sendfile
 607         .quad quiet_ni_syscall          /* streams1 */
 608         .quad quiet_ni_syscall          /* streams2 */
 609         .quad stub32_vfork            /* 190 */
 610         .quad compat_sys_getrlimit
 611         .quad sys32_mmap2
 612         .quad sys32_truncate64
 613         .quad sys32_ftruncate64
 614         .quad sys32_stat64              /* 195 */
 615         .quad sys32_lstat64
 616         .quad sys32_fstat64
 617         .quad sys_lchown
 618         .quad sys_getuid
 619         .quad sys_getgid                /* 200 */
 620         .quad sys_geteuid
 621         .quad sys_getegid
 622         .quad sys_setreuid
 623         .quad sys_setregid
 624         .quad sys_getgroups     /* 205 */
 625         .quad sys_setgroups
 626         .quad sys_fchown
 627         .quad sys_setresuid
 628         .quad sys_getresuid
 629         .quad sys_setresgid     /* 210 */
 630         .quad sys_getresgid
 631         .quad sys_chown
 632         .quad sys_setuid
 633         .quad sys_setgid
 634         .quad sys_setfsuid              /* 215 */
 635         .quad sys_setfsgid
 636         .quad sys_pivot_root
 637         .quad sys_mincore
 638         .quad sys_madvise
 639         .quad compat_sys_getdents64     /* 220 getdents64 */
 640         .quad compat_sys_fcntl64
 641         .quad quiet_ni_syscall          /* tux */
 642         .quad quiet_ni_syscall          /* security */
 643         .quad sys_gettid
 644         .quad sys32_readahead   /* 225 */
 645         .quad sys_setxattr
 646         .quad sys_lsetxattr
 647         .quad sys_fsetxattr
 648         .quad sys_getxattr
 649         .quad sys_lgetxattr     /* 230 */
 650         .quad sys_fgetxattr
 651         .quad sys_listxattr
 652         .quad sys_llistxattr
 653         .quad sys_flistxattr
 654         .quad sys_removexattr   /* 235 */
 655         .quad sys_lremovexattr
 656         .quad sys_fremovexattr
 657         .quad sys_tkill
 658         .quad sys_sendfile64
 659         .quad compat_sys_futex          /* 240 */
 660         .quad compat_sys_sched_setaffinity
 661         .quad compat_sys_sched_getaffinity
 662         .quad sys_set_thread_area
 663         .quad sys_get_thread_area
 664         .quad compat_sys_io_setup       /* 245 */
 665         .quad sys_io_destroy
 666         .quad compat_sys_io_getevents
 667         .quad compat_sys_io_submit
 668         .quad sys_io_cancel
 669         .quad sys32_fadvise64           /* 250 */
 670         .quad quiet_ni_syscall  /* free_huge_pages */
 671         .quad sys_exit_group
 672         .quad sys32_lookup_dcookie
 673         .quad sys_epoll_create
 674         .quad sys_epoll_ctl             /* 255 */
 675         .quad sys_epoll_wait
 676         .quad sys_remap_file_pages
 677         .quad sys_set_tid_address
 678         .quad compat_sys_timer_create
 679         .quad compat_sys_timer_settime  /* 260 */
 680         .quad compat_sys_timer_gettime
 681         .quad sys_timer_getoverrun
 682         .quad sys_timer_delete
 683         .quad compat_sys_clock_settime
 684         .quad compat_sys_clock_gettime  /* 265 */
 685         .quad compat_sys_clock_getres
 686         .quad compat_sys_clock_nanosleep
 687         .quad compat_sys_statfs64
 688         .quad compat_sys_fstatfs64
 689         .quad sys_tgkill                /* 270 */
 690         .quad compat_sys_utimes
 691         .quad sys32_fadvise64_64
 692         .quad quiet_ni_syscall  /* sys_vserver */
 693         .quad sys_mbind
 694         .quad compat_sys_get_mempolicy  /* 275 */
 695         .quad sys_set_mempolicy
 696         .quad compat_sys_mq_open
 697         .quad sys_mq_unlink
 698         .quad compat_sys_mq_timedsend
 699         .quad compat_sys_mq_timedreceive        /* 280 */
 700         .quad compat_sys_mq_notify
 701         .quad compat_sys_mq_getsetattr
 702         .quad compat_sys_kexec_load     /* reserved for kexec */
 703         .quad compat_sys_waitid
 704         .quad quiet_ni_syscall          /* 285: sys_altroot */
 705         .quad sys_add_key
 706         .quad sys_request_key
 707         .quad sys_keyctl
 708         .quad sys_ioprio_set
 709         .quad sys_ioprio_get            /* 290 */
 710         .quad sys_inotify_init
 711         .quad sys_inotify_add_watch
 712         .quad sys_inotify_rm_watch
 713         .quad sys_migrate_pages
 714         .quad compat_sys_openat         /* 295 */
 715         .quad sys_mkdirat
 716         .quad sys_mknodat
 717         .quad sys_fchownat
 718         .quad compat_sys_futimesat
 719         .quad sys32_fstatat             /* 300 */
 720         .quad sys_unlinkat
 721         .quad sys_renameat
 722         .quad sys_linkat
 723         .quad sys_symlinkat
 724         .quad sys_readlinkat            /* 305 */
 725         .quad sys_fchmodat
 726         .quad sys_faccessat
 727         .quad compat_sys_pselect6
 728         .quad compat_sys_ppoll
 729         .quad sys_unshare               /* 310 */
 730         .quad compat_sys_set_robust_list
 731         .quad compat_sys_get_robust_list
 732         .quad sys_splice
 733         .quad sys32_sync_file_range
 734         .quad sys_tee                   /* 315 */
 735         .quad compat_sys_vmsplice
 736         .quad compat_sys_move_pages
 737         .quad sys_getcpu
 738         .quad sys_epoll_pwait
 739         .quad compat_sys_utimensat      /* 320 */
 740         .quad compat_sys_signalfd
 741         .quad sys_timerfd_create
 742         .quad sys_eventfd
 743         .quad sys32_fallocate
 744         .quad compat_sys_timerfd_settime        /* 325 */
 745         .quad compat_sys_timerfd_gettime
 746 ia32_syscall_end: