arch/s390/kernel/vmlinux.lds.S

   1 /* ld script to make s390 Linux kernel
   2  * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
   3  */
   4
   5 #include <asm-generic/vmlinux.lds.h>
   6
   7 #ifndef CONFIG_64BIT
   8 OUTPUT_FORMAT("elf32-s390", "elf32-s390", "elf32-s390")
   9 OUTPUT_ARCH(s390)
  10 ENTRY(_start)
  11 jiffies = jiffies_64 + 4;
  12 #else
  13 OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
  14 OUTPUT_ARCH(s390:64-bit)
  15 ENTRY(_start)
  16 jiffies = jiffies_64;
  17 #endif
  18
  19 SECTIONS
  20 {
  21   . = 0x00000000;
  22   _text = .;                    /* Text and read-only data */
  23   .text : {
  24         *(.text)
  25         SCHED_TEXT
  26         LOCK_TEXT
  27         *(.fixup)
  28         *(.gnu.warning)
  29         } = 0x0700
  30
  31   _etext = .;                   /* End of text section */
  32
  33   . = ALIGN(16);                /* Exception table */
  34   __start___ex_table = .;
  35   __ex_table : { *(__ex_table) }
  36   __stop___ex_table = .;
  37
  38   RODATA
  39
  40 #ifdef CONFIG_SHARED_KERNEL
  41   . = ALIGN(1048576);           /* VM shared segments are 1MB aligned */
  42
  43   _eshared = .;                 /* End of shareable data */
  44 #endif
  45
  46   .data : {                     /* Data */
  47         *(.data)
  48         CONSTRUCTORS
  49         }
  50
  51   . = ALIGN(4096);
  52   __nosave_begin = .;
  53   .data_nosave : { *(.data.nosave) }
  54   . = ALIGN(4096);
  55   __nosave_end = .;
  56
  57   . = ALIGN(4096);
  58   .data.page_aligned : { *(.data.idt) }
  59
  60   . = ALIGN(256);
  61   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  62
  63   . = ALIGN(256);
  64   .data.read_mostly : { *(.data.read_mostly) }
  65   _edata = .;                   /* End of data section */
  66
  67   . = ALIGN(8192);              /* init_task */
  68   .data.init_task : { *(.data.init_task) }
  69
  70   /* will be freed after init */
  71   . = ALIGN(4096);              /* Init code and data */
  72   __init_begin = .;
  73   .init.text : {
  74         _sinittext = .;
  75         *(.init.text)
  76         _einittext = .;
  77   }
  78   .init.data : { *(.init.data) }
  79   . = ALIGN(256);
  80   __setup_start = .;
  81   .init.setup : { *(.init.setup) }
  82   __setup_end = .;
  83   __initcall_start = .;
  84   .initcall.init : {
  85         *(.initcall1.init)
  86         *(.initcall2.init)
  87         *(.initcall3.init)
  88         *(.initcall4.init)
  89         *(.initcall5.init)
  90         *(.initcall6.init)
  91         *(.initcall7.init)
  92   }
  93   __initcall_end = .;
  94   __con_initcall_start = .;
  95   .con_initcall.init : { *(.con_initcall.init) }
  96   __con_initcall_end = .;
  97   SECURITY_INIT
  98   . = ALIGN(256);
  99   __initramfs_start = .;
 100   .init.ramfs : { *(.init.initramfs) }
 101   . = ALIGN(2);
 102   __initramfs_end = .;
 103   . = ALIGN(256);
 104   __per_cpu_start = .;
 105   .data.percpu  : { *(.data.percpu) }
 106   __per_cpu_end = .;
 107   . = ALIGN(4096);
 108   __init_end = .;
 109   /* freed after init ends here */
 110
 111   __bss_start = .;              /* BSS */
 112   .bss : { *(.bss) }
 113   . = ALIGN(2);
 114   __bss_stop = .;
 115
 116   _end = . ;
 117
 118   /* Sections to be discarded */
 119   /DISCARD/ : {
 120         *(.exitcall.exit)
 121         }
 122
 123   /* Stabs debugging sections.  */
 124   .stab 0 : { *(.stab) }
 125   .stabstr 0 : { *(.stabstr) }
 126   .stab.excl 0 : { *(.stab.excl) }
 127   .stab.exclstr 0 : { *(.stab.exclstr) }
 128   .stab.index 0 : { *(.stab.index) }
 129   .stab.indexstr 0 : { *(.stab.indexstr) }
 130   .comment 0 : { *(.comment) }
 131 }