arch/powerpc/kernel/misc_32.S

   1 /*
   2  * This file contains miscellaneous low-level functions.
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *
   5  * Largely rewritten by Cort Dougan (cort@cs.nmt.edu)
   6  * and Paul Mackerras.
   7  *
   8  * kexec bits:
   9  * Copyright (C) 2002-2003 Eric Biederman  <ebiederm@xmission.com>
  10  * GameCube/ppc32 port Copyright (C) 2004 Albert Herranz
  11  *
  12  * This program is free software; you can redistribute it and/or
  13  * modify it under the terms of the GNU General Public License
  14  * as published by the Free Software Foundation; either version
  15  * 2 of the License, or (at your option) any later version.
  16  *
  17  */
  18
  19 #include <linux/sys.h>
  20 #include <asm/unistd.h>
  21 #include <asm/errno.h>
  22 #include <asm/reg.h>
  23 #include <asm/page.h>
  24 #include <asm/cache.h>
  25 #include <asm/cputable.h>
  26 #include <asm/mmu.h>
  27 #include <asm/ppc_asm.h>
  28 #include <asm/thread_info.h>
  29 #include <asm/asm-offsets.h>
  30 #include <asm/processor.h>
  31 #include <asm/kexec.h>
  32 #include <asm/bug.h>
  33
  34         .text
  35
  36 #ifdef CONFIG_IRQSTACKS
  37 _GLOBAL(call_do_softirq)
  38         mflr    r0
  39         stw     r0,4(r1)
  40         stwu    r1,THREAD_SIZE-STACK_FRAME_OVERHEAD(r3)
  41         mr      r1,r3
  42         bl      __do_softirq
  43         lwz     r1,0(r1)
  44         lwz     r0,4(r1)
  45         mtlr    r0
  46         blr
  47
  48 _GLOBAL(call_handle_irq)
  49         mflr    r0
  50         stw     r0,4(r1)
  51         mtctr   r6
  52         stwu    r1,THREAD_SIZE-STACK_FRAME_OVERHEAD(r5)
  53         mr      r1,r5
  54         bctrl
  55         lwz     r1,0(r1)
  56         lwz     r0,4(r1)
  57         mtlr    r0
  58         blr
  59 #endif /* CONFIG_IRQSTACKS */
  60
  61 /*
  62  * This returns the high 64 bits of the product of two 64-bit numbers.
  63  */
  64 _GLOBAL(mulhdu)
  65         cmpwi   r6,0
  66         cmpwi   cr1,r3,0
  67         mr      r10,r4
  68         mulhwu  r4,r4,r5
  69         beq     1f
  70         mulhwu  r0,r10,r6
  71         mullw   r7,r10,r5
  72         addc    r7,r0,r7
  73         addze   r4,r4
  74 1:      beqlr   cr1             /* all done if high part of A is 0 */
  75         mr      r10,r3
  76         mullw   r9,r3,r5
  77         mulhwu  r3,r3,r5
  78         beq     2f
  79         mullw   r0,r10,r6
  80         mulhwu  r8,r10,r6
  81         addc    r7,r0,r7
  82         adde    r4,r4,r8
  83         addze   r3,r3
  84 2:      addc    r4,r4,r9
  85         addze   r3,r3
  86         blr
  87
  88 /*
  89  * sub_reloc_offset(x) returns x - reloc_offset().
  90  */
  91 _GLOBAL(sub_reloc_offset)
  92         mflr    r0
  93         bl      1f
  94 1:      mflr    r5
  95         lis     r4,1b@ha
  96         addi    r4,r4,1b@l
  97         subf    r5,r4,r5
  98         subf    r3,r5,r3
  99         mtlr    r0
 100         blr
 101
 102 /*
 103  * reloc_got2 runs through the .got2 section adding an offset
 104  * to each entry.
 105  */
 106 _GLOBAL(reloc_got2)
 107         mflr    r11
 108         lis     r7,__got2_start@ha
 109         addi    r7,r7,__got2_start@l
 110         lis     r8,__got2_end@ha
 111         addi    r8,r8,__got2_end@l
 112         subf    r8,r7,r8
 113         srwi.   r8,r8,2
 114         beqlr
 115         mtctr   r8
 116         bl      1f
 117 1:      mflr    r0
 118         lis     r4,1b@ha
 119         addi    r4,r4,1b@l
 120         subf    r0,r4,r0
 121         add     r7,r0,r7
 122 2:      lwz     r0,0(r7)
 123         add     r0,r0,r3
 124         stw     r0,0(r7)
 125         addi    r7,r7,4
 126         bdnz    2b
 127         mtlr    r11
 128         blr
 129
 130 /*
 131  * call_setup_cpu - call the setup_cpu function for this cpu
 132  * r3 = data offset, r24 = cpu number
 133  *
 134  * Setup function is called with:
 135  *   r3 = data offset
 136  *   r4 = ptr to CPU spec (relocated)
 137  */
 138 _GLOBAL(call_setup_cpu)
 139         addis   r4,r3,cur_cpu_spec@ha
 140         addi    r4,r4,cur_cpu_spec@l
 141         lwz     r4,0(r4)
 142         add     r4,r4,r3
 143         lwz     r5,CPU_SPEC_SETUP(r4)
 144         cmpwi   0,r5,0
 145         add     r5,r5,r3
 146         beqlr
 147         mtctr   r5
 148         bctr
 149
 150 #if defined(CONFIG_CPU_FREQ_PMAC) && defined(CONFIG_6xx)
 151
 152 /* This gets called by via-pmu.c to switch the PLL selection
 153  * on 750fx CPU. This function should really be moved to some
 154  * other place (as most of the cpufreq code in via-pmu
 155  */
 156 _GLOBAL(low_choose_750fx_pll)
 157         /* Clear MSR:EE */
 158         mfmsr   r7
 159         rlwinm  r0,r7,0,17,15
 160         mtmsr   r0
 161
 162         /* If switching to PLL1, disable HID0:BTIC */
 163         cmplwi  cr0,r3,0
 164         beq     1f
 165         mfspr   r5,SPRN_HID0
 166         rlwinm  r5,r5,0,27,25
 167         sync
 168         mtspr   SPRN_HID0,r5
 169         isync
 170         sync
 171
 172 1:
 173         /* Calc new HID1 value */
 174         mfspr   r4,SPRN_HID1    /* Build a HID1:PS bit from parameter */
 175         rlwinm  r5,r3,16,15,15  /* Clear out HID1:PS from value read */
 176         rlwinm  r4,r4,0,16,14   /* Could have I used rlwimi here ? */
 177         or      r4,r4,r5
 178         mtspr   SPRN_HID1,r4
 179
 180         /* Store new HID1 image */
 181         rlwinm  r6,r1,0,0,(31-THREAD_SHIFT)
 182         lwz     r6,TI_CPU(r6)
 183         slwi    r6,r6,2
 184         addis   r6,r6,nap_save_hid1@ha
 185         stw     r4,nap_save_hid1@l(r6)
 186
 187         /* If switching to PLL0, enable HID0:BTIC */
 188         cmplwi  cr0,r3,0
 189         bne     1f
 190         mfspr   r5,SPRN_HID0
 191         ori     r5,r5,HID0_BTIC
 192         sync
 193         mtspr   SPRN_HID0,r5
 194         isync
 195         sync
 196
 197 1:
 198         /* Return */
 199         mtmsr   r7
 200         blr
 201
 202 _GLOBAL(low_choose_7447a_dfs)
 203         /* Clear MSR:EE */
 204         mfmsr   r7
 205         rlwinm  r0,r7,0,17,15
 206         mtmsr   r0
 207
 208         /* Calc new HID1 value */
 209         mfspr   r4,SPRN_HID1
 210         insrwi  r4,r3,1,9       /* insert parameter into bit 9 */
 211         sync
 212         mtspr   SPRN_HID1,r4
 213         sync
 214         isync
 215
 216         /* Return */
 217         mtmsr   r7
 218         blr
 219
 220 #endif /* CONFIG_CPU_FREQ_PMAC && CONFIG_6xx */
 221
 222 /*
 223  * complement mask on the msr then "or" some values on.
 224  *     _nmask_and_or_msr(nmask, value_to_or)
 225  */
 226 _GLOBAL(_nmask_and_or_msr)
 227         mfmsr   r0              /* Get current msr */
 228         andc    r0,r0,r3        /* And off the bits set in r3 (first parm) */
 229         or      r0,r0,r4        /* Or on the bits in r4 (second parm) */
 230         SYNC                    /* Some chip revs have problems here... */
 231         mtmsr   r0              /* Update machine state */
 232         isync
 233         blr                     /* Done */
 234
 235 #ifdef CONFIG_40x
 236
 237 /*
 238  * Do an IO access in real mode
 239  */
 240 _GLOBAL(real_readb)
 241         mfmsr   r7
 242         ori     r0,r7,MSR_DR
 243         xori    r0,r0,MSR_DR
 244         sync
 245         mtmsr   r0
 246         sync
 247         isync
 248         lbz     r3,0(r3)
 249         sync
 250         mtmsr   r7
 251         sync
 252         isync
 253         blr
 254
 255         /*
 256  * Do an IO access in real mode
 257  */
 258 _GLOBAL(real_writeb)
 259         mfmsr   r7
 260         ori     r0,r7,MSR_DR
 261         xori    r0,r0,MSR_DR
 262         sync
 263         mtmsr   r0
 264         sync
 265         isync
 266         stb     r3,0(r4)
 267         sync
 268         mtmsr   r7
 269         sync
 270         isync
 271         blr
 272
 273 #endif /* CONFIG_40x */
 274
 275
 276 /*
 277  * Flush instruction cache.
 278  * This is a no-op on the 601.
 279  */
 280 _GLOBAL(flush_instruction_cache)
 281 #if defined(CONFIG_8xx)
 282         isync
 283         lis     r5, IDC_INVALL@h
 284         mtspr   SPRN_IC_CST, r5
 285 #elif defined(CONFIG_4xx)
 286 #ifdef CONFIG_403GCX
 287         li      r3, 512
 288         mtctr   r3
 289         lis     r4, KERNELBASE@h
 290 1:      iccci   0, r4
 291         addi    r4, r4, 16
 292         bdnz    1b
 293 #else
 294         lis     r3, KERNELBASE@h
 295         iccci   0,r3
 296 #endif
 297 #elif CONFIG_FSL_BOOKE
 298 BEGIN_FTR_SECTION
 299         mfspr   r3,SPRN_L1CSR0
 300         ori     r3,r3,L1CSR0_CFI|L1CSR0_CLFC
 301         /* msync; isync recommended here */
 302         mtspr   SPRN_L1CSR0,r3
 303         isync
 304         blr
 305 END_FTR_SECTION_IFSET(CPU_FTR_UNIFIED_ID_CACHE)
 306         mfspr   r3,SPRN_L1CSR1
 307         ori     r3,r3,L1CSR1_ICFI|L1CSR1_ICLFR
 308         mtspr   SPRN_L1CSR1,r3
 309 #else
 310         mfspr   r3,SPRN_PVR
 311         rlwinm  r3,r3,16,16,31
 312         cmpwi   0,r3,1
 313         beqlr                   /* for 601, do nothing */
 314         /* 603/604 processor - use invalidate-all bit in HID0 */
 315         mfspr   r3,SPRN_HID0
 316         ori     r3,r3,HID0_ICFI
 317         mtspr   SPRN_HID0,r3
 318 #endif /* CONFIG_8xx/4xx */
 319         isync
 320         blr
 321
 322 /*
 323  * Write any modified data cache blocks out to memory
 324  * and invalidate the corresponding instruction cache blocks.
 325  * This is a no-op on the 601.
 326  *
 327  * flush_icache_range(unsigned long start, unsigned long stop)
 328  */
 329 _KPROBE(__flush_icache_range)
 330 BEGIN_FTR_SECTION
 331         blr                             /* for 601, do nothing */
 332 END_FTR_SECTION_IFSET(CPU_FTR_COHERENT_ICACHE)
 333         li      r5,L1_CACHE_BYTES-1
 334         andc    r3,r3,r5
 335         subf    r4,r3,r4
 336         add     r4,r4,r5
 337         srwi.   r4,r4,L1_CACHE_SHIFT
 338         beqlr
 339         mtctr   r4
 340         mr      r6,r3
 341 1:      dcbst   0,r3
 342         addi    r3,r3,L1_CACHE_BYTES
 343         bdnz    1b
 344         sync                            /* wait for dcbst's to get to ram */
 345 #ifndef CONFIG_44x
 346         mtctr   r4
 347 2:      icbi    0,r6
 348         addi    r6,r6,L1_CACHE_BYTES
 349         bdnz    2b
 350 #else
 351         /* Flash invalidate on 44x because we are passed kmapped addresses and
 352            this doesn't work for userspace pages due to the virtually tagged
 353            icache.  Sigh. */
 354         iccci   0, r0
 355 #endif
 356         sync                            /* additional sync needed on g4 */
 357         isync
 358         blr
 359 /*
 360  * Write any modified data cache blocks out to memory.
 361  * Does not invalidate the corresponding cache lines (especially for
 362  * any corresponding instruction cache).
 363  *
 364  * clean_dcache_range(unsigned long start, unsigned long stop)
 365  */
 366 _GLOBAL(clean_dcache_range)
 367         li      r5,L1_CACHE_BYTES-1
 368         andc    r3,r3,r5
 369         subf    r4,r3,r4
 370         add     r4,r4,r5
 371         srwi.   r4,r4,L1_CACHE_SHIFT
 372         beqlr
 373         mtctr   r4
 374
 375 1:      dcbst   0,r3
 376         addi    r3,r3,L1_CACHE_BYTES
 377         bdnz    1b
 378         sync                            /* wait for dcbst's to get to ram */
 379         blr
 380
 381 /*
 382  * Write any modified data cache blocks out to memory and invalidate them.
 383  * Does not invalidate the corresponding instruction cache blocks.
 384  *
 385  * flush_dcache_range(unsigned long start, unsigned long stop)
 386  */
 387 _GLOBAL(flush_dcache_range)
 388         li      r5,L1_CACHE_BYTES-1
 389         andc    r3,r3,r5
 390         subf    r4,r3,r4
 391         add     r4,r4,r5
 392         srwi.   r4,r4,L1_CACHE_SHIFT
 393         beqlr
 394         mtctr   r4
 395
 396 1:      dcbf    0,r3
 397         addi    r3,r3,L1_CACHE_BYTES
 398         bdnz    1b
 399         sync                            /* wait for dcbst's to get to ram */
 400         blr
 401
 402 /*
 403  * Like above, but invalidate the D-cache.  This is used by the 8xx
 404  * to invalidate the cache so the PPC core doesn't get stale data
 405  * from the CPM (no cache snooping here :-).
 406  *
 407  * invalidate_dcache_range(unsigned long start, unsigned long stop)
 408  */
 409 _GLOBAL(invalidate_dcache_range)
 410         li      r5,L1_CACHE_BYTES-1
 411         andc    r3,r3,r5
 412         subf    r4,r3,r4
 413         add     r4,r4,r5
 414         srwi.   r4,r4,L1_CACHE_SHIFT
 415         beqlr
 416         mtctr   r4
 417
 418 1:      dcbi    0,r3
 419         addi    r3,r3,L1_CACHE_BYTES
 420         bdnz    1b
 421         sync                            /* wait for dcbi's to get to ram */
 422         blr
 423
 424 /*
 425  * Flush a particular page from the data cache to RAM.
 426  * Note: this is necessary because the instruction cache does *not*
 427  * snoop from the data cache.
 428  * This is a no-op on the 601 which has a unified cache.
 429  *
 430  *      void __flush_dcache_icache(void *page)
 431  */
 432 _GLOBAL(__flush_dcache_icache)
 433 BEGIN_FTR_SECTION
 434         blr
 435 END_FTR_SECTION_IFSET(CPU_FTR_COHERENT_ICACHE)
 436         rlwinm  r3,r3,0,0,31-PAGE_SHIFT         /* Get page base address */
 437         li      r4,PAGE_SIZE/L1_CACHE_BYTES     /* Number of lines in a page */
 438         mtctr   r4
 439         mr      r6,r3
 440 0:      dcbst   0,r3                            /* Write line to ram */
 441         addi    r3,r3,L1_CACHE_BYTES
 442         bdnz    0b
 443         sync
 444 #ifdef CONFIG_44x
 445         /* We don't flush the icache on 44x. Those have a virtual icache
 446          * and we don't have access to the virtual address here (it's
 447          * not the page vaddr but where it's mapped in user space). The
 448          * flushing of the icache on these is handled elsewhere, when
 449          * a change in the address space occurs, before returning to
 450          * user space
 451          */
 452 BEGIN_MMU_FTR_SECTION
 453         blr
 454 END_MMU_FTR_SECTION_IFSET(MMU_FTR_TYPE_44x)
 455 #endif /* CONFIG_44x */
 456         mtctr   r4
 457 1:      icbi    0,r6
 458         addi    r6,r6,L1_CACHE_BYTES
 459         bdnz    1b
 460         sync
 461         isync
 462         blr
 463
 464 #ifndef CONFIG_BOOKE
 465 /*
 466  * Flush a particular page from the data cache to RAM, identified
 467  * by its physical address.  We turn off the MMU so we can just use
 468  * the physical address (this may be a highmem page without a kernel
 469  * mapping).
 470  *
 471  *      void __flush_dcache_icache_phys(unsigned long physaddr)
 472  */
 473 _GLOBAL(__flush_dcache_icache_phys)
 474 BEGIN_FTR_SECTION
 475         blr                                     /* for 601, do nothing */
 476 END_FTR_SECTION_IFSET(CPU_FTR_COHERENT_ICACHE)
 477         mfmsr   r10
 478         rlwinm  r0,r10,0,28,26                  /* clear DR */
 479         mtmsr   r0
 480         isync
 481         rlwinm  r3,r3,0,0,31-PAGE_SHIFT         /* Get page base address */
 482         li      r4,PAGE_SIZE/L1_CACHE_BYTES     /* Number of lines in a page */
 483         mtctr   r4
 484         mr      r6,r3
 485 0:      dcbst   0,r3                            /* Write line to ram */
 486         addi    r3,r3,L1_CACHE_BYTES
 487         bdnz    0b
 488         sync
 489         mtctr   r4
 490 1:      icbi    0,r6
 491         addi    r6,r6,L1_CACHE_BYTES
 492         bdnz    1b
 493         sync
 494         mtmsr   r10                             /* restore DR */
 495         isync
 496         blr
 497 #endif /* CONFIG_BOOKE */
 498
 499 /*
 500  * Clear pages using the dcbz instruction, which doesn't cause any
 501  * memory traffic (except to write out any cache lines which get
 502  * displaced).  This only works on cacheable memory.
 503  *
 504  * void clear_pages(void *page, int order) ;
 505  */
 506 _GLOBAL(clear_pages)
 507         li      r0,PAGE_SIZE/L1_CACHE_BYTES
 508         slw     r0,r0,r4
 509         mtctr   r0
 510 1:      dcbz    0,r3
 511         addi    r3,r3,L1_CACHE_BYTES
 512         bdnz    1b
 513         blr
 514
 515 /*
 516  * Copy a whole page.  We use the dcbz instruction on the destination
 517  * to reduce memory traffic (it eliminates the unnecessary reads of
 518  * the destination into cache).  This requires that the destination
 519  * is cacheable.
 520  */
 521 #define COPY_16_BYTES           \
 522         lwz     r6,4(r4);       \
 523         lwz     r7,8(r4);       \
 524         lwz     r8,12(r4);      \
 525         lwzu    r9,16(r4);      \
 526         stw     r6,4(r3);       \
 527         stw     r7,8(r3);       \
 528         stw     r8,12(r3);      \
 529         stwu    r9,16(r3)
 530
 531 _GLOBAL(copy_page)
 532         addi    r3,r3,-4
 533         addi    r4,r4,-4
 534
 535         li      r5,4
 536
 537 #if MAX_COPY_PREFETCH > 1
 538         li      r0,MAX_COPY_PREFETCH
 539         li      r11,4
 540         mtctr   r0
 541 11:     dcbt    r11,r4
 542         addi    r11,r11,L1_CACHE_BYTES
 543         bdnz    11b
 544 #else /* MAX_COPY_PREFETCH == 1 */
 545         dcbt    r5,r4
 546         li      r11,L1_CACHE_BYTES+4
 547 #endif /* MAX_COPY_PREFETCH */
 548         li      r0,PAGE_SIZE/L1_CACHE_BYTES - MAX_COPY_PREFETCH
 549         crclr   4*cr0+eq
 550 2:
 551         mtctr   r0
 552 1:
 553         dcbt    r11,r4
 554         dcbz    r5,r3
 555         COPY_16_BYTES
 556 #if L1_CACHE_BYTES >= 32
 557         COPY_16_BYTES
 558 #if L1_CACHE_BYTES >= 64
 559         COPY_16_BYTES
 560         COPY_16_BYTES
 561 #if L1_CACHE_BYTES >= 128
 562         COPY_16_BYTES
 563         COPY_16_BYTES
 564         COPY_16_BYTES
 565         COPY_16_BYTES
 566 #endif
 567 #endif
 568 #endif
 569         bdnz    1b
 570         beqlr
 571         crnot   4*cr0+eq,4*cr0+eq
 572         li      r0,MAX_COPY_PREFETCH
 573         li      r11,4
 574         b       2b
 575
 576 /*
 577  * void atomic_clear_mask(atomic_t mask, atomic_t *addr)
 578  * void atomic_set_mask(atomic_t mask, atomic_t *addr);
 579  */
 580 _GLOBAL(atomic_clear_mask)
 581 10:     lwarx   r5,0,r4
 582         andc    r5,r5,r3
 583         PPC405_ERR77(0,r4)
 584         stwcx.  r5,0,r4
 585         bne-    10b
 586         blr
 587 _GLOBAL(atomic_set_mask)
 588 10:     lwarx   r5,0,r4
 589         or      r5,r5,r3
 590         PPC405_ERR77(0,r4)
 591         stwcx.  r5,0,r4
 592         bne-    10b
 593         blr
 594
 595 /*
 596  * Extended precision shifts.
 597  *
 598  * Updated to be valid for shift counts from 0 to 63 inclusive.
 599  * -- Gabriel
 600  *
 601  * R3/R4 has 64 bit value
 602  * R5    has shift count
 603  * result in R3/R4
 604  *
 605  *  ashrdi3: arithmetic right shift (sign propagation)
 606  *  lshrdi3: logical right shift
 607  *  ashldi3: left shift
 608  */
 609 _GLOBAL(__ashrdi3)
 610         subfic  r6,r5,32
 611         srw     r4,r4,r5        # LSW = count > 31 ? 0 : LSW >> count
 612         addi    r7,r5,32        # could be xori, or addi with -32
 613         slw     r6,r3,r6        # t1 = count > 31 ? 0 : MSW << (32-count)
 614         rlwinm  r8,r7,0,32      # t3 = (count < 32) ? 32 : 0
 615         sraw    r7,r3,r7        # t2 = MSW >> (count-32)
 616         or      r4,r4,r6        # LSW |= t1
 617         slw     r7,r7,r8        # t2 = (count < 32) ? 0 : t2
 618         sraw    r3,r3,r5        # MSW = MSW >> count
 619         or      r4,r4,r7        # LSW |= t2
 620         blr
 621
 622 _GLOBAL(__ashldi3)
 623         subfic  r6,r5,32
 624         slw     r3,r3,r5        # MSW = count > 31 ? 0 : MSW << count
 625         addi    r7,r5,32        # could be xori, or addi with -32
 626         srw     r6,r4,r6        # t1 = count > 31 ? 0 : LSW >> (32-count)
 627         slw     r7,r4,r7        # t2 = count < 32 ? 0 : LSW << (count-32)
 628         or      r3,r3,r6        # MSW |= t1
 629         slw     r4,r4,r5        # LSW = LSW << count
 630         or      r3,r3,r7        # MSW |= t2
 631         blr
 632
 633 _GLOBAL(__lshrdi3)
 634         subfic  r6,r5,32
 635         srw     r4,r4,r5        # LSW = count > 31 ? 0 : LSW >> count
 636         addi    r7,r5,32        # could be xori, or addi with -32
 637         slw     r6,r3,r6        # t1 = count > 31 ? 0 : MSW << (32-count)
 638         srw     r7,r3,r7        # t2 = count < 32 ? 0 : MSW >> (count-32)
 639         or      r4,r4,r6        # LSW |= t1
 640         srw     r3,r3,r5        # MSW = MSW >> count
 641         or      r4,r4,r7        # LSW |= t2
 642         blr
 643
 644 /*
 645  * 64-bit comparison: __ucmpdi2(u64 a, u64 b)
 646  * Returns 0 if a < b, 1 if a == b, 2 if a > b.
 647  */
 648 _GLOBAL(__ucmpdi2)
 649         cmplw   r3,r5
 650         li      r3,1
 651         bne     1f
 652         cmplw   r4,r6
 653         beqlr
 654 1:      li      r3,0
 655         bltlr
 656         li      r3,2
 657         blr
 658
 659 _GLOBAL(abs)
 660         srawi   r4,r3,31
 661         xor     r3,r3,r4
 662         sub     r3,r3,r4
 663         blr
 664
 665 /*
 666  * Create a kernel thread
 667  *   kernel_thread(fn, arg, flags)
 668  */
 669 _GLOBAL(kernel_thread)
 670         stwu    r1,-16(r1)
 671         stw     r30,8(r1)
 672         stw     r31,12(r1)
 673         mr      r30,r3          /* function */
 674         mr      r31,r4          /* argument */
 675         ori     r3,r5,CLONE_VM  /* flags */
 676         oris    r3,r3,CLONE_UNTRACED>>16
 677         li      r4,0            /* new sp (unused) */
 678         li      r0,__NR_clone
 679         sc
 680         bns+    1f              /* did system call indicate error? */
 681         neg     r3,r3           /* if so, make return code negative */
 682 1:      cmpwi   0,r3,0          /* parent or child? */
 683         bne     2f              /* return if parent */
 684         li      r0,0            /* make top-level stack frame */
 685         stwu    r0,-16(r1)
 686         mtlr    r30             /* fn addr in lr */
 687         mr      r3,r31          /* load arg and call fn */
 688         PPC440EP_ERR42
 689         blrl
 690         li      r0,__NR_exit    /* exit if function returns */
 691         li      r3,0
 692         sc
 693 2:      lwz     r30,8(r1)
 694         lwz     r31,12(r1)
 695         addi    r1,r1,16
 696         blr
 697
 698 /*
 699  * This routine is just here to keep GCC happy - sigh...
 700  */
 701 _GLOBAL(__main)
 702         blr
 703
 704 #ifdef CONFIG_KEXEC
 705         /*
 706          * Must be relocatable PIC code callable as a C function.
 707          */
 708         .globl relocate_new_kernel
 709 relocate_new_kernel:
 710         /* r3 = page_list   */
 711         /* r4 = reboot_code_buffer */
 712         /* r5 = start_address      */
 713
 714 #ifdef CONFIG_FSL_BOOKE
 715
 716         mr      r29, r3
 717         mr      r30, r4
 718         mr      r31, r5
 719
 720 #define ENTRY_MAPPING_KEXEC_SETUP
 721 #include "fsl_booke_entry_mapping.S"
 722 #undef ENTRY_MAPPING_KEXEC_SETUP
 723
 724         mr      r3, r29
 725         mr      r4, r30
 726         mr      r5, r31
 727
 728         li      r0, 0
 729 #else
 730         li      r0, 0
 731
 732         /*
 733          * Set Machine Status Register to a known status,
 734          * switch the MMU off and jump to 1: in a single step.
 735          */
 736
 737         mr      r8, r0
 738         ori     r8, r8, MSR_RI|MSR_ME
 739         mtspr   SPRN_SRR1, r8
 740         addi    r8, r4, 1f - relocate_new_kernel
 741         mtspr   SPRN_SRR0, r8
 742         sync
 743         rfi
 744
 745 1:
 746 #endif
 747         /* from this point address translation is turned off */
 748         /* and interrupts are disabled */
 749
 750         /* set a new stack at the bottom of our page... */
 751         /* (not really needed now) */
 752         addi    r1, r4, KEXEC_CONTROL_PAGE_SIZE - 8 /* for LR Save+Back Chain */
 753         stw     r0, 0(r1)
 754
 755         /* Do the copies */
 756         li      r6, 0 /* checksum */
 757         mr      r0, r3
 758         b       1f
 759
 760 0:      /* top, read another word for the indirection page */
 761         lwzu    r0, 4(r3)
 762
 763 1:
 764         /* is it a destination page? (r8) */
 765         rlwinm. r7, r0, 0, 31, 31 /* IND_DESTINATION (1<<0) */
 766         beq     2f
 767
 768         rlwinm  r8, r0, 0, 0, 19 /* clear kexec flags, page align */
 769         b       0b
 770
 771 2:      /* is it an indirection page? (r3) */
 772         rlwinm. r7, r0, 0, 30, 30 /* IND_INDIRECTION (1<<1) */
 773         beq     2f
 774
 775         rlwinm  r3, r0, 0, 0, 19 /* clear kexec flags, page align */
 776         subi    r3, r3, 4
 777         b       0b
 778
 779 2:      /* are we done? */
 780         rlwinm. r7, r0, 0, 29, 29 /* IND_DONE (1<<2) */
 781         beq     2f
 782         b       3f
 783
 784 2:      /* is it a source page? (r9) */
 785         rlwinm. r7, r0, 0, 28, 28 /* IND_SOURCE (1<<3) */
 786         beq     0b
 787
 788         rlwinm  r9, r0, 0, 0, 19 /* clear kexec flags, page align */
 789
 790         li      r7, PAGE_SIZE / 4
 791         mtctr   r7
 792         subi    r9, r9, 4
 793         subi    r8, r8, 4
 794 9:
 795         lwzu    r0, 4(r9)  /* do the copy */
 796         xor     r6, r6, r0
 797         stwu    r0, 4(r8)
 798         dcbst   0, r8
 799         sync
 800         icbi    0, r8
 801         bdnz    9b
 802
 803         addi    r9, r9, 4
 804         addi    r8, r8, 4
 805         b       0b
 806
 807 3:
 808
 809         /* To be certain of avoiding problems with self-modifying code
 810          * execute a serializing instruction here.
 811          */
 812         isync
 813         sync
 814
 815         /* jump to the entry point, usually the setup routine */
 816         mtlr    r5
 817         blrl
 818
 819 1:      b       1b
 820
 821 relocate_new_kernel_end:
 822
 823         .globl relocate_new_kernel_size
 824 relocate_new_kernel_size:
 825         .long relocate_new_kernel_end - relocate_new_kernel
 826 #endif