arch/powerpc/kernel/head_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *
   5  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   6  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   7  *  Adapted for Power Macintosh by Paul Mackerras.
   8  *  Low-level exception handlers and MMU support
   9  *  rewritten by Paul Mackerras.
  10  *    Copyright (C) 1996 Paul Mackerras.
  11  *
  12  *  Adapted for 64bit PowerPC by Dave Engebretsen, Peter Bergner, and
  13  *    Mike Corrigan {engebret|bergner|mikejc}@us.ibm.com
  14  *
  15  *  This file contains the entry point for the 64-bit kernel along
  16  *  with some early initialization code common to all 64-bit powerpc
  17  *  variants.
  18  *
  19  *  This program is free software; you can redistribute it and/or
  20  *  modify it under the terms of the GNU General Public License
  21  *  as published by the Free Software Foundation; either version
  22  *  2 of the License, or (at your option) any later version.
  23  */
  24
  25 #include <linux/threads.h>
  26 #include <asm/reg.h>
  27 #include <asm/page.h>
  28 #include <asm/mmu.h>
  29 #include <asm/ppc_asm.h>
  30 #include <asm/asm-offsets.h>
  31 #include <asm/bug.h>
  32 #include <asm/cputable.h>
  33 #include <asm/setup.h>
  34 #include <asm/hvcall.h>
  35 #include <asm/iseries/lpar_map.h>
  36 #include <asm/thread_info.h>
  37 #include <asm/firmware.h>
  38 #include <asm/page_64.h>
  39 #include <asm/irqflags.h>
  40 #include <asm/kvm_book3s_asm.h>
  41 #include <asm/ptrace.h>
  42
  43 /* The physical memory is laid out such that the secondary processor
  44  * spin code sits at 0x0000...0x00ff. On server, the vectors follow
  45  * using the layout described in exceptions-64s.S
  46  */
  47
  48 /*
  49  * Entering into this code we make the following assumptions:
  50  *
  51  *  For pSeries or server processors:
  52  *   1. The MMU is off & open firmware is running in real mode.
  53  *   2. The kernel is entered at __start
  54  *
  55  *  For iSeries:
  56  *   1. The MMU is on (as it always is for iSeries)
  57  *   2. The kernel is entered at system_reset_iSeries
  58  *
  59  *  For Book3E processors:
  60  *   1. The MMU is on running in AS0 in a state defined in ePAPR
  61  *   2. The kernel is entered at __start
  62  */
  63
  64         .text
  65         .globl  _stext
  66 _stext:
  67 _GLOBAL(__start)
  68         /* NOP this out unconditionally */
  69 BEGIN_FTR_SECTION
  70         b       .__start_initialization_multiplatform
  71 END_FTR_SECTION(0, 1)
  72
  73         /* Catch branch to 0 in real mode */
  74         trap
  75
  76         /* Secondary processors spin on this value until it becomes nonzero.
  77          * When it does it contains the real address of the descriptor
  78          * of the function that the cpu should jump to to continue
  79          * initialization.
  80          */
  81         .globl  __secondary_hold_spinloop
  82 __secondary_hold_spinloop:
  83         .llong  0x0
  84
  85         /* Secondary processors write this value with their cpu # */
  86         /* after they enter the spin loop immediately below.      */
  87         .globl  __secondary_hold_acknowledge
  88 __secondary_hold_acknowledge:
  89         .llong  0x0
  90
  91 #ifdef CONFIG_PPC_ISERIES
  92         /*
  93          * At offset 0x20, there is a pointer to iSeries LPAR data.
  94          * This is required by the hypervisor
  95          */
  96         . = 0x20
  97         .llong hvReleaseData-KERNELBASE
  98 #endif /* CONFIG_PPC_ISERIES */
  99
 100 #ifdef CONFIG_RELOCATABLE
 101         /* This flag is set to 1 by a loader if the kernel should run
 102          * at the loaded address instead of the linked address.  This
 103          * is used by kexec-tools to keep the the kdump kernel in the
 104          * crash_kernel region.  The loader is responsible for
 105          * observing the alignment requirement.
 106          */
 107         /* Do not move this variable as kexec-tools knows about it. */
 108         . = 0x5c
 109         .globl  __run_at_load
 110 __run_at_load:
 111         .long   0x72756e30      /* "run0" -- relocate to 0 by default */
 112 #endif
 113
 114         . = 0x60
 115 /*
 116  * The following code is used to hold secondary processors
 117  * in a spin loop after they have entered the kernel, but
 118  * before the bulk of the kernel has been relocated.  This code
 119  * is relocated to physical address 0x60 before prom_init is run.
 120  * All of it must fit below the first exception vector at 0x100.
 121  * Use .globl here not _GLOBAL because we want __secondary_hold
 122  * to be the actual text address, not a descriptor.
 123  */
 124         .globl  __secondary_hold
 125 __secondary_hold:
 126 #ifndef CONFIG_PPC_BOOK3E
 127         mfmsr   r24
 128         ori     r24,r24,MSR_RI
 129         mtmsrd  r24                     /* RI on */
 130 #endif
 131         /* Grab our physical cpu number */
 132         mr      r24,r3
 133
 134         /* Tell the master cpu we're here */
 135         /* Relocation is off & we are located at an address less */
 136         /* than 0x100, so only need to grab low order offset.    */
 137         std     r24,__secondary_hold_acknowledge-_stext(0)
 138         sync
 139
 140         /* All secondary cpus wait here until told to start. */
 141 100:    ld      r4,__secondary_hold_spinloop-_stext(0)
 142         cmpdi   0,r4,0
 143         beq     100b
 144
 145 #if defined(CONFIG_SMP) || defined(CONFIG_KEXEC)
 146         ld      r4,0(r4)                /* deref function descriptor */
 147         mtctr   r4
 148         mr      r3,r24
 149         li      r4,0
 150         bctr
 151 #else
 152         BUG_OPCODE
 153 #endif
 154
 155 /* This value is used to mark exception frames on the stack. */
 156         .section ".toc","aw"
 157 exception_marker:
 158         .tc     ID_72656773_68657265[TC],0x7265677368657265
 159         .text
 160
 161 /*
 162  * On server, we include the exception vectors code here as it
 163  * relies on absolute addressing which is only possible within
 164  * this compilation unit
 165  */
 166 #ifdef CONFIG_PPC_BOOK3S
 167 #include "exceptions-64s.S"
 168 #endif
 169
 170 _GLOBAL(generic_secondary_thread_init)
 171         mr      r24,r3
 172
 173         /* turn on 64-bit mode */
 174         bl      .enable_64b_mode
 175
 176         /* get a valid TOC pointer, wherever we're mapped at */
 177         bl      .relative_toc
 178
 179 #ifdef CONFIG_PPC_BOOK3E
 180         /* Book3E initialization */
 181         mr      r3,r24
 182         bl      .book3e_secondary_thread_init
 183 #endif
 184         b       generic_secondary_common_init
 185
 186 /*
 187  * On pSeries and most other platforms, secondary processors spin
 188  * in the following code.
 189  * At entry, r3 = this processor's number (physical cpu id)
 190  *
 191  * On Book3E, r4 = 1 to indicate that the initial TLB entry for
 192  * this core already exists (setup via some other mechanism such
 193  * as SCOM before entry).
 194  */
 195 _GLOBAL(generic_secondary_smp_init)
 196         mr      r24,r3
 197         mr      r25,r4
 198
 199         /* turn on 64-bit mode */
 200         bl      .enable_64b_mode
 201
 202         /* get a valid TOC pointer, wherever we're mapped at */
 203         bl      .relative_toc
 204
 205 #ifdef CONFIG_PPC_BOOK3E
 206         /* Book3E initialization */
 207         mr      r3,r24
 208         mr      r4,r25
 209         bl      .book3e_secondary_core_init
 210 #endif
 211
 212 generic_secondary_common_init:
 213         /* Set up a paca value for this processor. Since we have the
 214          * physical cpu id in r24, we need to search the pacas to find
 215          * which logical id maps to our physical one.
 216          */
 217         LOAD_REG_ADDR(r13, paca)        /* Load paca pointer             */
 218         ld      r13,0(r13)              /* Get base vaddr of paca array  */
 219         li      r5,0                    /* logical cpu id                */
 220 1:      lhz     r6,PACAHWCPUID(r13)     /* Load HW procid from paca      */
 221         cmpw    r6,r24                  /* Compare to our id             */
 222         beq     2f
 223         addi    r13,r13,PACA_SIZE       /* Loop to next PACA on miss     */
 224         addi    r5,r5,1
 225         cmpwi   r5,NR_CPUS
 226         blt     1b
 227
 228         mr      r3,r24                  /* not found, copy phys to r3    */
 229         b       .kexec_wait             /* next kernel might do better   */
 230
 231 2:      SET_PACA(r13)
 232 #ifdef CONFIG_PPC_BOOK3E
 233         addi    r12,r13,PACA_EXTLB      /* and TLB exc frame in another  */
 234         mtspr   SPRN_SPRG_TLB_EXFRAME,r12
 235 #endif
 236
 237         /* From now on, r24 is expected to be logical cpuid */
 238         mr      r24,r5
 239
 240         /* See if we need to call a cpu state restore handler */
 241         LOAD_REG_ADDR(r23, cur_cpu_spec)
 242         ld      r23,0(r23)
 243         ld      r23,CPU_SPEC_RESTORE(r23)
 244         cmpdi   0,r23,0
 245         beq     3f
 246         ld      r23,0(r23)
 247         mtctr   r23
 248         bctrl
 249
 250 3:      LOAD_REG_ADDR(r3, boot_cpu_count) /* Decrement boot_cpu_count */
 251         lwarx   r4,0,r3
 252         subi    r4,r4,1
 253         stwcx.  r4,0,r3
 254         bne     3b
 255         isync
 256
 257 4:      HMT_LOW
 258         lbz     r23,PACAPROCSTART(r13)  /* Test if this processor should */
 259                                         /* start.                        */
 260 #ifndef CONFIG_SMP
 261         b       4b                      /* Never go on non-SMP           */
 262 #else
 263         cmpwi   0,r23,0
 264         beq     4b                      /* Loop until told to go         */
 265
 266         sync                            /* order paca.run and cur_cpu_spec */
 267         isync                           /* In case code patching happened */
 268
 269         /* Create a temp kernel stack for use before relocation is on.  */
 270         ld      r1,PACAEMERGSP(r13)
 271         subi    r1,r1,STACK_FRAME_OVERHEAD
 272
 273         b       __secondary_start
 274 #endif
 275
 276 /*
 277  * Turn the MMU off.
 278  * Assumes we're mapped EA == RA if the MMU is on.
 279  */
 280 #ifdef CONFIG_PPC_BOOK3S
 281 _STATIC(__mmu_off)
 282         mfmsr   r3
 283         andi.   r0,r3,MSR_IR|MSR_DR
 284         beqlr
 285         mflr    r4
 286         andc    r3,r3,r0
 287         mtspr   SPRN_SRR0,r4
 288         mtspr   SPRN_SRR1,r3
 289         sync
 290         rfid
 291         b       .       /* prevent speculative execution */
 292 #endif
 293
 294
 295 /*
 296  * Here is our main kernel entry point. We support currently 2 kind of entries
 297  * depending on the value of r5.
 298  *
 299  *   r5 != NULL -> OF entry, we go to prom_init, "legacy" parameter content
 300  *                 in r3...r7
 301  *
 302  *   r5 == NULL -> kexec style entry. r3 is a physical pointer to the
 303  *                 DT block, r4 is a physical pointer to the kernel itself
 304  *
 305  */
 306 _GLOBAL(__start_initialization_multiplatform)
 307         /* Make sure we are running in 64 bits mode */
 308         bl      .enable_64b_mode
 309
 310         /* Get TOC pointer (current runtime address) */
 311         bl      .relative_toc
 312
 313         /* find out where we are now */
 314         bcl     20,31,$+4
 315 0:      mflr    r26                     /* r26 = runtime addr here */
 316         addis   r26,r26,(_stext - 0b)@ha
 317         addi    r26,r26,(_stext - 0b)@l /* current runtime base addr */
 318
 319         /*
 320          * Are we booted from a PROM Of-type client-interface ?
 321          */
 322         cmpldi  cr0,r5,0
 323         beq     1f
 324         b       .__boot_from_prom               /* yes -> prom */
 325 1:
 326         /* Save parameters */
 327         mr      r31,r3
 328         mr      r30,r4
 329
 330 #ifdef CONFIG_PPC_BOOK3E
 331         bl      .start_initialization_book3e
 332         b       .__after_prom_start
 333 #else
 334         /* Setup some critical 970 SPRs before switching MMU off */
 335         mfspr   r0,SPRN_PVR
 336         srwi    r0,r0,16
 337         cmpwi   r0,0x39         /* 970 */
 338         beq     1f
 339         cmpwi   r0,0x3c         /* 970FX */
 340         beq     1f
 341         cmpwi   r0,0x44         /* 970MP */
 342         beq     1f
 343         cmpwi   r0,0x45         /* 970GX */
 344         bne     2f
 345 1:      bl      .__cpu_preinit_ppc970
 346 2:
 347
 348         /* Switch off MMU if not already off */
 349         bl      .__mmu_off
 350         b       .__after_prom_start
 351 #endif /* CONFIG_PPC_BOOK3E */
 352
 353 _INIT_STATIC(__boot_from_prom)
 354 #ifdef CONFIG_PPC_OF_BOOT_TRAMPOLINE
 355         /* Save parameters */
 356         mr      r31,r3
 357         mr      r30,r4
 358         mr      r29,r5
 359         mr      r28,r6
 360         mr      r27,r7
 361
 362         /*
 363          * Align the stack to 16-byte boundary
 364          * Depending on the size and layout of the ELF sections in the initial
 365          * boot binary, the stack pointer may be unaligned on PowerMac
 366          */
 367         rldicr  r1,r1,0,59
 368
 369 #ifdef CONFIG_RELOCATABLE
 370         /* Relocate code for where we are now */
 371         mr      r3,r26
 372         bl      .relocate
 373 #endif
 374
 375         /* Restore parameters */
 376         mr      r3,r31
 377         mr      r4,r30
 378         mr      r5,r29
 379         mr      r6,r28
 380         mr      r7,r27
 381
 382         /* Do all of the interaction with OF client interface */
 383         mr      r8,r26
 384         bl      .prom_init
 385 #endif /* #CONFIG_PPC_OF_BOOT_TRAMPOLINE */
 386
 387         /* We never return. We also hit that trap if trying to boot
 388          * from OF while CONFIG_PPC_OF_BOOT_TRAMPOLINE isn't selected */
 389         trap
 390
 391 _STATIC(__after_prom_start)
 392 #ifdef CONFIG_RELOCATABLE
 393         /* process relocations for the final address of the kernel */
 394         lis     r25,PAGE_OFFSET@highest /* compute virtual base of kernel */
 395         sldi    r25,r25,32
 396         lwz     r7,__run_at_load-_stext(r26)
 397         cmplwi  cr0,r7,1        /* flagged to stay where we are ? */
 398         bne     1f
 399         add     r25,r25,r26
 400 1:      mr      r3,r25
 401         bl      .relocate
 402 #endif
 403
 404 /*
 405  * We need to run with _stext at physical address PHYSICAL_START.
 406  * This will leave some code in the first 256B of
 407  * real memory, which are reserved for software use.
 408  *
 409  * Note: This process overwrites the OF exception vectors.
 410  */
 411         li      r3,0                    /* target addr */
 412 #ifdef CONFIG_PPC_BOOK3E
 413         tovirt(r3,r3)                   /* on booke, we already run at PAGE_OFFSET */
 414 #endif
 415         mr.     r4,r26                  /* In some cases the loader may  */
 416         beq     9f                      /* have already put us at zero */
 417         li      r6,0x100                /* Start offset, the first 0x100 */
 418                                         /* bytes were copied earlier.    */
 419 #ifdef CONFIG_PPC_BOOK3E
 420         tovirt(r6,r6)                   /* on booke, we already run at PAGE_OFFSET */
 421 #endif
 422
 423 #ifdef CONFIG_CRASH_DUMP
 424 /*
 425  * Check if the kernel has to be running as relocatable kernel based on the
 426  * variable __run_at_load, if it is set the kernel is treated as relocatable
 427  * kernel, otherwise it will be moved to PHYSICAL_START
 428  */
 429         lwz     r7,__run_at_load-_stext(r26)
 430         cmplwi  cr0,r7,1
 431         bne     3f
 432
 433         li      r5,__end_interrupts - _stext    /* just copy interrupts */
 434         b       5f
 435 3:
 436 #endif
 437         lis     r5,(copy_to_here - _stext)@ha
 438         addi    r5,r5,(copy_to_here - _stext)@l /* # bytes of memory to copy */
 439
 440         bl      .copy_and_flush         /* copy the first n bytes        */
 441                                         /* this includes the code being  */
 442                                         /* executed here.                */
 443         addis   r8,r3,(4f - _stext)@ha  /* Jump to the copy of this code */
 444         addi    r8,r8,(4f - _stext)@l   /* that we just made */
 445         mtctr   r8
 446         bctr
 447
 448 p_end:  .llong  _end - _stext
 449
 450 4:      /* Now copy the rest of the kernel up to _end */
 451         addis   r5,r26,(p_end - _stext)@ha
 452         ld      r5,(p_end - _stext)@l(r5)       /* get _end */
 453 5:      bl      .copy_and_flush         /* copy the rest */
 454
 455 9:      b       .start_here_multiplatform
 456
 457 /*
 458  * Copy routine used to copy the kernel to start at physical address 0
 459  * and flush and invalidate the caches as needed.
 460  * r3 = dest addr, r4 = source addr, r5 = copy limit, r6 = start offset
 461  * on exit, r3, r4, r5 are unchanged, r6 is updated to be >= r5.
 462  *
 463  * Note: this routine *only* clobbers r0, r6 and lr
 464  */
 465 _GLOBAL(copy_and_flush)
 466         addi    r5,r5,-8
 467         addi    r6,r6,-8
 468 4:      li      r0,8                    /* Use the smallest common      */
 469                                         /* denominator cache line       */
 470                                         /* size.  This results in       */
 471                                         /* extra cache line flushes     */
 472                                         /* but operation is correct.    */
 473                                         /* Can't get cache line size    */
 474                                         /* from NACA as it is being     */
 475                                         /* moved too.                   */
 476
 477         mtctr   r0                      /* put # words/line in ctr      */
 478 3:      addi    r6,r6,8                 /* copy a cache line            */
 479         ldx     r0,r6,r4
 480         stdx    r0,r6,r3
 481         bdnz    3b
 482         dcbst   r6,r3                   /* write it to memory           */
 483         sync
 484         icbi    r6,r3                   /* flush the icache line        */
 485         cmpld   0,r6,r5
 486         blt     4b
 487         sync
 488         addi    r5,r5,8
 489         addi    r6,r6,8
 490         blr
 491
 492 .align 8
 493 copy_to_here:
 494
 495 #ifdef CONFIG_SMP
 496 #ifdef CONFIG_PPC_PMAC
 497 /*
 498  * On PowerMac, secondary processors starts from the reset vector, which
 499  * is temporarily turned into a call to one of the functions below.
 500  */
 501         .section ".text";
 502         .align 2 ;
 503
 504         .globl  __secondary_start_pmac_0
 505 __secondary_start_pmac_0:
 506         /* NB the entries for cpus 0, 1, 2 must each occupy 8 bytes. */
 507         li      r24,0
 508         b       1f
 509         li      r24,1
 510         b       1f
 511         li      r24,2
 512         b       1f
 513         li      r24,3
 514 1:
 515
 516 _GLOBAL(pmac_secondary_start)
 517         /* turn on 64-bit mode */
 518         bl      .enable_64b_mode
 519
 520         li      r0,0
 521         mfspr   r3,SPRN_HID4
 522         rldimi  r3,r0,40,23     /* clear bit 23 (rm_ci) */
 523         sync
 524         mtspr   SPRN_HID4,r3
 525         isync
 526         sync
 527         slbia
 528
 529         /* get TOC pointer (real address) */
 530         bl      .relative_toc
 531
 532         /* Copy some CPU settings from CPU 0 */
 533         bl      .__restore_cpu_ppc970
 534
 535         /* pSeries do that early though I don't think we really need it */
 536         mfmsr   r3
 537         ori     r3,r3,MSR_RI
 538         mtmsrd  r3                      /* RI on */
 539
 540         /* Set up a paca value for this processor. */
 541         LOAD_REG_ADDR(r4,paca)          /* Load paca pointer            */
 542         ld      r4,0(r4)                /* Get base vaddr of paca array */
 543         mulli   r13,r24,PACA_SIZE       /* Calculate vaddr of right paca */
 544         add     r13,r13,r4              /* for this processor.          */
 545         SET_PACA(r13)                   /* Save vaddr of paca in an SPRG*/
 546
 547         /* Mark interrupts soft and hard disabled (they might be enabled
 548          * in the PACA when doing hotplug)
 549          */
 550         li      r0,0
 551         stb     r0,PACASOFTIRQEN(r13)
 552         stb     r0,PACAHARDIRQEN(r13)
 553
 554         /* Create a temp kernel stack for use before relocation is on.  */
 555         ld      r1,PACAEMERGSP(r13)
 556         subi    r1,r1,STACK_FRAME_OVERHEAD
 557
 558         b       __secondary_start
 559
 560 #endif /* CONFIG_PPC_PMAC */
 561
 562 /*
 563  * This function is called after the master CPU has released the
 564  * secondary processors.  The execution environment is relocation off.
 565  * The paca for this processor has the following fields initialized at
 566  * this point:
 567  *   1. Processor number
 568  *   2. Segment table pointer (virtual address)
 569  * On entry the following are set:
 570  *   r1        = stack pointer.  vaddr for iSeries, raddr (temp stack) for pSeries
 571  *   r24       = cpu# (in Linux terms)
 572  *   r13       = paca virtual address
 573  *   SPRG_PACA = paca virtual address
 574  */
 575         .section ".text";
 576         .align 2 ;
 577
 578         .globl  __secondary_start
 579 __secondary_start:
 580         /* Set thread priority to MEDIUM */
 581         HMT_MEDIUM
 582
 583         /* Initialize the kernel stack.  Just a repeat for iSeries.      */
 584         LOAD_REG_ADDR(r3, current_set)
 585         sldi    r28,r24,3               /* get current_set[cpu#]         */
 586         ldx     r14,r3,r28
 587         addi    r14,r14,THREAD_SIZE-STACK_FRAME_OVERHEAD
 588         std     r14,PACAKSAVE(r13)
 589
 590         /* Do early setup for that CPU (stab, slb, hash table pointer) */
 591         bl      .early_setup_secondary
 592
 593         /*
 594          * setup the new stack pointer, but *don't* use this until
 595          * translation is on.
 596          */
 597         mr      r1, r14
 598
 599         /* Clear backchain so we get nice backtraces */
 600         li      r7,0
 601         mtlr    r7
 602
 603         /* enable MMU and jump to start_secondary */
 604         LOAD_REG_ADDR(r3, .start_secondary_prolog)
 605         LOAD_REG_IMMEDIATE(r4, MSR_KERNEL)
 606 #ifdef CONFIG_PPC_ISERIES
 607 BEGIN_FW_FTR_SECTION
 608         ori     r4,r4,MSR_EE
 609         li      r8,1
 610         stb     r8,PACAHARDIRQEN(r13)
 611 END_FW_FTR_SECTION_IFSET(FW_FEATURE_ISERIES)
 612 #endif
 613 BEGIN_FW_FTR_SECTION
 614         stb     r7,PACAHARDIRQEN(r13)
 615 END_FW_FTR_SECTION_IFCLR(FW_FEATURE_ISERIES)
 616         stb     r7,PACASOFTIRQEN(r13)
 617
 618         mtspr   SPRN_SRR0,r3
 619         mtspr   SPRN_SRR1,r4
 620         RFI
 621         b       .       /* prevent speculative execution */
 622
 623 /*
 624  * Running with relocation on at this point.  All we want to do is
 625  * zero the stack back-chain pointer and get the TOC virtual address
 626  * before going into C code.
 627  */
 628 _GLOBAL(start_secondary_prolog)
 629         ld      r2,PACATOC(r13)
 630         li      r3,0
 631         std     r3,0(r1)                /* Zero the stack frame pointer */
 632         bl      .start_secondary
 633         b       .
 634 /*
 635  * Reset stack pointer and call start_secondary
 636  * to continue with online operation when woken up
 637  * from cede in cpu offline.
 638  */
 639 _GLOBAL(start_secondary_resume)
 640         ld      r1,PACAKSAVE(r13)       /* Reload kernel stack pointer */
 641         li      r3,0
 642         std     r3,0(r1)                /* Zero the stack frame pointer */
 643         bl      .start_secondary
 644         b       .
 645 #endif
 646
 647 /*
 648  * This subroutine clobbers r11 and r12
 649  */
 650 _GLOBAL(enable_64b_mode)
 651         mfmsr   r11                     /* grab the current MSR */
 652 #ifdef CONFIG_PPC_BOOK3E
 653         oris    r11,r11,0x8000          /* CM bit set, we'll set ICM later */
 654         mtmsr   r11
 655 #else /* CONFIG_PPC_BOOK3E */
 656         li      r12,(MSR_SF | MSR_ISF)@highest
 657         sldi    r12,r12,48
 658         or      r11,r11,r12
 659         mtmsrd  r11
 660         isync
 661 #endif
 662         blr
 663
 664 /*
 665  * This puts the TOC pointer into r2, offset by 0x8000 (as expected
 666  * by the toolchain).  It computes the correct value for wherever we
 667  * are running at the moment, using position-independent code.
 668  */
 669 _GLOBAL(relative_toc)
 670         mflr    r0
 671         bcl     20,31,$+4
 672 0:      mflr    r9
 673         ld      r2,(p_toc - 0b)(r9)
 674         add     r2,r2,r9
 675         mtlr    r0
 676         blr
 677
 678 p_toc:  .llong  __toc_start + 0x8000 - 0b
 679
 680 /*
 681  * This is where the main kernel code starts.
 682  */
 683 _INIT_STATIC(start_here_multiplatform)
 684         /* set up the TOC (real address) */
 685         bl      .relative_toc
 686
 687         /* Clear out the BSS. It may have been done in prom_init,
 688          * already but that's irrelevant since prom_init will soon
 689          * be detached from the kernel completely. Besides, we need
 690          * to clear it now for kexec-style entry.
 691          */
 692         LOAD_REG_ADDR(r11,__bss_stop)
 693         LOAD_REG_ADDR(r8,__bss_start)
 694         sub     r11,r11,r8              /* bss size                     */
 695         addi    r11,r11,7               /* round up to an even double word */
 696         srdi.   r11,r11,3               /* shift right by 3             */
 697         beq     4f
 698         addi    r8,r8,-8
 699         li      r0,0
 700         mtctr   r11                     /* zero this many doublewords   */
 701 3:      stdu    r0,8(r8)
 702         bdnz    3b
 703 4:
 704
 705 #ifndef CONFIG_PPC_BOOK3E
 706         mfmsr   r6
 707         ori     r6,r6,MSR_RI
 708         mtmsrd  r6                      /* RI on */
 709 #endif
 710
 711 #ifdef CONFIG_RELOCATABLE
 712         /* Save the physical address we're running at in kernstart_addr */
 713         LOAD_REG_ADDR(r4, kernstart_addr)
 714         clrldi  r0,r25,2
 715         std     r0,0(r4)
 716 #endif
 717
 718         /* The following gets the stack set up with the regs */
 719         /* pointing to the real addr of the kernel stack.  This is   */
 720         /* all done to support the C function call below which sets  */
 721         /* up the htab.  This is done because we have relocated the  */
 722         /* kernel but are still running in real mode. */
 723
 724         LOAD_REG_ADDR(r3,init_thread_union)
 725
 726         /* set up a stack pointer */
 727         addi    r1,r3,THREAD_SIZE
 728         li      r0,0
 729         stdu    r0,-STACK_FRAME_OVERHEAD(r1)
 730
 731         /* Do very early kernel initializations, including initial hash table,
 732          * stab and slb setup before we turn on relocation.     */
 733
 734         /* Restore parameters passed from prom_init/kexec */
 735         mr      r3,r31
 736         bl      .early_setup            /* also sets r13 and SPRG_PACA */
 737
 738         LOAD_REG_ADDR(r3, .start_here_common)
 739         ld      r4,PACAKMSR(r13)
 740         mtspr   SPRN_SRR0,r3
 741         mtspr   SPRN_SRR1,r4
 742         RFI
 743         b       .       /* prevent speculative execution */
 744
 745         /* This is where all platforms converge execution */
 746 _INIT_GLOBAL(start_here_common)
 747         /* relocation is on at this point */
 748         std     r1,PACAKSAVE(r13)
 749
 750         /* Load the TOC (virtual address) */
 751         ld      r2,PACATOC(r13)
 752
 753         bl      .setup_system
 754
 755         /* Load up the kernel context */
 756 5:
 757         li      r5,0
 758         stb     r5,PACASOFTIRQEN(r13)   /* Soft Disabled */
 759 #ifdef CONFIG_PPC_ISERIES
 760 BEGIN_FW_FTR_SECTION
 761         mfmsr   r5
 762         ori     r5,r5,MSR_EE            /* Hard Enabled on iSeries*/
 763         mtmsrd  r5
 764         li      r5,1
 765 END_FW_FTR_SECTION_IFSET(FW_FEATURE_ISERIES)
 766 #endif
 767         stb     r5,PACAHARDIRQEN(r13)   /* Hard Disabled on others */
 768
 769         bl      .start_kernel
 770
 771         /* Not reached */
 772         BUG_OPCODE
 773
 774 /*
 775  * We put a few things here that have to be page-aligned.
 776  * This stuff goes at the beginning of the bss, which is page-aligned.
 777  */
 778         .section ".bss"
 779
 780         .align  PAGE_SHIFT
 781
 782         .globl  empty_zero_page
 783 empty_zero_page:
 784         .space  PAGE_SIZE
 785
 786         .globl  swapper_pg_dir
 787 swapper_pg_dir:
 788         .space  PGD_TABLE_SIZE