arch/powerpc/kernel/head_64.S

   1 /*
   2  *  PowerPC version
   3  *    Copyright (C) 1995-1996 Gary Thomas (gdt@linuxppc.org)
   4  *
   5  *  Rewritten by Cort Dougan (cort@cs.nmt.edu) for PReP
   6  *    Copyright (C) 1996 Cort Dougan <cort@cs.nmt.edu>
   7  *  Adapted for Power Macintosh by Paul Mackerras.
   8  *  Low-level exception handlers and MMU support
   9  *  rewritten by Paul Mackerras.
  10  *    Copyright (C) 1996 Paul Mackerras.
  11  *
  12  *  Adapted for 64bit PowerPC by Dave Engebretsen, Peter Bergner, and
  13  *    Mike Corrigan {engebret|bergner|mikejc}@us.ibm.com
  14  *
  15  *  This file contains the entry point for the 64-bit kernel along
  16  *  with some early initialization code common to all 64-bit powerpc
  17  *  variants.
  18  *
  19  *  This program is free software; you can redistribute it and/or
  20  *  modify it under the terms of the GNU General Public License
  21  *  as published by the Free Software Foundation; either version
  22  *  2 of the License, or (at your option) any later version.
  23  */
  24
  25 #include <linux/threads.h>
  26 #include <asm/reg.h>
  27 #include <asm/page.h>
  28 #include <asm/mmu.h>
  29 #include <asm/ppc_asm.h>
  30 #include <asm/asm-offsets.h>
  31 #include <asm/bug.h>
  32 #include <asm/cputable.h>
  33 #include <asm/setup.h>
  34 #include <asm/hvcall.h>
  35 #include <asm/iseries/lpar_map.h>
  36 #include <asm/thread_info.h>
  37 #include <asm/firmware.h>
  38 #include <asm/page_64.h>
  39 #include <asm/irqflags.h>
  40 #include <asm/kvm_book3s_asm.h>
  41 #include <asm/ptrace.h>
  42
  43 /* The physical memory is laid out such that the secondary processor
  44  * spin code sits at 0x0000...0x00ff. On server, the vectors follow
  45  * using the layout described in exceptions-64s.S
  46  */
  47
  48 /*
  49  * Entering into this code we make the following assumptions:
  50  *
  51  *  For pSeries or server processors:
  52  *   1. The MMU is off & open firmware is running in real mode.
  53  *   2. The kernel is entered at __start
  54  *
  55  *  For iSeries:
  56  *   1. The MMU is on (as it always is for iSeries)
  57  *   2. The kernel is entered at system_reset_iSeries
  58  *
  59  *  For Book3E processors:
  60  *   1. The MMU is on running in AS0 in a state defined in ePAPR
  61  *   2. The kernel is entered at __start
  62  */
  63
  64         .text
  65         .globl  _stext
  66 _stext:
  67 _GLOBAL(__start)
  68         /* NOP this out unconditionally */
  69 BEGIN_FTR_SECTION
  70         b       .__start_initialization_multiplatform
  71 END_FTR_SECTION(0, 1)
  72
  73         /* Catch branch to 0 in real mode */
  74         trap
  75
  76         /* Secondary processors spin on this value until it becomes nonzero.
  77          * When it does it contains the real address of the descriptor
  78          * of the function that the cpu should jump to to continue
  79          * initialization.
  80          */
  81         .globl  __secondary_hold_spinloop
  82 __secondary_hold_spinloop:
  83         .llong  0x0
  84
  85         /* Secondary processors write this value with their cpu # */
  86         /* after they enter the spin loop immediately below.      */
  87         .globl  __secondary_hold_acknowledge
  88 __secondary_hold_acknowledge:
  89         .llong  0x0
  90
  91 #ifdef CONFIG_PPC_ISERIES
  92         /*
  93          * At offset 0x20, there is a pointer to iSeries LPAR data.
  94          * This is required by the hypervisor
  95          */
  96         . = 0x20
  97         .llong hvReleaseData-KERNELBASE
  98 #endif /* CONFIG_PPC_ISERIES */
  99
 100 #ifdef CONFIG_RELOCATABLE
 101         /* This flag is set to 1 by a loader if the kernel should run
 102          * at the loaded address instead of the linked address.  This
 103          * is used by kexec-tools to keep the the kdump kernel in the
 104          * crash_kernel region.  The loader is responsible for
 105          * observing the alignment requirement.
 106          */
 107         /* Do not move this variable as kexec-tools knows about it. */
 108         . = 0x5c
 109         .globl  __run_at_load
 110 __run_at_load:
 111         .long   0x72756e30      /* "run0" -- relocate to 0 by default */
 112 #endif
 113
 114         . = 0x60
 115 /*
 116  * The following code is used to hold secondary processors
 117  * in a spin loop after they have entered the kernel, but
 118  * before the bulk of the kernel has been relocated.  This code
 119  * is relocated to physical address 0x60 before prom_init is run.
 120  * All of it must fit below the first exception vector at 0x100.
 121  * Use .globl here not _GLOBAL because we want __secondary_hold
 122  * to be the actual text address, not a descriptor.
 123  */
 124         .globl  __secondary_hold
 125 __secondary_hold:
 126 #ifndef CONFIG_PPC_BOOK3E
 127         mfmsr   r24
 128         ori     r24,r24,MSR_RI
 129         mtmsrd  r24                     /* RI on */
 130 #endif
 131         /* Grab our physical cpu number */
 132         mr      r24,r3
 133
 134         /* Tell the master cpu we're here */
 135         /* Relocation is off & we are located at an address less */
 136         /* than 0x100, so only need to grab low order offset.    */
 137         std     r24,__secondary_hold_acknowledge-_stext(0)
 138         sync
 139
 140         /* All secondary cpus wait here until told to start. */
 141 100:    ld      r4,__secondary_hold_spinloop-_stext(0)
 142         cmpdi   0,r4,0
 143         beq     100b
 144
 145 #if defined(CONFIG_SMP) || defined(CONFIG_KEXEC)
 146         ld      r4,0(r4)                /* deref function descriptor */
 147         mtctr   r4
 148         mr      r3,r24
 149         li      r4,0
 150         /* Make sure that patched code is visible */
 151         isync
 152         bctr
 153 #else
 154         BUG_OPCODE
 155 #endif
 156
 157 /* This value is used to mark exception frames on the stack. */
 158         .section ".toc","aw"
 159 exception_marker:
 160         .tc     ID_72656773_68657265[TC],0x7265677368657265
 161         .text
 162
 163 /*
 164  * On server, we include the exception vectors code here as it
 165  * relies on absolute addressing which is only possible within
 166  * this compilation unit
 167  */
 168 #ifdef CONFIG_PPC_BOOK3S
 169 #include "exceptions-64s.S"
 170 #endif
 171
 172 _GLOBAL(generic_secondary_thread_init)
 173         mr      r24,r3
 174
 175         /* turn on 64-bit mode */
 176         bl      .enable_64b_mode
 177
 178         /* get a valid TOC pointer, wherever we're mapped at */
 179         bl      .relative_toc
 180
 181 #ifdef CONFIG_PPC_BOOK3E
 182         /* Book3E initialization */
 183         mr      r3,r24
 184         bl      .book3e_secondary_thread_init
 185 #endif
 186         b       generic_secondary_common_init
 187
 188 /*
 189  * On pSeries and most other platforms, secondary processors spin
 190  * in the following code.
 191  * At entry, r3 = this processor's number (physical cpu id)
 192  *
 193  * On Book3E, r4 = 1 to indicate that the initial TLB entry for
 194  * this core already exists (setup via some other mechanism such
 195  * as SCOM before entry).
 196  */
 197 _GLOBAL(generic_secondary_smp_init)
 198         mr      r24,r3
 199         mr      r25,r4
 200
 201         /* turn on 64-bit mode */
 202         bl      .enable_64b_mode
 203
 204         /* get a valid TOC pointer, wherever we're mapped at */
 205         bl      .relative_toc
 206
 207 #ifdef CONFIG_PPC_BOOK3E
 208         /* Book3E initialization */
 209         mr      r3,r24
 210         mr      r4,r25
 211         bl      .book3e_secondary_core_init
 212 #endif
 213
 214 generic_secondary_common_init:
 215         /* Set up a paca value for this processor. Since we have the
 216          * physical cpu id in r24, we need to search the pacas to find
 217          * which logical id maps to our physical one.
 218          */
 219         LOAD_REG_ADDR(r13, paca)        /* Load paca pointer             */
 220         ld      r13,0(r13)              /* Get base vaddr of paca array  */
 221         li      r5,0                    /* logical cpu id                */
 222 1:      lhz     r6,PACAHWCPUID(r13)     /* Load HW procid from paca      */
 223         cmpw    r6,r24                  /* Compare to our id             */
 224         beq     2f
 225         addi    r13,r13,PACA_SIZE       /* Loop to next PACA on miss     */
 226         addi    r5,r5,1
 227         cmpwi   r5,NR_CPUS
 228         blt     1b
 229
 230         mr      r3,r24                  /* not found, copy phys to r3    */
 231         b       .kexec_wait             /* next kernel might do better   */
 232
 233 2:      SET_PACA(r13)
 234 #ifdef CONFIG_PPC_BOOK3E
 235         addi    r12,r13,PACA_EXTLB      /* and TLB exc frame in another  */
 236         mtspr   SPRN_SPRG_TLB_EXFRAME,r12
 237 #endif
 238
 239         /* From now on, r24 is expected to be logical cpuid */
 240         mr      r24,r5
 241
 242         /* See if we need to call a cpu state restore handler */
 243         LOAD_REG_ADDR(r23, cur_cpu_spec)
 244         ld      r23,0(r23)
 245         ld      r23,CPU_SPEC_RESTORE(r23)
 246         cmpdi   0,r23,0
 247         beq     3f
 248         ld      r23,0(r23)
 249         mtctr   r23
 250         bctrl
 251
 252 3:      LOAD_REG_ADDR(r3, boot_cpu_count) /* Decrement boot_cpu_count */
 253         lwarx   r4,0,r3
 254         subi    r4,r4,1
 255         stwcx.  r4,0,r3
 256         bne     3b
 257         isync
 258
 259 4:      HMT_LOW
 260         lbz     r23,PACAPROCSTART(r13)  /* Test if this processor should */
 261                                         /* start.                        */
 262 #ifndef CONFIG_SMP
 263         b       4b                      /* Never go on non-SMP           */
 264 #else
 265         cmpwi   0,r23,0
 266         beq     4b                      /* Loop until told to go         */
 267
 268         sync                            /* order paca.run and cur_cpu_spec */
 269         isync                           /* In case code patching happened */
 270
 271         /* Create a temp kernel stack for use before relocation is on.  */
 272         ld      r1,PACAEMERGSP(r13)
 273         subi    r1,r1,STACK_FRAME_OVERHEAD
 274
 275         b       __secondary_start
 276 #endif
 277
 278 /*
 279  * Turn the MMU off.
 280  * Assumes we're mapped EA == RA if the MMU is on.
 281  */
 282 #ifdef CONFIG_PPC_BOOK3S
 283 _STATIC(__mmu_off)
 284         mfmsr   r3
 285         andi.   r0,r3,MSR_IR|MSR_DR
 286         beqlr
 287         mflr    r4
 288         andc    r3,r3,r0
 289         mtspr   SPRN_SRR0,r4
 290         mtspr   SPRN_SRR1,r3
 291         sync
 292         rfid
 293         b       .       /* prevent speculative execution */
 294 #endif
 295
 296
 297 /*
 298  * Here is our main kernel entry point. We support currently 2 kind of entries
 299  * depending on the value of r5.
 300  *
 301  *   r5 != NULL -> OF entry, we go to prom_init, "legacy" parameter content
 302  *                 in r3...r7
 303  *
 304  *   r5 == NULL -> kexec style entry. r3 is a physical pointer to the
 305  *                 DT block, r4 is a physical pointer to the kernel itself
 306  *
 307  */
 308 _GLOBAL(__start_initialization_multiplatform)
 309         /* Make sure we are running in 64 bits mode */
 310         bl      .enable_64b_mode
 311
 312         /* Get TOC pointer (current runtime address) */
 313         bl      .relative_toc
 314
 315         /* find out where we are now */
 316         bcl     20,31,$+4
 317 0:      mflr    r26                     /* r26 = runtime addr here */
 318         addis   r26,r26,(_stext - 0b)@ha
 319         addi    r26,r26,(_stext - 0b)@l /* current runtime base addr */
 320
 321         /*
 322          * Are we booted from a PROM Of-type client-interface ?
 323          */
 324         cmpldi  cr0,r5,0
 325         beq     1f
 326         b       .__boot_from_prom               /* yes -> prom */
 327 1:
 328         /* Save parameters */
 329         mr      r31,r3
 330         mr      r30,r4
 331
 332 #ifdef CONFIG_PPC_BOOK3E
 333         bl      .start_initialization_book3e
 334         b       .__after_prom_start
 335 #else
 336         /* Setup some critical 970 SPRs before switching MMU off */
 337         mfspr   r0,SPRN_PVR
 338         srwi    r0,r0,16
 339         cmpwi   r0,0x39         /* 970 */
 340         beq     1f
 341         cmpwi   r0,0x3c         /* 970FX */
 342         beq     1f
 343         cmpwi   r0,0x44         /* 970MP */
 344         beq     1f
 345         cmpwi   r0,0x45         /* 970GX */
 346         bne     2f
 347 1:      bl      .__cpu_preinit_ppc970
 348 2:
 349
 350         /* Switch off MMU if not already off */
 351         bl      .__mmu_off
 352         b       .__after_prom_start
 353 #endif /* CONFIG_PPC_BOOK3E */
 354
 355 _INIT_STATIC(__boot_from_prom)
 356 #ifdef CONFIG_PPC_OF_BOOT_TRAMPOLINE
 357         /* Save parameters */
 358         mr      r31,r3
 359         mr      r30,r4
 360         mr      r29,r5
 361         mr      r28,r6
 362         mr      r27,r7
 363
 364         /*
 365          * Align the stack to 16-byte boundary
 366          * Depending on the size and layout of the ELF sections in the initial
 367          * boot binary, the stack pointer may be unaligned on PowerMac
 368          */
 369         rldicr  r1,r1,0,59
 370
 371 #ifdef CONFIG_RELOCATABLE
 372         /* Relocate code for where we are now */
 373         mr      r3,r26
 374         bl      .relocate
 375 #endif
 376
 377         /* Restore parameters */
 378         mr      r3,r31
 379         mr      r4,r30
 380         mr      r5,r29
 381         mr      r6,r28
 382         mr      r7,r27
 383
 384         /* Do all of the interaction with OF client interface */
 385         mr      r8,r26
 386         bl      .prom_init
 387 #endif /* #CONFIG_PPC_OF_BOOT_TRAMPOLINE */
 388
 389         /* We never return. We also hit that trap if trying to boot
 390          * from OF while CONFIG_PPC_OF_BOOT_TRAMPOLINE isn't selected */
 391         trap
 392
 393 _STATIC(__after_prom_start)
 394 #ifdef CONFIG_RELOCATABLE
 395         /* process relocations for the final address of the kernel */
 396         lis     r25,PAGE_OFFSET@highest /* compute virtual base of kernel */
 397         sldi    r25,r25,32
 398         lwz     r7,__run_at_load-_stext(r26)
 399         cmplwi  cr0,r7,1        /* flagged to stay where we are ? */
 400         bne     1f
 401         add     r25,r25,r26
 402 1:      mr      r3,r25
 403         bl      .relocate
 404 #endif
 405
 406 /*
 407  * We need to run with _stext at physical address PHYSICAL_START.
 408  * This will leave some code in the first 256B of
 409  * real memory, which are reserved for software use.
 410  *
 411  * Note: This process overwrites the OF exception vectors.
 412  */
 413         li      r3,0                    /* target addr */
 414 #ifdef CONFIG_PPC_BOOK3E
 415         tovirt(r3,r3)                   /* on booke, we already run at PAGE_OFFSET */
 416 #endif
 417         mr.     r4,r26                  /* In some cases the loader may  */
 418         beq     9f                      /* have already put us at zero */
 419         li      r6,0x100                /* Start offset, the first 0x100 */
 420                                         /* bytes were copied earlier.    */
 421 #ifdef CONFIG_PPC_BOOK3E
 422         tovirt(r6,r6)                   /* on booke, we already run at PAGE_OFFSET */
 423 #endif
 424
 425 #ifdef CONFIG_CRASH_DUMP
 426 /*
 427  * Check if the kernel has to be running as relocatable kernel based on the
 428  * variable __run_at_load, if it is set the kernel is treated as relocatable
 429  * kernel, otherwise it will be moved to PHYSICAL_START
 430  */
 431         lwz     r7,__run_at_load-_stext(r26)
 432         cmplwi  cr0,r7,1
 433         bne     3f
 434
 435         li      r5,__end_interrupts - _stext    /* just copy interrupts */
 436         b       5f
 437 3:
 438 #endif
 439         lis     r5,(copy_to_here - _stext)@ha
 440         addi    r5,r5,(copy_to_here - _stext)@l /* # bytes of memory to copy */
 441
 442         bl      .copy_and_flush         /* copy the first n bytes        */
 443                                         /* this includes the code being  */
 444                                         /* executed here.                */
 445         addis   r8,r3,(4f - _stext)@ha  /* Jump to the copy of this code */
 446         addi    r8,r8,(4f - _stext)@l   /* that we just made */
 447         mtctr   r8
 448         bctr
 449
 450 p_end:  .llong  _end - _stext
 451
 452 4:      /* Now copy the rest of the kernel up to _end */
 453         addis   r5,r26,(p_end - _stext)@ha
 454         ld      r5,(p_end - _stext)@l(r5)       /* get _end */
 455 5:      bl      .copy_and_flush         /* copy the rest */
 456
 457 9:      b       .start_here_multiplatform
 458
 459 /*
 460  * Copy routine used to copy the kernel to start at physical address 0
 461  * and flush and invalidate the caches as needed.
 462  * r3 = dest addr, r4 = source addr, r5 = copy limit, r6 = start offset
 463  * on exit, r3, r4, r5 are unchanged, r6 is updated to be >= r5.
 464  *
 465  * Note: this routine *only* clobbers r0, r6 and lr
 466  */
 467 _GLOBAL(copy_and_flush)
 468         addi    r5,r5,-8
 469         addi    r6,r6,-8
 470 4:      li      r0,8                    /* Use the smallest common      */
 471                                         /* denominator cache line       */
 472                                         /* size.  This results in       */
 473                                         /* extra cache line flushes     */
 474                                         /* but operation is correct.    */
 475                                         /* Can't get cache line size    */
 476                                         /* from NACA as it is being     */
 477                                         /* moved too.                   */
 478
 479         mtctr   r0                      /* put # words/line in ctr      */
 480 3:      addi    r6,r6,8                 /* copy a cache line            */
 481         ldx     r0,r6,r4
 482         stdx    r0,r6,r3
 483         bdnz    3b
 484         dcbst   r6,r3                   /* write it to memory           */
 485         sync
 486         icbi    r6,r3                   /* flush the icache line        */
 487         cmpld   0,r6,r5
 488         blt     4b
 489         sync
 490         addi    r5,r5,8
 491         addi    r6,r6,8
 492         blr
 493
 494 .align 8
 495 copy_to_here:
 496
 497 #ifdef CONFIG_SMP
 498 #ifdef CONFIG_PPC_PMAC
 499 /*
 500  * On PowerMac, secondary processors starts from the reset vector, which
 501  * is temporarily turned into a call to one of the functions below.
 502  */
 503         .section ".text";
 504         .align 2 ;
 505
 506         .globl  __secondary_start_pmac_0
 507 __secondary_start_pmac_0:
 508         /* NB the entries for cpus 0, 1, 2 must each occupy 8 bytes. */
 509         li      r24,0
 510         b       1f
 511         li      r24,1
 512         b       1f
 513         li      r24,2
 514         b       1f
 515         li      r24,3
 516 1:
 517
 518 _GLOBAL(pmac_secondary_start)
 519         /* turn on 64-bit mode */
 520         bl      .enable_64b_mode
 521
 522         li      r0,0
 523         mfspr   r3,SPRN_HID4
 524         rldimi  r3,r0,40,23     /* clear bit 23 (rm_ci) */
 525         sync
 526         mtspr   SPRN_HID4,r3
 527         isync
 528         sync
 529         slbia
 530
 531         /* get TOC pointer (real address) */
 532         bl      .relative_toc
 533
 534         /* Copy some CPU settings from CPU 0 */
 535         bl      .__restore_cpu_ppc970
 536
 537         /* pSeries do that early though I don't think we really need it */
 538         mfmsr   r3
 539         ori     r3,r3,MSR_RI
 540         mtmsrd  r3                      /* RI on */
 541
 542         /* Set up a paca value for this processor. */
 543         LOAD_REG_ADDR(r4,paca)          /* Load paca pointer            */
 544         ld      r4,0(r4)                /* Get base vaddr of paca array */
 545         mulli   r13,r24,PACA_SIZE       /* Calculate vaddr of right paca */
 546         add     r13,r13,r4              /* for this processor.          */
 547         SET_PACA(r13)                   /* Save vaddr of paca in an SPRG*/
 548
 549         /* Mark interrupts soft and hard disabled (they might be enabled
 550          * in the PACA when doing hotplug)
 551          */
 552         li      r0,0
 553         stb     r0,PACASOFTIRQEN(r13)
 554         stb     r0,PACAHARDIRQEN(r13)
 555
 556         /* Create a temp kernel stack for use before relocation is on.  */
 557         ld      r1,PACAEMERGSP(r13)
 558         subi    r1,r1,STACK_FRAME_OVERHEAD
 559
 560         b       __secondary_start
 561
 562 #endif /* CONFIG_PPC_PMAC */
 563
 564 /*
 565  * This function is called after the master CPU has released the
 566  * secondary processors.  The execution environment is relocation off.
 567  * The paca for this processor has the following fields initialized at
 568  * this point:
 569  *   1. Processor number
 570  *   2. Segment table pointer (virtual address)
 571  * On entry the following are set:
 572  *   r1        = stack pointer.  vaddr for iSeries, raddr (temp stack) for pSeries
 573  *   r24       = cpu# (in Linux terms)
 574  *   r13       = paca virtual address
 575  *   SPRG_PACA = paca virtual address
 576  */
 577         .section ".text";
 578         .align 2 ;
 579
 580         .globl  __secondary_start
 581 __secondary_start:
 582         /* Set thread priority to MEDIUM */
 583         HMT_MEDIUM
 584
 585         /* Initialize the kernel stack.  Just a repeat for iSeries.      */
 586         LOAD_REG_ADDR(r3, current_set)
 587         sldi    r28,r24,3               /* get current_set[cpu#]         */
 588         ldx     r14,r3,r28
 589         addi    r14,r14,THREAD_SIZE-STACK_FRAME_OVERHEAD
 590         std     r14,PACAKSAVE(r13)
 591
 592         /* Do early setup for that CPU (stab, slb, hash table pointer) */
 593         bl      .early_setup_secondary
 594
 595         /*
 596          * setup the new stack pointer, but *don't* use this until
 597          * translation is on.
 598          */
 599         mr      r1, r14
 600
 601         /* Clear backchain so we get nice backtraces */
 602         li      r7,0
 603         mtlr    r7
 604
 605         /* enable MMU and jump to start_secondary */
 606         LOAD_REG_ADDR(r3, .start_secondary_prolog)
 607         LOAD_REG_IMMEDIATE(r4, MSR_KERNEL)
 608 #ifdef CONFIG_PPC_ISERIES
 609 BEGIN_FW_FTR_SECTION
 610         ori     r4,r4,MSR_EE
 611         li      r8,1
 612         stb     r8,PACAHARDIRQEN(r13)
 613 END_FW_FTR_SECTION_IFSET(FW_FEATURE_ISERIES)
 614 #endif
 615 BEGIN_FW_FTR_SECTION
 616         stb     r7,PACAHARDIRQEN(r13)
 617 END_FW_FTR_SECTION_IFCLR(FW_FEATURE_ISERIES)
 618         stb     r7,PACASOFTIRQEN(r13)
 619
 620         mtspr   SPRN_SRR0,r3
 621         mtspr   SPRN_SRR1,r4
 622         RFI
 623         b       .       /* prevent speculative execution */
 624
 625 /*
 626  * Running with relocation on at this point.  All we want to do is
 627  * zero the stack back-chain pointer and get the TOC virtual address
 628  * before going into C code.
 629  */
 630 _GLOBAL(start_secondary_prolog)
 631         ld      r2,PACATOC(r13)
 632         li      r3,0
 633         std     r3,0(r1)                /* Zero the stack frame pointer */
 634         bl      .start_secondary
 635         b       .
 636 /*
 637  * Reset stack pointer and call start_secondary
 638  * to continue with online operation when woken up
 639  * from cede in cpu offline.
 640  */
 641 _GLOBAL(start_secondary_resume)
 642         ld      r1,PACAKSAVE(r13)       /* Reload kernel stack pointer */
 643         li      r3,0
 644         std     r3,0(r1)                /* Zero the stack frame pointer */
 645         bl      .start_secondary
 646         b       .
 647 #endif
 648
 649 /*
 650  * This subroutine clobbers r11 and r12
 651  */
 652 _GLOBAL(enable_64b_mode)
 653         mfmsr   r11                     /* grab the current MSR */
 654 #ifdef CONFIG_PPC_BOOK3E
 655         oris    r11,r11,0x8000          /* CM bit set, we'll set ICM later */
 656         mtmsr   r11
 657 #else /* CONFIG_PPC_BOOK3E */
 658         li      r12,(MSR_SF | MSR_ISF)@highest
 659         sldi    r12,r12,48
 660         or      r11,r11,r12
 661         mtmsrd  r11
 662         isync
 663 #endif
 664         blr
 665
 666 /*
 667  * This puts the TOC pointer into r2, offset by 0x8000 (as expected
 668  * by the toolchain).  It computes the correct value for wherever we
 669  * are running at the moment, using position-independent code.
 670  */
 671 _GLOBAL(relative_toc)
 672         mflr    r0
 673         bcl     20,31,$+4
 674 0:      mflr    r9
 675         ld      r2,(p_toc - 0b)(r9)
 676         add     r2,r2,r9
 677         mtlr    r0
 678         blr
 679
 680 p_toc:  .llong  __toc_start + 0x8000 - 0b
 681
 682 /*
 683  * This is where the main kernel code starts.
 684  */
 685 _INIT_STATIC(start_here_multiplatform)
 686         /* set up the TOC (real address) */
 687         bl      .relative_toc
 688
 689         /* Clear out the BSS. It may have been done in prom_init,
 690          * already but that's irrelevant since prom_init will soon
 691          * be detached from the kernel completely. Besides, we need
 692          * to clear it now for kexec-style entry.
 693          */
 694         LOAD_REG_ADDR(r11,__bss_stop)
 695         LOAD_REG_ADDR(r8,__bss_start)
 696         sub     r11,r11,r8              /* bss size                     */
 697         addi    r11,r11,7               /* round up to an even double word */
 698         srdi.   r11,r11,3               /* shift right by 3             */
 699         beq     4f
 700         addi    r8,r8,-8
 701         li      r0,0
 702         mtctr   r11                     /* zero this many doublewords   */
 703 3:      stdu    r0,8(r8)
 704         bdnz    3b
 705 4:
 706
 707 #ifndef CONFIG_PPC_BOOK3E
 708         mfmsr   r6
 709         ori     r6,r6,MSR_RI
 710         mtmsrd  r6                      /* RI on */
 711 #endif
 712
 713 #ifdef CONFIG_RELOCATABLE
 714         /* Save the physical address we're running at in kernstart_addr */
 715         LOAD_REG_ADDR(r4, kernstart_addr)
 716         clrldi  r0,r25,2
 717         std     r0,0(r4)
 718 #endif
 719
 720         /* The following gets the stack set up with the regs */
 721         /* pointing to the real addr of the kernel stack.  This is   */
 722         /* all done to support the C function call below which sets  */
 723         /* up the htab.  This is done because we have relocated the  */
 724         /* kernel but are still running in real mode. */
 725
 726         LOAD_REG_ADDR(r3,init_thread_union)
 727
 728         /* set up a stack pointer */
 729         addi    r1,r3,THREAD_SIZE
 730         li      r0,0
 731         stdu    r0,-STACK_FRAME_OVERHEAD(r1)
 732
 733         /* Do very early kernel initializations, including initial hash table,
 734          * stab and slb setup before we turn on relocation.     */
 735
 736         /* Restore parameters passed from prom_init/kexec */
 737         mr      r3,r31
 738         bl      .early_setup            /* also sets r13 and SPRG_PACA */
 739
 740         LOAD_REG_ADDR(r3, .start_here_common)
 741         ld      r4,PACAKMSR(r13)
 742         mtspr   SPRN_SRR0,r3
 743         mtspr   SPRN_SRR1,r4
 744         RFI
 745         b       .       /* prevent speculative execution */
 746
 747         /* This is where all platforms converge execution */
 748 _INIT_GLOBAL(start_here_common)
 749         /* relocation is on at this point */
 750         std     r1,PACAKSAVE(r13)
 751
 752         /* Load the TOC (virtual address) */
 753         ld      r2,PACATOC(r13)
 754
 755         bl      .setup_system
 756
 757         /* Load up the kernel context */
 758 5:
 759         li      r5,0
 760         stb     r5,PACASOFTIRQEN(r13)   /* Soft Disabled */
 761 #ifdef CONFIG_PPC_ISERIES
 762 BEGIN_FW_FTR_SECTION
 763         mfmsr   r5
 764         ori     r5,r5,MSR_EE            /* Hard Enabled on iSeries*/
 765         mtmsrd  r5
 766         li      r5,1
 767 END_FW_FTR_SECTION_IFSET(FW_FEATURE_ISERIES)
 768 #endif
 769         stb     r5,PACAHARDIRQEN(r13)   /* Hard Disabled on others */
 770
 771         bl      .start_kernel
 772
 773         /* Not reached */
 774         BUG_OPCODE
 775
 776 /*
 777  * We put a few things here that have to be page-aligned.
 778  * This stuff goes at the beginning of the bss, which is page-aligned.
 779  */
 780         .section ".bss"
 781
 782         .align  PAGE_SHIFT
 783
 784         .globl  empty_zero_page
 785 empty_zero_page:
 786         .space  PAGE_SIZE
 787
 788         .globl  swapper_pg_dir
 789 swapper_pg_dir:
 790         .space  PGD_TABLE_SIZE