arch/parisc/kernel/vmlinux.lds.S

   1 /*    Kernel link layout for various "sections"
   2  *
   3  *    Copyright (C) 1999-2003 Matthew Wilcox <willy at parisc-linux.org>
   4  *    Copyright (C) 2000-2003 Paul Bame <bame at parisc-linux.org>
   5  *    Copyright (C) 2000 John Marvin <jsm at parisc-linux.org>
   6  *    Copyright (C) 2000 Michael Ang <mang with subcarrier.org>
   7  *    Copyright (C) 2002 Randolph Chung <tausq with parisc-linux.org>
   8  *    Copyright (C) 2003 James Bottomley <jejb with parisc-linux.org>
   9  *    Copyright (C) 2006 Helge Deller <deller@gmx.de>
  10  *
  11  *
  12  *    This program is free software; you can redistribute it and/or modify
  13  *    it under the terms of the GNU General Public License as published by
  14  *    the Free Software Foundation; either version 2 of the License, or
  15  *    (at your option) any later version.
  16  *
  17  *    This program is distributed in the hope that it will be useful,
  18  *    but WITHOUT ANY WARRANTY; without even the implied warranty of
  19  *    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20  *    GNU General Public License for more details.
  21  *
  22  *    You should have received a copy of the GNU General Public License
  23  *    along with this program; if not, write to the Free Software
  24  *    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  25  */
  26 #include <asm-generic/vmlinux.lds.h>
  27 /* needed for the processor specific cache alignment size */
  28 #include <asm/cache.h>
  29 #include <asm/page.h>
  30 #include <asm/asm-offsets.h>
  31
  32 /* ld script to make hppa Linux kernel */
  33 #ifndef CONFIG_64BIT
  34 OUTPUT_FORMAT("elf32-hppa-linux")
  35 OUTPUT_ARCH(hppa)
  36 #else
  37 OUTPUT_FORMAT("elf64-hppa-linux")
  38 OUTPUT_ARCH(hppa:hppa2.0w)
  39 #endif
  40
  41 ENTRY(_stext)
  42 #ifndef CONFIG_64BIT
  43 jiffies = jiffies_64 + 4;
  44 #else
  45 jiffies = jiffies_64;
  46 #endif
  47 SECTIONS
  48 {
  49         . = KERNEL_BINARY_TEXT_START;
  50
  51         _text = .;              /* Text and read-only data */
  52         .text ALIGN(16) : {
  53                 HEAD_TEXT
  54                 TEXT_TEXT
  55                 SCHED_TEXT
  56                 LOCK_TEXT
  57                 *(.text.do_softirq)
  58                 *(.text.sys_exit)
  59                 *(.text.do_sigaltstack)
  60                 *(.text.do_fork)
  61                 *(.text.*)
  62                 *(.fixup)
  63                 *(.lock.text)           /* out-of-line lock text */
  64                 *(.gnu.warning)
  65         } = 0
  66         /* End of text section */
  67         _etext = .;
  68
  69         RODATA
  70         BUG_TABLE
  71
  72         /* writeable */
  73         /* Make sure this is page aligned so
  74          * that we can properly leave these
  75          * as writable
  76          */
  77         . = ALIGN(PAGE_SIZE);
  78         data_start = .;
  79         . = ALIGN(16);
  80         /* Exception table */
  81         __ex_table : {
  82                 __start___ex_table = .;
  83                 *(__ex_table)
  84                 __stop___ex_table = .;
  85         }
  86
  87         NOTES
  88
  89         /* unwind info */
  90         .PARISC.unwind : {
  91                 __start___unwind = .;
  92                 *(.PARISC.unwind)
  93                 __stop___unwind = .;
  94         }
  95
  96         /* rarely changed data like cpu maps */
  97         . = ALIGN(16);
  98         .data.read_mostly : {
  99                 *(.data.read_mostly)
 100         }
 101
 102         . = ALIGN(L1_CACHE_BYTES);
 103         /* Data */
 104         .data : {
 105                 DATA_DATA
 106                 CONSTRUCTORS
 107         }
 108
 109         . = ALIGN(L1_CACHE_BYTES);
 110         .data.cacheline_aligned : {
 111                 *(.data.cacheline_aligned)
 112         }
 113
 114         /* PA-RISC locks requires 16-byte alignment */
 115         . = ALIGN(16);
 116         .data.lock_aligned : {
 117                 *(.data.lock_aligned)
 118         }
 119
 120         /* nosave data is really only used for software suspend...it's here
 121          * just in case we ever implement it
 122          */
 123         . = ALIGN(PAGE_SIZE);
 124         __nosave_begin = .;
 125         .data_nosave : {
 126                 *(.data.nosave)
 127         }
 128         . = ALIGN(PAGE_SIZE);
 129         __nosave_end = .;
 130
 131         /* End of data section */
 132         _edata = .;
 133
 134         /* BSS */
 135         __bss_start = .;
 136         /* page table entries need to be PAGE_SIZE aligned */
 137         . = ALIGN(PAGE_SIZE);
 138         .data.vmpages : {
 139                 *(.data.vm0.pmd)
 140                 *(.data.vm0.pgd)
 141                 *(.data.vm0.pte)
 142         }
 143         .bss : {
 144                 *(.bss)
 145                 *(COMMON)
 146         }
 147         __bss_stop = .;
 148
 149
 150         /* assembler code expects init_task to be 16k aligned */
 151         . = ALIGN(16384);
 152         /* init_task */
 153         .data.init_task : {
 154                 *(.data.init_task)
 155         }
 156
 157 #ifdef CONFIG_64BIT
 158         . = ALIGN(16);
 159         /* Linkage tables */
 160         .opd : {
 161                 *(.opd)
 162         } PROVIDE (__gp = .);
 163         .plt : {
 164                 *(.plt)
 165         }
 166         .dlt : {
 167                 *(.dlt)
 168         }
 169 #endif
 170
 171         /* reserve space for interrupt stack by aligning __init* to 16k */
 172         . = ALIGN(16384);
 173         __init_begin = .;
 174         .init.text : {
 175                 _sinittext = .;
 176                 INIT_TEXT
 177                 _einittext = .;
 178         }
 179         .init.data : {
 180                 INIT_DATA
 181         }
 182         . = ALIGN(16);
 183         .init.setup : {
 184                 __setup_start = .;
 185                 *(.init.setup)
 186                 __setup_end = .;
 187         }
 188         .initcall.init : {
 189                 __initcall_start = .;
 190                 INITCALLS
 191                 __initcall_end = .;
 192         }
 193         .con_initcall.init : {
 194                 __con_initcall_start = .;
 195                 *(.con_initcall.init)
 196                 __con_initcall_end = .;
 197         }
 198         SECURITY_INIT
 199
 200         /* alternate instruction replacement.  This is a mechanism x86 uses
 201          * to detect the CPU type and replace generic instruction sequences
 202          * with CPU specific ones.  We don't currently do this in PA, but
 203          * it seems like a good idea...
 204          */
 205         . = ALIGN(4);
 206         .altinstructions : {
 207                 __alt_instructions = .;
 208                 *(.altinstructions)
 209                 __alt_instructions_end = .;
 210         }
 211         .altinstr_replacement : {
 212                 *(.altinstr_replacement)
 213         }
 214
 215         /* .exit.text is discard at runtime, not link time, to deal with references
 216          *  from .altinstructions and .eh_frame
 217          */
 218         .exit.text : {
 219                 EXIT_TEXT
 220         }
 221         .exit.data : {
 222                 EXIT_DATA
 223         }
 224 #ifdef CONFIG_BLK_DEV_INITRD
 225         . = ALIGN(PAGE_SIZE);
 226         .init.ramfs : {
 227                 __initramfs_start = .;
 228                 *(.init.ramfs)
 229                 __initramfs_end = .;
 230         }
 231 #endif
 232
 233         PERCPU(PAGE_SIZE)
 234         . = ALIGN(PAGE_SIZE);
 235         __init_end = .;
 236         /* freed after init ends here */
 237         _end = . ;
 238
 239         /* Sections to be discarded */
 240         /DISCARD/ : {
 241                 *(.exitcall.exit)
 242 #ifdef CONFIG_64BIT
 243                 /* temporary hack until binutils is fixed to not emit these
 244                  * for static binaries
 245                  */
 246                 *(.interp)
 247                 *(.dynsym)
 248                 *(.dynstr)
 249                 *(.dynamic)
 250                 *(.hash)
 251                 *(.gnu.hash)
 252 #endif
 253         }
 254
 255         STABS_DEBUG
 256         .note 0 : { *(.note) }
 257 }