arch/mips/kernel/genex.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * Copyright (C) 1994 - 2000, 2001, 2003 Ralf Baechle
   7  * Copyright (C) 1999, 2000 Silicon Graphics, Inc.
   8  * Copyright (C) 2001 MIPS Technologies, Inc.
   9  * Copyright (C) 2002 Maciej W. Rozycki
  10  */
  11 #include <linux/init.h>
  12
  13 #include <asm/asm.h>
  14 #include <asm/asmmacro.h>
  15 #include <asm/cacheops.h>
  16 #include <asm/irqflags.h>
  17 #include <asm/regdef.h>
  18 #include <asm/fpregdef.h>
  19 #include <asm/mipsregs.h>
  20 #include <asm/stackframe.h>
  21 #include <asm/war.h>
  22
  23 #define PANIC_PIC(msg)                                  \
  24                 .set push;                              \
  25                 .set    reorder;                        \
  26                 PTR_LA  a0,8f;                          \
  27                 .set    noat;                           \
  28                 PTR_LA  AT, panic;                      \
  29                 jr      AT;                             \
  30 9:              b       9b;                             \
  31                 .set    pop;                            \
  32                 TEXT(msg)
  33
  34         __INIT
  35
  36 NESTED(except_vec0_generic, 0, sp)
  37         PANIC_PIC("Exception vector 0 called")
  38         END(except_vec0_generic)
  39
  40 NESTED(except_vec1_generic, 0, sp)
  41         PANIC_PIC("Exception vector 1 called")
  42         END(except_vec1_generic)
  43
  44 /*
  45  * General exception vector for all other CPUs.
  46  *
  47  * Be careful when changing this, it has to be at most 128 bytes
  48  * to fit into space reserved for the exception handler.
  49  */
  50 NESTED(except_vec3_generic, 0, sp)
  51         .set    push
  52         .set    noat
  53 #if R5432_CP0_INTERRUPT_WAR
  54         mfc0    k0, CP0_INDEX
  55 #endif
  56         mfc0    k1, CP0_CAUSE
  57         andi    k1, k1, 0x7c
  58 #ifdef CONFIG_64BIT
  59         dsll    k1, k1, 1
  60 #endif
  61         PTR_L   k0, exception_handlers(k1)
  62         jr      k0
  63         .set    pop
  64         END(except_vec3_generic)
  65
  66 /*
  67  * General exception handler for CPUs with virtual coherency exception.
  68  *
  69  * Be careful when changing this, it has to be at most 256 (as a special
  70  * exception) bytes to fit into space reserved for the exception handler.
  71  */
  72 NESTED(except_vec3_r4000, 0, sp)
  73         .set    push
  74         .set    mips3
  75         .set    noat
  76         mfc0    k1, CP0_CAUSE
  77         li      k0, 31<<2
  78         andi    k1, k1, 0x7c
  79         .set    push
  80         .set    noreorder
  81         .set    nomacro
  82         beq     k1, k0, handle_vced
  83          li     k0, 14<<2
  84         beq     k1, k0, handle_vcei
  85 #ifdef CONFIG_64BIT
  86          dsll   k1, k1, 1
  87 #endif
  88         .set    pop
  89         PTR_L   k0, exception_handlers(k1)
  90         jr      k0
  91
  92         /*
  93          * Big shit, we now may have two dirty primary cache lines for the same
  94          * physical address.  We can safely invalidate the line pointed to by
  95          * c0_badvaddr because after return from this exception handler the
  96          * load / store will be re-executed.
  97          */
  98 handle_vced:
  99         MFC0    k0, CP0_BADVADDR
 100         li      k1, -4                                  # Is this ...
 101         and     k0, k1                                  # ... really needed?
 102         mtc0    zero, CP0_TAGLO
 103         cache   Index_Store_Tag_D, (k0)
 104         cache   Hit_Writeback_Inv_SD, (k0)
 105 #ifdef CONFIG_PROC_FS
 106         PTR_LA  k0, vced_count
 107         lw      k1, (k0)
 108         addiu   k1, 1
 109         sw      k1, (k0)
 110 #endif
 111         eret
 112
 113 handle_vcei:
 114         MFC0    k0, CP0_BADVADDR
 115         cache   Hit_Writeback_Inv_SD, (k0)              # also cleans pi
 116 #ifdef CONFIG_PROC_FS
 117         PTR_LA  k0, vcei_count
 118         lw      k1, (k0)
 119         addiu   k1, 1
 120         sw      k1, (k0)
 121 #endif
 122         eret
 123         .set    pop
 124         END(except_vec3_r4000)
 125
 126         __FINIT
 127
 128         .align  5
 129 NESTED(handle_int, PT_SIZE, sp)
 130         SAVE_ALL
 131         CLI
 132         TRACE_IRQS_OFF
 133
 134         LONG_L  s0, TI_REGS($28)
 135         LONG_S  sp, TI_REGS($28)
 136         jal     plat_irq_dispatch
 137         LONG_S  s0, TI_REGS($28)
 138         j       ret_from_irq
 139         END(handle_int)
 140
 141         __INIT
 142
 143 /*
 144  * Special interrupt vector for MIPS64 ISA & embedded MIPS processors.
 145  * This is a dedicated interrupt exception vector which reduces the
 146  * interrupt processing overhead.  The jump instruction will be replaced
 147  * at the initialization time.
 148  *
 149  * Be careful when changing this, it has to be at most 128 bytes
 150  * to fit into space reserved for the exception handler.
 151  */
 152 NESTED(except_vec4, 0, sp)
 153 1:      j       1b                      /* Dummy, will be replaced */
 154         END(except_vec4)
 155
 156 /*
 157  * EJTAG debug exception handler.
 158  * The EJTAG debug exception entry point is 0xbfc00480, which
 159  * normally is in the boot PROM, so the boot PROM must do a
 160  * unconditional jump to this vector.
 161  */
 162 NESTED(except_vec_ejtag_debug, 0, sp)
 163         j       ejtag_debug_handler
 164         END(except_vec_ejtag_debug)
 165
 166         __FINIT
 167
 168 /*
 169  * Vectored interrupt handler.
 170  * This prototype is copied to ebase + n*IntCtl.VS and patched
 171  * to invoke the handler
 172  */
 173 NESTED(except_vec_vi, 0, sp)
 174         SAVE_SOME
 175         SAVE_AT
 176         .set    push
 177         .set    noreorder
 178 #ifdef CONFIG_MIPS_MT_SMTC
 179         /*
 180          * To keep from blindly blocking *all* interrupts
 181          * during service by SMTC kernel, we also want to
 182          * pass the IM value to be cleared.
 183          */
 184 EXPORT(except_vec_vi_mori)
 185         ori     a0, $0, 0
 186 #endif /* CONFIG_MIPS_MT_SMTC */
 187 EXPORT(except_vec_vi_lui)
 188         lui     v0, 0           /* Patched */
 189         j       except_vec_vi_handler
 190 EXPORT(except_vec_vi_ori)
 191          ori    v0, 0           /* Patched */
 192         .set    pop
 193         END(except_vec_vi)
 194 EXPORT(except_vec_vi_end)
 195
 196 /*
 197  * Common Vectored Interrupt code
 198  * Complete the register saves and invoke the handler which is passed in $v0
 199  */
 200 NESTED(except_vec_vi_handler, 0, sp)
 201         SAVE_TEMP
 202         SAVE_STATIC
 203 #ifdef CONFIG_MIPS_MT_SMTC
 204         /*
 205          * SMTC has an interesting problem that interrupts are level-triggered,
 206          * and the CLI macro will clear EXL, potentially causing a duplicate
 207          * interrupt service invocation. So we need to clear the associated
 208          * IM bit of Status prior to doing CLI, and restore it after the
 209          * service routine has been invoked - we must assume that the
 210          * service routine will have cleared the state, and any active
 211          * level represents a new or otherwised unserviced event...
 212          */
 213         mfc0    t1, CP0_STATUS
 214         and     t0, a0, t1
 215         mfc0    t2, CP0_TCCONTEXT
 216         or      t0, t0, t2
 217         mtc0    t0, CP0_TCCONTEXT
 218         xor     t1, t1, t0
 219         mtc0    t1, CP0_STATUS
 220         _ehb
 221 #endif /* CONFIG_MIPS_MT_SMTC */
 222         CLI
 223         TRACE_IRQS_OFF
 224
 225         LONG_L  s0, TI_REGS($28)
 226         LONG_S  sp, TI_REGS($28)
 227         jalr    v0
 228         LONG_S  s0, TI_REGS($28)
 229         PTR_LA  ra, ret_from_irq
 230         END(except_vec_vi_handler)
 231
 232 /*
 233  * EJTAG debug exception handler.
 234  */
 235 NESTED(ejtag_debug_handler, PT_SIZE, sp)
 236         .set    push
 237         .set    noat
 238         MTC0    k0, CP0_DESAVE
 239         mfc0    k0, CP0_DEBUG
 240
 241         sll     k0, k0, 30      # Check for SDBBP.
 242         bgez    k0, ejtag_return
 243
 244         PTR_LA  k0, ejtag_debug_buffer
 245         LONG_S  k1, 0(k0)
 246         SAVE_ALL
 247         move    a0, sp
 248         jal     ejtag_exception_handler
 249         RESTORE_ALL
 250         PTR_LA  k0, ejtag_debug_buffer
 251         LONG_L  k1, 0(k0)
 252
 253 ejtag_return:
 254         MFC0    k0, CP0_DESAVE
 255         .set    mips32
 256         deret
 257         .set pop
 258         END(ejtag_debug_handler)
 259
 260 /*
 261  * This buffer is reserved for the use of the EJTAG debug
 262  * handler.
 263  */
 264         .data
 265 EXPORT(ejtag_debug_buffer)
 266         .fill   LONGSIZE
 267         .previous
 268
 269         __INIT
 270
 271 /*
 272  * NMI debug exception handler for MIPS reference boards.
 273  * The NMI debug exception entry point is 0xbfc00000, which
 274  * normally is in the boot PROM, so the boot PROM must do a
 275  * unconditional jump to this vector.
 276  */
 277 NESTED(except_vec_nmi, 0, sp)
 278         j       nmi_handler
 279         END(except_vec_nmi)
 280
 281         __FINIT
 282
 283 NESTED(nmi_handler, PT_SIZE, sp)
 284         .set    push
 285         .set    noat
 286         SAVE_ALL
 287         move    a0, sp
 288         jal     nmi_exception_handler
 289         RESTORE_ALL
 290         .set    mips3
 291         eret
 292         .set    pop
 293         END(nmi_handler)
 294
 295         .macro  __build_clear_none
 296         .endm
 297
 298         .macro  __build_clear_sti
 299         TRACE_IRQS_ON
 300         STI
 301         .endm
 302
 303         .macro  __build_clear_cli
 304         CLI
 305         TRACE_IRQS_OFF
 306         .endm
 307
 308         .macro  __build_clear_fpe
 309         cfc1    a1, fcr31
 310         li      a2, ~(0x3f << 12)
 311         and     a2, a1
 312         ctc1    a2, fcr31
 313         TRACE_IRQS_ON
 314         STI
 315         .endm
 316
 317         .macro  __build_clear_ade
 318         MFC0    t0, CP0_BADVADDR
 319         PTR_S   t0, PT_BVADDR(sp)
 320         KMODE
 321         .endm
 322
 323         .macro  __BUILD_silent exception
 324         .endm
 325
 326         /* Gas tries to parse the PRINT argument as a string containing
 327            string escapes and emits bogus warnings if it believes to
 328            recognize an unknown escape code.  So make the arguments
 329            start with an n and gas will believe \n is ok ...  */
 330         .macro  __BUILD_verbose nexception
 331         LONG_L  a1, PT_EPC(sp)
 332 #ifdef CONFIG_32BIT
 333         PRINT("Got \nexception at %08lx\012")
 334 #endif
 335 #ifdef CONFIG_64BIT
 336         PRINT("Got \nexception at %016lx\012")
 337 #endif
 338         .endm
 339
 340         .macro  __BUILD_count exception
 341         LONG_L  t0,exception_count_\exception
 342         LONG_ADDIU t0, 1
 343         LONG_S  t0,exception_count_\exception
 344         .comm   exception_count\exception, 8, 8
 345         .endm
 346
 347         .macro  __BUILD_HANDLER exception handler clear verbose ext
 348         .align  5
 349         NESTED(handle_\exception, PT_SIZE, sp)
 350         .set    noat
 351         SAVE_ALL
 352         FEXPORT(handle_\exception\ext)
 353         __BUILD_clear_\clear
 354         .set    at
 355         __BUILD_\verbose \exception
 356         move    a0, sp
 357         PTR_LA  ra, ret_from_exception
 358         j       do_\handler
 359         END(handle_\exception)
 360         .endm
 361
 362         .macro  BUILD_HANDLER exception handler clear verbose
 363         __BUILD_HANDLER \exception \handler \clear \verbose _int
 364         .endm
 365
 366         BUILD_HANDLER adel ade ade silent               /* #4  */
 367         BUILD_HANDLER ades ade ade silent               /* #5  */
 368         BUILD_HANDLER ibe be cli silent                 /* #6  */
 369         BUILD_HANDLER dbe be cli silent                 /* #7  */
 370         BUILD_HANDLER bp bp sti silent                  /* #9  */
 371         BUILD_HANDLER ri ri sti silent                  /* #10 */
 372         BUILD_HANDLER cpu cpu sti silent                /* #11 */
 373         BUILD_HANDLER ov ov sti silent                  /* #12 */
 374         BUILD_HANDLER tr tr sti silent                  /* #13 */
 375         BUILD_HANDLER fpe fpe fpe silent                /* #15 */
 376         BUILD_HANDLER mdmx mdmx sti silent              /* #22 */
 377         BUILD_HANDLER watch watch sti verbose           /* #23 */
 378         BUILD_HANDLER mcheck mcheck cli verbose         /* #24 */
 379         BUILD_HANDLER mt mt sti silent                  /* #25 */
 380         BUILD_HANDLER dsp dsp sti silent                /* #26 */
 381         BUILD_HANDLER reserved reserved sti verbose     /* others */
 382
 383 #ifdef CONFIG_64BIT
 384 /* A temporary overflow handler used by check_daddi(). */
 385
 386         __INIT
 387
 388         BUILD_HANDLER  daddi_ov daddi_ov none silent    /* #12 */
 389 #endif