arch/mips/kernel/entry.S

   1 /*
   2  * This file is subject to the terms and conditions of the GNU General Public
   3  * License.  See the file "COPYING" in the main directory of this archive
   4  * for more details.
   5  *
   6  * Copyright (C) 1994 - 2000, 2001, 2003 Ralf Baechle
   7  * Copyright (C) 1999, 2000 Silicon Graphics, Inc.
   8  * Copyright (C) 2001 MIPS Technologies, Inc.
   9  */
  10
  11 #include <asm/asm.h>
  12 #include <asm/asmmacro.h>
  13 #include <asm/regdef.h>
  14 #include <asm/mipsregs.h>
  15 #include <asm/stackframe.h>
  16 #include <asm/isadep.h>
  17 #include <asm/thread_info.h>
  18 #include <asm/war.h>
  19 #ifdef CONFIG_MIPS_MT_SMTC
  20 #include <asm/mipsmtregs.h>
  21 #endif
  22
  23 #ifdef CONFIG_PREEMPT
  24         .macro  preempt_stop
  25         .endm
  26 #else
  27         .macro  preempt_stop
  28         local_irq_disable
  29         .endm
  30 #define resume_kernel   restore_all
  31 #endif
  32
  33         .text
  34         .align  5
  35 FEXPORT(ret_from_exception)
  36         preempt_stop
  37 FEXPORT(ret_from_irq)
  38         LONG_L  t0, PT_STATUS(sp)               # returning to kernel mode?
  39         andi    t0, t0, KU_USER
  40         beqz    t0, resume_kernel
  41
  42 resume_userspace:
  43         local_irq_disable               # make sure we dont miss an
  44                                         # interrupt setting need_resched
  45                                         # between sampling and return
  46         LONG_L  a2, TI_FLAGS($28)       # current->work
  47         andi    t0, a2, _TIF_WORK_MASK  # (ignoring syscall_trace)
  48         bnez    t0, work_pending
  49         j       restore_all
  50
  51 #ifdef CONFIG_PREEMPT
  52 resume_kernel:
  53         local_irq_disable
  54         lw      t0, TI_PRE_COUNT($28)
  55         bnez    t0, restore_all
  56 need_resched:
  57         LONG_L  t0, TI_FLAGS($28)
  58         andi    t1, t0, _TIF_NEED_RESCHED
  59         beqz    t1, restore_all
  60         LONG_L  t0, PT_STATUS(sp)               # Interrupts off?
  61         andi    t0, 1
  62         beqz    t0, restore_all
  63         jal     preempt_schedule_irq
  64         b       need_resched
  65 #endif
  66
  67 FEXPORT(ret_from_fork)
  68         jal     schedule_tail           # a0 = struct task_struct *prev
  69
  70 FEXPORT(syscall_exit)
  71         local_irq_disable               # make sure need_resched and
  72                                         # signals dont change between
  73                                         # sampling and return
  74         LONG_L  a2, TI_FLAGS($28)       # current->work
  75         li      t0, _TIF_ALLWORK_MASK
  76         and     t0, a2, t0
  77         bnez    t0, syscall_exit_work
  78
  79 FEXPORT(restore_all)                    # restore full frame
  80 #ifdef CONFIG_MIPS_MT_SMTC
  81 /* Detect and execute deferred IPI "interrupts" */
  82         jal     deferred_smtc_ipi
  83 /* Re-arm any temporarily masked interrupts not explicitly "acked" */
  84         mfc0    v0, CP0_TCSTATUS
  85         ori     v1, v0, TCSTATUS_IXMT
  86         mtc0    v1, CP0_TCSTATUS
  87         andi    v0, TCSTATUS_IXMT
  88         _ehb
  89         mfc0    t0, CP0_TCCONTEXT
  90         DMT     9                               # dmt t1
  91         jal     mips_ihb
  92         mfc0    t2, CP0_STATUS
  93         andi    t3, t0, 0xff00
  94         or      t2, t2, t3
  95         mtc0    t2, CP0_STATUS
  96         _ehb
  97         andi    t1, t1, VPECONTROL_TE
  98         beqz    t1, 1f
  99         EMT
 100 1:
 101         mfc0    v1, CP0_TCSTATUS
 102         /* We set IXMT above, XOR should clear it here */
 103         xori    v1, v1, TCSTATUS_IXMT
 104         or      v1, v0, v1
 105         mtc0    v1, CP0_TCSTATUS
 106         _ehb
 107         xor     t0, t0, t3
 108         mtc0    t0, CP0_TCCONTEXT
 109 #endif /* CONFIG_MIPS_MT_SMTC */
 110         .set    noat
 111         RESTORE_TEMP
 112         RESTORE_AT
 113         RESTORE_STATIC
 114 FEXPORT(restore_partial)                # restore partial frame
 115 #ifdef CONFIG_TRACE_IRQFLAGS
 116         SAVE_STATIC
 117         SAVE_AT
 118         SAVE_TEMP
 119         LONG_L  v0, PT_STATUS(sp)
 120         and     v0, 1
 121         beqz    v0, 1f
 122         jal     trace_hardirqs_on
 123         b       2f
 124 1:      jal     trace_hardirqs_off
 125 2:
 126         RESTORE_TEMP
 127         RESTORE_AT
 128         RESTORE_STATIC
 129 #endif
 130         RESTORE_SOME
 131         RESTORE_SP_AND_RET
 132         .set    at
 133
 134 work_pending:
 135         andi    t0, a2, _TIF_NEED_RESCHED # a2 is preloaded with TI_FLAGS
 136         beqz    t0, work_notifysig
 137 work_resched:
 138         jal     schedule
 139
 140         local_irq_disable               # make sure need_resched and
 141                                         # signals dont change between
 142                                         # sampling and return
 143         LONG_L  a2, TI_FLAGS($28)
 144         andi    t0, a2, _TIF_WORK_MASK  # is there any work to be done
 145                                         # other than syscall tracing?
 146         beqz    t0, restore_all
 147         andi    t0, a2, _TIF_NEED_RESCHED
 148         bnez    t0, work_resched
 149
 150 work_notifysig:                         # deal with pending signals and
 151                                         # notify-resume requests
 152         move    a0, sp
 153         li      a1, 0
 154         jal     do_notify_resume        # a2 already loaded
 155         j       resume_userspace
 156
 157 FEXPORT(syscall_exit_work_partial)
 158         SAVE_STATIC
 159 syscall_exit_work:
 160         li      t0, _TIF_SYSCALL_TRACE | _TIF_SYSCALL_AUDIT
 161         and     t0, a2                  # a2 is preloaded with TI_FLAGS
 162         beqz    t0, work_pending        # trace bit set?
 163         local_irq_enable                # could let do_syscall_trace()
 164                                         # call schedule() instead
 165         move    a0, sp
 166         li      a1, 1
 167         jal     do_syscall_trace
 168         b       resume_userspace
 169
 170 #if defined(CONFIG_CPU_MIPSR2) || defined(CONFIG_MIPS_MT)
 171
 172 /*
 173  * MIPS32R2 Instruction Hazard Barrier - must be called
 174  *
 175  * For C code use the inline version named instruction_hazard().
 176  */
 177 LEAF(mips_ihb)
 178         .set    mips32r2
 179         jr.hb   ra
 180         nop
 181         END(mips_ihb)
 182
 183 #endif /* CONFIG_CPU_MIPSR2 or CONFIG_MIPS_MT */