arch/microblaze/kernel/vmlinux.lds.S

   1 /*
   2  * Copyright (C) 2008-2009 Michal Simek <monstr@monstr.eu>
   3  * Copyright (C) 2008-2009 PetaLogix
   4  * Copyright (C) 2006 Atmark Techno, Inc.
   5  *
   6  * This file is subject to the terms and conditions of the GNU General Public
   7  * License. See the file "COPYING" in the main directory of this archive
   8  * for more details.
   9  */
  10
  11 OUTPUT_ARCH(microblaze)
  12 ENTRY(microblaze_start)
  13
  14 #include <asm/page.h>
  15 #include <asm-generic/vmlinux.lds.h>
  16 #include <asm/thread_info.h>
  17
  18 #ifdef __MICROBLAZEEL__
  19 jiffies = jiffies_64;
  20 #else
  21 jiffies = jiffies_64 + 4;
  22 #endif
  23
  24 SECTIONS {
  25         . = CONFIG_KERNEL_START;
  26         microblaze_start = CONFIG_KERNEL_BASE_ADDR;
  27         .text : AT(ADDR(.text) - LOAD_OFFSET) {
  28                 _text = . ;
  29                 _stext = . ;
  30                 HEAD_TEXT
  31                 TEXT_TEXT
  32                 *(.fixup)
  33                 EXIT_TEXT
  34                 EXIT_CALL
  35                 SCHED_TEXT
  36                 LOCK_TEXT
  37                 KPROBES_TEXT
  38                 IRQENTRY_TEXT
  39                 . = ALIGN (4) ;
  40                 _etext = . ;
  41         }
  42
  43         . = ALIGN (4) ;
  44         __fdt_blob : AT(ADDR(__fdt_blob) - LOAD_OFFSET) {
  45                 _fdt_start = . ;                /* place for fdt blob */
  46                 *(__fdt_blob) ;                 /* Any link-placed DTB */
  47                 . = _fdt_start + 0x4000;        /* Pad up to 16kbyte */
  48                 _fdt_end = . ;
  49         }
  50
  51         . = ALIGN(16);
  52         RODATA
  53         EXCEPTION_TABLE(16)
  54
  55         /*
  56          * sdata2 section can go anywhere, but must be word aligned
  57          * and SDA2_BASE must point to the middle of it
  58          */
  59         .sdata2 : AT(ADDR(.sdata2) - LOAD_OFFSET) {
  60                 _ssrw = .;
  61                 . = ALIGN(PAGE_SIZE); /* page aligned when MMU used */
  62                 *(.sdata2)
  63         . = ALIGN(8);
  64         _essrw = .;
  65         _ssrw_size = _essrw - _ssrw;
  66         _KERNEL_SDA2_BASE_ = _ssrw + (_ssrw_size / 2);
  67         }
  68
  69         _sdata = . ;
  70         RW_DATA_SECTION(32, PAGE_SIZE, THREAD_SIZE)
  71         _edata = . ;
  72
  73         /* Reserve some low RAM for r0 based memory references */
  74         . = ALIGN(0x4) ;
  75         r0_ram = . ;
  76         . = . +  PAGE_SIZE;     /* a page should be enough */
  77
  78         /* Under the microblaze ABI, .sdata and .sbss must be contiguous */
  79         . = ALIGN(8);
  80         .sdata : AT(ADDR(.sdata) - LOAD_OFFSET) {
  81                 _ssro = .;
  82                 *(.sdata)
  83         }
  84
  85         .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {
  86                 _ssbss = .;
  87                 *(.sbss)
  88                 _esbss = .;
  89                 _essro = .;
  90                 _ssro_size = _essro - _ssro ;
  91                 _KERNEL_SDA_BASE_ = _ssro + (_ssro_size / 2) ;
  92         }
  93
  94         . = ALIGN(PAGE_SIZE);
  95         __init_begin = .;
  96
  97         INIT_TEXT_SECTION(PAGE_SIZE)
  98
  99         .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
 100                 INIT_DATA
 101         }
 102
 103         . = ALIGN(4);
 104         .init.ivt : AT(ADDR(.init.ivt) - LOAD_OFFSET) {
 105                 __ivt_start = .;
 106                 *(.init.ivt)
 107                 __ivt_end = .;
 108         }
 109
 110         .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 111                 INIT_SETUP(0)
 112         }
 113
 114         .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET ) {
 115                 INIT_CALLS
 116         }
 117
 118         .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 119                 CON_INITCALL
 120         }
 121
 122         SECURITY_INIT
 123
 124         __init_end_before_initramfs = .;
 125
 126         .init.ramfs ALIGN(PAGE_SIZE) : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 127                 __initramfs_start = .;
 128                 *(.init.ramfs)
 129                 __initramfs_end = .;
 130                 . = ALIGN(4);
 131                 LONG(0);
 132 /*
 133  * FIXME this can break initramfs for MMU.
 134  * Pad init.ramfs up to page boundary,
 135  * so that __init_end == __bss_start. This will make image.elf
 136  * consistent with the image.bin
 137  */
 138                 /* . = ALIGN(PAGE_SIZE); */
 139         }
 140         __init_end = .;
 141
 142         .bss ALIGN (PAGE_SIZE) : AT(ADDR(.bss) - LOAD_OFFSET) {
 143                 /* page aligned when MMU used */
 144                 __bss_start = . ;
 145                         *(.bss*)
 146                         *(COMMON)
 147                 . = ALIGN (4) ;
 148                 __bss_stop = . ;
 149                 _ebss = . ;
 150         }
 151         . = ALIGN(PAGE_SIZE);
 152         _end = .;
 153
 154         DISCARDS
 155 }