arch/microblaze/kernel/head.S

   1 /*
   2  * Copyright (C) 2007-2009 Michal Simek <monstr@monstr.eu>
   3  * Copyright (C) 2007-2009 PetaLogix
   4  * Copyright (C) 2006 Atmark Techno, Inc.
   5  *
   6  * MMU code derived from arch/ppc/kernel/head_4xx.S:
   7  *    Copyright (c) 1995-1996 Gary Thomas <gdt@linuxppc.org>
   8  *      Initial PowerPC version.
   9  *    Copyright (c) 1996 Cort Dougan <cort@cs.nmt.edu>
  10  *      Rewritten for PReP
  11  *    Copyright (c) 1996 Paul Mackerras <paulus@cs.anu.edu.au>
  12  *      Low-level exception handers, MMU support, and rewrite.
  13  *    Copyright (c) 1997 Dan Malek <dmalek@jlc.net>
  14  *      PowerPC 8xx modifications.
  15  *    Copyright (c) 1998-1999 TiVo, Inc.
  16  *      PowerPC 403GCX modifications.
  17  *    Copyright (c) 1999 Grant Erickson <grant@lcse.umn.edu>
  18  *      PowerPC 403GCX/405GP modifications.
  19  *    Copyright 2000 MontaVista Software Inc.
  20  *      PPC405 modifications
  21  *      PowerPC 403GCX/405GP modifications.
  22  *      Author: MontaVista Software, Inc.
  23  *              frank_rowand@mvista.com or source@mvista.com
  24  *              debbie_chu@mvista.com
  25  *
  26  * This file is subject to the terms and conditions of the GNU General Public
  27  * License. See the file "COPYING" in the main directory of this archive
  28  * for more details.
  29  */
  30
  31 #include <linux/linkage.h>
  32 #include <asm/thread_info.h>
  33 #include <asm/page.h>
  34 #include <asm/prom.h>           /* for OF_DT_HEADER */
  35
  36 #ifdef CONFIG_MMU
  37 #include <asm/setup.h> /* COMMAND_LINE_SIZE */
  38 #include <asm/mmu.h>
  39 #include <asm/processor.h>
  40
  41 .data
  42 .global empty_zero_page
  43 .align 12
  44 empty_zero_page:
  45         .space  4096
  46 .global swapper_pg_dir
  47 swapper_pg_dir:
  48         .space  4096
  49
  50 #endif /* CONFIG_MMU */
  51
  52         .text
  53 ENTRY(_start)
  54         mfs     r1, rmsr
  55         andi    r1, r1, ~2
  56         mts     rmsr, r1
  57
  58 /* r7 may point to an FDT, or there may be one linked in.
  59    if it's in r7, we've got to save it away ASAP.
  60    We ensure r7 points to a valid FDT, just in case the bootloader
  61    is broken or non-existent */
  62         beqi    r7, no_fdt_arg                  /* NULL pointer?  don't copy */
  63         lw      r11, r0, r7                     /* Does r7 point to a */
  64         rsubi   r11, r11, OF_DT_HEADER          /* valid FDT? */
  65         bnei    r11, no_fdt_arg                 /* No - get out of here */
  66         or      r11, r0, r0 /* incremment */
  67         ori     r4, r0, TOPHYS(_fdt_start)
  68         ori     r3, r0, (0x4000 - 4)
  69 _copy_fdt:
  70         lw      r12, r7, r11 /* r12 = r7 + r11 */
  71         sw      r12, r4, r11 /* addr[r4 + r11] = r12 */
  72         addik   r11, r11, 4 /* increment counting */
  73         bgtid   r3, _copy_fdt /* loop for all entries */
  74         addik   r3, r3, -4 /* descrement loop */
  75 no_fdt_arg:
  76         add     r7, r0, r0                      /* Clear r7, just to be sure */
  77
  78 #ifdef CONFIG_MMU
  79
  80 #ifndef CONFIG_CMDLINE_BOOL
  81 /*
  82  * handling command line
  83  * copy command line to __init_end. There is space for storing command line.
  84  */
  85         or      r6, r0, r0              /* incremment */
  86         ori     r4, r0, __init_end      /* load address of command line */
  87         tophys(r4,r4)                   /* convert to phys address */
  88         ori     r3, r0, COMMAND_LINE_SIZE - 1 /* number of loops */
  89 _copy_command_line:
  90         lbu     r7, r5, r6 /* r7=r5+r6 - r5 contain pointer to command line */
  91         sb      r7, r4, r6              /* addr[r4+r6]= r7*/
  92         addik   r6, r6, 1               /* increment counting */
  93         bgtid   r3, _copy_command_line  /* loop for all entries       */
  94         addik   r3, r3, -1              /* descrement loop */
  95         addik   r5, r4, 0               /* add new space for command line */
  96         tovirt(r5,r5)
  97 #endif /* CONFIG_CMDLINE_BOOL */
  98
  99 #ifdef NOT_COMPILE
 100 /* save bram context */
 101         or      r6, r0, r0                              /* incremment */
 102         ori     r4, r0, TOPHYS(_bram_load_start)        /* save bram context */
 103         ori     r3, r0, (LMB_SIZE - 4)
 104 _copy_bram:
 105         lw      r7, r0, r6              /* r7 = r0 + r6 */
 106         sw      r7, r4, r6              /* addr[r4 + r6] = r7*/
 107         addik   r6, r6, 4               /* increment counting */
 108         bgtid   r3, _copy_bram          /* loop for all entries */
 109         addik   r3, r3, -4              /* descrement loop */
 110 #endif
 111         /* We have to turn on the MMU right away. */
 112
 113         /*
 114          * Set up the initial MMU state so we can do the first level of
 115          * kernel initialization.  This maps the first 16 MBytes of memory 1:1
 116          * virtual to physical.
 117          */
 118         nop
 119         addik   r3, r0, 63              /* Invalidate all TLB entries */
 120 _invalidate:
 121         mts     rtlbx, r3
 122         mts     rtlbhi, r0                      /* flush: ensure V is clear   */
 123         bgtid   r3, _invalidate         /* loop for all entries       */
 124         addik   r3, r3, -1
 125         /* sync */
 126
 127         /*
 128          * We should still be executing code at physical address area
 129          * RAM_BASEADDR at this point. However, kernel code is at
 130          * a virtual address. So, set up a TLB mapping to cover this once
 131          * translation is enabled.
 132          */
 133
 134         addik   r3,r0, CONFIG_KERNEL_START /* Load the kernel virtual address */
 135         tophys(r4,r3)                   /* Load the kernel physical address */
 136
 137         mts     rpid,r0                 /* Load the kernel PID */
 138         nop
 139         bri     4
 140
 141         /*
 142          * Configure and load two entries into TLB slots 0 and 1.
 143          * In case we are pinning TLBs, these are reserved in by the
 144          * other TLB functions.  If not reserving, then it doesn't
 145          * matter where they are loaded.
 146          */
 147         andi    r4,r4,0xfffffc00        /* Mask off the real page number */
 148         ori     r4,r4,(TLB_WR | TLB_EX) /* Set the write and execute bits */
 149
 150         andi    r3,r3,0xfffffc00        /* Mask off the effective page number */
 151         ori     r3,r3,(TLB_VALID | TLB_PAGESZ(PAGESZ_16M))
 152
 153         mts     rtlbx,r0                /* TLB slow 0 */
 154
 155         mts     rtlblo,r4               /* Load the data portion of the entry */
 156         mts     rtlbhi,r3               /* Load the tag portion of the entry */
 157
 158         addik   r4, r4, 0x01000000      /* Map next 16 M entries */
 159         addik   r3, r3, 0x01000000
 160
 161         ori     r6,r0,1                 /* TLB slot 1 */
 162         mts     rtlbx,r6
 163
 164         mts     rtlblo,r4               /* Load the data portion of the entry */
 165         mts     rtlbhi,r3               /* Load the tag portion of the entry */
 166
 167         /*
 168          * Load a TLB entry for LMB, since we need access to
 169          * the exception vectors, using a 4k real==virtual mapping.
 170          */
 171         ori     r6,r0,3                 /* TLB slot 3 */
 172         mts     rtlbx,r6
 173
 174         ori     r4,r0,(TLB_WR | TLB_EX)
 175         ori     r3,r0,(TLB_VALID | TLB_PAGESZ(PAGESZ_4K))
 176
 177         mts     rtlblo,r4               /* Load the data portion of the entry */
 178         mts     rtlbhi,r3               /* Load the tag portion of the entry */
 179
 180         /*
 181          * We now have the lower 16 Meg of RAM mapped into TLB entries, and the
 182          * caches ready to work.
 183          */
 184 turn_on_mmu:
 185         ori     r15,r0,start_here
 186         ori     r4,r0,MSR_KERNEL_VMS
 187         mts     rmsr,r4
 188         nop
 189         rted    r15,0                   /* enables MMU */
 190         nop
 191
 192 start_here:
 193 #endif /* CONFIG_MMU */
 194
 195         /* Initialize small data anchors */
 196         la      r13, r0, _KERNEL_SDA_BASE_
 197         la      r2, r0, _KERNEL_SDA2_BASE_
 198
 199         /* Initialize stack pointer */
 200         la      r1, r0, init_thread_union + THREAD_SIZE - 4
 201
 202         /* Initialize r31 with current task address */
 203         la      r31, r0, init_task
 204
 205         /*
 206          * Call platform dependent initialize function.
 207          * Please see $(ARCH)/mach-$(SUBARCH)/setup.c for
 208          * the function.
 209          */
 210         la      r8, r0, machine_early_init
 211         brald   r15, r8
 212         nop
 213
 214 #ifndef CONFIG_MMU
 215         la      r15, r0, machine_halt
 216         braid   start_kernel
 217         nop
 218 #else
 219         /*
 220          * Initialize the MMU.
 221          */
 222         bralid  r15, mmu_init
 223         nop
 224
 225         /* Go back to running unmapped so we can load up new values
 226          * and change to using our exception vectors.
 227          * On the MicroBlaze, all we invalidate the used TLB entries to clear
 228          * the old 16M byte TLB mappings.
 229          */
 230         ori     r15,r0,TOPHYS(kernel_load_context)
 231         ori     r4,r0,MSR_KERNEL
 232         mts     rmsr,r4
 233         nop
 234         bri     4
 235         rted    r15,0
 236         nop
 237
 238         /* Load up the kernel context */
 239 kernel_load_context:
 240         # Keep entry 0 and 1 valid. Entry 3 mapped to LMB can go away.
 241         ori     r5,r0,3
 242         mts     rtlbx,r5
 243         nop
 244         mts     rtlbhi,r0
 245         nop
 246         addi    r15, r0, machine_halt
 247         ori     r17, r0, start_kernel
 248         ori     r4, r0, MSR_KERNEL_VMS
 249         mts     rmsr, r4
 250         nop
 251         rted    r17, 0          /* enable MMU and jump to start_kernel */
 252         nop
 253 #endif /* CONFIG_MMU */