arch/m68knommu/platform/5307/head.S

   1 /*****************************************************************************/
   2
   3 /*
   4  *      head.S -- common startup code for ColdFire CPUs.
   5  *
   6  *      (C) Copyright 1999-2006, Greg Ungerer <gerg@snapgear.com>.
   7  */
   8
   9 /*****************************************************************************/
  10
  11 #include <linux/sys.h>
  12 #include <linux/linkage.h>
  13 #include <asm/asm-offsets.h>
  14 #include <asm/coldfire.h>
  15 #include <asm/mcfcache.h>
  16 #include <asm/mcfsim.h>
  17
  18 /*****************************************************************************/
  19
  20 /*
  21  *      If we don't have a fixed memory size, then lets build in code
  22  *      to auto detect the DRAM size. Obviously this is the prefered
  23  *      method, and should work for most boards. It won't work for those
  24  *      that do not have their RAM starting at address 0, and it only
  25  *      works on SDRAM (not boards fitted with SRAM).
  26  */
  27 #if CONFIG_RAMSIZE != 0
  28 .macro GET_MEM_SIZE
  29         movel   #CONFIG_RAMSIZE,%d0     /* hard coded memory size */
  30 .endm
  31
  32 #elif defined(CONFIG_M5206) || defined(CONFIG_M5206e) || \
  33       defined(CONFIG_M5249) || defined(CONFIG_M527x) || \
  34       defined(CONFIG_M528x) || defined(CONFIG_M5307) || \
  35       defined(CONFIG_M5407)
  36 /*
  37  *      Not all these devices have exactly the same DRAM controller,
  38  *      but the DCMR register is virtually identical - give or take
  39  *      a couple of bits. The only exception is the 5272 devices, their
  40  *      DRAM controller is quite different.
  41  */
  42 .macro GET_MEM_SIZE
  43         movel   MCF_MBAR+MCFSIM_DMR0,%d0 /* get mask for 1st bank */
  44         btst    #0,%d0                  /* check if region enabled */
  45         beq     1f
  46         andl    #0xfffc0000,%d0
  47         beq     1f
  48         addl    #0x00040000,%d0         /* convert mask to size */
  49 1:
  50         movel   MCF_MBAR+MCFSIM_DMR1,%d1 /* get mask for 2nd bank */
  51         btst    #0,%d1                  /* check if region enabled */
  52         beq     2f
  53         andl    #0xfffc0000, %d1
  54         beq     2f
  55         addl    #0x00040000,%d1
  56         addl    %d1,%d0                 /* total mem size in d0 */
  57 2:
  58 .endm
  59
  60 #elif defined(CONFIG_M5272)
  61 .macro GET_MEM_SIZE
  62         movel   MCF_MBAR+MCFSIM_CSOR7,%d0 /* get SDRAM address mask */
  63         andil   #0xfffff000,%d0         /* mask out chip select options */
  64         negl    %d0                     /* negate bits */
  65 .endm
  66
  67 #else
  68 #error "ERROR: I don't know how to probe your boards memory size?"
  69 #endif
  70
  71 /*****************************************************************************/
  72
  73 /*
  74  *      Boards and platforms can do specific early hardware setup if
  75  *      they need to. Most don't need this, define away if not required.
  76  */
  77 #ifndef PLATFORM_SETUP
  78 #define PLATFORM_SETUP
  79 #endif
  80
  81 /*****************************************************************************/
  82
  83 .global _start
  84 .global _rambase
  85 .global _ramvec
  86 .global _ramstart
  87 .global _ramend
  88
  89 /*****************************************************************************/
  90
  91 .data
  92
  93 /*
  94  *      During startup we store away the RAM setup. These are not in the
  95  *      bss, since their values are determined and written before the bss
  96  *      has been cleared.
  97  */
  98 _rambase:
  99 .long   0
 100 _ramvec:
 101 .long   0
 102 _ramstart:
 103 .long   0
 104 _ramend:
 105 .long   0
 106
 107 /*****************************************************************************/
 108
 109 .text
 110
 111 /*
 112  *      This is the codes first entry point. This is where it all
 113  *      begins...
 114  */
 115
 116 _start:
 117         nop                                     /* filler */
 118         movew   #0x2700, %sr                    /* no interrupts */
 119
 120         /*
 121          *      Do any platform or board specific setup now. Most boards
 122          *      don't need anything. Those exceptions are define this in
 123          *      their board specific includes.
 124          */
 125         PLATFORM_SETUP
 126
 127         /*
 128          *      Create basic memory configuration. Set VBR accordingly,
 129          *      and size memory.
 130          */
 131         movel   #CONFIG_VECTORBASE,%a7
 132         movec   %a7,%VBR                        /* set vectors addr */
 133         movel   %a7,_ramvec
 134
 135         movel   #CONFIG_RAMBASE,%a7             /* mark the base of RAM */
 136         movel   %a7,_rambase
 137
 138         GET_MEM_SIZE                            /* macro code determines size */
 139         addl    %a7,%d0
 140         movel   %d0,_ramend                     /* set end ram addr */
 141
 142         /*
 143          *      Now that we know what the memory is, lets enable cache
 144          *      and get things moving. This is Coldfire CPU specific.
 145          */
 146         CACHE_ENABLE                            /* enable CPU cache */
 147
 148
 149 #ifdef CONFIG_ROMFS_FS
 150         /*
 151          *      Move ROM filesystem above bss :-)
 152          */
 153         lea     _sbss,%a0                       /* get start of bss */
 154         lea     _ebss,%a1                       /* set up destination  */
 155         movel   %a0,%a2                         /* copy of bss start */
 156
 157         movel   8(%a0),%d0                      /* get size of ROMFS */
 158         addql   #8,%d0                          /* allow for rounding */
 159         andl    #0xfffffffc, %d0                /* whole words */
 160
 161         addl    %d0,%a0                         /* copy from end */
 162         addl    %d0,%a1                         /* copy from end */
 163         movel   %a1,_ramstart                   /* set start of ram */
 164
 165 _copy_romfs:
 166         movel   -(%a0),%d0                      /* copy dword */
 167         movel   %d0,-(%a1)
 168         cmpl    %a0,%a2                         /* check if at end */
 169         bne     _copy_romfs
 170
 171 #else /* CONFIG_ROMFS_FS */
 172         lea     _ebss,%a1
 173         movel   %a1,_ramstart
 174 #endif /* CONFIG_ROMFS_FS */
 175
 176
 177         /*
 178          *      Zero out the bss region.
 179          */
 180         lea     _sbss,%a0                       /* get start of bss */
 181         lea     _ebss,%a1                       /* get end of bss */
 182         clrl    %d0                             /* set value */
 183 _clear_bss:
 184         movel   %d0,(%a0)+                      /* clear each word */
 185         cmpl    %a0,%a1                         /* check if at end */
 186         bne     _clear_bss
 187
 188         /*
 189          *      Load the current task pointer and stack.
 190          */
 191         lea     init_thread_union,%a0
 192         lea     THREAD_SIZE(%a0),%sp
 193
 194         /*
 195          *      Assember start up done, start code proper.
 196          */
 197         jsr     start_kernel                    /* start Linux kernel */
 198
 199 _exit:
 200         jmp     _exit                           /* should never get here */
 201
 202 /*****************************************************************************/