arch/m68k/kernel/vmlinux-sun3.lds

   1 /* ld script to make m68k Linux kernel */
   2
   3 #include <asm-generic/vmlinux.lds.h>
   4
   5 OUTPUT_FORMAT("elf32-m68k", "elf32-m68k", "elf32-m68k")
   6 OUTPUT_ARCH(m68k)
   7 ENTRY(_start)
   8 jiffies = jiffies_64 + 4;
   9 SECTIONS
  10 {
  11   . = 0xE004000;
  12   _text = .;                    /* Text and read-only data */
  13   .text : {
  14         *(.head)
  15         *(.text)
  16         SCHED_TEXT
  17         LOCK_TEXT
  18         *(.fixup)
  19         *(.gnu.warning)
  20         } :text = 0x4e75
  21         RODATA
  22
  23   _etext = .;                   /* End of text section */
  24
  25   .data : {                     /* Data */
  26         *(.data)
  27         CONSTRUCTORS
  28         . = ALIGN(16);          /* Exception table */
  29         __start___ex_table = .;
  30         *(__ex_table)
  31         __stop___ex_table = .;
  32         } :data
  33   /* End of data goes *here* so that freeing init code works properly. */
  34   _edata = .;
  35
  36   /* will be freed after init */
  37   . = ALIGN(8192);      /* Init code and data */
  38 __init_begin = .;
  39         .init.text : {
  40                 _sinittext = .;
  41                 *(.init.text)
  42                 _einittext = .;
  43         }
  44         .init.data : { *(.init.data) }
  45         . = ALIGN(16);
  46         __setup_start = .;
  47         .init.setup : { *(.init.setup) }
  48         __setup_end = .;
  49         __initcall_start = .;
  50         .initcall.init : {
  51                 *(.initcall1.init)
  52                 *(.initcall2.init)
  53                 *(.initcall3.init)
  54                 *(.initcall4.init)
  55                 *(.initcall5.init)
  56                 *(.initcall6.init)
  57                 *(.initcall7.init)
  58         }
  59         __initcall_end = .;
  60         __con_initcall_start = .;
  61         .con_initcall.init : { *(.con_initcall.init) }
  62         __con_initcall_end = .;
  63         SECURITY_INIT
  64         . = ALIGN(8192);
  65         __initramfs_start = .;
  66         .init.ramfs : { *(.init.ramfs) }
  67         __initramfs_end = .;
  68         . = ALIGN(8192);
  69         __init_end = .;
  70         .data.init.task : { *(.data.init_task) }
  71
  72
  73   .bss : { *(.bss) }            /* BSS */
  74
  75   _end = . ;
  76
  77   /* Sections to be discarded */
  78   /DISCARD/ : {
  79         *(.exit.text)
  80         *(.exit.data)
  81         *(.exitcall.exit)
  82         }
  83
  84   .crap : {
  85         /* Stabs debugging sections.  */
  86         *(.stab)
  87         *(.stabstr)
  88         *(.stab.excl)
  89         *(.stab.exclstr)
  90         *(.stab.index)
  91         *(.stab.indexstr)
  92         *(.comment)
  93         *(.note)
  94   }
  95
  96 }