arch/ia64/kernel/vmlinux.lds.S

   1 #include <linux/config.h>
   2
   3 #include <asm/cache.h>
   4 #include <asm/ptrace.h>
   5 #include <asm/system.h>
   6 #include <asm/pgtable.h>
   7
   8 #define LOAD_OFFSET     (KERNEL_START - KERNEL_TR_PAGE_SIZE)
   9 #include <asm-generic/vmlinux.lds.h>
  10
  11 #define IVT_TEXT                                                        \
  12                 VMLINUX_SYMBOL(__start_ivt_text) = .;                   \
  13                 *(.text.ivt)                                            \
  14                 VMLINUX_SYMBOL(__end_ivt_text) = .;
  15
  16 OUTPUT_FORMAT("elf64-ia64-little")
  17 OUTPUT_ARCH(ia64)
  18 ENTRY(phys_start)
  19 jiffies = jiffies_64;
  20 PHDRS {
  21   code   PT_LOAD;
  22   percpu PT_LOAD;
  23   data   PT_LOAD;
  24 }
  25 SECTIONS
  26 {
  27   /* Sections to be discarded */
  28   /DISCARD/ : {
  29         *(.exit.text)
  30         *(.exit.data)
  31         *(.exitcall.exit)
  32         *(.IA_64.unwind.exit.text)
  33         *(.IA_64.unwind_info.exit.text)
  34         }
  35
  36   v = PAGE_OFFSET;      /* this symbol is here to make debugging easier... */
  37   phys_start = _start - LOAD_OFFSET;
  38
  39   code : { } :code
  40   . = KERNEL_START;
  41
  42   _text = .;
  43   _stext = .;
  44
  45   .text : AT(ADDR(.text) - LOAD_OFFSET)
  46     {
  47         IVT_TEXT
  48         *(.text)
  49         SCHED_TEXT
  50         LOCK_TEXT
  51         KPROBES_TEXT
  52         *(.gnu.linkonce.t*)
  53     }
  54   .text2 : AT(ADDR(.text2) - LOAD_OFFSET)
  55         { *(.text2) }
  56 #ifdef CONFIG_SMP
  57   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET)
  58         { *(.text.lock) }
  59 #endif
  60   _etext = .;
  61
  62   /* Read-only data */
  63
  64   /* Exception table */
  65   . = ALIGN(16);
  66   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET)
  67         {
  68           __start___ex_table = .;
  69           *(__ex_table)
  70           __stop___ex_table = .;
  71         }
  72
  73   /* MCA table */
  74   . = ALIGN(16);
  75   __mca_table : AT(ADDR(__mca_table) - LOAD_OFFSET)
  76         {
  77           __start___mca_table = .;
  78           *(__mca_table)
  79           __stop___mca_table = .;
  80         }
  81
  82   /* Global data */
  83   _data = .;
  84
  85   /* Unwind info & table: */
  86   . = ALIGN(8);
  87   .IA_64.unwind_info : AT(ADDR(.IA_64.unwind_info) - LOAD_OFFSET)
  88         { *(.IA_64.unwind_info*) }
  89   .IA_64.unwind : AT(ADDR(.IA_64.unwind) - LOAD_OFFSET)
  90         {
  91           __start_unwind = .;
  92           *(.IA_64.unwind*)
  93           __end_unwind = .;
  94         }
  95
  96   RODATA
  97
  98   .opd : AT(ADDR(.opd) - LOAD_OFFSET)
  99         { *(.opd) }
 100
 101   /* Initialization code and data: */
 102
 103   . = ALIGN(PAGE_SIZE);
 104   __init_begin = .;
 105   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET)
 106         {
 107           _sinittext = .;
 108           *(.init.text)
 109           _einittext = .;
 110         }
 111
 112   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET)
 113         { *(.init.data) }
 114
 115   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET)
 116         {
 117           __initramfs_start = .;
 118           *(.init.ramfs)
 119           __initramfs_end = .;
 120         }
 121
 122    . = ALIGN(16);
 123   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET)
 124         {
 125           __setup_start = .;
 126           *(.init.setup)
 127           __setup_end = .;
 128         }
 129   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET)
 130         {
 131           __initcall_start = .;
 132           *(.initcall1.init)
 133           *(.initcall2.init)
 134           *(.initcall3.init)
 135           *(.initcall4.init)
 136           *(.initcall5.init)
 137           *(.initcall6.init)
 138           *(.initcall7.init)
 139           __initcall_end = .;
 140         }
 141
 142   .data.patch.vtop : AT(ADDR(.data.patch.vtop) - LOAD_OFFSET)
 143         {
 144           __start___vtop_patchlist = .;
 145           *(.data.patch.vtop)
 146           __end___vtop_patchlist = .;
 147         }
 148
 149   .data.patch.mckinley_e9 : AT(ADDR(.data.patch.mckinley_e9) - LOAD_OFFSET)
 150         {
 151           __start___mckinley_e9_bundles = .;
 152           *(.data.patch.mckinley_e9)
 153           __end___mckinley_e9_bundles = .;
 154         }
 155
 156 #if defined(CONFIG_IA64_GENERIC)
 157   /* Machine Vector */
 158   . = ALIGN(16);
 159   .machvec : AT(ADDR(.machvec) - LOAD_OFFSET)
 160         {
 161           machvec_start = .;
 162           *(.machvec)
 163           machvec_end = .;
 164         }
 165 #endif
 166
 167    __con_initcall_start = .;
 168   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET)
 169         { *(.con_initcall.init) }
 170   __con_initcall_end = .;
 171   __security_initcall_start = .;
 172   .security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET)
 173         { *(.security_initcall.init) }
 174   __security_initcall_end = .;
 175   . = ALIGN(PAGE_SIZE);
 176   __init_end = .;
 177
 178   /* The initial task and kernel stack */
 179   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET)
 180         { *(.data.init_task) }
 181
 182   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET)
 183         { *(__special_page_section)
 184           __start_gate_section = .;
 185           *(.data.gate)
 186           __stop_gate_section = .;
 187         }
 188   . = ALIGN(PAGE_SIZE);         /* make sure the gate page doesn't expose kernel data */
 189
 190   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET)
 191         { *(.data.read_mostly) }
 192
 193   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET)
 194         { *(.data.cacheline_aligned) }
 195
 196   /* Per-cpu data: */
 197   percpu : { } :percpu
 198   . = ALIGN(PERCPU_PAGE_SIZE);
 199   __phys_per_cpu_start = .;
 200   .data.percpu PERCPU_ADDR : AT(__phys_per_cpu_start - LOAD_OFFSET)
 201         {
 202                 __per_cpu_start = .;
 203                 *(.data.percpu)
 204                 __per_cpu_end = .;
 205         }
 206   . = __phys_per_cpu_start + PERCPU_PAGE_SIZE;  /* ensure percpu data fits into percpu page size */
 207
 208   data : { } :data
 209   .data : AT(ADDR(.data) - LOAD_OFFSET)
 210         { *(.data) *(.data1) *(.gnu.linkonce.d*) CONSTRUCTORS }
 211
 212   . = ALIGN(16);        /* gp must be 16-byte aligned for exc. table */
 213   .got : AT(ADDR(.got) - LOAD_OFFSET)
 214         { *(.got.plt) *(.got) }
 215   __gp = ADDR(.got) + 0x200000;
 216   /* We want the small data sections together, so single-instruction offsets
 217      can access them all, and initialized data all before uninitialized, so
 218      we can shorten the on-disk segment size.  */
 219   .sdata : AT(ADDR(.sdata) - LOAD_OFFSET)
 220         { *(.sdata) *(.sdata1) *(.srdata) }
 221   _edata  =  .;
 222   _bss = .;
 223   .sbss : AT(ADDR(.sbss) - LOAD_OFFSET)
 224         { *(.sbss) *(.scommon) }
 225   .bss : AT(ADDR(.bss) - LOAD_OFFSET)
 226         { *(.bss) *(COMMON) }
 227
 228   _end = .;
 229
 230   code : { } :code
 231   /* Stabs debugging sections.  */
 232   .stab 0 : { *(.stab) }
 233   .stabstr 0 : { *(.stabstr) }
 234   .stab.excl 0 : { *(.stab.excl) }
 235   .stab.exclstr 0 : { *(.stab.exclstr) }
 236   .stab.index 0 : { *(.stab.index) }
 237   .stab.indexstr 0 : { *(.stab.indexstr) }
 238   /* DWARF debug sections.
 239      Symbols in the DWARF debugging sections are relative to the beginning
 240      of the section so we begin them at 0.  */
 241   /* DWARF 1 */
 242   .debug          0 : { *(.debug) }
 243   .line           0 : { *(.line) }
 244   /* GNU DWARF 1 extensions */
 245   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 246   .debug_sfnames  0 : { *(.debug_sfnames) }
 247   /* DWARF 1.1 and DWARF 2 */
 248   .debug_aranges  0 : { *(.debug_aranges) }
 249   .debug_pubnames 0 : { *(.debug_pubnames) }
 250   /* DWARF 2 */
 251   .debug_info     0 : { *(.debug_info) }
 252   .debug_abbrev   0 : { *(.debug_abbrev) }
 253   .debug_line     0 : { *(.debug_line) }
 254   .debug_frame    0 : { *(.debug_frame) }
 255   .debug_str      0 : { *(.debug_str) }
 256   .debug_loc      0 : { *(.debug_loc) }
 257   .debug_macinfo  0 : { *(.debug_macinfo) }
 258   /* SGI/MIPS DWARF 2 extensions */
 259   .debug_weaknames 0 : { *(.debug_weaknames) }
 260   .debug_funcnames 0 : { *(.debug_funcnames) }
 261   .debug_typenames 0 : { *(.debug_typenames) }
 262   .debug_varnames  0 : { *(.debug_varnames) }
 263   /* These must appear regardless of  .  */
 264   /* Discard them for now since Intel SoftSDV cannot handle them.
 265   .comment 0 : { *(.comment) }
 266   .note 0 : { *(.note) }
 267   */
 268   /DISCARD/ : { *(.comment) }
 269   /DISCARD/ : { *(.note) }
 270 }