arch/i386/kernel/vmlinux.lds.S

   1 /* ld script to make i386 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  *
   4  * Don't define absolute symbols until and unless you know that symbol
   5  * value is should remain constant even if kernel image is relocated
   6  * at run time. Absolute symbols are not relocated. If symbol value should
   7  * change if kernel is relocated, make the symbol section relative and
   8  * put it inside the section definition.
   9  */
  10
  11 /* Don't define absolute symbols until and unless you know that symbol
  12  * value is should remain constant even if kernel image is relocated
  13  * at run time. Absolute symbols are not relocated. If symbol value should
  14  * change if kernel is relocated, make the symbol section relative and
  15  * put it inside the section definition.
  16  */
  17 #define LOAD_OFFSET __PAGE_OFFSET
  18
  19 #include <asm-generic/vmlinux.lds.h>
  20 #include <asm/thread_info.h>
  21 #include <asm/page.h>
  22 #include <asm/cache.h>
  23 #include <asm/boot.h>
  24
  25 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  26 OUTPUT_ARCH(i386)
  27 ENTRY(phys_startup_32)
  28 jiffies = jiffies_64;
  29
  30 PHDRS {
  31         text PT_LOAD FLAGS(5);  /* R_E */
  32         data PT_LOAD FLAGS(7);  /* RWE */
  33         note PT_NOTE FLAGS(0);  /* ___ */
  34 }
  35 SECTIONS
  36 {
  37   . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  38   phys_startup_32 = startup_32 - LOAD_OFFSET;
  39
  40   .text.head : AT(ADDR(.text.head) - LOAD_OFFSET) {
  41         _text = .;                      /* Text and read-only data */
  42         *(.text.head)
  43   } :text = 0x9090
  44
  45   /* read-only */
  46   .text : AT(ADDR(.text) - LOAD_OFFSET) {
  47         TEXT_TEXT
  48         SCHED_TEXT
  49         LOCK_TEXT
  50         KPROBES_TEXT
  51         *(.fixup)
  52         *(.gnu.warning)
  53         _etext = .;                     /* End of text section */
  54   } :text = 0x9090
  55
  56   . = ALIGN(16);                /* Exception table */
  57   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
  58         __start___ex_table = .;
  59          *(__ex_table)
  60         __stop___ex_table = .;
  61   }
  62
  63   BUG_TABLE
  64
  65   . = ALIGN(4);
  66   .tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {
  67         __tracedata_start = .;
  68         *(.tracedata)
  69         __tracedata_end = .;
  70   }
  71
  72   RODATA
  73
  74   /* writeable */
  75   . = ALIGN(4096);
  76   .data : AT(ADDR(.data) - LOAD_OFFSET) {       /* Data */
  77         DATA_DATA
  78         CONSTRUCTORS
  79         } :data
  80
  81   . = ALIGN(4096);
  82   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
  83         __nosave_begin = .;
  84         *(.data.nosave)
  85         . = ALIGN(4096);
  86         __nosave_end = .;
  87   }
  88
  89   . = ALIGN(4096);
  90   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
  91         *(.data.page_aligned)
  92         *(.data.idt)
  93   }
  94
  95   . = ALIGN(32);
  96   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  97         *(.data.cacheline_aligned)
  98   }
  99
 100   /* rarely changed data like cpu maps */
 101   . = ALIGN(32);
 102   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) {
 103         *(.data.read_mostly)
 104         _edata = .;             /* End of data section */
 105   }
 106
 107   . = ALIGN(THREAD_SIZE);       /* init_task */
 108   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
 109         *(.data.init_task)
 110   }
 111
 112   /* might get freed after init */
 113   . = ALIGN(4096);
 114   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 115         __smp_locks = .;
 116         *(.smp_locks)
 117         __smp_locks_end = .;
 118   }
 119   /* will be freed after init
 120    * Following ALIGN() is required to make sure no other data falls on the
 121    * same page where __smp_alt_end is pointing as that page might be freed
 122    * after boot. Always make sure that ALIGN() directive is present after
 123    * the section which contains __smp_alt_end.
 124    */
 125   . = ALIGN(4096);
 126
 127   /* will be freed after init */
 128   . = ALIGN(4096);              /* Init code and data */
 129   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
 130         __init_begin = .;
 131         _sinittext = .;
 132         *(.init.text)
 133         _einittext = .;
 134   }
 135   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 136   . = ALIGN(16);
 137   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 138         __setup_start = .;
 139         *(.init.setup)
 140         __setup_end = .;
 141    }
 142   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 143         __initcall_start = .;
 144         INITCALLS
 145         __initcall_end = .;
 146   }
 147   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 148         __con_initcall_start = .;
 149         *(.con_initcall.init)
 150         __con_initcall_end = .;
 151   }
 152   SECURITY_INIT
 153   . = ALIGN(4);
 154   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 155         __alt_instructions = .;
 156         *(.altinstructions)
 157         __alt_instructions_end = .;
 158   }
 159   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 160         *(.altinstr_replacement)
 161   }
 162   . = ALIGN(4);
 163   .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 164         __parainstructions = .;
 165         *(.parainstructions)
 166         __parainstructions_end = .;
 167   }
 168   /* .exit.text is discard at runtime, not link time, to deal with references
 169      from .altinstructions and .eh_frame */
 170   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 171   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 172 #if defined(CONFIG_BLK_DEV_INITRD)
 173   . = ALIGN(4096);
 174   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 175         __initramfs_start = .;
 176         *(.init.ramfs)
 177         __initramfs_end = .;
 178   }
 179 #endif
 180   . = ALIGN(4096);
 181   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) {
 182         __per_cpu_start = .;
 183         *(.data.percpu)
 184         __per_cpu_end = .;
 185   }
 186   . = ALIGN(4096);
 187   /* freed after init ends here */
 188
 189   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 190         __init_end = .;
 191         __bss_start = .;                /* BSS */
 192         *(.bss.page_aligned)
 193         *(.bss)
 194         . = ALIGN(4);
 195         __bss_stop = .;
 196         _end = . ;
 197         /* This is where the kernel creates the early boot page tables */
 198         . = ALIGN(4096);
 199         pg0 = . ;
 200   }
 201
 202   /* Sections to be discarded */
 203   /DISCARD/ : {
 204         *(.exitcall.exit)
 205         }
 206
 207   STABS_DEBUG
 208
 209   DWARF_DEBUG
 210
 211   NOTES
 212 }