arch/i386/kernel/vmlinux.lds.S

   1 /* ld script to make i386 Linux kernel
   2  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
   3  */
   4
   5 #define LOAD_OFFSET __PAGE_OFFSET
   6
   7 #include <asm-generic/vmlinux.lds.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/page.h>
  10 #include <asm/cache.h>
  11
  12 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
  13 OUTPUT_ARCH(i386)
  14 ENTRY(phys_startup_32)
  15 jiffies = jiffies_64;
  16 SECTIONS
  17 {
  18   . = __KERNEL_START;
  19   phys_startup_32 = startup_32 - LOAD_OFFSET;
  20   /* read-only */
  21   _text = .;                    /* Text and read-only data */
  22   .text : AT(ADDR(.text) - LOAD_OFFSET) {
  23         *(.text)
  24         SCHED_TEXT
  25         LOCK_TEXT
  26         KPROBES_TEXT
  27         *(.fixup)
  28         *(.gnu.warning)
  29         } = 0x9090
  30
  31   _etext = .;                   /* End of text section */
  32
  33   . = ALIGN(16);                /* Exception table */
  34   __start___ex_table = .;
  35   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { *(__ex_table) }
  36   __stop___ex_table = .;
  37
  38   RODATA
  39
  40   /* writeable */
  41   .data : AT(ADDR(.data) - LOAD_OFFSET) {       /* Data */
  42         *(.data)
  43         CONSTRUCTORS
  44         }
  45
  46   . = ALIGN(4096);
  47   __nosave_begin = .;
  48   .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { *(.data.nosave) }
  49   . = ALIGN(4096);
  50   __nosave_end = .;
  51
  52   . = ALIGN(4096);
  53   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET) {
  54         *(.data.idt)
  55   }
  56
  57   . = ALIGN(32);
  58   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET) {
  59         *(.data.cacheline_aligned)
  60   }
  61
  62   /* rarely changed data like cpu maps */
  63   . = ALIGN(32);
  64   .data.read_mostly : AT(ADDR(.data.read_mostly) - LOAD_OFFSET) { *(.data.read_mostly) }
  65   _edata = .;                   /* End of data section */
  66
  67   . = ALIGN(THREAD_SIZE);       /* init_task */
  68   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET) {
  69         *(.data.init_task)
  70   }
  71
  72   /* might get freed after init */
  73   . = ALIGN(4096);
  74   __smp_alt_begin = .;
  75   __smp_alt_instructions = .;
  76   .smp_altinstructions : AT(ADDR(.smp_altinstructions) - LOAD_OFFSET) {
  77         *(.smp_altinstructions)
  78   }
  79   __smp_alt_instructions_end = .;
  80   . = ALIGN(4);
  81   __smp_locks = .;
  82   .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
  83         *(.smp_locks)
  84   }
  85   __smp_locks_end = .;
  86   .smp_altinstr_replacement : AT(ADDR(.smp_altinstr_replacement) - LOAD_OFFSET) {
  87         *(.smp_altinstr_replacement)
  88   }
  89   . = ALIGN(4096);
  90   __smp_alt_end = .;
  91
  92   /* will be freed after init */
  93   . = ALIGN(4096);              /* Init code and data */
  94   __init_begin = .;
  95   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  96         _sinittext = .;
  97         *(.init.text)
  98         _einittext = .;
  99   }
 100   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) { *(.init.data) }
 101   . = ALIGN(16);
 102   __setup_start = .;
 103   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) { *(.init.setup) }
 104   __setup_end = .;
 105   __initcall_start = .;
 106   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
 107         *(.initcall1.init)
 108         *(.initcall2.init)
 109         *(.initcall3.init)
 110         *(.initcall4.init)
 111         *(.initcall5.init)
 112         *(.initcall6.init)
 113         *(.initcall7.init)
 114   }
 115   __initcall_end = .;
 116   __con_initcall_start = .;
 117   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 118         *(.con_initcall.init)
 119   }
 120   __con_initcall_end = .;
 121   SECURITY_INIT
 122   . = ALIGN(4);
 123   __alt_instructions = .;
 124   .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 125         *(.altinstructions)
 126   }
 127   __alt_instructions_end = .;
 128   .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 129         *(.altinstr_replacement)
 130   }
 131   /* .exit.text is discard at runtime, not link time, to deal with references
 132      from .altinstructions and .eh_frame */
 133   .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { *(.exit.text) }
 134   .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { *(.exit.data) }
 135   . = ALIGN(4096);
 136   __initramfs_start = .;
 137   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) { *(.init.ramfs) }
 138   __initramfs_end = .;
 139   . = ALIGN(L1_CACHE_BYTES);
 140   __per_cpu_start = .;
 141   .data.percpu  : AT(ADDR(.data.percpu) - LOAD_OFFSET) { *(.data.percpu) }
 142   __per_cpu_end = .;
 143   . = ALIGN(4096);
 144   __init_end = .;
 145   /* freed after init ends here */
 146
 147   __bss_start = .;              /* BSS */
 148   .bss.page_aligned : AT(ADDR(.bss.page_aligned) - LOAD_OFFSET) {
 149         *(.bss.page_aligned)
 150   }
 151   .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 152         *(.bss)
 153   }
 154   . = ALIGN(4);
 155   __bss_stop = .;
 156
 157   _end = . ;
 158
 159   /* This is where the kernel creates the early boot page tables */
 160   . = ALIGN(4096);
 161   pg0 = .;
 162
 163   /* Sections to be discarded */
 164   /DISCARD/ : {
 165         *(.exitcall.exit)
 166         }
 167
 168   STABS_DEBUG
 169
 170   DWARF_DEBUG
 171 }