arch/arm/mm/proc-arm1022.S

   1 /*
   2  *  linux/arch/arm/mm/proc-arm1022.S: MMU functions for ARM1022E
   3  *
   4  *  Copyright (C) 2000 ARM Limited
   5  *  Copyright (C) 2000 Deep Blue Solutions Ltd.
   6  *  hacked for non-paged-MM by Hyok S. Choi, 2003.
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License as published by
  10  * the Free Software Foundation; either version 2 of the License, or
  11  * (at your option) any later version.
  12  *
  13  *
  14  * These are the low level assembler for performing cache and TLB
  15  * functions on the ARM1022E.
  16  */
  17 #include <linux/linkage.h>
  18 #include <linux/init.h>
  19 #include <asm/assembler.h>
  20 #include <asm/asm-offsets.h>
  21 #include <asm/hwcap.h>
  22 #include <asm/pgtable-hwdef.h>
  23 #include <asm/pgtable.h>
  24 #include <asm/ptrace.h>
  25
  26 #include "proc-macros.S"
  27
  28 /*
  29  * This is the maximum size of an area which will be invalidated
  30  * using the single invalidate entry instructions.  Anything larger
  31  * than this, and we go for the whole cache.
  32  *
  33  * This value should be chosen such that we choose the cheapest
  34  * alternative.
  35  */
  36 #define MAX_AREA_SIZE   32768
  37
  38 /*
  39  * The size of one data cache line.
  40  */
  41 #define CACHE_DLINESIZE 32
  42
  43 /*
  44  * The number of data cache segments.
  45  */
  46 #define CACHE_DSEGMENTS 16
  47
  48 /*
  49  * The number of lines in a cache segment.
  50  */
  51 #define CACHE_DENTRIES  64
  52
  53 /*
  54  * This is the size at which it becomes more efficient to
  55  * clean the whole cache, rather than using the individual
  56  * cache line maintainence instructions.
  57  */
  58 #define CACHE_DLIMIT    32768
  59
  60         .text
  61 /*
  62  * cpu_arm1022_proc_init()
  63  */
  64 ENTRY(cpu_arm1022_proc_init)
  65         mov     pc, lr
  66
  67 /*
  68  * cpu_arm1022_proc_fin()
  69  */
  70 ENTRY(cpu_arm1022_proc_fin)
  71         stmfd   sp!, {lr}
  72         mov     ip, #PSR_F_BIT | PSR_I_BIT | SVC_MODE
  73         msr     cpsr_c, ip
  74         bl      arm1022_flush_kern_cache_all
  75         mrc     p15, 0, r0, c1, c0, 0           @ ctrl register
  76         bic     r0, r0, #0x1000                 @ ...i............
  77         bic     r0, r0, #0x000e                 @ ............wca.
  78         mcr     p15, 0, r0, c1, c0, 0           @ disable caches
  79         ldmfd   sp!, {pc}
  80
  81 /*
  82  * cpu_arm1022_reset(loc)
  83  *
  84  * Perform a soft reset of the system.  Put the CPU into the
  85  * same state as it would be if it had been reset, and branch
  86  * to what would be the reset vector.
  87  *
  88  * loc: location to jump to for soft reset
  89  */
  90         .align  5
  91 ENTRY(cpu_arm1022_reset)
  92         mov     ip, #0
  93         mcr     p15, 0, ip, c7, c7, 0           @ invalidate I,D caches
  94         mcr     p15, 0, ip, c7, c10, 4          @ drain WB
  95 #ifdef CONFIG_MMU
  96         mcr     p15, 0, ip, c8, c7, 0           @ invalidate I & D TLBs
  97 #endif
  98         mrc     p15, 0, ip, c1, c0, 0           @ ctrl register
  99         bic     ip, ip, #0x000f                 @ ............wcam
 100         bic     ip, ip, #0x1100                 @ ...i...s........
 101         mcr     p15, 0, ip, c1, c0, 0           @ ctrl register
 102         mov     pc, r0
 103
 104 /*
 105  * cpu_arm1022_do_idle()
 106  */
 107         .align  5
 108 ENTRY(cpu_arm1022_do_idle)
 109         mcr     p15, 0, r0, c7, c0, 4           @ Wait for interrupt
 110         mov     pc, lr
 111
 112 /* ================================= CACHE ================================ */
 113
 114         .align  5
 115 /*
 116  *      flush_user_cache_all()
 117  *
 118  *      Invalidate all cache entries in a particular address
 119  *      space.
 120  */
 121 ENTRY(arm1022_flush_user_cache_all)
 122         /* FALLTHROUGH */
 123 /*
 124  *      flush_kern_cache_all()
 125  *
 126  *      Clean and invalidate the entire cache.
 127  */
 128 ENTRY(arm1022_flush_kern_cache_all)
 129         mov     r2, #VM_EXEC
 130         mov     ip, #0
 131 __flush_whole_cache:
 132 #ifndef CONFIG_CPU_DCACHE_DISABLE
 133         mov     r1, #(CACHE_DSEGMENTS - 1) << 5 @ 16 segments
 134 1:      orr     r3, r1, #(CACHE_DENTRIES - 1) << 26 @ 64 entries
 135 2:      mcr     p15, 0, r3, c7, c14, 2          @ clean+invalidate D index
 136         subs    r3, r3, #1 << 26
 137         bcs     2b                              @ entries 63 to 0
 138         subs    r1, r1, #1 << 5
 139         bcs     1b                              @ segments 15 to 0
 140 #endif
 141         tst     r2, #VM_EXEC
 142 #ifndef CONFIG_CPU_ICACHE_DISABLE
 143         mcrne   p15, 0, ip, c7, c5, 0           @ invalidate I cache
 144 #endif
 145         mcrne   p15, 0, ip, c7, c10, 4          @ drain WB
 146         mov     pc, lr
 147
 148 /*
 149  *      flush_user_cache_range(start, end, flags)
 150  *
 151  *      Invalidate a range of cache entries in the specified
 152  *      address space.
 153  *
 154  *      - start - start address (inclusive)
 155  *      - end   - end address (exclusive)
 156  *      - flags - vm_flags for this space
 157  */
 158 ENTRY(arm1022_flush_user_cache_range)
 159         mov     ip, #0
 160         sub     r3, r1, r0                      @ calculate total size
 161         cmp     r3, #CACHE_DLIMIT
 162         bhs     __flush_whole_cache
 163
 164 #ifndef CONFIG_CPU_DCACHE_DISABLE
 165 1:      mcr     p15, 0, r0, c7, c14, 1          @ clean+invalidate D entry
 166         add     r0, r0, #CACHE_DLINESIZE
 167         cmp     r0, r1
 168         blo     1b
 169 #endif
 170         tst     r2, #VM_EXEC
 171 #ifndef CONFIG_CPU_ICACHE_DISABLE
 172         mcrne   p15, 0, ip, c7, c5, 0           @ invalidate I cache
 173 #endif
 174         mcrne   p15, 0, ip, c7, c10, 4          @ drain WB
 175         mov     pc, lr
 176
 177 /*
 178  *      coherent_kern_range(start, end)
 179  *
 180  *      Ensure coherency between the Icache and the Dcache in the
 181  *      region described by start.  If you have non-snooping
 182  *      Harvard caches, you need to implement this function.
 183  *
 184  *      - start - virtual start address
 185  *      - end   - virtual end address
 186  */
 187 ENTRY(arm1022_coherent_kern_range)
 188         /* FALLTHROUGH */
 189
 190 /*
 191  *      coherent_user_range(start, end)
 192  *
 193  *      Ensure coherency between the Icache and the Dcache in the
 194  *      region described by start.  If you have non-snooping
 195  *      Harvard caches, you need to implement this function.
 196  *
 197  *      - start - virtual start address
 198  *      - end   - virtual end address
 199  */
 200 ENTRY(arm1022_coherent_user_range)
 201         mov     ip, #0
 202         bic     r0, r0, #CACHE_DLINESIZE - 1
 203 1:
 204 #ifndef CONFIG_CPU_DCACHE_DISABLE
 205         mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
 206 #endif
 207 #ifndef CONFIG_CPU_ICACHE_DISABLE
 208         mcr     p15, 0, r0, c7, c5, 1           @ invalidate I entry
 209 #endif
 210         add     r0, r0, #CACHE_DLINESIZE
 211         cmp     r0, r1
 212         blo     1b
 213         mcr     p15, 0, ip, c7, c10, 4          @ drain WB
 214         mov     pc, lr
 215
 216 /*
 217  *      flush_kern_dcache_area(void *addr, size_t size)
 218  *
 219  *      Ensure no D cache aliasing occurs, either with itself or
 220  *      the I cache
 221  *
 222  *      - addr  - kernel address
 223  *      - size  - region size
 224  */
 225 ENTRY(arm1022_flush_kern_dcache_area)
 226         mov     ip, #0
 227 #ifndef CONFIG_CPU_DCACHE_DISABLE
 228         add     r1, r0, r1
 229 1:      mcr     p15, 0, r0, c7, c14, 1          @ clean+invalidate D entry
 230         add     r0, r0, #CACHE_DLINESIZE
 231         cmp     r0, r1
 232         blo     1b
 233 #endif
 234         mcr     p15, 0, ip, c7, c10, 4          @ drain WB
 235         mov     pc, lr
 236
 237 /*
 238  *      dma_inv_range(start, end)
 239  *
 240  *      Invalidate (discard) the specified virtual address range.
 241  *      May not write back any entries.  If 'start' or 'end'
 242  *      are not cache line aligned, those lines must be written
 243  *      back.
 244  *
 245  *      - start - virtual start address
 246  *      - end   - virtual end address
 247  *
 248  * (same as v4wb)
 249  */
 250 arm1022_dma_inv_range:
 251         mov     ip, #0
 252 #ifndef CONFIG_CPU_DCACHE_DISABLE
 253         tst     r0, #CACHE_DLINESIZE - 1
 254         bic     r0, r0, #CACHE_DLINESIZE - 1
 255         mcrne   p15, 0, r0, c7, c10, 1          @ clean D entry
 256         tst     r1, #CACHE_DLINESIZE - 1
 257         mcrne   p15, 0, r1, c7, c10, 1          @ clean D entry
 258 1:      mcr     p15, 0, r0, c7, c6, 1           @ invalidate D entry
 259         add     r0, r0, #CACHE_DLINESIZE
 260         cmp     r0, r1
 261         blo     1b
 262 #endif
 263         mcr     p15, 0, ip, c7, c10, 4          @ drain WB
 264         mov     pc, lr
 265
 266 /*
 267  *      dma_clean_range(start, end)
 268  *
 269  *      Clean the specified virtual address range.
 270  *
 271  *      - start - virtual start address
 272  *      - end   - virtual end address
 273  *
 274  * (same as v4wb)
 275  */
 276 arm1022_dma_clean_range:
 277         mov     ip, #0
 278 #ifndef CONFIG_CPU_DCACHE_DISABLE
 279         bic     r0, r0, #CACHE_DLINESIZE - 1
 280 1:      mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
 281         add     r0, r0, #CACHE_DLINESIZE
 282         cmp     r0, r1
 283         blo     1b
 284 #endif
 285         mcr     p15, 0, ip, c7, c10, 4          @ drain WB
 286         mov     pc, lr
 287
 288 /*
 289  *      dma_flush_range(start, end)
 290  *
 291  *      Clean and invalidate the specified virtual address range.
 292  *
 293  *      - start - virtual start address
 294  *      - end   - virtual end address
 295  */
 296 ENTRY(arm1022_dma_flush_range)
 297         mov     ip, #0
 298 #ifndef CONFIG_CPU_DCACHE_DISABLE
 299         bic     r0, r0, #CACHE_DLINESIZE - 1
 300 1:      mcr     p15, 0, r0, c7, c14, 1          @ clean+invalidate D entry
 301         add     r0, r0, #CACHE_DLINESIZE
 302         cmp     r0, r1
 303         blo     1b
 304 #endif
 305         mcr     p15, 0, ip, c7, c10, 4          @ drain WB
 306         mov     pc, lr
 307
 308 /*
 309  *      dma_map_area(start, size, dir)
 310  *      - start - kernel virtual start address
 311  *      - size  - size of region
 312  *      - dir   - DMA direction
 313  */
 314 ENTRY(arm1022_dma_map_area)
 315         add     r1, r1, r0
 316         cmp     r2, #DMA_TO_DEVICE
 317         beq     arm1022_dma_clean_range
 318         bcs     arm1022_dma_inv_range
 319         b       arm1022_dma_flush_range
 320 ENDPROC(arm1022_dma_map_area)
 321
 322 /*
 323  *      dma_unmap_area(start, size, dir)
 324  *      - start - kernel virtual start address
 325  *      - size  - size of region
 326  *      - dir   - DMA direction
 327  */
 328 ENTRY(arm1022_dma_unmap_area)
 329         mov     pc, lr
 330 ENDPROC(arm1022_dma_unmap_area)
 331
 332 ENTRY(arm1022_cache_fns)
 333         .long   arm1022_flush_kern_cache_all
 334         .long   arm1022_flush_user_cache_all
 335         .long   arm1022_flush_user_cache_range
 336         .long   arm1022_coherent_kern_range
 337         .long   arm1022_coherent_user_range
 338         .long   arm1022_flush_kern_dcache_area
 339         .long   arm1022_dma_map_area
 340         .long   arm1022_dma_unmap_area
 341         .long   arm1022_dma_flush_range
 342
 343         .align  5
 344 ENTRY(cpu_arm1022_dcache_clean_area)
 345 #ifndef CONFIG_CPU_DCACHE_DISABLE
 346         mov     ip, #0
 347 1:      mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
 348         add     r0, r0, #CACHE_DLINESIZE
 349         subs    r1, r1, #CACHE_DLINESIZE
 350         bhi     1b
 351 #endif
 352         mov     pc, lr
 353
 354 /* =============================== PageTable ============================== */
 355
 356 /*
 357  * cpu_arm1022_switch_mm(pgd)
 358  *
 359  * Set the translation base pointer to be as described by pgd.
 360  *
 361  * pgd: new page tables
 362  */
 363         .align  5
 364 ENTRY(cpu_arm1022_switch_mm)
 365 #ifdef CONFIG_MMU
 366 #ifndef CONFIG_CPU_DCACHE_DISABLE
 367         mov     r1, #(CACHE_DSEGMENTS - 1) << 5 @ 16 segments
 368 1:      orr     r3, r1, #(CACHE_DENTRIES - 1) << 26 @ 64 entries
 369 2:      mcr     p15, 0, r3, c7, c14, 2          @ clean+invalidate D index
 370         subs    r3, r3, #1 << 26
 371         bcs     2b                              @ entries 63 to 0
 372         subs    r1, r1, #1 << 5
 373         bcs     1b                              @ segments 15 to 0
 374 #endif
 375         mov     r1, #0
 376 #ifndef CONFIG_CPU_ICACHE_DISABLE
 377         mcr     p15, 0, r1, c7, c5, 0           @ invalidate I cache
 378 #endif
 379         mcr     p15, 0, r1, c7, c10, 4          @ drain WB
 380         mcr     p15, 0, r0, c2, c0, 0           @ load page table pointer
 381         mcr     p15, 0, r1, c8, c7, 0           @ invalidate I & D TLBs
 382 #endif
 383         mov     pc, lr
 384
 385 /*
 386  * cpu_arm1022_set_pte_ext(ptep, pte, ext)
 387  *
 388  * Set a PTE and flush it out
 389  */
 390         .align  5
 391 ENTRY(cpu_arm1022_set_pte_ext)
 392 #ifdef CONFIG_MMU
 393         armv3_set_pte_ext
 394         mov     r0, r0
 395 #ifndef CONFIG_CPU_DCACHE_DISABLE
 396         mcr     p15, 0, r0, c7, c10, 1          @ clean D entry
 397 #endif
 398 #endif /* CONFIG_MMU */
 399         mov     pc, lr
 400
 401         __INIT
 402
 403         .type   __arm1022_setup, #function
 404 __arm1022_setup:
 405         mov     r0, #0
 406         mcr     p15, 0, r0, c7, c7              @ invalidate I,D caches on v4
 407         mcr     p15, 0, r0, c7, c10, 4          @ drain write buffer on v4
 408 #ifdef CONFIG_MMU
 409         mcr     p15, 0, r0, c8, c7              @ invalidate I,D TLBs on v4
 410 #endif
 411         adr     r5, arm1022_crval
 412         ldmia   r5, {r5, r6}
 413         mrc     p15, 0, r0, c1, c0              @ get control register v4
 414         bic     r0, r0, r5
 415         orr     r0, r0, r6
 416 #ifdef CONFIG_CPU_CACHE_ROUND_ROBIN
 417         orr     r0, r0, #0x4000                 @ .R..............
 418 #endif
 419         mov     pc, lr
 420         .size   __arm1022_setup, . - __arm1022_setup
 421
 422         /*
 423          *  R
 424          * .RVI ZFRS BLDP WCAM
 425          * .011 1001 ..11 0101
 426          *
 427          */
 428         .type   arm1022_crval, #object
 429 arm1022_crval:
 430         crval   clear=0x00007f3f, mmuset=0x00003935, ucset=0x00001930
 431
 432         __INITDATA
 433
 434 /*
 435  * Purpose : Function pointers used to access above functions - all calls
 436  *           come through these
 437  */
 438         .type   arm1022_processor_functions, #object
 439 arm1022_processor_functions:
 440         .word   v4t_early_abort
 441         .word   legacy_pabort
 442         .word   cpu_arm1022_proc_init
 443         .word   cpu_arm1022_proc_fin
 444         .word   cpu_arm1022_reset
 445         .word   cpu_arm1022_do_idle
 446         .word   cpu_arm1022_dcache_clean_area
 447         .word   cpu_arm1022_switch_mm
 448         .word   cpu_arm1022_set_pte_ext
 449         .size   arm1022_processor_functions, . - arm1022_processor_functions
 450
 451         .section ".rodata"
 452
 453         .type   cpu_arch_name, #object
 454 cpu_arch_name:
 455         .asciz  "armv5te"
 456         .size   cpu_arch_name, . - cpu_arch_name
 457
 458         .type   cpu_elf_name, #object
 459 cpu_elf_name:
 460         .asciz  "v5"
 461         .size   cpu_elf_name, . - cpu_elf_name
 462
 463         .type   cpu_arm1022_name, #object
 464 cpu_arm1022_name:
 465         .asciz  "ARM1022"
 466         .size   cpu_arm1022_name, . - cpu_arm1022_name
 467
 468         .align
 469
 470         .section ".proc.info.init", #alloc, #execinstr
 471
 472         .type   __arm1022_proc_info,#object
 473 __arm1022_proc_info:
 474         .long   0x4105a220                      @ ARM 1022E (v5TE)
 475         .long   0xff0ffff0
 476         .long   PMD_TYPE_SECT | \
 477                 PMD_BIT4 | \
 478                 PMD_SECT_AP_WRITE | \
 479                 PMD_SECT_AP_READ
 480         .long   PMD_TYPE_SECT | \
 481                 PMD_BIT4 | \
 482                 PMD_SECT_AP_WRITE | \
 483                 PMD_SECT_AP_READ
 484         b       __arm1022_setup
 485         .long   cpu_arch_name
 486         .long   cpu_elf_name
 487         .long   HWCAP_SWP | HWCAP_HALF | HWCAP_THUMB | HWCAP_EDSP
 488         .long   cpu_arm1022_name
 489         .long   arm1022_processor_functions
 490         .long   v4wbi_tlb_fns
 491         .long   v4wb_user_fns
 492         .long   arm1022_cache_fns
 493         .size   __arm1022_proc_info, . - __arm1022_proc_info