arch/arm/mach-omap2/sleep242x.S

   1 /*
   2  * linux/arch/arm/mach-omap2/sleep.S
   3  *
   4  * (C) Copyright 2004
   5  * Texas Instruments, <www.ti.com>
   6  * Richard Woodruff <r-woodruff2@ti.com>
   7  *
   8  * (C) Copyright 2006 Nokia Corporation
   9  * Fixed idle loop sleep
  10  * Igor Stoppa <igor.stoppa@nokia.com>
  11  *
  12  * This program is free software; you can redistribute it and/or
  13  * modify it under the terms of the GNU General Public License as
  14  * published by the Free Software Foundation; either version 2 of
  15  * the License, or (at your option) any later version.
  16  *
  17  * This program is distributed in the hope that it will be useful,
  18  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  19  * MERCHANTABILITY or FITNESS FOR A PARTICULAR /PURPOSE.  See the
  20  * GNU General Public License for more details.
  21  *
  22  * You should have received a copy of the GNU General Public License
  23  * along with this program; if not, write to the Free Software
  24  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  25  * MA 02111-1307 USA
  26  */
  27
  28 #include <linux/linkage.h>
  29 #include <asm/assembler.h>
  30 #include <asm/arch/io.h>
  31 #include <asm/arch/pm.h>
  32
  33 #include <asm/arch/omap24xx.h>
  34
  35 #include "sdrc.h"
  36
  37 /* First address of reserved address space?  apparently valid for OMAP2 & 3 */
  38 #define A_SDRC0_V               (0xC0000000)
  39
  40         .text
  41
  42 /*
  43  * Forces OMAP into idle state
  44  *
  45  * omap242x_idle_loop_suspend() - This bit of code just executes the WFI
  46  * for normal idles.
  47  *
  48  * Note: This code get's copied to internal SRAM at boot. When the OMAP
  49  *       wakes up it continues execution at the point it went to sleep.
  50  */
  51 ENTRY(omap242x_idle_loop_suspend)
  52         stmfd   sp!, {r0, lr}           @ save registers on stack
  53         mov     r0, #0x0                @ clear for mrc call
  54         mcr     p15, 0, r0, c7, c0, 4   @ wait for interrupt
  55         ldmfd   sp!, {r0, pc}           @ restore regs and return
  56
  57 ENTRY(omap242x_idle_loop_suspend_sz)
  58         .word   . - omap242x_idle_loop_suspend
  59
  60 /*
  61  * omap242x_cpu_suspend() - Forces OMAP into deep sleep state by completing
  62  * SDRC shutdown then ARM shutdown.  Upon wake MPU is back on so just restore
  63  * SDRC.
  64  *
  65  * Input:
  66  * R0 : DLL ctrl value pre-Sleep
  67  *
  68  * The if the DPLL is going to AutoIdle. It seems like the DPLL may be back on
  69  * when we get called, but the DLL probably isn't.  We will wait a bit more in
  70  * case the DPLL isn't quite there yet. The code will wait on DLL for DDR even
  71  * if in unlocked mode.
  72  *
  73  * For less than 242x-ES2.2 upon wake from a sleep mode where the external
  74  * oscillator was stopped, a timing bug exists where a non-stabilized 12MHz
  75  * clock can pass into the PRCM can cause problems at DSP and IVA.
  76  * To work around this the code will switch to the 32kHz source prior to sleep.
  77  * Post sleep we will shift back to using the DPLL.  Apparently,
  78  * CM_IDLEST_CLKGEN does not reflect the full clock change so you need to wait
  79  * 3x12MHz + 3x32kHz clocks for a full switch.
  80  *
  81  * The DLL load value is not kept in RETENTION or OFF.  It needs to be restored
  82  * at wake
  83  */
  84 ENTRY(omap242x_cpu_suspend)
  85         stmfd   sp!, {r0 - r12, lr}     @ save registers on stack
  86         mov     r3, #0x0                @ clear for mrc call
  87         mcr     p15, 0, r3, c7, c10, 4  @ memory barrier, hope SDR/DDR finished
  88         nop
  89         nop
  90         ldr     r3, omap2_ocs_sdrc_power        @ addr of sdrc power
  91         ldr     r4, [r3]                @ value of sdrc power
  92         orr     r4, r4, #0x40           @ enable self refresh on idle req
  93         mov     r5, #0x2000             @ set delay (DPLL relock + DLL relock)
  94         str     r4, [r3]                @ make it so
  95         mov     r2, #0
  96         nop
  97         mcr     p15, 0, r2, c7, c0, 4   @ wait for interrupt
  98         nop
  99 loop:
 100         subs    r5, r5, #0x1            @ awake, wait just a bit
 101         bne     loop
 102
 103         /* The DPLL has on before we take the DDR out of self refresh */
 104         bic     r4, r4, #0x40           @ now clear self refresh bit.
 105         str     r4, [r3]                @ put vlaue back.
 106         ldr     r4, A_SDRC0             @ make a clock happen
 107         ldr     r4, [r4]
 108         nop                             @ start auto refresh only after clk ok
 109         movs    r0, r0                  @ see if DDR or SDR
 110         ldrne   r1, omap2_ocs_sdrc_dlla_ctrl    @ get addr of DLL ctrl
 111         strne   r0, [r1]                @ rewrite DLLA to force DLL reload
 112         addne   r1, r1, #0x8            @ move to DLLB
 113         strne   r0, [r1]                @ rewrite DLLB to force DLL reload
 114
 115         mov     r5, #0x1000
 116 loop2:
 117         subs    r5, r5, #0x1
 118         bne     loop2
 119         /* resume*/
 120         ldmfd   sp!, {r0 - r12, pc}     @ restore regs and return
 121
 122 omap2_ocs_sdrc_power:
 123         .word OMAP242X_SDRC_REGADDR(SDRC_POWER)
 124 A_SDRC0:
 125         .word A_SDRC0_V
 126 omap2_ocs_sdrc_dlla_ctrl:
 127         .word OMAP242X_SDRC_REGADDR(SDRC_DLLA_CTRL)
 128
 129 ENTRY(omap242x_cpu_suspend_sz)
 130         .word   . - omap242x_cpu_suspend
 131