arch/arm/mach-omap2/include/mach/entry-macro.S

   1 /*
   2  * arch/arm/plat-omap/include/mach/entry-macro.S
   3  *
   4  * Low-level IRQ helper macros for OMAP-based platforms
   5  *
   6  * Copyright (C) 2009 Texas Instruments
   7  * Added OMAP4 support - Santosh Shilimkar <santosh.shilimkar@ti.com>
   8  *
   9  * This file is licensed under  the terms of the GNU General Public
  10  * License version 2. This program is licensed "as is" without any
  11  * warranty of any kind, whether express or implied.
  12  */
  13 #include <mach/hardware.h>
  14 #include <mach/io.h>
  15 #include <mach/irqs.h>
  16 #include <asm/hardware/gic.h>
  17
  18 #include <plat/omap24xx.h>
  19 #include <plat/omap34xx.h>
  20 #include <plat/omap44xx.h>
  21
  22 #include <plat/multi.h>
  23
  24 #define OMAP2_IRQ_BASE          OMAP2_L4_IO_ADDRESS(OMAP24XX_IC_BASE)
  25 #define OMAP3_IRQ_BASE          OMAP2_L4_IO_ADDRESS(OMAP34XX_IC_BASE)
  26 #define OMAP4_IRQ_BASE          OMAP2_L4_IO_ADDRESS(OMAP44XX_GIC_CPU_BASE)
  27 #define INTCPS_SIR_IRQ_OFFSET   0x0040  /* omap2/3 active interrupt offset */
  28 #define ACTIVEIRQ_MASK          0x7f    /* omap2/3 active interrupt bits */
  29
  30                 .macro  disable_fiq
  31                 .endm
  32
  33                 .macro  arch_ret_to_user, tmp1, tmp2
  34                 .endm
  35
  36 /*
  37  * Unoptimized irq functions for multi-omap2, 3 and 4
  38  */
  39
  40 #ifdef MULTI_OMAP2
  41                 .pushsection .data
  42 omap_irq_base:  .word   0
  43                 .popsection
  44
  45                 /* Configure the interrupt base on the first interrupt */
  46                 .macro  get_irqnr_preamble, base, tmp
  47 9:
  48                 ldr     \base, =omap_irq_base   @ irq base address
  49                 ldr     \base, [\base, #0]      @ irq base value
  50                 cmp     \base, #0               @ already configured?
  51                 bne     9997f                   @ nothing to do
  52
  53                 mrc     p15, 0, \tmp, c0, c0, 0 @ get processor revision
  54                 and     \tmp, \tmp, #0x000f0000 @ only check architecture
  55                 cmp     \tmp, #0x00070000       @ is v6?
  56                 beq     2400f                   @ found v6 so it's omap24xx
  57                 mrc     p15, 0, \tmp, c0, c0, 0 @ get processor revision
  58                 and     \tmp, \tmp, #0x000000f0 @ check cortex 8 or 9
  59                 cmp     \tmp, #0x00000080       @ cortex A-8?
  60                 beq     3400f                   @ found A-8 so it's omap34xx
  61                 cmp     \tmp, #0x00000090       @ cortex A-9?
  62                 beq     4400f                   @ found A-9 so it's omap44xx
  63 2400:           ldr     \base, =OMAP2_IRQ_BASE
  64                 ldr     \tmp, =omap_irq_base
  65                 str     \base, [\tmp, #0]
  66                 b       9b
  67 3400:           ldr     \base, =OMAP3_IRQ_BASE
  68                 ldr     \tmp, =omap_irq_base
  69                 str     \base, [\tmp, #0]
  70                 b       9b
  71 4400:           ldr     \base, =OMAP4_IRQ_BASE
  72                 ldr     \tmp, =omap_irq_base
  73                 str     \base, [\tmp, #0]
  74                 b       9b
  75 9997:
  76                 .endm
  77
  78                 /* Check the pending interrupts. Note that base already set */
  79                 .macro  get_irqnr_and_base, irqnr, irqstat, base, tmp
  80                 tst     \base, #0x100           @ gic address?
  81                 bne     4401f                   @ found gic
  82
  83                 /* Handle omap2 and omap3 */
  84                 ldr     \irqnr, [\base, #0x98] /* IRQ pending reg 1 */
  85                 cmp     \irqnr, #0x0
  86                 bne     9998f
  87                 ldr     \irqnr, [\base, #0xb8] /* IRQ pending reg 2 */
  88                 cmp     \irqnr, #0x0
  89                 bne     9998f
  90                 ldr     \irqnr, [\base, #0xd8] /* IRQ pending reg 3 */
  91                 cmp     \irqnr, #0x0
  92 9998:
  93                 ldrne   \irqnr, [\base, #INTCPS_SIR_IRQ_OFFSET]
  94                 and     \irqnr, \irqnr, #ACTIVEIRQ_MASK /* Clear spurious bits */
  95                 b       9999f
  96
  97                 /* Handle omap4 */
  98 4401:           ldr     \irqstat, [\base, #GIC_CPU_INTACK]
  99                 ldr     \tmp, =1021
 100                 bic     \irqnr, \irqstat, #0x1c00
 101                 cmp     \irqnr, #29
 102                 cmpcc   \irqnr, \irqnr
 103                 cmpne   \irqnr, \tmp
 104                 cmpcs   \irqnr, \irqnr
 105 9999:
 106                 .endm
 107
 108 #ifdef CONFIG_SMP
 109                 /* We assume that irqstat (the raw value of the IRQ acknowledge
 110                  * register) is preserved from the macro above.
 111                  * If there is an IPI, we immediately signal end of interrupt
 112                  * on the controller, since this requires the original irqstat
 113                  * value which we won't easily be able to recreate later.
 114                  */
 115
 116                 .macro test_for_ipi, irqnr, irqstat, base, tmp
 117                 bic     \irqnr, \irqstat, #0x1c00
 118                 cmp     \irqnr, #16
 119                 it      cc
 120                 strcc   \irqstat, [\base, #GIC_CPU_EOI]
 121                 it      cs
 122                 cmpcs   \irqnr, \irqnr
 123                 .endm
 124
 125                 /* As above, this assumes that irqstat and base are preserved */
 126
 127                 .macro test_for_ltirq, irqnr, irqstat, base, tmp
 128                 bic     \irqnr, \irqstat, #0x1c00
 129                 mov     \tmp, #0
 130                 cmp     \irqnr, #29
 131                 itt     eq
 132                 moveq   \tmp, #1
 133                 streq   \irqstat, [\base, #GIC_CPU_EOI]
 134                 cmp     \tmp, #0
 135                 .endm
 136 #endif  /* CONFIG_SMP */
 137
 138 #else   /* MULTI_OMAP2 */
 139
 140
 141 /*
 142  * Optimized irq functions for omap2, 3 and 4
 143  */
 144
 145 #if defined(CONFIG_ARCH_OMAP2) || defined(CONFIG_ARCH_OMAP3)
 146                 .macro  get_irqnr_preamble, base, tmp
 147 #ifdef CONFIG_ARCH_OMAP2
 148                 ldr     \base, =OMAP2_IRQ_BASE
 149 #else
 150                 ldr     \base, =OMAP3_IRQ_BASE
 151 #endif
 152                 .endm
 153
 154                 /* Check the pending interrupts. Note that base already set */
 155                 .macro  get_irqnr_and_base, irqnr, irqstat, base, tmp
 156                 ldr     \irqnr, [\base, #0x98] /* IRQ pending reg 1 */
 157                 cmp     \irqnr, #0x0
 158                 bne     9999f
 159                 ldr     \irqnr, [\base, #0xb8] /* IRQ pending reg 2 */
 160                 cmp     \irqnr, #0x0
 161                 bne     9999f
 162                 ldr     \irqnr, [\base, #0xd8] /* IRQ pending reg 3 */
 163                 cmp     \irqnr, #0x0
 164 9999:
 165                 ldrne   \irqnr, [\base, #INTCPS_SIR_IRQ_OFFSET]
 166                 and     \irqnr, \irqnr, #ACTIVEIRQ_MASK /* Clear spurious bits */
 167
 168                 .endm
 169 #endif
 170
 171
 172 #ifdef CONFIG_ARCH_OMAP4
 173 #define HAVE_GET_IRQNR_PREAMBLE
 174 #include <asm/hardware/entry-macro-gic.S>
 175
 176                 .macro  get_irqnr_preamble, base, tmp
 177                 ldr     \base, =OMAP4_IRQ_BASE
 178                 .endm
 179
 180 #endif
 181
 182 #endif  /* MULTI_OMAP2 */
 183
 184                 .macro  irq_prio_table
 185                 .endm