arch/arm/kernel/head.S

   1 /*
   2  *  linux/arch/arm/kernel/head.S
   3  *
   4  *  Copyright (C) 1994-2002 Russell King
   5  *  Copyright (c) 2003 ARM Limited
   6  *  All Rights Reserved
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  *  Kernel startup code for all 32-bit CPUs
  13  */
  14 #include <linux/linkage.h>
  15 #include <linux/init.h>
  16
  17 #include <asm/assembler.h>
  18 #include <asm/domain.h>
  19 #include <asm/ptrace.h>
  20 #include <asm/asm-offsets.h>
  21 #include <asm/memory.h>
  22 #include <asm/thread_info.h>
  23 #include <asm/system.h>
  24
  25 #ifdef CONFIG_DEBUG_LL
  26 #include <mach/debug-macro.S>
  27 #endif
  28
  29 #if (PHYS_OFFSET & 0x001fffff)
  30 #error "PHYS_OFFSET must be at an even 2MiB boundary!"
  31 #endif
  32
  33 #define KERNEL_RAM_VADDR        (PAGE_OFFSET + TEXT_OFFSET)
  34 #define KERNEL_RAM_PADDR        (PHYS_OFFSET + TEXT_OFFSET)
  35
  36
  37 /*
  38  * swapper_pg_dir is the virtual address of the initial page table.
  39  * We place the page tables 16K below KERNEL_RAM_VADDR.  Therefore, we must
  40  * make sure that KERNEL_RAM_VADDR is correctly set.  Currently, we expect
  41  * the least significant 16 bits to be 0x8000, but we could probably
  42  * relax this restriction to KERNEL_RAM_VADDR >= PAGE_OFFSET + 0x4000.
  43  */
  44 #if (KERNEL_RAM_VADDR & 0xffff) != 0x8000
  45 #error KERNEL_RAM_VADDR must start at 0xXXXX8000
  46 #endif
  47
  48         .globl  swapper_pg_dir
  49         .equ    swapper_pg_dir, KERNEL_RAM_VADDR - 0x4000
  50
  51         .macro  pgtbl, rd
  52         ldr     \rd, =(KERNEL_RAM_PADDR - 0x4000)
  53         .endm
  54
  55 #ifdef CONFIG_XIP_KERNEL
  56 #define KERNEL_START    XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR)
  57 #define KERNEL_END      _edata_loc
  58 #else
  59 #define KERNEL_START    KERNEL_RAM_VADDR
  60 #define KERNEL_END      _end
  61 #endif
  62
  63 /*
  64  * Kernel startup entry point.
  65  * ---------------------------
  66  *
  67  * This is normally called from the decompressor code.  The requirements
  68  * are: MMU = off, D-cache = off, I-cache = dont care, r0 = 0,
  69  * r1 = machine nr, r2 = atags pointer.
  70  *
  71  * This code is mostly position independent, so if you link the kernel at
  72  * 0xc0008000, you call this at __pa(0xc0008000).
  73  *
  74  * See linux/arch/arm/tools/mach-types for the complete list of machine
  75  * numbers for r1.
  76  *
  77  * We're trying to keep crap to a minimum; DO NOT add any machine specific
  78  * crap here - that's what the boot loader (or in extreme, well justified
  79  * circumstances, zImage) is for.
  80  */
  81         __HEAD
  82 ENTRY(stext)
  83         setmode PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9 @ ensure svc mode
  84                                                 @ and irqs disabled
  85         mrc     p15, 0, r9, c0, c0              @ get processor id
  86         bl      __lookup_processor_type         @ r5=procinfo r9=cpuid
  87         movs    r10, r5                         @ invalid processor (r5=0)?
  88         beq     __error_p                       @ yes, error 'p'
  89         bl      __lookup_machine_type           @ r5=machinfo
  90         movs    r8, r5                          @ invalid machine (r5=0)?
  91         beq     __error_a                       @ yes, error 'a'
  92
  93         /*
  94          * r1 = machine no, r2 = atags,
  95          * r8 = machinfo, r9 = cpuid, r10 = procinfo
  96          */
  97         bl      __vet_atags
  98 #ifdef CONFIG_SMP_ON_UP
  99         bl      __fixup_smp
 100 #endif
 101         bl      __create_page_tables
 102
 103         /*
 104          * The following calls CPU specific code in a position independent
 105          * manner.  See arch/arm/mm/proc-*.S for details.  r10 = base of
 106          * xxx_proc_info structure selected by __lookup_machine_type
 107          * above.  On return, the CPU will be ready for the MMU to be
 108          * turned on, and r0 will hold the CPU control register value.
 109          */
 110         ldr     r13, =__mmap_switched           @ address to jump to after
 111                                                 @ mmu has been enabled
 112         adr     lr, BSYM(1f)                    @ return (PIC) address
 113  ARM(   add     pc, r10, #PROCINFO_INITFUNC     )
 114  THUMB( add     r12, r10, #PROCINFO_INITFUNC    )
 115  THUMB( mov     pc, r12                         )
 116 1:      b       __enable_mmu
 117 ENDPROC(stext)
 118         .ltorg
 119
 120 /*
 121  * Setup the initial page tables.  We only setup the barest
 122  * amount which are required to get the kernel running, which
 123  * generally means mapping in the kernel code.
 124  *
 125  * r8  = machinfo
 126  * r9  = cpuid
 127  * r10 = procinfo
 128  *
 129  * Returns:
 130  *  r0, r3, r5-r7 corrupted
 131  *  r4 = physical page table address
 132  */
 133 __create_page_tables:
 134         pgtbl   r4                              @ page table address
 135
 136         /*
 137          * Clear the 16K level 1 swapper page table
 138          */
 139         mov     r0, r4
 140         mov     r3, #0
 141         add     r6, r0, #0x4000
 142 1:      str     r3, [r0], #4
 143         str     r3, [r0], #4
 144         str     r3, [r0], #4
 145         str     r3, [r0], #4
 146         teq     r0, r6
 147         bne     1b
 148
 149         ldr     r7, [r10, #PROCINFO_MM_MMUFLAGS] @ mm_mmuflags
 150
 151         /*
 152          * Create identity mapping to cater for __enable_mmu.
 153          * This identity mapping will be removed by paging_init().
 154          */
 155         adr     r0, __enable_mmu_loc
 156         ldmia   r0, {r3, r5, r6}
 157         sub     r0, r0, r3                      @ virt->phys offset
 158         add     r5, r5, r0                      @ phys __enable_mmu
 159         add     r6, r6, r0                      @ phys __enable_mmu_end
 160         mov     r5, r5, lsr #20
 161         mov     r6, r6, lsr #20
 162
 163 1:      orr     r3, r7, r5, lsl #20             @ flags + kernel base
 164         str     r3, [r4, r5, lsl #2]            @ identity mapping
 165         teq     r5, r6
 166         addne   r5, r5, #1                      @ next section
 167         bne     1b
 168
 169         /*
 170          * Now setup the pagetables for our kernel direct
 171          * mapped region.
 172          */
 173         mov     r3, pc
 174         mov     r3, r3, lsr #20
 175         orr     r3, r7, r3, lsl #20
 176         add     r0, r4,  #(KERNEL_START & 0xff000000) >> 18
 177         str     r3, [r0, #(KERNEL_START & 0x00f00000) >> 18]!
 178         ldr     r6, =(KERNEL_END - 1)
 179         add     r0, r0, #4
 180         add     r6, r4, r6, lsr #18
 181 1:      cmp     r0, r6
 182         add     r3, r3, #1 << 20
 183         strls   r3, [r0], #4
 184         bls     1b
 185
 186 #ifdef CONFIG_XIP_KERNEL
 187         /*
 188          * Map some ram to cover our .data and .bss areas.
 189          */
 190         orr     r3, r7, #(KERNEL_RAM_PADDR & 0xff000000)
 191         .if     (KERNEL_RAM_PADDR & 0x00f00000)
 192         orr     r3, r3, #(KERNEL_RAM_PADDR & 0x00f00000)
 193         .endif
 194         add     r0, r4,  #(KERNEL_RAM_VADDR & 0xff000000) >> 18
 195         str     r3, [r0, #(KERNEL_RAM_VADDR & 0x00f00000) >> 18]!
 196         ldr     r6, =(_end - 1)
 197         add     r0, r0, #4
 198         add     r6, r4, r6, lsr #18
 199 1:      cmp     r0, r6
 200         add     r3, r3, #1 << 20
 201         strls   r3, [r0], #4
 202         bls     1b
 203 #endif
 204
 205         /*
 206          * Then map first 1MB of ram in case it contains our boot params.
 207          */
 208         add     r0, r4, #PAGE_OFFSET >> 18
 209         orr     r6, r7, #(PHYS_OFFSET & 0xff000000)
 210         .if     (PHYS_OFFSET & 0x00f00000)
 211         orr     r6, r6, #(PHYS_OFFSET & 0x00f00000)
 212         .endif
 213         str     r6, [r0]
 214
 215 #ifdef CONFIG_DEBUG_LL
 216 #ifndef CONFIG_DEBUG_ICEDCC
 217         /*
 218          * Map in IO space for serial debugging.
 219          * This allows debug messages to be output
 220          * via a serial console before paging_init.
 221          */
 222         addruart r7, r3
 223
 224         mov     r3, r3, lsr #20
 225         mov     r3, r3, lsl #2
 226
 227         add     r0, r4, r3
 228         rsb     r3, r3, #0x4000                 @ PTRS_PER_PGD*sizeof(long)
 229         cmp     r3, #0x0800                     @ limit to 512MB
 230         movhi   r3, #0x0800
 231         add     r6, r0, r3
 232         mov     r3, r7, lsr #20
 233         ldr     r7, [r10, #PROCINFO_IO_MMUFLAGS] @ io_mmuflags
 234         orr     r3, r7, r3, lsl #20
 235 1:      str     r3, [r0], #4
 236         add     r3, r3, #1 << 20
 237         teq     r0, r6
 238         bne     1b
 239
 240 #else /* CONFIG_DEBUG_ICEDCC */
 241         /* we don't need any serial debugging mappings for ICEDCC */
 242         ldr     r7, [r10, #PROCINFO_IO_MMUFLAGS] @ io_mmuflags
 243 #endif /* !CONFIG_DEBUG_ICEDCC */
 244
 245 #if defined(CONFIG_ARCH_NETWINDER) || defined(CONFIG_ARCH_CATS)
 246         /*
 247          * If we're using the NetWinder or CATS, we also need to map
 248          * in the 16550-type serial port for the debug messages
 249          */
 250         add     r0, r4, #0xff000000 >> 18
 251         orr     r3, r7, #0x7c000000
 252         str     r3, [r0]
 253 #endif
 254 #ifdef CONFIG_ARCH_RPC
 255         /*
 256          * Map in screen at 0x02000000 & SCREEN2_BASE
 257          * Similar reasons here - for debug.  This is
 258          * only for Acorn RiscPC architectures.
 259          */
 260         add     r0, r4, #0x02000000 >> 18
 261         orr     r3, r7, #0x02000000
 262         str     r3, [r0]
 263         add     r0, r4, #0xd8000000 >> 18
 264         str     r3, [r0]
 265 #endif
 266 #endif
 267         mov     pc, lr
 268 ENDPROC(__create_page_tables)
 269         .ltorg
 270 __enable_mmu_loc:
 271         .long   .
 272         .long   __enable_mmu
 273         .long   __enable_mmu_end
 274
 275 #if defined(CONFIG_SMP)
 276         __CPUINIT
 277 ENTRY(secondary_startup)
 278         /*
 279          * Common entry point for secondary CPUs.
 280          *
 281          * Ensure that we're in SVC mode, and IRQs are disabled.  Lookup
 282          * the processor type - there is no need to check the machine type
 283          * as it has already been validated by the primary processor.
 284          */
 285         setmode PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9
 286         mrc     p15, 0, r9, c0, c0              @ get processor id
 287         bl      __lookup_processor_type
 288         movs    r10, r5                         @ invalid processor?
 289         moveq   r0, #'p'                        @ yes, error 'p'
 290         beq     __error_p
 291
 292         /*
 293          * Use the page tables supplied from  __cpu_up.
 294          */
 295         adr     r4, __secondary_data
 296         ldmia   r4, {r5, r7, r12}               @ address to jump to after
 297         sub     r4, r4, r5                      @ mmu has been enabled
 298         ldr     r4, [r7, r4]                    @ get secondary_data.pgdir
 299         adr     lr, BSYM(__enable_mmu)          @ return address
 300         mov     r13, r12                        @ __secondary_switched address
 301  ARM(   add     pc, r10, #PROCINFO_INITFUNC     ) @ initialise processor
 302                                                   @ (return control reg)
 303  THUMB( add     r12, r10, #PROCINFO_INITFUNC    )
 304  THUMB( mov     pc, r12                         )
 305 ENDPROC(secondary_startup)
 306
 307         /*
 308          * r6  = &secondary_data
 309          */
 310 ENTRY(__secondary_switched)
 311         ldr     sp, [r7, #4]                    @ get secondary_data.stack
 312         mov     fp, #0
 313         b       secondary_start_kernel
 314 ENDPROC(__secondary_switched)
 315
 316         .type   __secondary_data, %object
 317 __secondary_data:
 318         .long   .
 319         .long   secondary_data
 320         .long   __secondary_switched
 321 #endif /* defined(CONFIG_SMP) */
 322
 323
 324
 325 /*
 326  * Setup common bits before finally enabling the MMU.  Essentially
 327  * this is just loading the page table pointer and domain access
 328  * registers.
 329  *
 330  *  r0  = cp#15 control register
 331  *  r1  = machine ID
 332  *  r2  = atags pointer
 333  *  r4  = page table pointer
 334  *  r9  = processor ID
 335  *  r13 = *virtual* address to jump to upon completion
 336  */
 337 __enable_mmu:
 338 #ifdef CONFIG_ALIGNMENT_TRAP
 339         orr     r0, r0, #CR_A
 340 #else
 341         bic     r0, r0, #CR_A
 342 #endif
 343 #ifdef CONFIG_CPU_DCACHE_DISABLE
 344         bic     r0, r0, #CR_C
 345 #endif
 346 #ifdef CONFIG_CPU_BPREDICT_DISABLE
 347         bic     r0, r0, #CR_Z
 348 #endif
 349 #ifdef CONFIG_CPU_ICACHE_DISABLE
 350         bic     r0, r0, #CR_I
 351 #endif
 352         mov     r5, #(domain_val(DOMAIN_USER, DOMAIN_MANAGER) | \
 353                       domain_val(DOMAIN_KERNEL, DOMAIN_MANAGER) | \
 354                       domain_val(DOMAIN_TABLE, DOMAIN_MANAGER) | \
 355                       domain_val(DOMAIN_IO, DOMAIN_CLIENT))
 356         mcr     p15, 0, r5, c3, c0, 0           @ load domain access register
 357         mcr     p15, 0, r4, c2, c0, 0           @ load page table pointer
 358         b       __turn_mmu_on
 359 ENDPROC(__enable_mmu)
 360
 361 /*
 362  * Enable the MMU.  This completely changes the structure of the visible
 363  * memory space.  You will not be able to trace execution through this.
 364  * If you have an enquiry about this, *please* check the linux-arm-kernel
 365  * mailing list archives BEFORE sending another post to the list.
 366  *
 367  *  r0  = cp#15 control register
 368  *  r1  = machine ID
 369  *  r2  = atags pointer
 370  *  r9  = processor ID
 371  *  r13 = *virtual* address to jump to upon completion
 372  *
 373  * other registers depend on the function called upon completion
 374  */
 375         .align  5
 376 __turn_mmu_on:
 377         mov     r0, r0
 378         mcr     p15, 0, r0, c1, c0, 0           @ write control reg
 379         mrc     p15, 0, r3, c0, c0, 0           @ read id reg
 380         mov     r3, r3
 381         mov     r3, r13
 382         mov     pc, r3
 383 __enable_mmu_end:
 384 ENDPROC(__turn_mmu_on)
 385
 386
 387 #ifdef CONFIG_SMP_ON_UP
 388 __fixup_smp:
 389         mov     r4, #0x00070000
 390         orr     r3, r4, #0xff000000     @ mask 0xff070000
 391         orr     r4, r4, #0x41000000     @ val 0x41070000
 392         and     r0, r9, r3
 393         teq     r0, r4                  @ ARM CPU and ARMv6/v7?
 394         bne     __fixup_smp_on_up       @ no, assume UP
 395
 396         orr     r3, r3, #0x0000ff00
 397         orr     r3, r3, #0x000000f0     @ mask 0xff07fff0
 398         orr     r4, r4, #0x0000b000
 399         orr     r4, r4, #0x00000020     @ val 0x4107b020
 400         and     r0, r9, r3
 401         teq     r0, r4                  @ ARM 11MPCore?
 402         moveq   pc, lr                  @ yes, assume SMP
 403
 404         mrc     p15, 0, r0, c0, c0, 5   @ read MPIDR
 405         tst     r0, #1 << 31
 406         movne   pc, lr                  @ bit 31 => SMP
 407
 408 __fixup_smp_on_up:
 409         adr     r0, 1f
 410         ldmia   r0, {r3 - r5}
 411         sub     r3, r0, r3
 412         add     r4, r4, r3
 413         add     r5, r5, r3
 414 2:      cmp     r4, r5
 415         movhs   pc, lr
 416         ldmia   r4!, {r0, r6}
 417  ARM(   str     r6, [r0, r3]    )
 418  THUMB( add     r0, r0, r3      )
 419 #ifdef __ARMEB__
 420  THUMB( mov     r6, r6, ror #16 )       @ Convert word order for big-endian.
 421 #endif
 422  THUMB( strh    r6, [r0], #2    )       @ For Thumb-2, store as two halfwords
 423  THUMB( mov     r6, r6, lsr #16 )       @ to be robust against misaligned r3.
 424  THUMB( strh    r6, [r0]        )
 425         b       2b
 426 ENDPROC(__fixup_smp)
 427
 428 1:      .word   .
 429         .word   __smpalt_begin
 430         .word   __smpalt_end
 431
 432         .pushsection .data
 433         .globl  smp_on_up
 434 smp_on_up:
 435         ALT_SMP(.long   1)
 436         ALT_UP(.long    0)
 437         .popsection
 438
 439 #endif
 440
 441 #include "head-common.S"