arch/arm/kernel/head.S

   1 /*
   2  *  linux/arch/arm/kernel/head.S
   3  *
   4  *  Copyright (C) 1994-2002 Russell King
   5  *  Copyright (c) 2003 ARM Limited
   6  *  All Rights Reserved
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  *  Kernel startup code for all 32-bit CPUs
  13  */
  14 #include <linux/linkage.h>
  15 #include <linux/init.h>
  16
  17 #include <asm/assembler.h>
  18 #include <asm/domain.h>
  19 #include <asm/ptrace.h>
  20 #include <asm/asm-offsets.h>
  21 #include <asm/memory.h>
  22 #include <asm/thread_info.h>
  23 #include <asm/system.h>
  24 #include <asm/pgtable.h>
  25
  26 #ifdef CONFIG_DEBUG_LL
  27 #include <mach/debug-macro.S>
  28 #endif
  29
  30 /*
  31  * swapper_pg_dir is the virtual address of the initial page table.
  32  * We place the page tables 16K below KERNEL_RAM_VADDR.  Therefore, we must
  33  * make sure that KERNEL_RAM_VADDR is correctly set.  Currently, we expect
  34  * the least significant 16 bits to be 0x8000, but we could probably
  35  * relax this restriction to KERNEL_RAM_VADDR >= PAGE_OFFSET + 0x4000.
  36  */
  37 #define KERNEL_RAM_VADDR        (PAGE_OFFSET + TEXT_OFFSET)
  38 #if (KERNEL_RAM_VADDR & 0xffff) != 0x8000
  39 #error KERNEL_RAM_VADDR must start at 0xXXXX8000
  40 #endif
  41
  42 #define PG_DIR_SIZE     0x4000
  43 #define PMD_ORDER       2
  44
  45         .globl  swapper_pg_dir
  46         .equ    swapper_pg_dir, KERNEL_RAM_VADDR - PG_DIR_SIZE
  47
  48         .macro  pgtbl, rd, phys
  49         add     \rd, \phys, #TEXT_OFFSET - PG_DIR_SIZE
  50         .endm
  51
  52 #ifdef CONFIG_XIP_KERNEL
  53 #define KERNEL_START    XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR)
  54 #define KERNEL_END      _edata_loc
  55 #else
  56 #define KERNEL_START    KERNEL_RAM_VADDR
  57 #define KERNEL_END      _end
  58 #endif
  59
  60 /*
  61  * Kernel startup entry point.
  62  * ---------------------------
  63  *
  64  * This is normally called from the decompressor code.  The requirements
  65  * are: MMU = off, D-cache = off, I-cache = dont care, r0 = 0,
  66  * r1 = machine nr, r2 = atags or dtb pointer.
  67  *
  68  * This code is mostly position independent, so if you link the kernel at
  69  * 0xc0008000, you call this at __pa(0xc0008000).
  70  *
  71  * See linux/arch/arm/tools/mach-types for the complete list of machine
  72  * numbers for r1.
  73  *
  74  * We're trying to keep crap to a minimum; DO NOT add any machine specific
  75  * crap here - that's what the boot loader (or in extreme, well justified
  76  * circumstances, zImage) is for.
  77  */
  78         .arm
  79
  80         __HEAD
  81 ENTRY(stext)
  82
  83  THUMB( adr     r9, BSYM(1f)    )       @ Kernel is always entered in ARM.
  84  THUMB( bx      r9              )       @ If this is a Thumb-2 kernel,
  85  THUMB( .thumb                  )       @ switch to Thumb now.
  86  THUMB(1:                       )
  87
  88         setmode PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9 @ ensure svc mode
  89                                                 @ and irqs disabled
  90         mrc     p15, 0, r9, c0, c0              @ get processor id
  91         bl      __lookup_processor_type         @ r5=procinfo r9=cpuid
  92         movs    r10, r5                         @ invalid processor (r5=0)?
  93  THUMB( it      eq )            @ force fixup-able long branch encoding
  94         beq     __error_p                       @ yes, error 'p'
  95
  96 #ifndef CONFIG_XIP_KERNEL
  97         adr     r3, 2f
  98         ldmia   r3, {r4, r8}
  99         sub     r4, r3, r4                      @ (PHYS_OFFSET - PAGE_OFFSET)
 100         add     r8, r8, r4                      @ PHYS_OFFSET
 101 #else
 102         ldr     r8, =PHYS_OFFSET                @ always constant in this case
 103 #endif
 104
 105         /*
 106          * r1 = machine no, r2 = atags or dtb,
 107          * r8 = phys_offset, r9 = cpuid, r10 = procinfo
 108          */
 109         bl      __vet_atags
 110 #ifdef CONFIG_SMP_ON_UP
 111         bl      __fixup_smp
 112 #endif
 113 #ifdef CONFIG_ARM_PATCH_PHYS_VIRT
 114         bl      __fixup_pv_table
 115 #endif
 116         bl      __create_page_tables
 117
 118         /*
 119          * The following calls CPU specific code in a position independent
 120          * manner.  See arch/arm/mm/proc-*.S for details.  r10 = base of
 121          * xxx_proc_info structure selected by __lookup_processor_type
 122          * above.  On return, the CPU will be ready for the MMU to be
 123          * turned on, and r0 will hold the CPU control register value.
 124          */
 125         ldr     r13, =__mmap_switched           @ address to jump to after
 126                                                 @ mmu has been enabled
 127         adr     lr, BSYM(1f)                    @ return (PIC) address
 128         mov     r8, r4                          @ set TTBR1 to swapper_pg_dir
 129  ARM(   add     pc, r10, #PROCINFO_INITFUNC     )
 130  THUMB( add     r12, r10, #PROCINFO_INITFUNC    )
 131  THUMB( mov     pc, r12                         )
 132 1:      b       __enable_mmu
 133 ENDPROC(stext)
 134         .ltorg
 135 #ifndef CONFIG_XIP_KERNEL
 136 2:      .long   .
 137         .long   PAGE_OFFSET
 138 #endif
 139
 140 /*
 141  * Setup the initial page tables.  We only setup the barest
 142  * amount which are required to get the kernel running, which
 143  * generally means mapping in the kernel code.
 144  *
 145  * r8 = phys_offset, r9 = cpuid, r10 = procinfo
 146  *
 147  * Returns:
 148  *  r0, r3, r5-r7 corrupted
 149  *  r4 = physical page table address
 150  */
 151 __create_page_tables:
 152         pgtbl   r4, r8                          @ page table address
 153
 154         /*
 155          * Clear the swapper page table
 156          */
 157         mov     r0, r4
 158         mov     r3, #0
 159         add     r6, r0, #PG_DIR_SIZE
 160 1:      str     r3, [r0], #4
 161         str     r3, [r0], #4
 162         str     r3, [r0], #4
 163         str     r3, [r0], #4
 164         teq     r0, r6
 165         bne     1b
 166
 167         ldr     r7, [r10, #PROCINFO_MM_MMUFLAGS] @ mm_mmuflags
 168
 169         /*
 170          * Create identity mapping to cater for __enable_mmu.
 171          * This identity mapping will be removed by paging_init().
 172          */
 173         adr     r0, __enable_mmu_loc
 174         ldmia   r0, {r3, r5, r6}
 175         sub     r0, r0, r3                      @ virt->phys offset
 176         add     r5, r5, r0                      @ phys __enable_mmu
 177         add     r6, r6, r0                      @ phys __enable_mmu_end
 178         mov     r5, r5, lsr #SECTION_SHIFT
 179         mov     r6, r6, lsr #SECTION_SHIFT
 180
 181 1:      orr     r3, r7, r5, lsl #SECTION_SHIFT  @ flags + kernel base
 182         str     r3, [r4, r5, lsl #PMD_ORDER]    @ identity mapping
 183         cmp     r5, r6
 184         addlo   r5, r5, #1                      @ next section
 185         blo     1b
 186
 187         /*
 188          * Now setup the pagetables for our kernel direct
 189          * mapped region.
 190          */
 191         mov     r3, pc
 192         mov     r3, r3, lsr #SECTION_SHIFT
 193         orr     r3, r7, r3, lsl #SECTION_SHIFT
 194         add     r0, r4,  #(KERNEL_START & 0xff000000) >> (SECTION_SHIFT - PMD_ORDER)
 195         str     r3, [r0, #((KERNEL_START & 0x00f00000) >> SECTION_SHIFT) << PMD_ORDER]!
 196         ldr     r6, =(KERNEL_END - 1)
 197         add     r0, r0, #1 << PMD_ORDER
 198         add     r6, r4, r6, lsr #(SECTION_SHIFT - PMD_ORDER)
 199 1:      cmp     r0, r6
 200         add     r3, r3, #1 << SECTION_SHIFT
 201         strls   r3, [r0], #1 << PMD_ORDER
 202         bls     1b
 203
 204 #ifdef CONFIG_XIP_KERNEL
 205         /*
 206          * Map some ram to cover our .data and .bss areas.
 207          */
 208         add     r3, r8, #TEXT_OFFSET
 209         orr     r3, r3, r7
 210         add     r0, r4,  #(KERNEL_RAM_VADDR & 0xff000000) >> (SECTION_SHIFT - PMD_ORDER)
 211         str     r3, [r0, #(KERNEL_RAM_VADDR & 0x00f00000) >> (SECTION_SHIFT - PMD_ORDER)]!
 212         ldr     r6, =(_end - 1)
 213         add     r0, r0, #4
 214         add     r6, r4, r6, lsr #(SECTION_SHIFT - PMD_ORDER)
 215 1:      cmp     r0, r6
 216         add     r3, r3, #1 << 20
 217         strls   r3, [r0], #4
 218         bls     1b
 219 #endif
 220
 221         /*
 222          * Then map boot params address in r2 or
 223          * the first 1MB of ram if boot params address is not specified.
 224          * We map 2 sections in case the ATAGs/DTB crosses a section boundary.
 225          */
 226         mov     r0, r2, lsr #SECTION_SHIFT
 227         movs    r0, r0, lsl #SECTION_SHIFT
 228         moveq   r0, r8
 229         sub     r3, r0, r8
 230         add     r3, r3, #PAGE_OFFSET
 231         add     r3, r4, r3, lsr #(SECTION_SHIFT - PMD_ORDER)
 232         orr     r6, r7, r0
 233         str     r6, [r3], #1 << PMD_ORDER
 234         add     r6, r6, #1 << SECTION_SHIFT
 235         str     r6, [r3]
 236
 237 #ifdef CONFIG_DEBUG_LL
 238 #ifndef CONFIG_DEBUG_ICEDCC
 239         /*
 240          * Map in IO space for serial debugging.
 241          * This allows debug messages to be output
 242          * via a serial console before paging_init.
 243          */
 244         addruart r7, r3, r0
 245
 246         mov     r3, r3, lsr #SECTION_SHIFT
 247         mov     r3, r3, lsl #PMD_ORDER
 248
 249         add     r0, r4, r3
 250         rsb     r3, r3, #0x4000                 @ PTRS_PER_PGD*sizeof(long)
 251         cmp     r3, #0x0800                     @ limit to 512MB
 252         movhi   r3, #0x0800
 253         add     r6, r0, r3
 254         mov     r3, r7, lsr #SECTION_SHIFT
 255         ldr     r7, [r10, #PROCINFO_IO_MMUFLAGS] @ io_mmuflags
 256         orr     r3, r7, r3, lsl #SECTION_SHIFT
 257 1:      str     r3, [r0], #4
 258         add     r3, r3, #1 << SECTION_SHIFT
 259         cmp     r0, r6
 260         blo     1b
 261
 262 #else /* CONFIG_DEBUG_ICEDCC */
 263         /* we don't need any serial debugging mappings for ICEDCC */
 264         ldr     r7, [r10, #PROCINFO_IO_MMUFLAGS] @ io_mmuflags
 265 #endif /* !CONFIG_DEBUG_ICEDCC */
 266
 267 #if defined(CONFIG_ARCH_NETWINDER) || defined(CONFIG_ARCH_CATS)
 268         /*
 269          * If we're using the NetWinder or CATS, we also need to map
 270          * in the 16550-type serial port for the debug messages
 271          */
 272         add     r0, r4, #0xff000000 >> (SECTION_SHIFT - PMD_ORDER)
 273         orr     r3, r7, #0x7c000000
 274         str     r3, [r0]
 275 #endif
 276 #ifdef CONFIG_ARCH_RPC
 277         /*
 278          * Map in screen at 0x02000000 & SCREEN2_BASE
 279          * Similar reasons here - for debug.  This is
 280          * only for Acorn RiscPC architectures.
 281          */
 282         add     r0, r4, #0x02000000 >> (SECTION_SHIFT - PMD_ORDER)
 283         orr     r3, r7, #0x02000000
 284         str     r3, [r0]
 285         add     r0, r4, #0xd8000000 >> (SECTION_SHIFT - PMD_ORDER)
 286         str     r3, [r0]
 287 #endif
 288 #endif
 289         mov     pc, lr
 290 ENDPROC(__create_page_tables)
 291         .ltorg
 292         .align
 293 __enable_mmu_loc:
 294         .long   .
 295         .long   __enable_mmu
 296         .long   __enable_mmu_end
 297
 298 #if defined(CONFIG_SMP)
 299         __CPUINIT
 300 ENTRY(secondary_startup)
 301         /*
 302          * Common entry point for secondary CPUs.
 303          *
 304          * Ensure that we're in SVC mode, and IRQs are disabled.  Lookup
 305          * the processor type - there is no need to check the machine type
 306          * as it has already been validated by the primary processor.
 307          */
 308         setmode PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9
 309         mrc     p15, 0, r9, c0, c0              @ get processor id
 310         bl      __lookup_processor_type
 311         movs    r10, r5                         @ invalid processor?
 312         moveq   r0, #'p'                        @ yes, error 'p'
 313  THUMB( it      eq )            @ force fixup-able long branch encoding
 314         beq     __error_p
 315
 316         /*
 317          * Use the page tables supplied from  __cpu_up.
 318          */
 319         adr     r4, __secondary_data
 320         ldmia   r4, {r5, r7, r12}               @ address to jump to after
 321         sub     lr, r4, r5                      @ mmu has been enabled
 322         ldr     r4, [r7, lr]                    @ get secondary_data.pgdir
 323         add     r7, r7, #4
 324         ldr     r8, [r7, lr]                    @ get secondary_data.swapper_pg_dir
 325         adr     lr, BSYM(__enable_mmu)          @ return address
 326         mov     r13, r12                        @ __secondary_switched address
 327  ARM(   add     pc, r10, #PROCINFO_INITFUNC     ) @ initialise processor
 328                                                   @ (return control reg)
 329  THUMB( add     r12, r10, #PROCINFO_INITFUNC    )
 330  THUMB( mov     pc, r12                         )
 331 ENDPROC(secondary_startup)
 332
 333         /*
 334          * r6  = &secondary_data
 335          */
 336 ENTRY(__secondary_switched)
 337         ldr     sp, [r7, #4]                    @ get secondary_data.stack
 338         mov     fp, #0
 339         b       secondary_start_kernel
 340 ENDPROC(__secondary_switched)
 341
 342         .align
 343
 344         .type   __secondary_data, %object
 345 __secondary_data:
 346         .long   .
 347         .long   secondary_data
 348         .long   __secondary_switched
 349 #endif /* defined(CONFIG_SMP) */
 350
 351
 352
 353 /*
 354  * Setup common bits before finally enabling the MMU.  Essentially
 355  * this is just loading the page table pointer and domain access
 356  * registers.
 357  *
 358  *  r0  = cp#15 control register
 359  *  r1  = machine ID
 360  *  r2  = atags or dtb pointer
 361  *  r4  = page table pointer
 362  *  r9  = processor ID
 363  *  r13 = *virtual* address to jump to upon completion
 364  */
 365 __enable_mmu:
 366 #if defined(CONFIG_ALIGNMENT_TRAP) && __LINUX_ARM_ARCH__ < 6
 367         orr     r0, r0, #CR_A
 368 #else
 369         bic     r0, r0, #CR_A
 370 #endif
 371 #ifdef CONFIG_CPU_DCACHE_DISABLE
 372         bic     r0, r0, #CR_C
 373 #endif
 374 #ifdef CONFIG_CPU_BPREDICT_DISABLE
 375         bic     r0, r0, #CR_Z
 376 #endif
 377 #ifdef CONFIG_CPU_ICACHE_DISABLE
 378         bic     r0, r0, #CR_I
 379 #endif
 380 #ifdef CONFIG_USER_L2_PLE
 381         mov     r5, #3
 382         mcr     p15, 0, r5, c11, c1, 0
 383 #endif
 384         mov     r5, #(domain_val(DOMAIN_USER, DOMAIN_MANAGER) | \
 385                       domain_val(DOMAIN_KERNEL, DOMAIN_MANAGER) | \
 386                       domain_val(DOMAIN_TABLE, DOMAIN_MANAGER) | \
 387                       domain_val(DOMAIN_IO, DOMAIN_CLIENT))
 388         mcr     p15, 0, r5, c3, c0, 0           @ load domain access register
 389         mcr     p15, 0, r4, c2, c0, 0           @ load page table pointer
 390         b       __turn_mmu_on
 391 ENDPROC(__enable_mmu)
 392
 393 /*
 394  * Enable the MMU.  This completely changes the structure of the visible
 395  * memory space.  You will not be able to trace execution through this.
 396  * If you have an enquiry about this, *please* check the linux-arm-kernel
 397  * mailing list archives BEFORE sending another post to the list.
 398  *
 399  *  r0  = cp#15 control register
 400  *  r1  = machine ID
 401  *  r2  = atags or dtb pointer
 402  *  r9  = processor ID
 403  *  r13 = *virtual* address to jump to upon completion
 404  *
 405  * other registers depend on the function called upon completion
 406  */
 407         .align  5
 408 __turn_mmu_on:
 409         mov     r0, r0
 410         mcr     p15, 0, r0, c1, c0, 0           @ write control reg
 411         mrc     p15, 0, r3, c0, c0, 0           @ read id reg
 412         mov     r3, r3
 413         mov     r3, r13
 414         mov     pc, r3
 415 __enable_mmu_end:
 416 ENDPROC(__turn_mmu_on)
 417
 418
 419 #ifdef CONFIG_SMP_ON_UP
 420         __INIT
 421 __fixup_smp:
 422         and     r3, r9, #0x000f0000     @ architecture version
 423         teq     r3, #0x000f0000         @ CPU ID supported?
 424         bne     __fixup_smp_on_up       @ no, assume UP
 425
 426         bic     r3, r9, #0x00ff0000
 427         bic     r3, r3, #0x0000000f     @ mask 0xff00fff0
 428         mov     r4, #0x41000000
 429         orr     r4, r4, #0x0000b000
 430         orr     r4, r4, #0x00000020     @ val 0x4100b020
 431         teq     r3, r4                  @ ARM 11MPCore?
 432         moveq   pc, lr                  @ yes, assume SMP
 433
 434         mrc     p15, 0, r0, c0, c0, 5   @ read MPIDR
 435         and     r0, r0, #0xc0000000     @ multiprocessing extensions and
 436         teq     r0, #0x80000000         @ not part of a uniprocessor system?
 437         moveq   pc, lr                  @ yes, assume SMP
 438
 439 __fixup_smp_on_up:
 440         adr     r0, 1f
 441         ldmia   r0, {r3 - r5}
 442         sub     r3, r0, r3
 443         add     r4, r4, r3
 444         add     r5, r5, r3
 445         b       __do_fixup_smp_on_up
 446 ENDPROC(__fixup_smp)
 447
 448         .align
 449 1:      .word   .
 450         .word   __smpalt_begin
 451         .word   __smpalt_end
 452
 453         .pushsection .data
 454         .globl  smp_on_up
 455 smp_on_up:
 456         ALT_SMP(.long   1)
 457         ALT_UP(.long    0)
 458         .popsection
 459 #endif
 460
 461         .text
 462 __do_fixup_smp_on_up:
 463         cmp     r4, r5
 464         movhs   pc, lr
 465         ldmia   r4!, {r0, r6}
 466  ARM(   str     r6, [r0, r3]    )
 467  THUMB( add     r0, r0, r3      )
 468 #ifdef __ARMEB__
 469  THUMB( mov     r6, r6, ror #16 )       @ Convert word order for big-endian.
 470 #endif
 471  THUMB( strh    r6, [r0], #2    )       @ For Thumb-2, store as two halfwords
 472  THUMB( mov     r6, r6, lsr #16 )       @ to be robust against misaligned r3.
 473  THUMB( strh    r6, [r0]        )
 474         b       __do_fixup_smp_on_up
 475 ENDPROC(__do_fixup_smp_on_up)
 476
 477 ENTRY(fixup_smp)
 478         stmfd   sp!, {r4 - r6, lr}
 479         mov     r4, r0
 480         add     r5, r0, r1
 481         mov     r3, #0
 482         bl      __do_fixup_smp_on_up
 483         ldmfd   sp!, {r4 - r6, pc}
 484 ENDPROC(fixup_smp)
 485
 486 #ifdef CONFIG_ARM_PATCH_PHYS_VIRT
 487
 488 /* __fixup_pv_table - patch the stub instructions with the delta between
 489  * PHYS_OFFSET and PAGE_OFFSET, which is assumed to be 16MiB aligned and
 490  * can be expressed by an immediate shifter operand. The stub instruction
 491  * has a form of '(add|sub) rd, rn, #imm'.
 492  */
 493         __HEAD
 494 __fixup_pv_table:
 495         adr     r0, 1f
 496         ldmia   r0, {r3-r5, r7}
 497         sub     r3, r0, r3      @ PHYS_OFFSET - PAGE_OFFSET
 498         add     r4, r4, r3      @ adjust table start address
 499         add     r5, r5, r3      @ adjust table end address
 500         add     r7, r7, r3      @ adjust __pv_phys_offset address
 501         str     r8, [r7]        @ save computed PHYS_OFFSET to __pv_phys_offset
 502         mov     r6, r3, lsr #24 @ constant for add/sub instructions
 503         teq     r3, r6, lsl #24 @ must be 16MiB aligned
 504 THUMB(  it      ne              @ cross section branch )
 505         bne     __error
 506         str     r6, [r7, #4]    @ save to __pv_offset
 507         b       __fixup_a_pv_table
 508 ENDPROC(__fixup_pv_table)
 509
 510         .align
 511 1:      .long   .
 512         .long   __pv_table_begin
 513         .long   __pv_table_end
 514 2:      .long   __pv_phys_offset
 515
 516         .text
 517 __fixup_a_pv_table:
 518 #ifdef CONFIG_THUMB2_KERNEL
 519         lsls    r6, #24
 520         beq     2f
 521         clz     r7, r6
 522         lsr     r6, #24
 523         lsl     r6, r7
 524         bic     r6, #0x0080
 525         lsrs    r7, #1
 526         orrcs   r6, #0x0080
 527         orr     r6, r6, r7, lsl #12
 528         orr     r6, #0x4000
 529         b       2f
 530 1:      add     r7, r3
 531         ldrh    ip, [r7, #2]
 532         and     ip, 0x8f00
 533         orr     ip, r6  @ mask in offset bits 31-24
 534         strh    ip, [r7, #2]
 535 2:      cmp     r4, r5
 536         ldrcc   r7, [r4], #4    @ use branch for delay slot
 537         bcc     1b
 538         bx      lr
 539 #else
 540         b       2f
 541 1:      ldr     ip, [r7, r3]
 542         bic     ip, ip, #0x000000ff
 543         orr     ip, ip, r6      @ mask in offset bits 31-24
 544         str     ip, [r7, r3]
 545 2:      cmp     r4, r5
 546         ldrcc   r7, [r4], #4    @ use branch for delay slot
 547         bcc     1b
 548         mov     pc, lr
 549 #endif
 550 ENDPROC(__fixup_a_pv_table)
 551
 552 ENTRY(fixup_pv_table)
 553         stmfd   sp!, {r4 - r7, lr}
 554         ldr     r2, 2f                  @ get address of __pv_phys_offset
 555         mov     r3, #0                  @ no offset
 556         mov     r4, r0                  @ r0 = table start
 557         add     r5, r0, r1              @ r1 = table size
 558         ldr     r6, [r2, #4]            @ get __pv_offset
 559         bl      __fixup_a_pv_table
 560         ldmfd   sp!, {r4 - r7, pc}
 561 ENDPROC(fixup_pv_table)
 562
 563         .align
 564 2:      .long   __pv_phys_offset
 565
 566         .data
 567         .globl  __pv_phys_offset
 568         .type   __pv_phys_offset, %object
 569 __pv_phys_offset:
 570         .long   0
 571         .size   __pv_phys_offset, . - __pv_phys_offset
 572 __pv_offset:
 573         .long   0
 574 #endif
 575
 576 #include "head-common.S"