arch/arm/kernel/head-common.S

   1 /*
   2  *  linux/arch/arm/kernel/head-common.S
   3  *
   4  *  Copyright (C) 1994-2002 Russell King
   5  *  Copyright (c) 2003 ARM Limited
   6  *  All Rights Reserved
   7  *
   8  * This program is free software; you can redistribute it and/or modify
   9  * it under the terms of the GNU General Public License version 2 as
  10  * published by the Free Software Foundation.
  11  *
  12  */
  13
  14 #define ATAG_CORE 0x54410001
  15 #define ATAG_CORE_SIZE ((2*4 + 3*4) >> 2)
  16 #define ATAG_CORE_SIZE_EMPTY ((2*4) >> 2)
  17
  18         .align  2
  19         .type   __switch_data, %object
  20 __switch_data:
  21         .long   __mmap_switched
  22         .long   __data_loc                      @ r4
  23         .long   _data                           @ r5
  24         .long   __bss_start                     @ r6
  25         .long   _end                            @ r7
  26         .long   processor_id                    @ r4
  27         .long   __machine_arch_type             @ r5
  28         .long   __atags_pointer                 @ r6
  29         .long   cr_alignment                    @ r7
  30         .long   init_thread_union + THREAD_START_SP @ sp
  31
  32 /*
  33  * The following fragment of code is executed with the MMU on in MMU mode,
  34  * and uses absolute addresses; this is not position independent.
  35  *
  36  *  r0  = cp#15 control register
  37  *  r1  = machine ID
  38  *  r2  = atags pointer
  39  *  r9  = processor ID
  40  */
  41 __mmap_switched:
  42         adr     r3, __switch_data + 4
  43
  44         ldmia   r3!, {r4, r5, r6, r7}
  45         cmp     r4, r5                          @ Copy data segment if needed
  46 1:      cmpne   r5, r6
  47         ldrne   fp, [r4], #4
  48         strne   fp, [r5], #4
  49         bne     1b
  50
  51         mov     fp, #0                          @ Clear BSS (and zero fp)
  52 1:      cmp     r6, r7
  53         strcc   fp, [r6],#4
  54         bcc     1b
  55
  56  ARM(   ldmia   r3, {r4, r5, r6, r7, sp})
  57  THUMB( ldmia   r3, {r4, r5, r6, r7}    )
  58  THUMB( ldr     sp, [r3, #16]           )
  59         str     r9, [r4]                        @ Save processor ID
  60         str     r1, [r5]                        @ Save machine type
  61         str     r2, [r6]                        @ Save atags pointer
  62         bic     r4, r0, #CR_A                   @ Clear 'A' bit
  63         stmia   r7, {r0, r4}                    @ Save control register values
  64         b       start_kernel
  65 ENDPROC(__mmap_switched)
  66
  67 /*
  68  * Exception handling.  Something went wrong and we can't proceed.  We
  69  * ought to tell the user, but since we don't have any guarantee that
  70  * we're even running on the right architecture, we do virtually nothing.
  71  *
  72  * If CONFIG_DEBUG_LL is set we try to print out something about the error
  73  * and hope for the best (useful if bootloader fails to pass a proper
  74  * machine ID for example).
  75  */
  76 __error_p:
  77 #ifdef CONFIG_DEBUG_LL
  78         adr     r0, str_p1
  79         bl      printascii
  80         mov     r0, r9
  81         bl      printhex8
  82         adr     r0, str_p2
  83         bl      printascii
  84         b       __error
  85 str_p1: .asciz  "\nError: unrecognized/unsupported processor variant (0x"
  86 str_p2: .asciz  ").\n"
  87         .align
  88 #endif
  89 ENDPROC(__error_p)
  90
  91 __error_a:
  92 #ifdef CONFIG_DEBUG_LL
  93         mov     r4, r1                          @ preserve machine ID
  94         adr     r0, str_a1
  95         bl      printascii
  96         mov     r0, r4
  97         bl      printhex8
  98         adr     r0, str_a2
  99         bl      printascii
 100         adr     r3, 4f
 101         ldmia   r3, {r4, r5, r6}                @ get machine desc list
 102         sub     r4, r3, r4                      @ get offset between virt&phys
 103         add     r5, r5, r4                      @ convert virt addresses to
 104         add     r6, r6, r4                      @ physical address space
 105 1:      ldr     r0, [r5, #MACHINFO_TYPE]        @ get machine type
 106         bl      printhex8
 107         mov     r0, #'\t'
 108         bl      printch
 109         ldr     r0, [r5, #MACHINFO_NAME]        @ get machine name
 110         add     r0, r0, r4
 111         bl      printascii
 112         mov     r0, #'\n'
 113         bl      printch
 114         add     r5, r5, #SIZEOF_MACHINE_DESC    @ next machine_desc
 115         cmp     r5, r6
 116         blo     1b
 117         adr     r0, str_a3
 118         bl      printascii
 119         b       __error
 120 ENDPROC(__error_a)
 121
 122 str_a1: .asciz  "\nError: unrecognized/unsupported machine ID (r1 = 0x"
 123 str_a2: .asciz  ").\n\nAvailable machine support:\n\nID (hex)\tNAME\n"
 124 str_a3: .asciz  "\nPlease check your kernel config and/or bootloader.\n"
 125         .align
 126 #endif
 127
 128 __error:
 129 #ifdef CONFIG_ARCH_RPC
 130 /*
 131  * Turn the screen red on a error - RiscPC only.
 132  */
 133         mov     r0, #0x02000000
 134         mov     r3, #0x11
 135         orr     r3, r3, r3, lsl #8
 136         orr     r3, r3, r3, lsl #16
 137         str     r3, [r0], #4
 138         str     r3, [r0], #4
 139         str     r3, [r0], #4
 140         str     r3, [r0], #4
 141 #endif
 142 1:      mov     r0, r0
 143         b       1b
 144 ENDPROC(__error)
 145
 146
 147 /*
 148  * This provides a C-API version of __lookup_processor_type
 149  */
 150 ENTRY(lookup_processor_type)
 151         stmfd   sp!, {r4 - r6, r9, lr}
 152         mov     r9, r0
 153         bl      __lookup_processor_type
 154         mov     r0, r5
 155         ldmfd   sp!, {r4 - r6, r9, pc}
 156 ENDPROC(lookup_processor_type)
 157
 158 /*
 159  * Look in <asm/procinfo.h> and arch/arm/kernel/arch.[ch] for
 160  * more information about the __proc_info and __arch_info structures.
 161  */
 162         .align  2
 163 4:      .long   .
 164         .long   __arch_info_begin
 165         .long   __arch_info_end
 166
 167 /*
 168  * Lookup machine architecture in the linker-build list of architectures.
 169  * Note that we can't use the absolute addresses for the __arch_info
 170  * lists since we aren't running with the MMU on (and therefore, we are
 171  * not in the correct address space).  We have to calculate the offset.
 172  *
 173  *  r1 = machine architecture number
 174  * Returns:
 175  *  r3, r4, r6 corrupted
 176  *  r5 = mach_info pointer in physical address space
 177  */
 178 __lookup_machine_type:
 179         adr     r3, 4b
 180         ldmia   r3, {r4, r5, r6}
 181         sub     r3, r3, r4                      @ get offset between virt&phys
 182         add     r5, r5, r3                      @ convert virt addresses to
 183         add     r6, r6, r3                      @ physical address space
 184 1:      ldr     r3, [r5, #MACHINFO_TYPE]        @ get machine type
 185         teq     r3, r1                          @ matches loader number?
 186         beq     2f                              @ found
 187         add     r5, r5, #SIZEOF_MACHINE_DESC    @ next machine_desc
 188         cmp     r5, r6
 189         blo     1b
 190         mov     r5, #0                          @ unknown machine
 191 2:      mov     pc, lr
 192 ENDPROC(__lookup_machine_type)
 193
 194 /*
 195  * This provides a C-API version of the above function.
 196  */
 197 ENTRY(lookup_machine_type)
 198         stmfd   sp!, {r4 - r6, lr}
 199         mov     r1, r0
 200         bl      __lookup_machine_type
 201         mov     r0, r5
 202         ldmfd   sp!, {r4 - r6, pc}
 203 ENDPROC(lookup_machine_type)
 204
 205 /* Determine validity of the r2 atags pointer.  The heuristic requires
 206  * that the pointer be aligned, in the first 16k of physical RAM and
 207  * that the ATAG_CORE marker is first and present.  Future revisions
 208  * of this function may be more lenient with the physical address and
 209  * may also be able to move the ATAGS block if necessary.
 210  *
 211  * r8  = machinfo
 212  *
 213  * Returns:
 214  *  r2 either valid atags pointer, or zero
 215  *  r5, r6 corrupted
 216  */
 217 __vet_atags:
 218         tst     r2, #0x3                        @ aligned?
 219         bne     1f
 220
 221         ldr     r5, [r2, #0]                    @ is first tag ATAG_CORE?
 222         cmp     r5, #ATAG_CORE_SIZE
 223         cmpne   r5, #ATAG_CORE_SIZE_EMPTY
 224         bne     1f
 225         ldr     r5, [r2, #4]
 226         ldr     r6, =ATAG_CORE
 227         cmp     r5, r6
 228         bne     1f
 229
 230         mov     pc, lr                          @ atag pointer is ok
 231
 232 1:      mov     r2, #0
 233         mov     pc, lr
 234 ENDPROC(__vet_atags)
 235
 236 /*
 237  * Read processor ID register (CP#15, CR0), and look up in the linker-built
 238  * supported processor list.  Note that we can't use the absolute addresses
 239  * for the __proc_info lists since we aren't running with the MMU on
 240  * (and therefore, we are not in the correct address space).  We have to
 241  * calculate the offset.
 242  *
 243  *      r9 = cpuid
 244  * Returns:
 245  *      r3, r4, r6 corrupted
 246  *      r5 = proc_info pointer in physical address space
 247  *      r9 = cpuid (preserved)
 248  */
 249         __CPUINIT
 250 __lookup_processor_type:
 251         adr     r3, __lookup_processor_type_data
 252         ldmia   r3, {r4 - r6}
 253         sub     r3, r3, r4                      @ get offset between virt&phys
 254         add     r5, r5, r3                      @ convert virt addresses to
 255         add     r6, r6, r3                      @ physical address space
 256 1:      ldmia   r5, {r3, r4}                    @ value, mask
 257         and     r4, r4, r9                      @ mask wanted bits
 258         teq     r3, r4
 259         beq     2f
 260         add     r5, r5, #PROC_INFO_SZ           @ sizeof(proc_info_list)
 261         cmp     r5, r6
 262         blo     1b
 263         mov     r5, #0                          @ unknown processor
 264 2:      mov     pc, lr
 265 ENDPROC(__lookup_processor_type)
 266
 267 /*
 268  * Look in <asm/procinfo.h> for information about the __proc_info structure.
 269  */
 270         .align  2
 271         .type   __lookup_processor_type_data, %object
 272 __lookup_processor_type_data:
 273         .long   .
 274         .long   __proc_info_begin
 275         .long   __proc_info_end
 276         .size   __lookup_processor_type_data, . - __lookup_processor_type_data