arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/unistd.h>
  12 #include <asm/ftrace.h>
  13 #include <mach/entry-macro.S>
  14 #include <asm/unwind.h>
  15
  16 #include "entry-header.S"
  17
  18
  19         .align  5
  20 /*
  21  * This is the fast syscall return path.  We do as little as
  22  * possible here, and this includes saving r0 back into the SVC
  23  * stack.
  24  */
  25 ret_fast_syscall:
  26  UNWIND(.fnstart        )
  27  UNWIND(.cantunwind     )
  28         disable_irq                             @ disable interrupts
  29         ldr     r1, [tsk, #TI_FLAGS]
  30         tst     r1, #_TIF_WORK_MASK
  31         bne     fast_work_pending
  32
  33         /* perform architecture specific actions before user return */
  34         arch_ret_to_user r1, lr
  35
  36         restore_user_regs fast = 1, offset = S_OFF
  37  UNWIND(.fnend          )
  38
  39 /*
  40  * Ok, we need to do extra processing, enter the slow path.
  41  */
  42 fast_work_pending:
  43         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  44 work_pending:
  45         tst     r1, #_TIF_NEED_RESCHED
  46         bne     work_resched
  47         tst     r1, #_TIF_SIGPENDING|_TIF_NOTIFY_RESUME
  48         beq     no_work_pending
  49         mov     r0, sp                          @ 'regs'
  50         mov     r2, why                         @ 'syscall'
  51         bl      do_notify_resume
  52         b       ret_slow_syscall                @ Check work again
  53
  54 work_resched:
  55         bl      schedule
  56 /*
  57  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  58  */
  59 ENTRY(ret_to_user)
  60 ret_slow_syscall:
  61         disable_irq                             @ disable interrupts
  62         ldr     r1, [tsk, #TI_FLAGS]
  63         tst     r1, #_TIF_WORK_MASK
  64         bne     work_pending
  65 no_work_pending:
  66         /* perform architecture specific actions before user return */
  67         arch_ret_to_user r1, lr
  68
  69         restore_user_regs fast = 0, offset = 0
  70 ENDPROC(ret_to_user)
  71
  72 /*
  73  * This is how we return from a fork.
  74  */
  75 ENTRY(ret_from_fork)
  76         bl      schedule_tail
  77         get_thread_info tsk
  78         ldr     r1, [tsk, #TI_FLAGS]            @ check for syscall tracing
  79         mov     why, #1
  80         tst     r1, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
  81         beq     ret_slow_syscall
  82         mov     r1, sp
  83         mov     r0, #1                          @ trace exit [IP = 1]
  84         bl      syscall_trace
  85         b       ret_slow_syscall
  86 ENDPROC(ret_from_fork)
  87
  88         .equ NR_syscalls,0
  89 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
  90 #include "calls.S"
  91 #undef CALL
  92 #define CALL(x) .long x
  93
  94 #ifdef CONFIG_FUNCTION_TRACER
  95 /*
  96  * When compiling with -pg, gcc inserts a call to the mcount routine at the
  97  * start of every function.  In mcount, apart from the function's address (in
  98  * lr), we need to get hold of the function's caller's address.
  99  *
 100  * Older GCCs (pre-4.4) inserted a call to a routine called mcount like this:
 101  *
 102  *      bl      mcount
 103  *
 104  * These versions have the limitation that in order for the mcount routine to
 105  * be able to determine the function's caller's address, an APCS-style frame
 106  * pointer (which is set up with something like the code below) is required.
 107  *
 108  *      mov     ip, sp
 109  *      push    {fp, ip, lr, pc}
 110  *      sub     fp, ip, #4
 111  *
 112  * With EABI, these frame pointers are not available unless -mapcs-frame is
 113  * specified, and if building as Thumb-2, not even then.
 114  *
 115  * Newer GCCs (4.4+) solve this problem by introducing a new version of mcount,
 116  * with call sites like:
 117  *
 118  *      push    {lr}
 119  *      bl      __gnu_mcount_nc
 120  *
 121  * With these compilers, frame pointers are not necessary.
 122  *
 123  * mcount can be thought of as a function called in the middle of a subroutine
 124  * call.  As such, it needs to be transparent for both the caller and the
 125  * callee: the original lr needs to be restored when leaving mcount, and no
 126  * registers should be clobbered.  (In the __gnu_mcount_nc implementation, we
 127  * clobber the ip register.  This is OK because the ARM calling convention
 128  * allows it to be clobbered in subroutines and doesn't use it to hold
 129  * parameters.)
 130  *
 131  * When using dynamic ftrace, we patch out the mcount call by a "mov r0, r0"
 132  * for the mcount case, and a "pop {lr}" for the __gnu_mcount_nc case (see
 133  * arch/arm/kernel/ftrace.c).
 134  */
 135
 136 #ifndef CONFIG_OLD_MCOUNT
 137 #if (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 4))
 138 #error Ftrace requires CONFIG_FRAME_POINTER=y with GCC older than 4.4.0.
 139 #endif
 140 #endif
 141
 142 #ifdef CONFIG_DYNAMIC_FTRACE
 143 ENTRY(__gnu_mcount_nc)
 144         mov     ip, lr
 145         ldmia   sp!, {lr}
 146         mov     pc, ip
 147 ENDPROC(__gnu_mcount_nc)
 148
 149 ENTRY(ftrace_caller)
 150         stmdb   sp!, {r0-r3, lr}
 151         mov     r0, lr
 152         sub     r0, r0, #MCOUNT_INSN_SIZE
 153         ldr     r1, [sp, #20]
 154
 155         .global ftrace_call
 156 ftrace_call:
 157         bl      ftrace_stub
 158         ldmia   sp!, {r0-r3, ip, lr}
 159         mov     pc, ip
 160 ENDPROC(ftrace_caller)
 161
 162 #ifdef CONFIG_OLD_MCOUNT
 163 ENTRY(mcount)
 164         stmdb   sp!, {lr}
 165         ldr     lr, [fp, #-4]
 166         ldmia   sp!, {pc}
 167 ENDPROC(mcount)
 168
 169 ENTRY(ftrace_caller_old)
 170         stmdb   sp!, {r0-r3, lr}
 171         ldr     r1, [fp, #-4]
 172         mov     r0, lr
 173         sub     r0, r0, #MCOUNT_INSN_SIZE
 174
 175         .globl ftrace_call_old
 176 ftrace_call_old:
 177         bl      ftrace_stub
 178         ldr     lr, [fp, #-4]                   @ restore lr
 179         ldmia   sp!, {r0-r3, pc}
 180 ENDPROC(ftrace_caller_old)
 181 #endif
 182
 183 #else
 184
 185 ENTRY(__gnu_mcount_nc)
 186         stmdb   sp!, {r0-r3, lr}
 187         ldr     r0, =ftrace_trace_function
 188         ldr     r2, [r0]
 189         adr     r0, .Lftrace_stub
 190         cmp     r0, r2
 191         bne     gnu_trace
 192         ldmia   sp!, {r0-r3, ip, lr}
 193         mov     pc, ip
 194
 195 gnu_trace:
 196         ldr     r1, [sp, #20]                   @ lr of instrumented routine
 197         mov     r0, lr
 198         sub     r0, r0, #MCOUNT_INSN_SIZE
 199         adr     lr, BSYM(1f)
 200         mov     pc, r2
 201 1:
 202         ldmia   sp!, {r0-r3, ip, lr}
 203         mov     pc, ip
 204 ENDPROC(__gnu_mcount_nc)
 205
 206 #ifdef CONFIG_OLD_MCOUNT
 207 /*
 208  * This is under an ifdef in order to force link-time errors for people trying
 209  * to build with !FRAME_POINTER with a GCC which doesn't use the new-style
 210  * mcount.
 211  */
 212 ENTRY(mcount)
 213         stmdb   sp!, {r0-r3, lr}
 214         ldr     r0, =ftrace_trace_function
 215         ldr     r2, [r0]
 216         adr     r0, ftrace_stub
 217         cmp     r0, r2
 218         bne     trace
 219         ldr     lr, [fp, #-4]                   @ restore lr
 220         ldmia   sp!, {r0-r3, pc}
 221
 222 trace:
 223         ldr     r1, [fp, #-4]                   @ lr of instrumented routine
 224         mov     r0, lr
 225         sub     r0, r0, #MCOUNT_INSN_SIZE
 226         mov     lr, pc
 227         mov     pc, r2
 228         ldr     lr, [fp, #-4]                   @ restore lr
 229         ldmia   sp!, {r0-r3, pc}
 230 ENDPROC(mcount)
 231 #endif
 232
 233 #endif /* CONFIG_DYNAMIC_FTRACE */
 234
 235 ENTRY(ftrace_stub)
 236 .Lftrace_stub:
 237         mov     pc, lr
 238 ENDPROC(ftrace_stub)
 239
 240 #endif /* CONFIG_FUNCTION_TRACER */
 241
 242 /*=============================================================================
 243  * SWI handler
 244  *-----------------------------------------------------------------------------
 245  */
 246
 247         /* If we're optimising for StrongARM the resulting code won't
 248            run on an ARM7 and we can save a couple of instructions.
 249                                                                 --pb */
 250 #ifdef CONFIG_CPU_ARM710
 251 #define A710(code...) code
 252 .Larm710bug:
 253         ldmia   sp, {r0 - lr}^                  @ Get calling r0 - lr
 254         mov     r0, r0
 255         add     sp, sp, #S_FRAME_SIZE
 256         subs    pc, lr, #4
 257 #else
 258 #define A710(code...)
 259 #endif
 260
 261         .align  5
 262 ENTRY(vector_swi)
 263         sub     sp, sp, #S_FRAME_SIZE
 264         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 265  ARM(   add     r8, sp, #S_PC           )
 266  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 267  THUMB( mov     r8, sp                  )
 268  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 269         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 270         str     lr, [sp, #S_PC]                 @ Save calling PC
 271         str     r8, [sp, #S_PSR]                @ Save CPSR
 272         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 273         zero_fp
 274
 275         /*
 276          * Get the system call number.
 277          */
 278
 279 #if defined(CONFIG_OABI_COMPAT)
 280
 281         /*
 282          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 283          * value to determine if it is an EABI or an old ABI call.
 284          */
 285 #ifdef CONFIG_ARM_THUMB
 286         tst     r8, #PSR_T_BIT
 287         movne   r10, #0                         @ no thumb OABI emulation
 288         ldreq   r10, [lr, #-4]                  @ get SWI instruction
 289 #else
 290         ldr     r10, [lr, #-4]                  @ get SWI instruction
 291   A710( and     ip, r10, #0x0f000000            @ check for SWI         )
 292   A710( teq     ip, #0x0f000000                                         )
 293   A710( bne     .Larm710bug                                             )
 294 #endif
 295 #ifdef CONFIG_CPU_ENDIAN_BE8
 296         rev     r10, r10                        @ little endian instruction
 297 #endif
 298
 299 #elif defined(CONFIG_AEABI)
 300
 301         /*
 302          * Pure EABI user space always put syscall number into scno (r7).
 303          */
 304   A710( ldr     ip, [lr, #-4]                   @ get SWI instruction   )
 305   A710( and     ip, ip, #0x0f000000             @ check for SWI         )
 306   A710( teq     ip, #0x0f000000                                         )
 307   A710( bne     .Larm710bug                                             )
 308
 309 #elif defined(CONFIG_ARM_THUMB)
 310
 311         /* Legacy ABI only, possibly thumb mode. */
 312         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 313         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 314         ldreq   scno, [lr, #-4]
 315
 316 #else
 317
 318         /* Legacy ABI only. */
 319         ldr     scno, [lr, #-4]                 @ get SWI instruction
 320   A710( and     ip, scno, #0x0f000000           @ check for SWI         )
 321   A710( teq     ip, #0x0f000000                                         )
 322   A710( bne     .Larm710bug                                             )
 323
 324 #endif
 325
 326 #ifdef CONFIG_ALIGNMENT_TRAP
 327         ldr     ip, __cr_alignment
 328         ldr     ip, [ip]
 329         mcr     p15, 0, ip, c1, c0              @ update control register
 330 #endif
 331         enable_irq
 332
 333         get_thread_info tsk
 334         adr     tbl, sys_call_table             @ load syscall table pointer
 335         ldr     ip, [tsk, #TI_FLAGS]            @ check for syscall tracing
 336
 337 #if defined(CONFIG_OABI_COMPAT)
 338         /*
 339          * If the swi argument is zero, this is an EABI call and we do nothing.
 340          *
 341          * If this is an old ABI call, get the syscall number into scno and
 342          * get the old ABI syscall table address.
 343          */
 344         bics    r10, r10, #0xff000000
 345         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 346         ldrne   tbl, =sys_oabi_call_table
 347 #elif !defined(CONFIG_AEABI)
 348         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 349         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 350 #endif
 351
 352         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 353         tst     ip, #_TIF_SYSCALL_TRACE         @ are we tracing syscalls?
 354         bne     __sys_trace
 355
 356         cmp     scno, #NR_syscalls              @ check upper syscall limit
 357         adr     lr, BSYM(ret_fast_syscall)      @ return address
 358         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 359
 360         add     r1, sp, #S_OFF
 361 2:      mov     why, #0                         @ no longer a real syscall
 362         cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 363         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 364         bcs     arm_syscall
 365         b       sys_ni_syscall                  @ not private func
 366 ENDPROC(vector_swi)
 367
 368         /*
 369          * This is the really slow path.  We're going to be doing
 370          * context switches, and waiting for our parent to respond.
 371          */
 372 __sys_trace:
 373         mov     r2, scno
 374         add     r1, sp, #S_OFF
 375         mov     r0, #0                          @ trace entry [IP = 0]
 376         bl      syscall_trace
 377
 378         adr     lr, BSYM(__sys_trace_return)    @ return address
 379         mov     scno, r0                        @ syscall number (possibly new)
 380         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 381         cmp     scno, #NR_syscalls              @ check upper syscall limit
 382         ldmccia r1, {r0 - r3}                   @ have to reload r0 - r3
 383         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 384         b       2b
 385
 386 __sys_trace_return:
 387         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 388         mov     r2, scno
 389         mov     r1, sp
 390         mov     r0, #1                          @ trace exit [IP = 1]
 391         bl      syscall_trace
 392         b       ret_slow_syscall
 393
 394         .align  5
 395 #ifdef CONFIG_ALIGNMENT_TRAP
 396         .type   __cr_alignment, #object
 397 __cr_alignment:
 398         .word   cr_alignment
 399 #endif
 400         .ltorg
 401
 402 /*
 403  * This is the syscall table declaration for native ABI syscalls.
 404  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 405  */
 406 #define ABI(native, compat) native
 407 #ifdef CONFIG_AEABI
 408 #define OBSOLETE(syscall) sys_ni_syscall
 409 #else
 410 #define OBSOLETE(syscall) syscall
 411 #endif
 412
 413         .type   sys_call_table, #object
 414 ENTRY(sys_call_table)
 415 #include "calls.S"
 416 #undef ABI
 417 #undef OBSOLETE
 418
 419 /*============================================================================
 420  * Special system call wrappers
 421  */
 422 @ r0 = syscall number
 423 @ r8 = syscall table
 424 sys_syscall:
 425                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 426                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 427                 cmpne   scno, #NR_syscalls      @ check range
 428                 stmloia sp, {r5, r6}            @ shuffle args
 429                 movlo   r0, r1
 430                 movlo   r1, r2
 431                 movlo   r2, r3
 432                 movlo   r3, r4
 433                 ldrlo   pc, [tbl, scno, lsl #2]
 434                 b       sys_ni_syscall
 435 ENDPROC(sys_syscall)
 436
 437 sys_fork_wrapper:
 438                 add     r0, sp, #S_OFF
 439                 b       sys_fork
 440 ENDPROC(sys_fork_wrapper)
 441
 442 sys_vfork_wrapper:
 443                 add     r0, sp, #S_OFF
 444                 b       sys_vfork
 445 ENDPROC(sys_vfork_wrapper)
 446
 447 sys_execve_wrapper:
 448                 add     r3, sp, #S_OFF
 449                 b       sys_execve
 450 ENDPROC(sys_execve_wrapper)
 451
 452 sys_clone_wrapper:
 453                 add     ip, sp, #S_OFF
 454                 str     ip, [sp, #4]
 455                 b       sys_clone
 456 ENDPROC(sys_clone_wrapper)
 457
 458 sys_sigreturn_wrapper:
 459                 add     r0, sp, #S_OFF
 460                 b       sys_sigreturn
 461 ENDPROC(sys_sigreturn_wrapper)
 462
 463 sys_rt_sigreturn_wrapper:
 464                 add     r0, sp, #S_OFF
 465                 b       sys_rt_sigreturn
 466 ENDPROC(sys_rt_sigreturn_wrapper)
 467
 468 sys_sigaltstack_wrapper:
 469                 ldr     r2, [sp, #S_OFF + S_SP]
 470                 b       do_sigaltstack
 471 ENDPROC(sys_sigaltstack_wrapper)
 472
 473 sys_statfs64_wrapper:
 474                 teq     r1, #88
 475                 moveq   r1, #84
 476                 b       sys_statfs64
 477 ENDPROC(sys_statfs64_wrapper)
 478
 479 sys_fstatfs64_wrapper:
 480                 teq     r1, #88
 481                 moveq   r1, #84
 482                 b       sys_fstatfs64
 483 ENDPROC(sys_fstatfs64_wrapper)
 484
 485 /*
 486  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 487  * offset, we return EINVAL.
 488  */
 489 sys_mmap2:
 490 #if PAGE_SHIFT > 12
 491                 tst     r5, #PGOFF_MASK
 492                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 493                 streq   r5, [sp, #4]
 494                 beq     sys_mmap_pgoff
 495                 mov     r0, #-EINVAL
 496                 mov     pc, lr
 497 #else
 498                 str     r5, [sp, #4]
 499                 b       sys_mmap_pgoff
 500 #endif
 501 ENDPROC(sys_mmap2)
 502
 503 #ifdef CONFIG_OABI_COMPAT
 504
 505 /*
 506  * These are syscalls with argument register differences
 507  */
 508
 509 sys_oabi_pread64:
 510                 stmia   sp, {r3, r4}
 511                 b       sys_pread64
 512 ENDPROC(sys_oabi_pread64)
 513
 514 sys_oabi_pwrite64:
 515                 stmia   sp, {r3, r4}
 516                 b       sys_pwrite64
 517 ENDPROC(sys_oabi_pwrite64)
 518
 519 sys_oabi_truncate64:
 520                 mov     r3, r2
 521                 mov     r2, r1
 522                 b       sys_truncate64
 523 ENDPROC(sys_oabi_truncate64)
 524
 525 sys_oabi_ftruncate64:
 526                 mov     r3, r2
 527                 mov     r2, r1
 528                 b       sys_ftruncate64
 529 ENDPROC(sys_oabi_ftruncate64)
 530
 531 sys_oabi_readahead:
 532                 str     r3, [sp]
 533                 mov     r3, r2
 534                 mov     r2, r1
 535                 b       sys_readahead
 536 ENDPROC(sys_oabi_readahead)
 537
 538 /*
 539  * Let's declare a second syscall table for old ABI binaries
 540  * using the compatibility syscall entries.
 541  */
 542 #define ABI(native, compat) compat
 543 #define OBSOLETE(syscall) syscall
 544
 545         .type   sys_oabi_call_table, #object
 546 ENTRY(sys_oabi_call_table)
 547 #include "calls.S"
 548 #undef ABI
 549 #undef OBSOLETE
 550
 551 #endif
 552