arch/arm/boot/compressed/vmlinux.lds.in

   1 /*
   2  *  linux/arch/arm/boot/compressed/vmlinux.lds.in
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10 OUTPUT_ARCH(arm)
  11 ENTRY(_start)
  12 SECTIONS
  13 {
  14   /DISCARD/ : {
  15     *(.ARM.exidx*)
  16     *(.ARM.extab*)
  17   }
  18
  19   . = TEXT_START;
  20   _text = .;
  21
  22   .text : {
  23     _start = .;
  24     *(.start)
  25     *(.text)
  26     *(.text.*)
  27     *(.fixup)
  28     *(.gnu.warning)
  29     *(.rodata)
  30     *(.rodata.*)
  31     *(.glue_7)
  32     *(.glue_7t)
  33     *(.piggydata)
  34     . = ALIGN(4);
  35   }
  36
  37   _etext = .;
  38
  39   /* Assume size of decompressed image is 4x the compressed image */
  40   _image_size = (_etext - _text) * 4;
  41
  42   _got_start = .;
  43   .got                  : { *(.got) }
  44   _got_end = .;
  45   .got.plt              : { *(.got.plt) }
  46   .data                 : { *(.data) }
  47   _edata = .;
  48
  49   . = BSS_START;
  50   __bss_start = .;
  51   .bss                  : { *(.bss) }
  52   _end = .;
  53
  54   .stack (NOLOAD)       : { *(.stack) }
  55
  56   .stab 0               : { *(.stab) }
  57   .stabstr 0            : { *(.stabstr) }
  58   .stab.excl 0          : { *(.stab.excl) }
  59   .stab.exclstr 0       : { *(.stab.exclstr) }
  60   .stab.index 0         : { *(.stab.index) }
  61   .stab.indexstr 0      : { *(.stab.indexstr) }
  62   .comment 0            : { *(.comment) }
  63 }
  64