arch/arm/boot/compressed/head.S

   1 /*
   2  *  linux/arch/arm/boot/compressed/head.S
   3  *
   4  *  Copyright (C) 1996-2002 Russell King
   5  *  Copyright (C) 2004 Hyok S. Choi (MPU support)
   6  *
   7  * This program is free software; you can redistribute it and/or modify
   8  * it under the terms of the GNU General Public License version 2 as
   9  * published by the Free Software Foundation.
  10  */
  11 #include <linux/linkage.h>
  12
  13 /*
  14  * Debugging stuff
  15  *
  16  * Note that these macros must not contain any code which is not
  17  * 100% relocatable.  Any attempt to do so will result in a crash.
  18  * Please select one of the following when turning on debugging.
  19  */
  20 #ifdef DEBUG
  21
  22 #if defined(CONFIG_DEBUG_ICEDCC)
  23                 .macro  loadsp, rb
  24                 .endm
  25                 .macro  writeb, ch, rb
  26                 mcr     p14, 0, \ch, c0, c1, 0
  27                 .endm
  28 #else
  29
  30 #include <asm/arch/debug-macro.S>
  31
  32                 .macro  writeb, ch, rb
  33                 senduart \ch, \rb
  34                 .endm
  35
  36 #if defined(CONFIG_ARCH_SA1100)
  37                 .macro  loadsp, rb
  38                 mov     \rb, #0x80000000        @ physical base address
  39 #ifdef CONFIG_DEBUG_LL_SER3
  40                 add     \rb, \rb, #0x00050000   @ Ser3
  41 #else
  42                 add     \rb, \rb, #0x00010000   @ Ser1
  43 #endif
  44                 .endm
  45 #elif defined(CONFIG_ARCH_IOP331)
  46                 .macro loadsp, rb
  47                 mov     \rb, #0xff000000
  48                 orr     \rb, \rb, #0x00ff0000
  49                 orr     \rb, \rb, #0x0000f700   @ location of the UART
  50                 .endm
  51 #elif defined(CONFIG_ARCH_S3C2410)
  52                 .macro loadsp, rb
  53                 mov     \rb, #0x50000000
  54                 add     \rb, \rb, #0x4000 * CONFIG_S3C2410_LOWLEVEL_UART_PORT
  55                 .endm
  56 #else
  57                 .macro  loadsp, rb
  58                 addruart \rb
  59                 .endm
  60 #endif
  61 #endif
  62 #endif
  63
  64                 .macro  kputc,val
  65                 mov     r0, \val
  66                 bl      putc
  67                 .endm
  68
  69                 .macro  kphex,val,len
  70                 mov     r0, \val
  71                 mov     r1, #\len
  72                 bl      phex
  73                 .endm
  74
  75                 .macro  debug_reloc_start
  76 #ifdef DEBUG
  77                 kputc   #'\n'
  78                 kphex   r6, 8           /* processor id */
  79                 kputc   #':'
  80                 kphex   r7, 8           /* architecture id */
  81                 kputc   #':'
  82                 mrc     p15, 0, r0, c1, c0
  83                 kphex   r0, 8           /* control reg */
  84                 kputc   #'\n'
  85                 kphex   r5, 8           /* decompressed kernel start */
  86                 kputc   #'-'
  87                 kphex   r9, 8           /* decompressed kernel end  */
  88                 kputc   #'>'
  89                 kphex   r4, 8           /* kernel execution address */
  90                 kputc   #'\n'
  91 #endif
  92                 .endm
  93
  94                 .macro  debug_reloc_end
  95 #ifdef DEBUG
  96                 kphex   r5, 8           /* end of kernel */
  97                 kputc   #'\n'
  98                 mov     r0, r4
  99                 bl      memdump         /* dump 256 bytes at start of kernel */
 100 #endif
 101                 .endm
 102
 103                 .section ".start", #alloc, #execinstr
 104 /*
 105  * sort out different calling conventions
 106  */
 107                 .align
 108 start:
 109                 .type   start,#function
 110                 .rept   8
 111                 mov     r0, r0
 112                 .endr
 113
 114                 b       1f
 115                 .word   0x016f2818              @ Magic numbers to help the loader
 116                 .word   start                   @ absolute load/run zImage address
 117                 .word   _edata                  @ zImage end address
 118 1:              mov     r7, r1                  @ save architecture ID
 119                 mov     r8, r2                  @ save atags pointer
 120
 121 #ifndef __ARM_ARCH_2__
 122                 /*
 123                  * Booting from Angel - need to enter SVC mode and disable
 124                  * FIQs/IRQs (numeric definitions from angel arm.h source).
 125                  * We only do this if we were in user mode on entry.
 126                  */
 127                 mrs     r2, cpsr                @ get current mode
 128                 tst     r2, #3                  @ not user?
 129                 bne     not_angel
 130                 mov     r0, #0x17               @ angel_SWIreason_EnterSVC
 131                 swi     0x123456                @ angel_SWI_ARM
 132 not_angel:
 133                 mrs     r2, cpsr                @ turn off interrupts to
 134                 orr     r2, r2, #0xc0           @ prevent angel from running
 135                 msr     cpsr_c, r2
 136 #else
 137                 teqp    pc, #0x0c000003         @ turn off interrupts
 138 #endif
 139
 140                 /*
 141                  * Note that some cache flushing and other stuff may
 142                  * be needed here - is there an Angel SWI call for this?
 143                  */
 144
 145                 /*
 146                  * some architecture specific code can be inserted
 147                  * by the linker here, but it should preserve r7, r8, and r9.
 148                  */
 149
 150                 .text
 151                 adr     r0, LC0
 152                 ldmia   r0, {r1, r2, r3, r4, r5, r6, ip, sp}
 153                 subs    r0, r0, r1              @ calculate the delta offset
 154
 155                                                 @ if delta is zero, we are
 156                 beq     not_relocated           @ running at the address we
 157                                                 @ were linked at.
 158
 159                 /*
 160                  * We're running at a different address.  We need to fix
 161                  * up various pointers:
 162                  *   r5 - zImage base address
 163                  *   r6 - GOT start
 164                  *   ip - GOT end
 165                  */
 166                 add     r5, r5, r0
 167                 add     r6, r6, r0
 168                 add     ip, ip, r0
 169
 170 #ifndef CONFIG_ZBOOT_ROM
 171                 /*
 172                  * If we're running fully PIC === CONFIG_ZBOOT_ROM = n,
 173                  * we need to fix up pointers into the BSS region.
 174                  *   r2 - BSS start
 175                  *   r3 - BSS end
 176                  *   sp - stack pointer
 177                  */
 178                 add     r2, r2, r0
 179                 add     r3, r3, r0
 180                 add     sp, sp, r0
 181
 182                 /*
 183                  * Relocate all entries in the GOT table.
 184                  */
 185 1:              ldr     r1, [r6, #0]            @ relocate entries in the GOT
 186                 add     r1, r1, r0              @ table.  This fixes up the
 187                 str     r1, [r6], #4            @ C references.
 188                 cmp     r6, ip
 189                 blo     1b
 190 #else
 191
 192                 /*
 193                  * Relocate entries in the GOT table.  We only relocate
 194                  * the entries that are outside the (relocated) BSS region.
 195                  */
 196 1:              ldr     r1, [r6, #0]            @ relocate entries in the GOT
 197                 cmp     r1, r2                  @ entry < bss_start ||
 198                 cmphs   r3, r1                  @ _end < entry
 199                 addlo   r1, r1, r0              @ table.  This fixes up the
 200                 str     r1, [r6], #4            @ C references.
 201                 cmp     r6, ip
 202                 blo     1b
 203 #endif
 204
 205 not_relocated:  mov     r0, #0
 206 1:              str     r0, [r2], #4            @ clear bss
 207                 str     r0, [r2], #4
 208                 str     r0, [r2], #4
 209                 str     r0, [r2], #4
 210                 cmp     r2, r3
 211                 blo     1b
 212
 213                 /*
 214                  * The C runtime environment should now be setup
 215                  * sufficiently.  Turn the cache on, set up some
 216                  * pointers, and start decompressing.
 217                  */
 218                 bl      cache_on
 219
 220                 mov     r1, sp                  @ malloc space above stack
 221                 add     r2, sp, #0x10000        @ 64k max
 222
 223 /*
 224  * Check to see if we will overwrite ourselves.
 225  *   r4 = final kernel address
 226  *   r5 = start of this image
 227  *   r2 = end of malloc space (and therefore this image)
 228  * We basically want:
 229  *   r4 >= r2 -> OK
 230  *   r4 + image length <= r5 -> OK
 231  */
 232                 cmp     r4, r2
 233                 bhs     wont_overwrite
 234                 add     r0, r4, #4096*1024      @ 4MB largest kernel size
 235                 cmp     r0, r5
 236                 bls     wont_overwrite
 237
 238                 mov     r5, r2                  @ decompress after malloc space
 239                 mov     r0, r5
 240                 mov     r3, r7
 241                 bl      decompress_kernel
 242
 243                 add     r0, r0, #127
 244                 bic     r0, r0, #127            @ align the kernel length
 245 /*
 246  * r0     = decompressed kernel length
 247  * r1-r3  = unused
 248  * r4     = kernel execution address
 249  * r5     = decompressed kernel start
 250  * r6     = processor ID
 251  * r7     = architecture ID
 252  * r8     = atags pointer
 253  * r9-r14 = corrupted
 254  */
 255                 add     r1, r5, r0              @ end of decompressed kernel
 256                 adr     r2, reloc_start
 257                 ldr     r3, LC1
 258                 add     r3, r2, r3
 259 1:              ldmia   r2!, {r9 - r14}         @ copy relocation code
 260                 stmia   r1!, {r9 - r14}
 261                 ldmia   r2!, {r9 - r14}
 262                 stmia   r1!, {r9 - r14}
 263                 cmp     r2, r3
 264                 blo     1b
 265
 266                 bl      cache_clean_flush
 267                 add     pc, r5, r0              @ call relocation code
 268
 269 /*
 270  * We're not in danger of overwriting ourselves.  Do this the simple way.
 271  *
 272  * r4     = kernel execution address
 273  * r7     = architecture ID
 274  */
 275 wont_overwrite: mov     r0, r4
 276                 mov     r3, r7
 277                 bl      decompress_kernel
 278                 b       call_kernel
 279
 280                 .type   LC0, #object
 281 LC0:            .word   LC0                     @ r1
 282                 .word   __bss_start             @ r2
 283                 .word   _end                    @ r3
 284                 .word   zreladdr                @ r4
 285                 .word   _start                  @ r5
 286                 .word   _got_start              @ r6
 287                 .word   _got_end                @ ip
 288                 .word   user_stack+4096         @ sp
 289 LC1:            .word   reloc_end - reloc_start
 290                 .size   LC0, . - LC0
 291
 292 #ifdef CONFIG_ARCH_RPC
 293                 .globl  params
 294 params:         ldr     r0, =params_phys
 295                 mov     pc, lr
 296                 .ltorg
 297                 .align
 298 #endif
 299
 300 /*
 301  * Turn on the cache.  We need to setup some page tables so that we
 302  * can have both the I and D caches on.
 303  *
 304  * We place the page tables 16k down from the kernel execution address,
 305  * and we hope that nothing else is using it.  If we're using it, we
 306  * will go pop!
 307  *
 308  * On entry,
 309  *  r4 = kernel execution address
 310  *  r6 = processor ID
 311  *  r7 = architecture number
 312  *  r8 = atags pointer
 313  *  r9 = run-time address of "start"  (???)
 314  * On exit,
 315  *  r1, r2, r3, r9, r10, r12 corrupted
 316  * This routine must preserve:
 317  *  r4, r5, r6, r7, r8
 318  */
 319                 .align  5
 320 cache_on:       mov     r3, #8                  @ cache_on function
 321                 b       call_cache_fn
 322
 323 /*
 324  * Initialize the highest priority protection region, PR7
 325  * to cover all 32bit address and cacheable and bufferable.
 326  */
 327 __armv4_mpu_cache_on:
 328                 mov     r0, #0x3f               @ 4G, the whole
 329                 mcr     p15, 0, r0, c6, c7, 0   @ PR7 Area Setting
 330                 mcr     p15, 0, r0, c6, c7, 1
 331
 332                 mov     r0, #0x80               @ PR7
 333                 mcr     p15, 0, r0, c2, c0, 0   @ D-cache on
 334                 mcr     p15, 0, r0, c2, c0, 1   @ I-cache on
 335                 mcr     p15, 0, r0, c3, c0, 0   @ write-buffer on
 336
 337                 mov     r0, #0xc000
 338                 mcr     p15, 0, r0, c5, c0, 1   @ I-access permission
 339                 mcr     p15, 0, r0, c5, c0, 0   @ D-access permission
 340
 341                 mov     r0, #0
 342                 mcr     p15, 0, r0, c7, c10, 4  @ drain write buffer
 343                 mcr     p15, 0, r0, c7, c5, 0   @ flush(inval) I-Cache
 344                 mcr     p15, 0, r0, c7, c6, 0   @ flush(inval) D-Cache
 345                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
 346                                                 @ ...I .... ..D. WC.M
 347                 orr     r0, r0, #0x002d         @ .... .... ..1. 11.1
 348                 orr     r0, r0, #0x1000         @ ...1 .... .... ....
 349
 350                 mcr     p15, 0, r0, c1, c0, 0   @ write control reg
 351
 352                 mov     r0, #0
 353                 mcr     p15, 0, r0, c7, c5, 0   @ flush(inval) I-Cache
 354                 mcr     p15, 0, r0, c7, c6, 0   @ flush(inval) D-Cache
 355                 mov     pc, lr
 356
 357 __armv3_mpu_cache_on:
 358                 mov     r0, #0x3f               @ 4G, the whole
 359                 mcr     p15, 0, r0, c6, c7, 0   @ PR7 Area Setting
 360
 361                 mov     r0, #0x80               @ PR7
 362                 mcr     p15, 0, r0, c2, c0, 0   @ cache on
 363                 mcr     p15, 0, r0, c3, c0, 0   @ write-buffer on
 364
 365                 mov     r0, #0xc000
 366                 mcr     p15, 0, r0, c5, c0, 0   @ access permission
 367
 368                 mov     r0, #0
 369                 mcr     p15, 0, r0, c7, c0, 0   @ invalidate whole cache v3
 370                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
 371                                                 @ .... .... .... WC.M
 372                 orr     r0, r0, #0x000d         @ .... .... .... 11.1
 373                 mov     r0, #0
 374                 mcr     p15, 0, r0, c1, c0, 0   @ write control reg
 375
 376                 mcr     p15, 0, r0, c7, c0, 0   @ invalidate whole cache v3
 377                 mov     pc, lr
 378
 379 __setup_mmu:    sub     r3, r4, #16384          @ Page directory size
 380                 bic     r3, r3, #0xff           @ Align the pointer
 381                 bic     r3, r3, #0x3f00
 382 /*
 383  * Initialise the page tables, turning on the cacheable and bufferable
 384  * bits for the RAM area only.
 385  */
 386                 mov     r0, r3
 387                 mov     r9, r0, lsr #18
 388                 mov     r9, r9, lsl #18         @ start of RAM
 389                 add     r10, r9, #0x10000000    @ a reasonable RAM size
 390                 mov     r1, #0x12
 391                 orr     r1, r1, #3 << 10
 392                 add     r2, r3, #16384
 393 1:              cmp     r1, r9                  @ if virt > start of RAM
 394                 orrhs   r1, r1, #0x0c           @ set cacheable, bufferable
 395                 cmp     r1, r10                 @ if virt > end of RAM
 396                 bichs   r1, r1, #0x0c           @ clear cacheable, bufferable
 397                 str     r1, [r0], #4            @ 1:1 mapping
 398                 add     r1, r1, #1048576
 399                 teq     r0, r2
 400                 bne     1b
 401 /*
 402  * If ever we are running from Flash, then we surely want the cache
 403  * to be enabled also for our execution instance...  We map 2MB of it
 404  * so there is no map overlap problem for up to 1 MB compressed kernel.
 405  * If the execution is in RAM then we would only be duplicating the above.
 406  */
 407                 mov     r1, #0x1e
 408                 orr     r1, r1, #3 << 10
 409                 mov     r2, pc, lsr #20
 410                 orr     r1, r1, r2, lsl #20
 411                 add     r0, r3, r2, lsl #2
 412                 str     r1, [r0], #4
 413                 add     r1, r1, #1048576
 414                 str     r1, [r0]
 415                 mov     pc, lr
 416
 417 __armv4_mmu_cache_on:
 418                 mov     r12, lr
 419                 bl      __setup_mmu
 420                 mov     r0, #0
 421                 mcr     p15, 0, r0, c7, c10, 4  @ drain write buffer
 422                 mcr     p15, 0, r0, c8, c7, 0   @ flush I,D TLBs
 423                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
 424                 orr     r0, r0, #0x5000         @ I-cache enable, RR cache replacement
 425                 orr     r0, r0, #0x0030
 426                 bl      __common_mmu_cache_on
 427                 mov     r0, #0
 428                 mcr     p15, 0, r0, c8, c7, 0   @ flush I,D TLBs
 429                 mov     pc, r12
 430
 431 __arm6_mmu_cache_on:
 432                 mov     r12, lr
 433                 bl      __setup_mmu
 434                 mov     r0, #0
 435                 mcr     p15, 0, r0, c7, c0, 0   @ invalidate whole cache v3
 436                 mcr     p15, 0, r0, c5, c0, 0   @ invalidate whole TLB v3
 437                 mov     r0, #0x30
 438                 bl      __common_mmu_cache_on
 439                 mov     r0, #0
 440                 mcr     p15, 0, r0, c5, c0, 0   @ invalidate whole TLB v3
 441                 mov     pc, r12
 442
 443 __common_mmu_cache_on:
 444 #ifndef DEBUG
 445                 orr     r0, r0, #0x000d         @ Write buffer, mmu
 446 #endif
 447                 mov     r1, #-1
 448                 mcr     p15, 0, r3, c2, c0, 0   @ load page table pointer
 449                 mcr     p15, 0, r1, c3, c0, 0   @ load domain access control
 450                 mcr     p15, 0, r0, c1, c0, 0   @ load control register
 451                 mov     pc, lr
 452
 453 /*
 454  * All code following this line is relocatable.  It is relocated by
 455  * the above code to the end of the decompressed kernel image and
 456  * executed there.  During this time, we have no stacks.
 457  *
 458  * r0     = decompressed kernel length
 459  * r1-r3  = unused
 460  * r4     = kernel execution address
 461  * r5     = decompressed kernel start
 462  * r6     = processor ID
 463  * r7     = architecture ID
 464  * r8     = atags pointer
 465  * r9-r14 = corrupted
 466  */
 467                 .align  5
 468 reloc_start:    add     r9, r5, r0
 469                 debug_reloc_start
 470                 mov     r1, r4
 471 1:
 472                 .rept   4
 473                 ldmia   r5!, {r0, r2, r3, r10 - r14}    @ relocate kernel
 474                 stmia   r1!, {r0, r2, r3, r10 - r14}
 475                 .endr
 476
 477                 cmp     r5, r9
 478                 blo     1b
 479                 debug_reloc_end
 480
 481 call_kernel:    bl      cache_clean_flush
 482                 bl      cache_off
 483                 mov     r0, #0                  @ must be zero
 484                 mov     r1, r7                  @ restore architecture number
 485                 mov     r2, r8                  @ restore atags pointer
 486                 mov     pc, r4                  @ call kernel
 487
 488 /*
 489  * Here follow the relocatable cache support functions for the
 490  * various processors.  This is a generic hook for locating an
 491  * entry and jumping to an instruction at the specified offset
 492  * from the start of the block.  Please note this is all position
 493  * independent code.
 494  *
 495  *  r1  = corrupted
 496  *  r2  = corrupted
 497  *  r3  = block offset
 498  *  r6  = corrupted
 499  *  r12 = corrupted
 500  */
 501
 502 call_cache_fn:  adr     r12, proc_types
 503                 mrc     p15, 0, r6, c0, c0      @ get processor ID
 504 1:              ldr     r1, [r12, #0]           @ get value
 505                 ldr     r2, [r12, #4]           @ get mask
 506                 eor     r1, r1, r6              @ (real ^ match)
 507                 tst     r1, r2                  @       & mask
 508                 addeq   pc, r12, r3             @ call cache function
 509                 add     r12, r12, #4*5
 510                 b       1b
 511
 512 /*
 513  * Table for cache operations.  This is basically:
 514  *   - CPU ID match
 515  *   - CPU ID mask
 516  *   - 'cache on' method instruction
 517  *   - 'cache off' method instruction
 518  *   - 'cache flush' method instruction
 519  *
 520  * We match an entry using: ((real_id ^ match) & mask) == 0
 521  *
 522  * Writethrough caches generally only need 'on' and 'off'
 523  * methods.  Writeback caches _must_ have the flush method
 524  * defined.
 525  */
 526                 .type   proc_types,#object
 527 proc_types:
 528                 .word   0x41560600              @ ARM6/610
 529                 .word   0xffffffe0
 530                 b       __arm6_mmu_cache_off    @ works, but slow
 531                 b       __arm6_mmu_cache_off
 532                 mov     pc, lr
 533 @               b       __arm6_mmu_cache_on             @ untested
 534 @               b       __arm6_mmu_cache_off
 535 @               b       __armv3_mmu_cache_flush
 536
 537                 .word   0x00000000              @ old ARM ID
 538                 .word   0x0000f000
 539                 mov     pc, lr
 540                 mov     pc, lr
 541                 mov     pc, lr
 542
 543                 .word   0x41007000              @ ARM7/710
 544                 .word   0xfff8fe00
 545                 b       __arm7_mmu_cache_off
 546                 b       __arm7_mmu_cache_off
 547                 mov     pc, lr
 548
 549                 .word   0x41807200              @ ARM720T (writethrough)
 550                 .word   0xffffff00
 551                 b       __armv4_mmu_cache_on
 552                 b       __armv4_mmu_cache_off
 553                 mov     pc, lr
 554
 555                 .word   0x41007400              @ ARM74x
 556                 .word   0xff00ff00
 557                 b       __armv3_mpu_cache_on
 558                 b       __armv3_mpu_cache_off
 559                 b       __armv3_mpu_cache_flush
 560
 561                 .word   0x41009400              @ ARM94x
 562                 .word   0xff00ff00
 563                 b       __armv4_mpu_cache_on
 564                 b       __armv4_mpu_cache_off
 565                 b       __armv4_mpu_cache_flush
 566
 567                 .word   0x00007000              @ ARM7 IDs
 568                 .word   0x0000f000
 569                 mov     pc, lr
 570                 mov     pc, lr
 571                 mov     pc, lr
 572
 573                 @ Everything from here on will be the new ID system.
 574
 575                 .word   0x4401a100              @ sa110 / sa1100
 576                 .word   0xffffffe0
 577                 b       __armv4_mmu_cache_on
 578                 b       __armv4_mmu_cache_off
 579                 b       __armv4_mmu_cache_flush
 580
 581                 .word   0x6901b110              @ sa1110
 582                 .word   0xfffffff0
 583                 b       __armv4_mmu_cache_on
 584                 b       __armv4_mmu_cache_off
 585                 b       __armv4_mmu_cache_flush
 586
 587                 @ These match on the architecture ID
 588
 589                 .word   0x00020000              @ ARMv4T
 590                 .word   0x000f0000
 591                 b       __armv4_mmu_cache_on
 592                 b       __armv4_mmu_cache_off
 593                 b       __armv4_mmu_cache_flush
 594
 595                 .word   0x00050000              @ ARMv5TE
 596                 .word   0x000f0000
 597                 b       __armv4_mmu_cache_on
 598                 b       __armv4_mmu_cache_off
 599                 b       __armv4_mmu_cache_flush
 600
 601                 .word   0x00060000              @ ARMv5TEJ
 602                 .word   0x000f0000
 603                 b       __armv4_mmu_cache_on
 604                 b       __armv4_mmu_cache_off
 605                 b       __armv4_mmu_cache_flush
 606
 607                 .word   0x0007b000              @ ARMv6
 608                 .word   0x0007f000
 609                 b       __armv4_mmu_cache_on
 610                 b       __armv4_mmu_cache_off
 611                 b       __armv6_mmu_cache_flush
 612
 613                 .word   0                       @ unrecognised type
 614                 .word   0
 615                 mov     pc, lr
 616                 mov     pc, lr
 617                 mov     pc, lr
 618
 619                 .size   proc_types, . - proc_types
 620
 621 /*
 622  * Turn off the Cache and MMU.  ARMv3 does not support
 623  * reading the control register, but ARMv4 does.
 624  *
 625  * On entry,  r6 = processor ID
 626  * On exit,   r0, r1, r2, r3, r12 corrupted
 627  * This routine must preserve: r4, r6, r7
 628  */
 629                 .align  5
 630 cache_off:      mov     r3, #12                 @ cache_off function
 631                 b       call_cache_fn
 632
 633 __armv4_mpu_cache_off:
 634                 mrc     p15, 0, r0, c1, c0
 635                 bic     r0, r0, #0x000d
 636                 mcr     p15, 0, r0, c1, c0      @ turn MPU and cache off
 637                 mov     r0, #0
 638                 mcr     p15, 0, r0, c7, c10, 4  @ drain write buffer
 639                 mcr     p15, 0, r0, c7, c6, 0   @ flush D-Cache
 640                 mcr     p15, 0, r0, c7, c5, 0   @ flush I-Cache
 641                 mov     pc, lr
 642
 643 __armv3_mpu_cache_off:
 644                 mrc     p15, 0, r0, c1, c0
 645                 bic     r0, r0, #0x000d
 646                 mcr     p15, 0, r0, c1, c0, 0   @ turn MPU and cache off
 647                 mov     r0, #0
 648                 mcr     p15, 0, r0, c7, c0, 0   @ invalidate whole cache v3
 649                 mov     pc, lr
 650
 651 __armv4_mmu_cache_off:
 652                 mrc     p15, 0, r0, c1, c0
 653                 bic     r0, r0, #0x000d
 654                 mcr     p15, 0, r0, c1, c0      @ turn MMU and cache off
 655                 mov     r0, #0
 656                 mcr     p15, 0, r0, c7, c7      @ invalidate whole cache v4
 657                 mcr     p15, 0, r0, c8, c7      @ invalidate whole TLB v4
 658                 mov     pc, lr
 659
 660 __arm6_mmu_cache_off:
 661                 mov     r0, #0x00000030         @ ARM6 control reg.
 662                 b       __armv3_mmu_cache_off
 663
 664 __arm7_mmu_cache_off:
 665                 mov     r0, #0x00000070         @ ARM7 control reg.
 666                 b       __armv3_mmu_cache_off
 667
 668 __armv3_mmu_cache_off:
 669                 mcr     p15, 0, r0, c1, c0, 0   @ turn MMU and cache off
 670                 mov     r0, #0
 671                 mcr     p15, 0, r0, c7, c0, 0   @ invalidate whole cache v3
 672                 mcr     p15, 0, r0, c5, c0, 0   @ invalidate whole TLB v3
 673                 mov     pc, lr
 674
 675 /*
 676  * Clean and flush the cache to maintain consistency.
 677  *
 678  * On entry,
 679  *  r6 = processor ID
 680  * On exit,
 681  *  r1, r2, r3, r11, r12 corrupted
 682  * This routine must preserve:
 683  *  r0, r4, r5, r6, r7
 684  */
 685                 .align  5
 686 cache_clean_flush:
 687                 mov     r3, #16
 688                 b       call_cache_fn
 689
 690 __armv4_mpu_cache_flush:
 691                 mov     r2, #1
 692                 mov     r3, #0
 693                 mcr     p15, 0, ip, c7, c6, 0   @ invalidate D cache
 694                 mov     r1, #7 << 5             @ 8 segments
 695 1:              orr     r3, r1, #63 << 26       @ 64 entries
 696 2:              mcr     p15, 0, r3, c7, c14, 2  @ clean & invalidate D index
 697                 subs    r3, r3, #1 << 26
 698                 bcs     2b                      @ entries 63 to 0
 699                 subs    r1, r1, #1 << 5
 700                 bcs     1b                      @ segments 7 to 0
 701
 702                 teq     r2, #0
 703                 mcrne   p15, 0, ip, c7, c5, 0   @ invalidate I cache
 704                 mcr     p15, 0, ip, c7, c10, 4  @ drain WB
 705                 mov     pc, lr
 706
 707
 708 __armv6_mmu_cache_flush:
 709                 mov     r1, #0
 710                 mcr     p15, 0, r1, c7, c14, 0  @ clean+invalidate D
 711                 mcr     p15, 0, r1, c7, c5, 0   @ invalidate I+BTB
 712                 mcr     p15, 0, r1, c7, c15, 0  @ clean+invalidate unified
 713                 mcr     p15, 0, r1, c7, c10, 4  @ drain WB
 714                 mov     pc, lr
 715
 716 __armv4_mmu_cache_flush:
 717                 mov     r2, #64*1024            @ default: 32K dcache size (*2)
 718                 mov     r11, #32                @ default: 32 byte line size
 719                 mrc     p15, 0, r3, c0, c0, 1   @ read cache type
 720                 teq     r3, r6                  @ cache ID register present?
 721                 beq     no_cache_id
 722                 mov     r1, r3, lsr #18
 723                 and     r1, r1, #7
 724                 mov     r2, #1024
 725                 mov     r2, r2, lsl r1          @ base dcache size *2
 726                 tst     r3, #1 << 14            @ test M bit
 727                 addne   r2, r2, r2, lsr #1      @ +1/2 size if M == 1
 728                 mov     r3, r3, lsr #12
 729                 and     r3, r3, #3
 730                 mov     r11, #8
 731                 mov     r11, r11, lsl r3        @ cache line size in bytes
 732 no_cache_id:
 733                 bic     r1, pc, #63             @ align to longest cache line
 734                 add     r2, r1, r2
 735 1:              ldr     r3, [r1], r11           @ s/w flush D cache
 736                 teq     r1, r2
 737                 bne     1b
 738
 739                 mcr     p15, 0, r1, c7, c5, 0   @ flush I cache
 740                 mcr     p15, 0, r1, c7, c6, 0   @ flush D cache
 741                 mcr     p15, 0, r1, c7, c10, 4  @ drain WB
 742                 mov     pc, lr
 743
 744 __armv3_mmu_cache_flush:
 745 __armv3_mpu_cache_flush:
 746                 mov     r1, #0
 747                 mcr     p15, 0, r0, c7, c0, 0   @ invalidate whole cache v3
 748                 mov     pc, lr
 749
 750 /*
 751  * Various debugging routines for printing hex characters and
 752  * memory, which again must be relocatable.
 753  */
 754 #ifdef DEBUG
 755                 .type   phexbuf,#object
 756 phexbuf:        .space  12
 757                 .size   phexbuf, . - phexbuf
 758
 759 phex:           adr     r3, phexbuf
 760                 mov     r2, #0
 761                 strb    r2, [r3, r1]
 762 1:              subs    r1, r1, #1
 763                 movmi   r0, r3
 764                 bmi     puts
 765                 and     r2, r0, #15
 766                 mov     r0, r0, lsr #4
 767                 cmp     r2, #10
 768                 addge   r2, r2, #7
 769                 add     r2, r2, #'0'
 770                 strb    r2, [r3, r1]
 771                 b       1b
 772
 773 puts:           loadsp  r3
 774 1:              ldrb    r2, [r0], #1
 775                 teq     r2, #0
 776                 moveq   pc, lr
 777 2:              writeb  r2, r3
 778                 mov     r1, #0x00020000
 779 3:              subs    r1, r1, #1
 780                 bne     3b
 781                 teq     r2, #'\n'
 782                 moveq   r2, #'\r'
 783                 beq     2b
 784                 teq     r0, #0
 785                 bne     1b
 786                 mov     pc, lr
 787 putc:
 788                 mov     r2, r0
 789                 mov     r0, #0
 790                 loadsp  r3
 791                 b       2b
 792
 793 memdump:        mov     r12, r0
 794                 mov     r10, lr
 795                 mov     r11, #0
 796 2:              mov     r0, r11, lsl #2
 797                 add     r0, r0, r12
 798                 mov     r1, #8
 799                 bl      phex
 800                 mov     r0, #':'
 801                 bl      putc
 802 1:              mov     r0, #' '
 803                 bl      putc
 804                 ldr     r0, [r12, r11, lsl #2]
 805                 mov     r1, #8
 806                 bl      phex
 807                 and     r0, r11, #7
 808                 teq     r0, #3
 809                 moveq   r0, #' '
 810                 bleq    putc
 811                 and     r0, r11, #7
 812                 add     r11, r11, #1
 813                 teq     r0, #7
 814                 bne     1b
 815                 mov     r0, #'\n'
 816                 bl      putc
 817                 cmp     r11, #64
 818                 blt     2b
 819                 mov     pc, r10
 820 #endif
 821
 822 reloc_end:
 823
 824                 .align
 825                 .section ".stack", "w"
 826 user_stack:     .space  4096