classes/cpan.bbclass

   1 #
   2 # This is for perl modules that use the old Makefile.PL build system
   3 #
   4 inherit cpan-base
   5
   6 EXTRA_CPANFLAGS ?= ""
   7
   8 # Env var which tells perl if it should use host (no) or target (yes) settings
   9 export PERLCONFIGTARGET = "${@is_target(d)}"
  10
  11 # Env var which tells perl where the perl include files are
  12 export PERL_INC = "${STAGING_LIBDIR}/perl/${@get_perl_version(d)}/CORE"
  13 export PERL_LIB = "${STAGING_DATADIR}/perl/${@get_perl_version(d)}"
  14 export PERL_ARCHLIB = "${STAGING_LIBDIR}/perl/${@get_perl_version(d)}"
  15
  16 cpan_do_configure () {
  17         yes '' | perl Makefile.PL ${EXTRA_CPANFLAGS}
  18         if [ "${BUILD_SYS}" != "${HOST_SYS}" ]; then
  19                 . ${STAGING_LIBDIR}/perl/config.sh
  20                 if [ "${IS_NEW_PERL}" = "yes" ]; then
  21                         sed -i -e "s:\(SITELIBEXP = \).*:\1${sitelibexp}:" \
  22                                 -e "s:\(SITEARCHEXP = \).*:\1${sitearchexp}:" \
  23                                 -e "s:\(INSTALLVENDORLIB = \).*:\1${D}${datadir}/perl5:" \
  24                                 -e "s:\(INSTALLVENDORARCH = \).*:\1${D}${libdir}/perl5:" \
  25                                 -e "s:\(LDDLFLAGS.*\)${STAGING_LIBDIR_NATIVE}:\1${STAGING_LIBDIR}:" \
  26                                 Makefile
  27                 else
  28                         sed -i -e "s:\(SITELIBEXP = \).*:\1${sitelibexp}:" \
  29                                 -e "s:\(SITEARCHEXP = \).*:\1${sitearchexp}:" \
  30                                 -e "s:\(INSTALLVENDORLIB = \).*:\1${D}${libdir}/perl5/site_perl/${version}:" \
  31                                 -e "s:\(INSTALLVENDORARCH = \).*:\1${D}${libdir}/perl5/site_perl/${version}:" \
  32                                 -e "s:\(LDDLFLAGS.*\)${STAGING_LIBDIR_NATIVE}:\1${STAGING_LIBDIR}:" \
  33                                 Makefile
  34                 fi
  35         fi
  36 }
  37
  38 cpan_do_compile () {
  39         if [ "${IS_NEW_PERL}" = "yes" ]; then
  40                 oe_runmake PASTHRU_INC="${CFLAGS}" CCFLAGS="${CFLAGS}" LD="${CCLD}"
  41         else
  42                 # You must use gcc to link on sh
  43                 OPTIONS=""
  44                 if test ${TARGET_ARCH} = "sh3" -o ${TARGET_ARCH} = "sh4"; then
  45                         OPTIONS="LD=${TARGET_ARCH}-${TARGET_OS}-gcc"
  46                 fi
  47                 if test ${TARGET_ARCH} = "powerpc" ; then
  48                         OPTIONS="LD=${TARGET_ARCH}-${TARGET_OS}-gcc"
  49                 fi
  50                 oe_runmake PASTHRU_INC="${CFLAGS}" CCFLAGS="${CFLAGS}" $OPTIONS
  51         fi
  52 }
  53
  54 cpan_do_install () {
  55         if [ ${@is_target(d)} = "yes" ]; then
  56                 oe_runmake install_vendor
  57         fi
  58 }
  59
  60 cpan_do_stage () {
  61         if [ ${@is_target(d)} = "no" ]; then
  62                 oe_runmake install_vendor
  63         fi
  64 }
  65
  66
  67 EXPORT_FUNCTIONS do_configure do_compile do_install do_stage