arch/x86_64/ia32/ia32entry.S

   1 /*
   2  * Compatibility mode system call entry point for x86-64.
   3  *
   4  * Copyright 2000-2002 Andi Kleen, SuSE Labs.
   5  */
   6
   7 #include <asm/dwarf2.h>
   8 #include <asm/calling.h>
   9 #include <asm/asm-offsets.h>
  10 #include <asm/current.h>
  11 #include <asm/errno.h>
  12 #include <asm/ia32_unistd.h>
  13 #include <asm/thread_info.h>
  14 #include <asm/segment.h>
  15 #include <asm/vsyscall32.h>
  16 #include <linux/linkage.h>
  17
  18 #define IA32_NR_syscalls ((ia32_syscall_end - ia32_sys_call_table)/8)
  19
  20         .macro IA32_ARG_FIXUP noebp=0
  21         movl    %edi,%r8d
  22         .if \noebp
  23         .else
  24         movl    %ebp,%r9d
  25         .endif
  26         xchg    %ecx,%esi
  27         movl    %ebx,%edi
  28         movl    %edx,%edx       /* zero extension */
  29         .endm
  30
  31         /* clobbers %eax */
  32         .macro  CLEAR_RREGS
  33         xorl    %eax,%eax
  34         movq    %rax,R11(%rsp)
  35         movq    %rax,R10(%rsp)
  36         movq    %rax,R9(%rsp)
  37         movq    %rax,R8(%rsp)
  38         .endm
  39
  40         .macro CFI_STARTPROC32 simple
  41         CFI_STARTPROC   \simple
  42         CFI_UNDEFINED   r8
  43         CFI_UNDEFINED   r9
  44         CFI_UNDEFINED   r10
  45         CFI_UNDEFINED   r11
  46         CFI_UNDEFINED   r12
  47         CFI_UNDEFINED   r13
  48         CFI_UNDEFINED   r14
  49         CFI_UNDEFINED   r15
  50         .endm
  51
  52 /*
  53  * 32bit SYSENTER instruction entry.
  54  *
  55  * Arguments:
  56  * %eax System call number.
  57  * %ebx Arg1
  58  * %ecx Arg2
  59  * %edx Arg3
  60  * %esi Arg4
  61  * %edi Arg5
  62  * %ebp user stack
  63  * 0(%ebp) Arg6
  64  *
  65  * Interrupts off.
  66  *
  67  * This is purely a fast path. For anything complicated we use the int 0x80
  68  * path below.  Set up a complete hardware stack frame to share code
  69  * with the int 0x80 path.
  70  */
  71 ENTRY(ia32_sysenter_target)
  72         CFI_STARTPROC32 simple
  73         CFI_DEF_CFA     rsp,0
  74         CFI_REGISTER    rsp,rbp
  75         swapgs
  76         movq    %gs:pda_kernelstack, %rsp
  77         addq    $(PDA_STACKOFFSET),%rsp
  78         sti
  79         movl    %ebp,%ebp               /* zero extension */
  80         pushq   $__USER32_DS
  81         CFI_ADJUST_CFA_OFFSET 8
  82         /*CFI_REL_OFFSET ss,0*/
  83         pushq   %rbp
  84         CFI_ADJUST_CFA_OFFSET 8
  85         CFI_REL_OFFSET rsp,0
  86         pushfq
  87         CFI_ADJUST_CFA_OFFSET 8
  88         /*CFI_REL_OFFSET rflags,0*/
  89         movl    $VSYSCALL32_SYSEXIT, %r10d
  90         CFI_REGISTER rip,r10
  91         pushq   $__USER32_CS
  92         CFI_ADJUST_CFA_OFFSET 8
  93         /*CFI_REL_OFFSET cs,0*/
  94         movl    %eax, %eax
  95         pushq   %r10
  96         CFI_ADJUST_CFA_OFFSET 8
  97         CFI_REL_OFFSET rip,0
  98         pushq   %rax
  99         CFI_ADJUST_CFA_OFFSET 8
 100         cld
 101         SAVE_ARGS 0,0,1
 102         /* no need to do an access_ok check here because rbp has been
 103            32bit zero extended */
 104 1:      movl    (%rbp),%r9d
 105         .section __ex_table,"a"
 106         .quad 1b,ia32_badarg
 107         .previous
 108         GET_THREAD_INFO(%r10)
 109         orl    $TS_COMPAT,threadinfo_status(%r10)
 110         testl  $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 111         CFI_REMEMBER_STATE
 112         jnz  sysenter_tracesys
 113 sysenter_do_call:
 114         cmpl    $(IA32_NR_syscalls-1),%eax
 115         ja      ia32_badsys
 116         IA32_ARG_FIXUP 1
 117         call    *ia32_sys_call_table(,%rax,8)
 118         movq    %rax,RAX-ARGOFFSET(%rsp)
 119         GET_THREAD_INFO(%r10)
 120         cli
 121         testl   $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 122         jnz     int_ret_from_sys_call
 123         andl    $~TS_COMPAT,threadinfo_status(%r10)
 124         /* clear IF, that popfq doesn't enable interrupts early */
 125         andl  $~0x200,EFLAGS-R11(%rsp)
 126         RESTORE_ARGS 1,24,1,1,1,1
 127         popfq
 128         CFI_ADJUST_CFA_OFFSET -8
 129         /*CFI_RESTORE rflags*/
 130         popq    %rcx                            /* User %esp */
 131         CFI_ADJUST_CFA_OFFSET -8
 132         CFI_REGISTER rsp,rcx
 133         movl    $VSYSCALL32_SYSEXIT,%edx        /* User %eip */
 134         CFI_REGISTER rip,rdx
 135         swapgs
 136         sti             /* sti only takes effect after the next instruction */
 137         /* sysexit */
 138         .byte   0xf, 0x35
 139
 140 sysenter_tracesys:
 141         CFI_RESTORE_STATE
 142         SAVE_REST
 143         CLEAR_RREGS
 144         movq    $-ENOSYS,RAX(%rsp)      /* really needed? */
 145         movq    %rsp,%rdi        /* &pt_regs -> arg1 */
 146         call    syscall_trace_enter
 147         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 148         RESTORE_REST
 149         movl    %ebp, %ebp
 150         /* no need to do an access_ok check here because rbp has been
 151            32bit zero extended */
 152 1:      movl    (%rbp),%r9d
 153         .section __ex_table,"a"
 154         .quad 1b,ia32_badarg
 155         .previous
 156         jmp     sysenter_do_call
 157         CFI_ENDPROC
 158 ENDPROC(ia32_sysenter_target)
 159
 160 /*
 161  * 32bit SYSCALL instruction entry.
 162  *
 163  * Arguments:
 164  * %eax System call number.
 165  * %ebx Arg1
 166  * %ecx return EIP
 167  * %edx Arg3
 168  * %esi Arg4
 169  * %edi Arg5
 170  * %ebp Arg2    [note: not saved in the stack frame, should not be touched]
 171  * %esp user stack
 172  * 0(%esp) Arg6
 173  *
 174  * Interrupts off.
 175  *
 176  * This is purely a fast path. For anything complicated we use the int 0x80
 177  * path below.  Set up a complete hardware stack frame to share code
 178  * with the int 0x80 path.
 179  */
 180 ENTRY(ia32_cstar_target)
 181         CFI_STARTPROC32 simple
 182         CFI_DEF_CFA     rsp,0
 183         CFI_REGISTER    rip,rcx
 184         /*CFI_REGISTER  rflags,r11*/
 185         swapgs
 186         movl    %esp,%r8d
 187         CFI_REGISTER    rsp,r8
 188         movq    %gs:pda_kernelstack,%rsp
 189         sti
 190         SAVE_ARGS 8,1,1
 191         movl    %eax,%eax       /* zero extension */
 192         movq    %rax,ORIG_RAX-ARGOFFSET(%rsp)
 193         movq    %rcx,RIP-ARGOFFSET(%rsp)
 194         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 195         movq    %rbp,RCX-ARGOFFSET(%rsp) /* this lies slightly to ptrace */
 196         movl    %ebp,%ecx
 197         movq    $__USER32_CS,CS-ARGOFFSET(%rsp)
 198         movq    $__USER32_DS,SS-ARGOFFSET(%rsp)
 199         movq    %r11,EFLAGS-ARGOFFSET(%rsp)
 200         /*CFI_REL_OFFSET rflags,EFLAGS-ARGOFFSET*/
 201         movq    %r8,RSP-ARGOFFSET(%rsp)
 202         CFI_REL_OFFSET rsp,RSP-ARGOFFSET
 203         /* no need to do an access_ok check here because r8 has been
 204            32bit zero extended */
 205         /* hardware stack frame is complete now */
 206 1:      movl    (%r8),%r9d
 207         .section __ex_table,"a"
 208         .quad 1b,ia32_badarg
 209         .previous
 210         GET_THREAD_INFO(%r10)
 211         orl   $TS_COMPAT,threadinfo_status(%r10)
 212         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 213         CFI_REMEMBER_STATE
 214         jnz   cstar_tracesys
 215 cstar_do_call:
 216         cmpl $IA32_NR_syscalls-1,%eax
 217         ja  ia32_badsys
 218         IA32_ARG_FIXUP 1
 219         call *ia32_sys_call_table(,%rax,8)
 220         movq %rax,RAX-ARGOFFSET(%rsp)
 221         GET_THREAD_INFO(%r10)
 222         cli
 223         testl $_TIF_ALLWORK_MASK,threadinfo_flags(%r10)
 224         jnz  int_ret_from_sys_call
 225         andl $~TS_COMPAT,threadinfo_status(%r10)
 226         RESTORE_ARGS 1,-ARG_SKIP,1,1,1
 227         movl RIP-ARGOFFSET(%rsp),%ecx
 228         CFI_REGISTER rip,rcx
 229         movl EFLAGS-ARGOFFSET(%rsp),%r11d
 230         /*CFI_REGISTER rflags,r11*/
 231         movl RSP-ARGOFFSET(%rsp),%esp
 232         CFI_RESTORE rsp
 233         swapgs
 234         sysretl
 235
 236 cstar_tracesys:
 237         CFI_RESTORE_STATE
 238         SAVE_REST
 239         CLEAR_RREGS
 240         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 241         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 242         call syscall_trace_enter
 243         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 244         RESTORE_REST
 245         movl RSP-ARGOFFSET(%rsp), %r8d
 246         /* no need to do an access_ok check here because r8 has been
 247            32bit zero extended */
 248 1:      movl    (%r8),%r9d
 249         .section __ex_table,"a"
 250         .quad 1b,ia32_badarg
 251         .previous
 252         jmp cstar_do_call
 253 END(ia32_cstar_target)
 254
 255 ia32_badarg:
 256         movq $-EFAULT,%rax
 257         jmp ia32_sysret
 258         CFI_ENDPROC
 259
 260 /*
 261  * Emulated IA32 system calls via int 0x80.
 262  *
 263  * Arguments:
 264  * %eax System call number.
 265  * %ebx Arg1
 266  * %ecx Arg2
 267  * %edx Arg3
 268  * %esi Arg4
 269  * %edi Arg5
 270  * %ebp Arg6    [note: not saved in the stack frame, should not be touched]
 271  *
 272  * Notes:
 273  * Uses the same stack frame as the x86-64 version.
 274  * All registers except %eax must be saved (but ptrace may violate that)
 275  * Arguments are zero extended. For system calls that want sign extension and
 276  * take long arguments a wrapper is needed. Most calls can just be called
 277  * directly.
 278  * Assumes it is only called from user space and entered with interrupts off.
 279  */
 280
 281 ENTRY(ia32_syscall)
 282         CFI_STARTPROC   simple
 283         CFI_DEF_CFA     rsp,SS+8-RIP
 284         /*CFI_REL_OFFSET        ss,SS-RIP*/
 285         CFI_REL_OFFSET  rsp,RSP-RIP
 286         /*CFI_REL_OFFSET        rflags,EFLAGS-RIP*/
 287         /*CFI_REL_OFFSET        cs,CS-RIP*/
 288         CFI_REL_OFFSET  rip,RIP-RIP
 289         swapgs
 290         sti
 291         movl %eax,%eax
 292         pushq %rax
 293         CFI_ADJUST_CFA_OFFSET 8
 294         cld
 295         /* note the registers are not zero extended to the sf.
 296            this could be a problem. */
 297         SAVE_ARGS 0,0,1
 298         GET_THREAD_INFO(%r10)
 299         orl   $TS_COMPAT,threadinfo_status(%r10)
 300         testl $(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT|_TIF_SECCOMP),threadinfo_flags(%r10)
 301         jnz ia32_tracesys
 302 ia32_do_syscall:
 303         cmpl $(IA32_NR_syscalls-1),%eax
 304         ja  ia32_badsys
 305         IA32_ARG_FIXUP
 306         call *ia32_sys_call_table(,%rax,8) # xxx: rip relative
 307 ia32_sysret:
 308         movq %rax,RAX-ARGOFFSET(%rsp)
 309         jmp int_ret_from_sys_call
 310
 311 ia32_tracesys:
 312         SAVE_REST
 313         movq $-ENOSYS,RAX(%rsp) /* really needed? */
 314         movq %rsp,%rdi        /* &pt_regs -> arg1 */
 315         call syscall_trace_enter
 316         LOAD_ARGS ARGOFFSET  /* reload args from stack in case ptrace changed it */
 317         RESTORE_REST
 318         jmp ia32_do_syscall
 319 END(ia32_syscall)
 320
 321 ia32_badsys:
 322         movq $0,ORIG_RAX-ARGOFFSET(%rsp)
 323         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 324         jmp int_ret_from_sys_call
 325
 326 ni_syscall:
 327         movq %rax,%rdi
 328         jmp  sys32_ni_syscall
 329
 330 quiet_ni_syscall:
 331         movq $-ENOSYS,%rax
 332         ret
 333         CFI_ENDPROC
 334
 335         .macro PTREGSCALL label, func, arg
 336         .globl \label
 337 \label:
 338         leaq \func(%rip),%rax
 339         leaq -ARGOFFSET+8(%rsp),\arg    /* 8 for return address */
 340         jmp  ia32_ptregs_common
 341         .endm
 342
 343         CFI_STARTPROC32
 344
 345         PTREGSCALL stub32_rt_sigreturn, sys32_rt_sigreturn, %rdi
 346         PTREGSCALL stub32_sigreturn, sys32_sigreturn, %rdi
 347         PTREGSCALL stub32_sigaltstack, sys32_sigaltstack, %rdx
 348         PTREGSCALL stub32_sigsuspend, sys32_sigsuspend, %rcx
 349         PTREGSCALL stub32_execve, sys32_execve, %rcx
 350         PTREGSCALL stub32_fork, sys_fork, %rdi
 351         PTREGSCALL stub32_clone, sys32_clone, %rdx
 352         PTREGSCALL stub32_vfork, sys_vfork, %rdi
 353         PTREGSCALL stub32_iopl, sys_iopl, %rsi
 354         PTREGSCALL stub32_rt_sigsuspend, sys_rt_sigsuspend, %rdx
 355
 356 ENTRY(ia32_ptregs_common)
 357         popq %r11
 358         CFI_ENDPROC
 359         CFI_STARTPROC32 simple
 360         CFI_DEF_CFA     rsp,SS+8-ARGOFFSET
 361         CFI_REL_OFFSET  rax,RAX-ARGOFFSET
 362         CFI_REL_OFFSET  rcx,RCX-ARGOFFSET
 363         CFI_REL_OFFSET  rdx,RDX-ARGOFFSET
 364         CFI_REL_OFFSET  rsi,RSI-ARGOFFSET
 365         CFI_REL_OFFSET  rdi,RDI-ARGOFFSET
 366         CFI_REL_OFFSET  rip,RIP-ARGOFFSET
 367 /*      CFI_REL_OFFSET  cs,CS-ARGOFFSET*/
 368 /*      CFI_REL_OFFSET  rflags,EFLAGS-ARGOFFSET*/
 369         CFI_REL_OFFSET  rsp,RSP-ARGOFFSET
 370 /*      CFI_REL_OFFSET  ss,SS-ARGOFFSET*/
 371         SAVE_REST
 372         call *%rax
 373         RESTORE_REST
 374         jmp  ia32_sysret        /* misbalances the return cache */
 375         CFI_ENDPROC
 376 END(ia32_ptregs_common)
 377
 378         .section .rodata,"a"
 379         .align 8
 380         .globl ia32_sys_call_table
 381 ia32_sys_call_table:
 382         .quad sys_restart_syscall
 383         .quad sys_exit
 384         .quad stub32_fork
 385         .quad sys_read
 386         .quad sys_write
 387         .quad compat_sys_open           /* 5 */
 388         .quad sys_close
 389         .quad sys32_waitpid
 390         .quad sys_creat
 391         .quad sys_link
 392         .quad sys_unlink                /* 10 */
 393         .quad stub32_execve
 394         .quad sys_chdir
 395         .quad compat_sys_time
 396         .quad sys_mknod
 397         .quad sys_chmod         /* 15 */
 398         .quad sys_lchown16
 399         .quad quiet_ni_syscall                  /* old break syscall holder */
 400         .quad sys_stat
 401         .quad sys32_lseek
 402         .quad sys_getpid                /* 20 */
 403         .quad compat_sys_mount  /* mount  */
 404         .quad sys_oldumount     /* old_umount  */
 405         .quad sys_setuid16
 406         .quad sys_getuid16
 407         .quad compat_sys_stime  /* stime */             /* 25 */
 408         .quad sys32_ptrace      /* ptrace */
 409         .quad sys_alarm
 410         .quad sys_fstat /* (old)fstat */
 411         .quad sys_pause
 412         .quad compat_sys_utime  /* 30 */
 413         .quad quiet_ni_syscall  /* old stty syscall holder */
 414         .quad quiet_ni_syscall  /* old gtty syscall holder */
 415         .quad sys_access
 416         .quad sys_nice
 417         .quad quiet_ni_syscall  /* 35 */        /* old ftime syscall holder */
 418         .quad sys_sync
 419         .quad sys32_kill
 420         .quad sys_rename
 421         .quad sys_mkdir
 422         .quad sys_rmdir         /* 40 */
 423         .quad sys_dup
 424         .quad sys32_pipe
 425         .quad compat_sys_times
 426         .quad quiet_ni_syscall                  /* old prof syscall holder */
 427         .quad sys_brk           /* 45 */
 428         .quad sys_setgid16
 429         .quad sys_getgid16
 430         .quad sys_signal
 431         .quad sys_geteuid16
 432         .quad sys_getegid16     /* 50 */
 433         .quad sys_acct
 434         .quad sys_umount                        /* new_umount */
 435         .quad quiet_ni_syscall                  /* old lock syscall holder */
 436         .quad compat_sys_ioctl
 437         .quad compat_sys_fcntl64                /* 55 */
 438         .quad quiet_ni_syscall                  /* old mpx syscall holder */
 439         .quad sys_setpgid
 440         .quad quiet_ni_syscall                  /* old ulimit syscall holder */
 441         .quad sys32_olduname
 442         .quad sys_umask         /* 60 */
 443         .quad sys_chroot
 444         .quad sys32_ustat
 445         .quad sys_dup2
 446         .quad sys_getppid
 447         .quad sys_getpgrp               /* 65 */
 448         .quad sys_setsid
 449         .quad sys32_sigaction
 450         .quad sys_sgetmask
 451         .quad sys_ssetmask
 452         .quad sys_setreuid16    /* 70 */
 453         .quad sys_setregid16
 454         .quad stub32_sigsuspend
 455         .quad compat_sys_sigpending
 456         .quad sys_sethostname
 457         .quad compat_sys_setrlimit      /* 75 */
 458         .quad compat_sys_old_getrlimit  /* old_getrlimit */
 459         .quad compat_sys_getrusage
 460         .quad sys32_gettimeofday
 461         .quad sys32_settimeofday
 462         .quad sys_getgroups16   /* 80 */
 463         .quad sys_setgroups16
 464         .quad sys32_old_select
 465         .quad sys_symlink
 466         .quad sys_lstat
 467         .quad sys_readlink              /* 85 */
 468 #ifdef CONFIG_IA32_AOUT
 469         .quad sys_uselib
 470 #else
 471         .quad quiet_ni_syscall
 472 #endif
 473         .quad sys_swapon
 474         .quad sys_reboot
 475         .quad compat_sys_old_readdir
 476         .quad sys32_mmap                /* 90 */
 477         .quad sys_munmap
 478         .quad sys_truncate
 479         .quad sys_ftruncate
 480         .quad sys_fchmod
 481         .quad sys_fchown16              /* 95 */
 482         .quad sys_getpriority
 483         .quad sys_setpriority
 484         .quad quiet_ni_syscall                  /* old profil syscall holder */
 485         .quad compat_sys_statfs
 486         .quad compat_sys_fstatfs                /* 100 */
 487         .quad sys_ioperm
 488         .quad compat_sys_socketcall
 489         .quad sys_syslog
 490         .quad compat_sys_setitimer
 491         .quad compat_sys_getitimer      /* 105 */
 492         .quad compat_sys_newstat
 493         .quad compat_sys_newlstat
 494         .quad compat_sys_newfstat
 495         .quad sys32_uname
 496         .quad stub32_iopl               /* 110 */
 497         .quad sys_vhangup
 498         .quad quiet_ni_syscall  /* old "idle" system call */
 499         .quad sys32_vm86_warning        /* vm86old */
 500         .quad compat_sys_wait4
 501         .quad sys_swapoff               /* 115 */
 502         .quad sys32_sysinfo
 503         .quad sys32_ipc
 504         .quad sys_fsync
 505         .quad stub32_sigreturn
 506         .quad stub32_clone              /* 120 */
 507         .quad sys_setdomainname
 508         .quad sys_uname
 509         .quad sys_modify_ldt
 510         .quad compat_sys_adjtimex
 511         .quad sys32_mprotect            /* 125 */
 512         .quad compat_sys_sigprocmask
 513         .quad quiet_ni_syscall          /* create_module */
 514         .quad sys_init_module
 515         .quad sys_delete_module
 516         .quad quiet_ni_syscall          /* 130  get_kernel_syms */
 517         .quad sys_quotactl
 518         .quad sys_getpgid
 519         .quad sys_fchdir
 520         .quad quiet_ni_syscall  /* bdflush */
 521         .quad sys_sysfs         /* 135 */
 522         .quad sys_personality
 523         .quad quiet_ni_syscall  /* for afs_syscall */
 524         .quad sys_setfsuid16
 525         .quad sys_setfsgid16
 526         .quad sys_llseek                /* 140 */
 527         .quad compat_sys_getdents
 528         .quad compat_sys_select
 529         .quad sys_flock
 530         .quad sys_msync
 531         .quad compat_sys_readv          /* 145 */
 532         .quad compat_sys_writev
 533         .quad sys_getsid
 534         .quad sys_fdatasync
 535         .quad sys32_sysctl      /* sysctl */
 536         .quad sys_mlock         /* 150 */
 537         .quad sys_munlock
 538         .quad sys_mlockall
 539         .quad sys_munlockall
 540         .quad sys_sched_setparam
 541         .quad sys_sched_getparam   /* 155 */
 542         .quad sys_sched_setscheduler
 543         .quad sys_sched_getscheduler
 544         .quad sys_sched_yield
 545         .quad sys_sched_get_priority_max
 546         .quad sys_sched_get_priority_min  /* 160 */
 547         .quad sys_sched_rr_get_interval
 548         .quad compat_sys_nanosleep
 549         .quad sys_mremap
 550         .quad sys_setresuid16
 551         .quad sys_getresuid16   /* 165 */
 552         .quad sys32_vm86_warning        /* vm86 */
 553         .quad quiet_ni_syscall  /* query_module */
 554         .quad sys_poll
 555         .quad compat_sys_nfsservctl
 556         .quad sys_setresgid16   /* 170 */
 557         .quad sys_getresgid16
 558         .quad sys_prctl
 559         .quad stub32_rt_sigreturn
 560         .quad sys32_rt_sigaction
 561         .quad sys32_rt_sigprocmask      /* 175 */
 562         .quad sys32_rt_sigpending
 563         .quad compat_sys_rt_sigtimedwait
 564         .quad sys32_rt_sigqueueinfo
 565         .quad stub32_rt_sigsuspend
 566         .quad sys32_pread               /* 180 */
 567         .quad sys32_pwrite
 568         .quad sys_chown16
 569         .quad sys_getcwd
 570         .quad sys_capget
 571         .quad sys_capset
 572         .quad stub32_sigaltstack
 573         .quad sys32_sendfile
 574         .quad quiet_ni_syscall          /* streams1 */
 575         .quad quiet_ni_syscall          /* streams2 */
 576         .quad stub32_vfork            /* 190 */
 577         .quad compat_sys_getrlimit
 578         .quad sys32_mmap2
 579         .quad sys32_truncate64
 580         .quad sys32_ftruncate64
 581         .quad sys32_stat64              /* 195 */
 582         .quad sys32_lstat64
 583         .quad sys32_fstat64
 584         .quad sys_lchown
 585         .quad sys_getuid
 586         .quad sys_getgid                /* 200 */
 587         .quad sys_geteuid
 588         .quad sys_getegid
 589         .quad sys_setreuid
 590         .quad sys_setregid
 591         .quad sys_getgroups     /* 205 */
 592         .quad sys_setgroups
 593         .quad sys_fchown
 594         .quad sys_setresuid
 595         .quad sys_getresuid
 596         .quad sys_setresgid     /* 210 */
 597         .quad sys_getresgid
 598         .quad sys_chown
 599         .quad sys_setuid
 600         .quad sys_setgid
 601         .quad sys_setfsuid              /* 215 */
 602         .quad sys_setfsgid
 603         .quad sys_pivot_root
 604         .quad sys_mincore
 605         .quad sys_madvise
 606         .quad compat_sys_getdents64     /* 220 getdents64 */
 607         .quad compat_sys_fcntl64
 608         .quad quiet_ni_syscall          /* tux */
 609         .quad quiet_ni_syscall          /* security */
 610         .quad sys_gettid
 611         .quad sys_readahead     /* 225 */
 612         .quad sys_setxattr
 613         .quad sys_lsetxattr
 614         .quad sys_fsetxattr
 615         .quad sys_getxattr
 616         .quad sys_lgetxattr     /* 230 */
 617         .quad sys_fgetxattr
 618         .quad sys_listxattr
 619         .quad sys_llistxattr
 620         .quad sys_flistxattr
 621         .quad sys_removexattr   /* 235 */
 622         .quad sys_lremovexattr
 623         .quad sys_fremovexattr
 624         .quad sys_tkill
 625         .quad sys_sendfile64
 626         .quad compat_sys_futex          /* 240 */
 627         .quad compat_sys_sched_setaffinity
 628         .quad compat_sys_sched_getaffinity
 629         .quad sys32_set_thread_area
 630         .quad sys32_get_thread_area
 631         .quad compat_sys_io_setup       /* 245 */
 632         .quad sys_io_destroy
 633         .quad compat_sys_io_getevents
 634         .quad compat_sys_io_submit
 635         .quad sys_io_cancel
 636         .quad sys_fadvise64             /* 250 */
 637         .quad quiet_ni_syscall  /* free_huge_pages */
 638         .quad sys_exit_group
 639         .quad sys32_lookup_dcookie
 640         .quad sys_epoll_create
 641         .quad sys_epoll_ctl             /* 255 */
 642         .quad sys_epoll_wait
 643         .quad sys_remap_file_pages
 644         .quad sys_set_tid_address
 645         .quad compat_sys_timer_create
 646         .quad compat_sys_timer_settime  /* 260 */
 647         .quad compat_sys_timer_gettime
 648         .quad sys_timer_getoverrun
 649         .quad sys_timer_delete
 650         .quad compat_sys_clock_settime
 651         .quad compat_sys_clock_gettime  /* 265 */
 652         .quad compat_sys_clock_getres
 653         .quad compat_sys_clock_nanosleep
 654         .quad compat_sys_statfs64
 655         .quad compat_sys_fstatfs64
 656         .quad sys_tgkill                /* 270 */
 657         .quad compat_sys_utimes
 658         .quad sys32_fadvise64_64
 659         .quad quiet_ni_syscall  /* sys_vserver */
 660         .quad sys_mbind
 661         .quad compat_sys_get_mempolicy  /* 275 */
 662         .quad sys_set_mempolicy
 663         .quad compat_sys_mq_open
 664         .quad sys_mq_unlink
 665         .quad compat_sys_mq_timedsend
 666         .quad compat_sys_mq_timedreceive        /* 280 */
 667         .quad compat_sys_mq_notify
 668         .quad compat_sys_mq_getsetattr
 669         .quad compat_sys_kexec_load     /* reserved for kexec */
 670         .quad compat_sys_waitid
 671         .quad quiet_ni_syscall          /* 285: sys_altroot */
 672         .quad sys_add_key
 673         .quad sys_request_key
 674         .quad sys_keyctl
 675         .quad sys_ioprio_set
 676         .quad sys_ioprio_get            /* 290 */
 677         .quad sys_inotify_init
 678         .quad sys_inotify_add_watch
 679         .quad sys_inotify_rm_watch
 680         .quad sys_migrate_pages
 681         .quad compat_sys_openat         /* 295 */
 682         .quad sys_mkdirat
 683         .quad sys_mknodat
 684         .quad sys_fchownat
 685         .quad compat_sys_futimesat
 686         .quad sys32_fstatat             /* 300 */
 687         .quad sys_unlinkat
 688         .quad sys_renameat
 689         .quad sys_linkat
 690         .quad sys_symlinkat
 691         .quad sys_readlinkat            /* 305 */
 692         .quad sys_fchmodat
 693         .quad sys_faccessat
 694         .quad quiet_ni_syscall          /* pselect6 for now */
 695         .quad quiet_ni_syscall          /* ppoll for now */
 696         .quad sys_unshare               /* 310 */
 697         .quad compat_sys_set_robust_list
 698         .quad compat_sys_get_robust_list
 699         .quad sys_splice
 700         .quad sys_sync_file_range
 701         .quad sys_tee
 702         .quad compat_sys_vmsplice
 703         .quad compat_sys_move_pages
 704 ia32_syscall_end: