arch/x86/tools/gen-insn-attr-x86.awk

   1 #!/bin/awk -f
   2 # gen-insn-attr-x86.awk: Instruction attribute table generator
   3 # Written by Masami Hiramatsu <mhiramat@redhat.com>
   4 #
   5 # Usage: awk -f gen-insn-attr-x86.awk x86-opcode-map.txt > inat-tables.c
   6
   7 # Awk implementation sanity check
   8 function check_awk_implement() {
   9         if (!match("abc", "[[:lower:]]+"))
  10                 return "Your awk doesn't support charactor-class."
  11         if (sprintf("%x", 0) != "0")
  12                 return "Your awk has a printf-format problem."
  13         return ""
  14 }
  15
  16 # Clear working vars
  17 function clear_vars() {
  18         delete table
  19         delete lptable2
  20         delete lptable1
  21         delete lptable3
  22         eid = -1 # escape id
  23         gid = -1 # group id
  24         aid = -1 # AVX id
  25         tname = ""
  26 }
  27
  28 BEGIN {
  29         # Implementation error checking
  30         awkchecked = check_awk_implement()
  31         if (awkchecked != "") {
  32                 print "Error: " awkchecked > "/dev/stderr"
  33                 print "Please try to use gawk." > "/dev/stderr"
  34                 exit 1
  35         }
  36
  37         # Setup generating tables
  38         print "/* x86 opcode map generated from x86-opcode-map.txt */"
  39         print "/* Do not change this code. */\n"
  40         ggid = 1
  41         geid = 1
  42         gaid = 0
  43         delete etable
  44         delete gtable
  45         delete atable
  46
  47         opnd_expr = "^[[:alpha:]/]"
  48         ext_expr = "^\\("
  49         sep_expr = "^\\|$"
  50         group_expr = "^Grp[[:alnum:]]+"
  51
  52         imm_expr = "^[IJAO][[:lower:]]"
  53         imm_flag["Ib"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"
  54         imm_flag["Jb"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"
  55         imm_flag["Iw"] = "INAT_MAKE_IMM(INAT_IMM_WORD)"
  56         imm_flag["Id"] = "INAT_MAKE_IMM(INAT_IMM_DWORD)"
  57         imm_flag["Iq"] = "INAT_MAKE_IMM(INAT_IMM_QWORD)"
  58         imm_flag["Ap"] = "INAT_MAKE_IMM(INAT_IMM_PTR)"
  59         imm_flag["Iz"] = "INAT_MAKE_IMM(INAT_IMM_VWORD32)"
  60         imm_flag["Jz"] = "INAT_MAKE_IMM(INAT_IMM_VWORD32)"
  61         imm_flag["Iv"] = "INAT_MAKE_IMM(INAT_IMM_VWORD)"
  62         imm_flag["Ob"] = "INAT_MOFFSET"
  63         imm_flag["Ov"] = "INAT_MOFFSET"
  64
  65         modrm_expr = "^([CDEGMNPQRSUVW/][[:lower:]]+|NTA|T[012])"
  66         force64_expr = "\\([df]64\\)"
  67         rex_expr = "^REX(\\.[XRWB]+)*"
  68         fpu_expr = "^ESC" # TODO
  69
  70         lprefix1_expr = "\\(66\\)"
  71         lprefix2_expr = "\\(F3\\)"
  72         lprefix3_expr = "\\(F2\\)"
  73         max_lprefix = 4
  74
  75         vexok_expr = "\\(VEX\\)"
  76         vexonly_expr = "\\(oVEX\\)"
  77
  78         prefix_expr = "\\(Prefix\\)"
  79         prefix_num["Operand-Size"] = "INAT_PFX_OPNDSZ"
  80         prefix_num["REPNE"] = "INAT_PFX_REPNE"
  81         prefix_num["REP/REPE"] = "INAT_PFX_REPE"
  82         prefix_num["LOCK"] = "INAT_PFX_LOCK"
  83         prefix_num["SEG=CS"] = "INAT_PFX_CS"
  84         prefix_num["SEG=DS"] = "INAT_PFX_DS"
  85         prefix_num["SEG=ES"] = "INAT_PFX_ES"
  86         prefix_num["SEG=FS"] = "INAT_PFX_FS"
  87         prefix_num["SEG=GS"] = "INAT_PFX_GS"
  88         prefix_num["SEG=SS"] = "INAT_PFX_SS"
  89         prefix_num["Address-Size"] = "INAT_PFX_ADDRSZ"
  90         prefix_num["2bytes-VEX"] = "INAT_PFX_VEX2"
  91         prefix_num["3bytes-VEX"] = "INAT_PFX_VEX3"
  92
  93         clear_vars()
  94 }
  95
  96 function semantic_error(msg) {
  97         print "Semantic error at " NR ": " msg > "/dev/stderr"
  98         exit 1
  99 }
 100
 101 function debug(msg) {
 102         print "DEBUG: " msg
 103 }
 104
 105 function array_size(arr,   i,c) {
 106         c = 0
 107         for (i in arr)
 108                 c++
 109         return c
 110 }
 111
 112 /^Table:/ {
 113         print "/* " $0 " */"
 114         if (tname != "")
 115                 semantic_error("Hit Table: before EndTable:.");
 116 }
 117
 118 /^Referrer:/ {
 119         if (NF != 1) {
 120                 # escape opcode table
 121                 ref = ""
 122                 for (i = 2; i <= NF; i++)
 123                         ref = ref $i
 124                 eid = escape[ref]
 125                 tname = sprintf("inat_escape_table_%d", eid)
 126         }
 127 }
 128
 129 /^AVXcode:/ {
 130         if (NF != 1) {
 131                 # AVX/escape opcode table
 132                 aid = $2
 133                 if (gaid <= aid)
 134                         gaid = aid + 1
 135                 if (tname == "")        # AVX only opcode table
 136                         tname = sprintf("inat_avx_table_%d", $2)
 137         }
 138         if (aid == -1 && eid == -1)     # primary opcode table
 139                 tname = "inat_primary_table"
 140 }
 141
 142 /^GrpTable:/ {
 143         print "/* " $0 " */"
 144         if (!($2 in group))
 145                 semantic_error("No group: " $2 )
 146         gid = group[$2]
 147         tname = "inat_group_table_" gid
 148 }
 149
 150 function print_table(tbl,name,fmt,n)
 151 {
 152         print "const insn_attr_t " name " = {"
 153         for (i = 0; i < n; i++) {
 154                 id = sprintf(fmt, i)
 155                 if (tbl[id])
 156                         print " [" id "] = " tbl[id] ","
 157         }
 158         print "};"
 159 }
 160
 161 /^EndTable/ {
 162         if (gid != -1) {
 163                 # print group tables
 164                 if (array_size(table) != 0) {
 165                         print_table(table, tname "[INAT_GROUP_TABLE_SIZE]",
 166                                     "0x%x", 8)
 167                         gtable[gid,0] = tname
 168                 }
 169                 if (array_size(lptable1) != 0) {
 170                         print_table(lptable1, tname "_1[INAT_GROUP_TABLE_SIZE]",
 171                                     "0x%x", 8)
 172                         gtable[gid,1] = tname "_1"
 173                 }
 174                 if (array_size(lptable2) != 0) {
 175                         print_table(lptable2, tname "_2[INAT_GROUP_TABLE_SIZE]",
 176                                     "0x%x", 8)
 177                         gtable[gid,2] = tname "_2"
 178                 }
 179                 if (array_size(lptable3) != 0) {
 180                         print_table(lptable3, tname "_3[INAT_GROUP_TABLE_SIZE]",
 181                                     "0x%x", 8)
 182                         gtable[gid,3] = tname "_3"
 183                 }
 184         } else {
 185                 # print primary/escaped tables
 186                 if (array_size(table) != 0) {
 187                         print_table(table, tname "[INAT_OPCODE_TABLE_SIZE]",
 188                                     "0x%02x", 256)
 189                         etable[eid,0] = tname
 190                         if (aid >= 0)
 191                                 atable[aid,0] = tname
 192                 }
 193                 if (array_size(lptable1) != 0) {
 194                         print_table(lptable1,tname "_1[INAT_OPCODE_TABLE_SIZE]",
 195                                     "0x%02x", 256)
 196                         etable[eid,1] = tname "_1"
 197                         if (aid >= 0)
 198                                 atable[aid,1] = tname "_1"
 199                 }
 200                 if (array_size(lptable2) != 0) {
 201                         print_table(lptable2,tname "_2[INAT_OPCODE_TABLE_SIZE]",
 202                                     "0x%02x", 256)
 203                         etable[eid,2] = tname "_2"
 204                         if (aid >= 0)
 205                                 atable[aid,2] = tname "_2"
 206                 }
 207                 if (array_size(lptable3) != 0) {
 208                         print_table(lptable3,tname "_3[INAT_OPCODE_TABLE_SIZE]",
 209                                     "0x%02x", 256)
 210                         etable[eid,3] = tname "_3"
 211                         if (aid >= 0)
 212                                 atable[aid,3] = tname "_3"
 213                 }
 214         }
 215         print ""
 216         clear_vars()
 217 }
 218
 219 function add_flags(old,new) {
 220         if (old && new)
 221                 return old " | " new
 222         else if (old)
 223                 return old
 224         else
 225                 return new
 226 }
 227
 228 # convert operands to flags.
 229 function convert_operands(count,opnd,       i,j,imm,mod)
 230 {
 231         imm = null
 232         mod = null
 233         for (j = 1; j <= count; j++) {
 234                 i = opnd[j]
 235                 if (match(i, imm_expr) == 1) {
 236                         if (!imm_flag[i])
 237                                 semantic_error("Unknown imm opnd: " i)
 238                         if (imm) {
 239                                 if (i != "Ib")
 240                                         semantic_error("Second IMM error")
 241                                 imm = add_flags(imm, "INAT_SCNDIMM")
 242                         } else
 243                                 imm = imm_flag[i]
 244                 } else if (match(i, modrm_expr))
 245                         mod = "INAT_MODRM"
 246         }
 247         return add_flags(imm, mod)
 248 }
 249
 250 /^[0-9a-f]+\:/ {
 251         if (NR == 1)
 252                 next
 253         # get index
 254         idx = "0x" substr($1, 1, index($1,":") - 1)
 255         if (idx in table)
 256                 semantic_error("Redefine " idx " in " tname)
 257
 258         # check if escaped opcode
 259         if ("escape" == $2) {
 260                 if ($3 != "#")
 261                         semantic_error("No escaped name")
 262                 ref = ""
 263                 for (i = 4; i <= NF; i++)
 264                         ref = ref $i
 265                 if (ref in escape)
 266                         semantic_error("Redefine escape (" ref ")")
 267                 escape[ref] = geid
 268                 geid++
 269                 table[idx] = "INAT_MAKE_ESCAPE(" escape[ref] ")"
 270                 next
 271         }
 272
 273         variant = null
 274         # converts
 275         i = 2
 276         while (i <= NF) {
 277                 opcode = $(i++)
 278                 delete opnds
 279                 ext = null
 280                 flags = null
 281                 opnd = null
 282                 # parse one opcode
 283                 if (match($i, opnd_expr)) {
 284                         opnd = $i
 285                         count = split($(i++), opnds, ",")
 286                         flags = convert_operands(count, opnds)
 287                 }
 288                 if (match($i, ext_expr))
 289                         ext = $(i++)
 290                 if (match($i, sep_expr))
 291                         i++
 292                 else if (i < NF)
 293                         semantic_error($i " is not a separator")
 294
 295                 # check if group opcode
 296                 if (match(opcode, group_expr)) {
 297                         if (!(opcode in group)) {
 298                                 group[opcode] = ggid
 299                                 ggid++
 300                         }
 301                         flags = add_flags(flags, "INAT_MAKE_GROUP(" group[opcode] ")")
 302                 }
 303                 # check force(or default) 64bit
 304                 if (match(ext, force64_expr))
 305                         flags = add_flags(flags, "INAT_FORCE64")
 306
 307                 # check REX prefix
 308                 if (match(opcode, rex_expr))
 309                         flags = add_flags(flags, "INAT_MAKE_PREFIX(INAT_PFX_REX)")
 310
 311                 # check coprocessor escape : TODO
 312                 if (match(opcode, fpu_expr))
 313                         flags = add_flags(flags, "INAT_MODRM")
 314
 315                 # check VEX only code
 316                 if (match(ext, vexonly_expr))
 317                         flags = add_flags(flags, "INAT_VEXOK | INAT_VEXONLY")
 318
 319                 # check VEX only code
 320                 if (match(ext, vexok_expr))
 321                         flags = add_flags(flags, "INAT_VEXOK")
 322
 323                 # check prefixes
 324                 if (match(ext, prefix_expr)) {
 325                         if (!prefix_num[opcode])
 326                                 semantic_error("Unknown prefix: " opcode)
 327                         flags = add_flags(flags, "INAT_MAKE_PREFIX(" prefix_num[opcode] ")")
 328                 }
 329                 if (length(flags) == 0)
 330                         continue
 331                 # check if last prefix
 332                 if (match(ext, lprefix1_expr)) {
 333                         lptable1[idx] = add_flags(lptable1[idx],flags)
 334                         variant = "INAT_VARIANT"
 335                 } else if (match(ext, lprefix2_expr)) {
 336                         lptable2[idx] = add_flags(lptable2[idx],flags)
 337                         variant = "INAT_VARIANT"
 338                 } else if (match(ext, lprefix3_expr)) {
 339                         lptable3[idx] = add_flags(lptable3[idx],flags)
 340                         variant = "INAT_VARIANT"
 341                 } else {
 342                         table[idx] = add_flags(table[idx],flags)
 343                 }
 344         }
 345         if (variant)
 346                 table[idx] = add_flags(table[idx],variant)
 347 }
 348
 349 END {
 350         if (awkchecked != "")
 351                 exit 1
 352         # print escape opcode map's array
 353         print "/* Escape opcode map array */"
 354         print "const insn_attr_t const *inat_escape_tables[INAT_ESC_MAX + 1]" \
 355               "[INAT_LSTPFX_MAX + 1] = {"
 356         for (i = 0; i < geid; i++)
 357                 for (j = 0; j < max_lprefix; j++)
 358                         if (etable[i,j])
 359                                 print " ["i"]["j"] = "etable[i,j]","
 360         print "};\n"
 361         # print group opcode map's array
 362         print "/* Group opcode map array */"
 363         print "const insn_attr_t const *inat_group_tables[INAT_GRP_MAX + 1]"\
 364               "[INAT_LSTPFX_MAX + 1] = {"
 365         for (i = 0; i < ggid; i++)
 366                 for (j = 0; j < max_lprefix; j++)
 367                         if (gtable[i,j])
 368                                 print " ["i"]["j"] = "gtable[i,j]","
 369         print "};\n"
 370         # print AVX opcode map's array
 371         print "/* AVX opcode map array */"
 372         print "const insn_attr_t const *inat_avx_tables[X86_VEX_M_MAX + 1]"\
 373               "[INAT_LSTPFX_MAX + 1] = {"
 374         for (i = 0; i < gaid; i++)
 375                 for (j = 0; j < max_lprefix; j++)
 376                         if (atable[i,j])
 377                                 print " ["i"]["j"] = "atable[i,j]","
 378         print "};"
 379 }
 380