arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58
  59 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  60 #include <linux/elf-em.h>
  61 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  62 #define __AUDIT_ARCH_64BIT 0x80000000
  63 #define __AUDIT_ARCH_LE    0x40000000
  64
  65         .code64
  66         .section .entry.text, "ax"
  67
  68 #ifdef CONFIG_FUNCTION_TRACER
  69 #ifdef CONFIG_DYNAMIC_FTRACE
  70 ENTRY(mcount)
  71         retq
  72 END(mcount)
  73
  74 ENTRY(ftrace_caller)
  75         cmpl $0, function_trace_stop
  76         jne  ftrace_stub
  77
  78         MCOUNT_SAVE_FRAME
  79
  80         movq 0x38(%rsp), %rdi
  81         movq 8(%rbp), %rsi
  82         subq $MCOUNT_INSN_SIZE, %rdi
  83
  84 GLOBAL(ftrace_call)
  85         call ftrace_stub
  86
  87         MCOUNT_RESTORE_FRAME
  88
  89 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  90 GLOBAL(ftrace_graph_call)
  91         jmp ftrace_stub
  92 #endif
  93
  94 GLOBAL(ftrace_stub)
  95         retq
  96 END(ftrace_caller)
  97
  98 #else /* ! CONFIG_DYNAMIC_FTRACE */
  99 ENTRY(mcount)
 100         cmpl $0, function_trace_stop
 101         jne  ftrace_stub
 102
 103         cmpq $ftrace_stub, ftrace_trace_function
 104         jnz trace
 105
 106 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 107         cmpq $ftrace_stub, ftrace_graph_return
 108         jnz ftrace_graph_caller
 109
 110         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 111         jnz ftrace_graph_caller
 112 #endif
 113
 114 GLOBAL(ftrace_stub)
 115         retq
 116
 117 trace:
 118         MCOUNT_SAVE_FRAME
 119
 120         movq 0x38(%rsp), %rdi
 121         movq 8(%rbp), %rsi
 122         subq $MCOUNT_INSN_SIZE, %rdi
 123
 124         call   *ftrace_trace_function
 125
 126         MCOUNT_RESTORE_FRAME
 127
 128         jmp ftrace_stub
 129 END(mcount)
 130 #endif /* CONFIG_DYNAMIC_FTRACE */
 131 #endif /* CONFIG_FUNCTION_TRACER */
 132
 133 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 134 ENTRY(ftrace_graph_caller)
 135         cmpl $0, function_trace_stop
 136         jne ftrace_stub
 137
 138         MCOUNT_SAVE_FRAME
 139
 140         leaq 8(%rbp), %rdi
 141         movq 0x38(%rsp), %rsi
 142         movq (%rbp), %rdx
 143         subq $MCOUNT_INSN_SIZE, %rsi
 144
 145         call    prepare_ftrace_return
 146
 147         MCOUNT_RESTORE_FRAME
 148
 149         retq
 150 END(ftrace_graph_caller)
 151
 152 GLOBAL(return_to_handler)
 153         subq  $24, %rsp
 154
 155         /* Save the return values */
 156         movq %rax, (%rsp)
 157         movq %rdx, 8(%rsp)
 158         movq %rbp, %rdi
 159
 160         call ftrace_return_to_handler
 161
 162         movq %rax, %rdi
 163         movq 8(%rsp), %rdx
 164         movq (%rsp), %rax
 165         addq $24, %rsp
 166         jmp *%rdi
 167 #endif
 168
 169
 170 #ifndef CONFIG_PREEMPT
 171 #define retint_kernel retint_restore_args
 172 #endif
 173
 174 #ifdef CONFIG_PARAVIRT
 175 ENTRY(native_usergs_sysret64)
 176         swapgs
 177         sysretq
 178 ENDPROC(native_usergs_sysret64)
 179 #endif /* CONFIG_PARAVIRT */
 180
 181
 182 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 183 #ifdef CONFIG_TRACE_IRQFLAGS
 184         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 185         jnc  1f
 186         TRACE_IRQS_ON
 187 1:
 188 #endif
 189 .endm
 190
 191 /*
 192  * C code is not supposed to know about undefined top of stack. Every time
 193  * a C function with an pt_regs argument is called from the SYSCALL based
 194  * fast path FIXUP_TOP_OF_STACK is needed.
 195  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 196  * manipulation.
 197  */
 198
 199         /* %rsp:at FRAMEEND */
 200         .macro FIXUP_TOP_OF_STACK tmp offset=0
 201         movq PER_CPU_VAR(old_rsp),\tmp
 202         movq \tmp,RSP+\offset(%rsp)
 203         movq $__USER_DS,SS+\offset(%rsp)
 204         movq $__USER_CS,CS+\offset(%rsp)
 205         movq $-1,RCX+\offset(%rsp)
 206         movq R11+\offset(%rsp),\tmp  /* get eflags */
 207         movq \tmp,EFLAGS+\offset(%rsp)
 208         .endm
 209
 210         .macro RESTORE_TOP_OF_STACK tmp offset=0
 211         movq RSP+\offset(%rsp),\tmp
 212         movq \tmp,PER_CPU_VAR(old_rsp)
 213         movq EFLAGS+\offset(%rsp),\tmp
 214         movq \tmp,R11+\offset(%rsp)
 215         .endm
 216
 217         .macro FAKE_STACK_FRAME child_rip
 218         /* push in order ss, rsp, eflags, cs, rip */
 219         xorl %eax, %eax
 220         pushq_cfi $__KERNEL_DS /* ss */
 221         /*CFI_REL_OFFSET        ss,0*/
 222         pushq_cfi %rax /* rsp */
 223         CFI_REL_OFFSET  rsp,0
 224         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 225         /*CFI_REL_OFFSET        rflags,0*/
 226         pushq_cfi $__KERNEL_CS /* cs */
 227         /*CFI_REL_OFFSET        cs,0*/
 228         pushq_cfi \child_rip /* rip */
 229         CFI_REL_OFFSET  rip,0
 230         pushq_cfi %rax /* orig rax */
 231         .endm
 232
 233         .macro UNFAKE_STACK_FRAME
 234         addq $8*6, %rsp
 235         CFI_ADJUST_CFA_OFFSET   -(6*8)
 236         .endm
 237
 238 /*
 239  * initial frame state for interrupts (and exceptions without error code)
 240  */
 241         .macro EMPTY_FRAME start=1 offset=0
 242         .if \start
 243         CFI_STARTPROC simple
 244         CFI_SIGNAL_FRAME
 245         CFI_DEF_CFA rsp,8+\offset
 246         .else
 247         CFI_DEF_CFA_OFFSET 8+\offset
 248         .endif
 249         .endm
 250
 251 /*
 252  * initial frame state for interrupts (and exceptions without error code)
 253  */
 254         .macro INTR_FRAME start=1 offset=0
 255         EMPTY_FRAME \start, SS+8+\offset-RIP
 256         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 257         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 258         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 259         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 260         CFI_REL_OFFSET rip, RIP+\offset-RIP
 261         .endm
 262
 263 /*
 264  * initial frame state for exceptions with error code (and interrupts
 265  * with vector already pushed)
 266  */
 267         .macro XCPT_FRAME start=1 offset=0
 268         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 269         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 270         .endm
 271
 272 /*
 273  * frame that enables calling into C.
 274  */
 275         .macro PARTIAL_FRAME start=1 offset=0
 276         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 277         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 278         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 283         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 286         .endm
 287
 288 /*
 289  * frame that enables passing a complete pt_regs to a C function.
 290  */
 291         .macro DEFAULT_FRAME start=1 offset=0
 292         PARTIAL_FRAME \start, R11+\offset-R15
 293         CFI_REL_OFFSET rbx, RBX+\offset
 294         CFI_REL_OFFSET rbp, RBP+\offset
 295         CFI_REL_OFFSET r12, R12+\offset
 296         CFI_REL_OFFSET r13, R13+\offset
 297         CFI_REL_OFFSET r14, R14+\offset
 298         CFI_REL_OFFSET r15, R15+\offset
 299         .endm
 300
 301 /* save partial stack frame */
 302         .pushsection .kprobes.text, "ax"
 303 ENTRY(save_args)
 304         XCPT_FRAME
 305         cld
 306         /*
 307          * start from rbp in pt_regs and jump over
 308          * return address.
 309          */
 310         movq_cfi rdi, RDI+8-RBP
 311         movq_cfi rsi, RSI+8-RBP
 312         movq_cfi rdx, RDX+8-RBP
 313         movq_cfi rcx, RCX+8-RBP
 314         movq_cfi rax, RAX+8-RBP
 315         movq_cfi  r8,  R8+8-RBP
 316         movq_cfi  r9,  R9+8-RBP
 317         movq_cfi r10, R10+8-RBP
 318         movq_cfi r11, R11+8-RBP
 319
 320         leaq -RBP+8(%rsp),%rdi  /* arg1 for handler */
 321         movq_cfi rbp, 8         /* push %rbp */
 322         leaq 8(%rsp), %rbp              /* mov %rsp, %ebp */
 323         testl $3, CS(%rdi)
 324         je 1f
 325         SWAPGS
 326         /*
 327          * irq_count is used to check if a CPU is already on an interrupt stack
 328          * or not. While this is essentially redundant with preempt_count it is
 329          * a little cheaper to use a separate counter in the PDA (short of
 330          * moving irq_enter into assembly, which would be too much work)
 331          */
 332 1:      incl PER_CPU_VAR(irq_count)
 333         jne 2f
 334         popq_cfi %rax                   /* move return address... */
 335         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 336         EMPTY_FRAME 0
 337         pushq_cfi %rbp                  /* backlink for unwinder */
 338         pushq_cfi %rax                  /* ... to the new stack */
 339         /*
 340          * We entered an interrupt context - irqs are off:
 341          */
 342 2:      TRACE_IRQS_OFF
 343         ret
 344         CFI_ENDPROC
 345 END(save_args)
 346         .popsection
 347
 348 ENTRY(save_rest)
 349         PARTIAL_FRAME 1 REST_SKIP+8
 350         movq 5*8+16(%rsp), %r11 /* save return address */
 351         movq_cfi rbx, RBX+16
 352         movq_cfi rbp, RBP+16
 353         movq_cfi r12, R12+16
 354         movq_cfi r13, R13+16
 355         movq_cfi r14, R14+16
 356         movq_cfi r15, R15+16
 357         movq %r11, 8(%rsp)      /* return address */
 358         FIXUP_TOP_OF_STACK %r11, 16
 359         ret
 360         CFI_ENDPROC
 361 END(save_rest)
 362
 363 /* save complete stack frame */
 364         .pushsection .kprobes.text, "ax"
 365 ENTRY(save_paranoid)
 366         XCPT_FRAME 1 RDI+8
 367         cld
 368         movq_cfi rdi, RDI+8
 369         movq_cfi rsi, RSI+8
 370         movq_cfi rdx, RDX+8
 371         movq_cfi rcx, RCX+8
 372         movq_cfi rax, RAX+8
 373         movq_cfi r8, R8+8
 374         movq_cfi r9, R9+8
 375         movq_cfi r10, R10+8
 376         movq_cfi r11, R11+8
 377         movq_cfi rbx, RBX+8
 378         movq_cfi rbp, RBP+8
 379         movq_cfi r12, R12+8
 380         movq_cfi r13, R13+8
 381         movq_cfi r14, R14+8
 382         movq_cfi r15, R15+8
 383         movl $1,%ebx
 384         movl $MSR_GS_BASE,%ecx
 385         rdmsr
 386         testl %edx,%edx
 387         js 1f   /* negative -> in kernel */
 388         SWAPGS
 389         xorl %ebx,%ebx
 390 1:      ret
 391         CFI_ENDPROC
 392 END(save_paranoid)
 393         .popsection
 394
 395 /*
 396  * A newly forked process directly context switches into this address.
 397  *
 398  * rdi: prev task we switched from
 399  */
 400 ENTRY(ret_from_fork)
 401         DEFAULT_FRAME
 402
 403         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 404
 405         pushq_cfi kernel_eflags(%rip)
 406         popfq_cfi                               # reset kernel eflags
 407
 408         call schedule_tail                      # rdi: 'prev' task parameter
 409
 410         GET_THREAD_INFO(%rcx)
 411
 412         RESTORE_REST
 413
 414         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 415         je   int_ret_from_sys_call
 416
 417         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 418         jnz  int_ret_from_sys_call
 419
 420         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 421         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 422
 423         CFI_ENDPROC
 424 END(ret_from_fork)
 425
 426 /*
 427  * System call entry. Up to 6 arguments in registers are supported.
 428  *
 429  * SYSCALL does not save anything on the stack and does not change the
 430  * stack pointer.
 431  */
 432
 433 /*
 434  * Register setup:
 435  * rax  system call number
 436  * rdi  arg0
 437  * rcx  return address for syscall/sysret, C arg3
 438  * rsi  arg1
 439  * rdx  arg2
 440  * r10  arg3    (--> moved to rcx for C)
 441  * r8   arg4
 442  * r9   arg5
 443  * r11  eflags for syscall/sysret, temporary for C
 444  * r12-r15,rbp,rbx saved by C code, not touched.
 445  *
 446  * Interrupts are off on entry.
 447  * Only called from user space.
 448  *
 449  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 450  *      and report it properly in ps. Unfortunately we haven't.
 451  *
 452  * When user can change the frames always force IRET. That is because
 453  * it deals with uncanonical addresses better. SYSRET has trouble
 454  * with them due to bugs in both AMD and Intel CPUs.
 455  */
 456
 457 ENTRY(system_call)
 458         CFI_STARTPROC   simple
 459         CFI_SIGNAL_FRAME
 460         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 461         CFI_REGISTER    rip,rcx
 462         /*CFI_REGISTER  rflags,r11*/
 463         SWAPGS_UNSAFE_STACK
 464         /*
 465          * A hypervisor implementation might want to use a label
 466          * after the swapgs, so that it can do the swapgs
 467          * for the guest and jump here on syscall.
 468          */
 469 ENTRY(system_call_after_swapgs)
 470
 471         movq    %rsp,PER_CPU_VAR(old_rsp)
 472         movq    PER_CPU_VAR(kernel_stack),%rsp
 473         /*
 474          * No need to follow this irqs off/on section - it's straight
 475          * and short:
 476          */
 477         ENABLE_INTERRUPTS(CLBR_NONE)
 478         SAVE_ARGS 8,1
 479         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 480         movq  %rcx,RIP-ARGOFFSET(%rsp)
 481         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 482         GET_THREAD_INFO(%rcx)
 483         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 484         jnz tracesys
 485 system_call_fastpath:
 486         cmpq $__NR_syscall_max,%rax
 487         ja badsys
 488         movq %r10,%rcx
 489         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 490         movq %rax,RAX-ARGOFFSET(%rsp)
 491 /*
 492  * Syscall return path ending with SYSRET (fast path)
 493  * Has incomplete stack frame and undefined top of stack.
 494  */
 495 ret_from_sys_call:
 496         movl $_TIF_ALLWORK_MASK,%edi
 497         /* edi: flagmask */
 498 sysret_check:
 499         LOCKDEP_SYS_EXIT
 500         GET_THREAD_INFO(%rcx)
 501         DISABLE_INTERRUPTS(CLBR_NONE)
 502         TRACE_IRQS_OFF
 503         movl TI_flags(%rcx),%edx
 504         andl %edi,%edx
 505         jnz  sysret_careful
 506         CFI_REMEMBER_STATE
 507         /*
 508          * sysretq will re-enable interrupts:
 509          */
 510         TRACE_IRQS_ON
 511         movq RIP-ARGOFFSET(%rsp),%rcx
 512         CFI_REGISTER    rip,rcx
 513         RESTORE_ARGS 0,-ARG_SKIP,1
 514         /*CFI_REGISTER  rflags,r11*/
 515         movq    PER_CPU_VAR(old_rsp), %rsp
 516         USERGS_SYSRET64
 517
 518         CFI_RESTORE_STATE
 519         /* Handle reschedules */
 520         /* edx: work, edi: workmask */
 521 sysret_careful:
 522         bt $TIF_NEED_RESCHED,%edx
 523         jnc sysret_signal
 524         TRACE_IRQS_ON
 525         ENABLE_INTERRUPTS(CLBR_NONE)
 526         pushq_cfi %rdi
 527         call schedule
 528         popq_cfi %rdi
 529         jmp sysret_check
 530
 531         /* Handle a signal */
 532 sysret_signal:
 533         TRACE_IRQS_ON
 534         ENABLE_INTERRUPTS(CLBR_NONE)
 535 #ifdef CONFIG_AUDITSYSCALL
 536         bt $TIF_SYSCALL_AUDIT,%edx
 537         jc sysret_audit
 538 #endif
 539         /*
 540          * We have a signal, or exit tracing or single-step.
 541          * These all wind up with the iret return path anyway,
 542          * so just join that path right now.
 543          */
 544         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 545         jmp int_check_syscall_exit_work
 546
 547 badsys:
 548         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 549         jmp ret_from_sys_call
 550
 551 #ifdef CONFIG_AUDITSYSCALL
 552         /*
 553          * Fast path for syscall audit without full syscall trace.
 554          * We just call audit_syscall_entry() directly, and then
 555          * jump back to the normal fast path.
 556          */
 557 auditsys:
 558         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 559         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 560         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 561         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 562         movq %rax,%rsi                  /* 2nd arg: syscall number */
 563         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 564         call audit_syscall_entry
 565         LOAD_ARGS 0             /* reload call-clobbered registers */
 566         jmp system_call_fastpath
 567
 568         /*
 569          * Return fast path for syscall audit.  Call audit_syscall_exit()
 570          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 571          * masked off.
 572          */
 573 sysret_audit:
 574         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 575         cmpq $0,%rsi            /* is it < 0? */
 576         setl %al                /* 1 if so, 0 if not */
 577         movzbl %al,%edi         /* zero-extend that into %edi */
 578         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 579         call audit_syscall_exit
 580         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 581         jmp sysret_check
 582 #endif  /* CONFIG_AUDITSYSCALL */
 583
 584         /* Do syscall tracing */
 585 tracesys:
 586 #ifdef CONFIG_AUDITSYSCALL
 587         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 588         jz auditsys
 589 #endif
 590         SAVE_REST
 591         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 592         FIXUP_TOP_OF_STACK %rdi
 593         movq %rsp,%rdi
 594         call syscall_trace_enter
 595         /*
 596          * Reload arg registers from stack in case ptrace changed them.
 597          * We don't reload %rax because syscall_trace_enter() returned
 598          * the value it wants us to use in the table lookup.
 599          */
 600         LOAD_ARGS ARGOFFSET, 1
 601         RESTORE_REST
 602         cmpq $__NR_syscall_max,%rax
 603         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 604         movq %r10,%rcx  /* fixup for C */
 605         call *sys_call_table(,%rax,8)
 606         movq %rax,RAX-ARGOFFSET(%rsp)
 607         /* Use IRET because user could have changed frame */
 608
 609 /*
 610  * Syscall return path ending with IRET.
 611  * Has correct top of stack, but partial stack frame.
 612  */
 613 GLOBAL(int_ret_from_sys_call)
 614         DISABLE_INTERRUPTS(CLBR_NONE)
 615         TRACE_IRQS_OFF
 616         testl $3,CS-ARGOFFSET(%rsp)
 617         je retint_restore_args
 618         movl $_TIF_ALLWORK_MASK,%edi
 619         /* edi: mask to check */
 620 GLOBAL(int_with_check)
 621         LOCKDEP_SYS_EXIT_IRQ
 622         GET_THREAD_INFO(%rcx)
 623         movl TI_flags(%rcx),%edx
 624         andl %edi,%edx
 625         jnz   int_careful
 626         andl    $~TS_COMPAT,TI_status(%rcx)
 627         jmp   retint_swapgs
 628
 629         /* Either reschedule or signal or syscall exit tracking needed. */
 630         /* First do a reschedule test. */
 631         /* edx: work, edi: workmask */
 632 int_careful:
 633         bt $TIF_NEED_RESCHED,%edx
 634         jnc  int_very_careful
 635         TRACE_IRQS_ON
 636         ENABLE_INTERRUPTS(CLBR_NONE)
 637         pushq_cfi %rdi
 638         call schedule
 639         popq_cfi %rdi
 640         DISABLE_INTERRUPTS(CLBR_NONE)
 641         TRACE_IRQS_OFF
 642         jmp int_with_check
 643
 644         /* handle signals and tracing -- both require a full stack frame */
 645 int_very_careful:
 646         TRACE_IRQS_ON
 647         ENABLE_INTERRUPTS(CLBR_NONE)
 648 int_check_syscall_exit_work:
 649         SAVE_REST
 650         /* Check for syscall exit trace */
 651         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 652         jz int_signal
 653         pushq_cfi %rdi
 654         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 655         call syscall_trace_leave
 656         popq_cfi %rdi
 657         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 658         jmp int_restore_rest
 659
 660 int_signal:
 661         testl $_TIF_DO_NOTIFY_MASK,%edx
 662         jz 1f
 663         movq %rsp,%rdi          # &ptregs -> arg1
 664         xorl %esi,%esi          # oldset -> arg2
 665         call do_notify_resume
 666 1:      movl $_TIF_WORK_MASK,%edi
 667 int_restore_rest:
 668         RESTORE_REST
 669         DISABLE_INTERRUPTS(CLBR_NONE)
 670         TRACE_IRQS_OFF
 671         jmp int_with_check
 672         CFI_ENDPROC
 673 END(system_call)
 674
 675 /*
 676  * Certain special system calls that need to save a complete full stack frame.
 677  */
 678         .macro PTREGSCALL label,func,arg
 679 ENTRY(\label)
 680         PARTIAL_FRAME 1 8               /* offset 8: return address */
 681         subq $REST_SKIP, %rsp
 682         CFI_ADJUST_CFA_OFFSET REST_SKIP
 683         call save_rest
 684         DEFAULT_FRAME 0 8               /* offset 8: return address */
 685         leaq 8(%rsp), \arg      /* pt_regs pointer */
 686         call \func
 687         jmp ptregscall_common
 688         CFI_ENDPROC
 689 END(\label)
 690         .endm
 691
 692         PTREGSCALL stub_clone, sys_clone, %r8
 693         PTREGSCALL stub_fork, sys_fork, %rdi
 694         PTREGSCALL stub_vfork, sys_vfork, %rdi
 695         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 696         PTREGSCALL stub_iopl, sys_iopl, %rsi
 697
 698 ENTRY(ptregscall_common)
 699         DEFAULT_FRAME 1 8       /* offset 8: return address */
 700         RESTORE_TOP_OF_STACK %r11, 8
 701         movq_cfi_restore R15+8, r15
 702         movq_cfi_restore R14+8, r14
 703         movq_cfi_restore R13+8, r13
 704         movq_cfi_restore R12+8, r12
 705         movq_cfi_restore RBP+8, rbp
 706         movq_cfi_restore RBX+8, rbx
 707         ret $REST_SKIP          /* pop extended registers */
 708         CFI_ENDPROC
 709 END(ptregscall_common)
 710
 711 ENTRY(stub_execve)
 712         CFI_STARTPROC
 713         addq $8, %rsp
 714         PARTIAL_FRAME 0
 715         SAVE_REST
 716         FIXUP_TOP_OF_STACK %r11
 717         movq %rsp, %rcx
 718         call sys_execve
 719         RESTORE_TOP_OF_STACK %r11
 720         movq %rax,RAX(%rsp)
 721         RESTORE_REST
 722         jmp int_ret_from_sys_call
 723         CFI_ENDPROC
 724 END(stub_execve)
 725
 726 /*
 727  * sigreturn is special because it needs to restore all registers on return.
 728  * This cannot be done with SYSRET, so use the IRET return path instead.
 729  */
 730 ENTRY(stub_rt_sigreturn)
 731         CFI_STARTPROC
 732         addq $8, %rsp
 733         PARTIAL_FRAME 0
 734         SAVE_REST
 735         movq %rsp,%rdi
 736         FIXUP_TOP_OF_STACK %r11
 737         call sys_rt_sigreturn
 738         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 739         RESTORE_REST
 740         jmp int_ret_from_sys_call
 741         CFI_ENDPROC
 742 END(stub_rt_sigreturn)
 743
 744 /*
 745  * Build the entry stubs and pointer table with some assembler magic.
 746  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 747  * single cache line on all modern x86 implementations.
 748  */
 749         .section .init.rodata,"a"
 750 ENTRY(interrupt)
 751         .section .entry.text
 752         .p2align 5
 753         .p2align CONFIG_X86_L1_CACHE_SHIFT
 754 ENTRY(irq_entries_start)
 755         INTR_FRAME
 756 vector=FIRST_EXTERNAL_VECTOR
 757 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 758         .balign 32
 759   .rept 7
 760     .if vector < NR_VECTORS
 761       .if vector <> FIRST_EXTERNAL_VECTOR
 762         CFI_ADJUST_CFA_OFFSET -8
 763       .endif
 764 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 765       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 766         jmp 2f
 767       .endif
 768       .previous
 769         .quad 1b
 770       .section .entry.text
 771 vector=vector+1
 772     .endif
 773   .endr
 774 2:      jmp common_interrupt
 775 .endr
 776         CFI_ENDPROC
 777 END(irq_entries_start)
 778
 779 .previous
 780 END(interrupt)
 781 .previous
 782
 783 /*
 784  * Interrupt entry/exit.
 785  *
 786  * Interrupt entry points save only callee clobbered registers in fast path.
 787  *
 788  * Entry runs with interrupts off.
 789  */
 790
 791 /* 0(%rsp): ~(interrupt number) */
 792         .macro interrupt func
 793         /* reserve pt_regs for scratch regs and rbp */
 794         subq $ORIG_RAX-RBP, %rsp
 795         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 796         call save_args
 797         PARTIAL_FRAME 0
 798         call \func
 799         .endm
 800
 801 /*
 802  * Interrupt entry/exit should be protected against kprobes
 803  */
 804         .pushsection .kprobes.text, "ax"
 805         /*
 806          * The interrupt stubs push (~vector+0x80) onto the stack and
 807          * then jump to common_interrupt.
 808          */
 809         .p2align CONFIG_X86_L1_CACHE_SHIFT
 810 common_interrupt:
 811         XCPT_FRAME
 812         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 813         interrupt do_IRQ
 814         /* 0(%rsp): old_rsp-ARGOFFSET */
 815 ret_from_intr:
 816         DISABLE_INTERRUPTS(CLBR_NONE)
 817         TRACE_IRQS_OFF
 818         decl PER_CPU_VAR(irq_count)
 819         leaveq
 820
 821         CFI_RESTORE             rbp
 822         CFI_DEF_CFA_REGISTER    rsp
 823         CFI_ADJUST_CFA_OFFSET   -8
 824
 825         /* we did not save rbx, restore only from ARGOFFSET */
 826         addq $8, %rsp
 827         CFI_ADJUST_CFA_OFFSET   -8
 828 exit_intr:
 829         GET_THREAD_INFO(%rcx)
 830         testl $3,CS-ARGOFFSET(%rsp)
 831         je retint_kernel
 832
 833         /* Interrupt came from user space */
 834         /*
 835          * Has a correct top of stack, but a partial stack frame
 836          * %rcx: thread info. Interrupts off.
 837          */
 838 retint_with_reschedule:
 839         movl $_TIF_WORK_MASK,%edi
 840 retint_check:
 841         LOCKDEP_SYS_EXIT_IRQ
 842         movl TI_flags(%rcx),%edx
 843         andl %edi,%edx
 844         CFI_REMEMBER_STATE
 845         jnz  retint_careful
 846
 847 retint_swapgs:          /* return to user-space */
 848         /*
 849          * The iretq could re-enable interrupts:
 850          */
 851         DISABLE_INTERRUPTS(CLBR_ANY)
 852         TRACE_IRQS_IRETQ
 853         SWAPGS
 854         jmp restore_args
 855
 856 retint_restore_args:    /* return to kernel space */
 857         DISABLE_INTERRUPTS(CLBR_ANY)
 858         /*
 859          * The iretq could re-enable interrupts:
 860          */
 861         TRACE_IRQS_IRETQ
 862 restore_args:
 863         RESTORE_ARGS 0,8,0
 864
 865 irq_return:
 866         INTERRUPT_RETURN
 867
 868         .section __ex_table, "a"
 869         .quad irq_return, bad_iret
 870         .previous
 871
 872 #ifdef CONFIG_PARAVIRT
 873 ENTRY(native_iret)
 874         iretq
 875
 876         .section __ex_table,"a"
 877         .quad native_iret, bad_iret
 878         .previous
 879 #endif
 880
 881         .section .fixup,"ax"
 882 bad_iret:
 883         /*
 884          * The iret traps when the %cs or %ss being restored is bogus.
 885          * We've lost the original trap vector and error code.
 886          * #GPF is the most likely one to get for an invalid selector.
 887          * So pretend we completed the iret and took the #GPF in user mode.
 888          *
 889          * We are now running with the kernel GS after exception recovery.
 890          * But error_entry expects us to have user GS to match the user %cs,
 891          * so swap back.
 892          */
 893         pushq $0
 894
 895         SWAPGS
 896         jmp general_protection
 897
 898         .previous
 899
 900         /* edi: workmask, edx: work */
 901 retint_careful:
 902         CFI_RESTORE_STATE
 903         bt    $TIF_NEED_RESCHED,%edx
 904         jnc   retint_signal
 905         TRACE_IRQS_ON
 906         ENABLE_INTERRUPTS(CLBR_NONE)
 907         pushq_cfi %rdi
 908         call  schedule
 909         popq_cfi %rdi
 910         GET_THREAD_INFO(%rcx)
 911         DISABLE_INTERRUPTS(CLBR_NONE)
 912         TRACE_IRQS_OFF
 913         jmp retint_check
 914
 915 retint_signal:
 916         testl $_TIF_DO_NOTIFY_MASK,%edx
 917         jz    retint_swapgs
 918         TRACE_IRQS_ON
 919         ENABLE_INTERRUPTS(CLBR_NONE)
 920         SAVE_REST
 921         movq $-1,ORIG_RAX(%rsp)
 922         xorl %esi,%esi          # oldset
 923         movq %rsp,%rdi          # &pt_regs
 924         call do_notify_resume
 925         RESTORE_REST
 926         DISABLE_INTERRUPTS(CLBR_NONE)
 927         TRACE_IRQS_OFF
 928         GET_THREAD_INFO(%rcx)
 929         jmp retint_with_reschedule
 930
 931 #ifdef CONFIG_PREEMPT
 932         /* Returning to kernel space. Check if we need preemption */
 933         /* rcx:  threadinfo. interrupts off. */
 934 ENTRY(retint_kernel)
 935         cmpl $0,TI_preempt_count(%rcx)
 936         jnz  retint_restore_args
 937         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 938         jnc  retint_restore_args
 939         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 940         jnc  retint_restore_args
 941         call preempt_schedule_irq
 942         jmp exit_intr
 943 #endif
 944
 945         CFI_ENDPROC
 946 END(common_interrupt)
 947 /*
 948  * End of kprobes section
 949  */
 950        .popsection
 951
 952 /*
 953  * APIC interrupts.
 954  */
 955 .macro apicinterrupt num sym do_sym
 956 ENTRY(\sym)
 957         INTR_FRAME
 958         pushq_cfi $~(\num)
 959         interrupt \do_sym
 960         jmp ret_from_intr
 961         CFI_ENDPROC
 962 END(\sym)
 963 .endm
 964
 965 #ifdef CONFIG_SMP
 966 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 967         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 968 apicinterrupt REBOOT_VECTOR \
 969         reboot_interrupt smp_reboot_interrupt
 970 #endif
 971
 972 #ifdef CONFIG_X86_UV
 973 apicinterrupt UV_BAU_MESSAGE \
 974         uv_bau_message_intr1 uv_bau_message_interrupt
 975 #endif
 976 apicinterrupt LOCAL_TIMER_VECTOR \
 977         apic_timer_interrupt smp_apic_timer_interrupt
 978 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 979         x86_platform_ipi smp_x86_platform_ipi
 980
 981 #ifdef CONFIG_SMP
 982 .irp idx,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
 983         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
 984 .if NUM_INVALIDATE_TLB_VECTORS > \idx
 985 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
 986         invalidate_interrupt\idx smp_invalidate_interrupt
 987 .endif
 988 .endr
 989 #endif
 990
 991 apicinterrupt THRESHOLD_APIC_VECTOR \
 992         threshold_interrupt smp_threshold_interrupt
 993 apicinterrupt THERMAL_APIC_VECTOR \
 994         thermal_interrupt smp_thermal_interrupt
 995
 996 #ifdef CONFIG_X86_MCE
 997 apicinterrupt MCE_SELF_VECTOR \
 998         mce_self_interrupt smp_mce_self_interrupt
 999 #endif
1000
1001 #ifdef CONFIG_SMP
1002 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1003         call_function_single_interrupt smp_call_function_single_interrupt
1004 apicinterrupt CALL_FUNCTION_VECTOR \
1005         call_function_interrupt smp_call_function_interrupt
1006 apicinterrupt RESCHEDULE_VECTOR \
1007         reschedule_interrupt smp_reschedule_interrupt
1008 #endif
1009
1010 apicinterrupt ERROR_APIC_VECTOR \
1011         error_interrupt smp_error_interrupt
1012 apicinterrupt SPURIOUS_APIC_VECTOR \
1013         spurious_interrupt smp_spurious_interrupt
1014
1015 #ifdef CONFIG_IRQ_WORK
1016 apicinterrupt IRQ_WORK_VECTOR \
1017         irq_work_interrupt smp_irq_work_interrupt
1018 #endif
1019
1020 /*
1021  * Exception entry points.
1022  */
1023 .macro zeroentry sym do_sym
1024 ENTRY(\sym)
1025         INTR_FRAME
1026         PARAVIRT_ADJUST_EXCEPTION_FRAME
1027         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1028         subq $ORIG_RAX-R15, %rsp
1029         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1030         call error_entry
1031         DEFAULT_FRAME 0
1032         movq %rsp,%rdi          /* pt_regs pointer */
1033         xorl %esi,%esi          /* no error code */
1034         call \do_sym
1035         jmp error_exit          /* %ebx: no swapgs flag */
1036         CFI_ENDPROC
1037 END(\sym)
1038 .endm
1039
1040 .macro paranoidzeroentry sym do_sym
1041 ENTRY(\sym)
1042         INTR_FRAME
1043         PARAVIRT_ADJUST_EXCEPTION_FRAME
1044         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1045         subq $ORIG_RAX-R15, %rsp
1046         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1047         call save_paranoid
1048         TRACE_IRQS_OFF
1049         movq %rsp,%rdi          /* pt_regs pointer */
1050         xorl %esi,%esi          /* no error code */
1051         call \do_sym
1052         jmp paranoid_exit       /* %ebx: no swapgs flag */
1053         CFI_ENDPROC
1054 END(\sym)
1055 .endm
1056
1057 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1058 .macro paranoidzeroentry_ist sym do_sym ist
1059 ENTRY(\sym)
1060         INTR_FRAME
1061         PARAVIRT_ADJUST_EXCEPTION_FRAME
1062         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1063         subq $ORIG_RAX-R15, %rsp
1064         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1065         call save_paranoid
1066         TRACE_IRQS_OFF
1067         movq %rsp,%rdi          /* pt_regs pointer */
1068         xorl %esi,%esi          /* no error code */
1069         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1070         call \do_sym
1071         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1072         jmp paranoid_exit       /* %ebx: no swapgs flag */
1073         CFI_ENDPROC
1074 END(\sym)
1075 .endm
1076
1077 .macro errorentry sym do_sym
1078 ENTRY(\sym)
1079         XCPT_FRAME
1080         PARAVIRT_ADJUST_EXCEPTION_FRAME
1081         subq $ORIG_RAX-R15, %rsp
1082         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1083         call error_entry
1084         DEFAULT_FRAME 0
1085         movq %rsp,%rdi                  /* pt_regs pointer */
1086         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1087         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1088         call \do_sym
1089         jmp error_exit                  /* %ebx: no swapgs flag */
1090         CFI_ENDPROC
1091 END(\sym)
1092 .endm
1093
1094         /* error code is on the stack already */
1095 .macro paranoiderrorentry sym do_sym
1096 ENTRY(\sym)
1097         XCPT_FRAME
1098         PARAVIRT_ADJUST_EXCEPTION_FRAME
1099         subq $ORIG_RAX-R15, %rsp
1100         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1101         call save_paranoid
1102         DEFAULT_FRAME 0
1103         TRACE_IRQS_OFF
1104         movq %rsp,%rdi                  /* pt_regs pointer */
1105         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1106         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1107         call \do_sym
1108         jmp paranoid_exit               /* %ebx: no swapgs flag */
1109         CFI_ENDPROC
1110 END(\sym)
1111 .endm
1112
1113 zeroentry divide_error do_divide_error
1114 zeroentry overflow do_overflow
1115 zeroentry bounds do_bounds
1116 zeroentry invalid_op do_invalid_op
1117 zeroentry device_not_available do_device_not_available
1118 paranoiderrorentry double_fault do_double_fault
1119 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1120 errorentry invalid_TSS do_invalid_TSS
1121 errorentry segment_not_present do_segment_not_present
1122 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1123 zeroentry coprocessor_error do_coprocessor_error
1124 errorentry alignment_check do_alignment_check
1125 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1126 zeroentry emulate_vsyscall do_emulate_vsyscall
1127
1128
1129         /* Reload gs selector with exception handling */
1130         /* edi:  new selector */
1131 ENTRY(native_load_gs_index)
1132         CFI_STARTPROC
1133         pushfq_cfi
1134         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1135         SWAPGS
1136 gs_change:
1137         movl %edi,%gs
1138 2:      mfence          /* workaround */
1139         SWAPGS
1140         popfq_cfi
1141         ret
1142         CFI_ENDPROC
1143 END(native_load_gs_index)
1144
1145         .section __ex_table,"a"
1146         .align 8
1147         .quad gs_change,bad_gs
1148         .previous
1149         .section .fixup,"ax"
1150         /* running with kernelgs */
1151 bad_gs:
1152         SWAPGS                  /* switch back to user gs */
1153         xorl %eax,%eax
1154         movl %eax,%gs
1155         jmp  2b
1156         .previous
1157
1158 ENTRY(kernel_thread_helper)
1159         pushq $0                # fake return address
1160         CFI_STARTPROC
1161         /*
1162          * Here we are in the child and the registers are set as they were
1163          * at kernel_thread() invocation in the parent.
1164          */
1165         call *%rsi
1166         # exit
1167         mov %eax, %edi
1168         call do_exit
1169         ud2                     # padding for call trace
1170         CFI_ENDPROC
1171 END(kernel_thread_helper)
1172
1173 /*
1174  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1175  *
1176  * C extern interface:
1177  *       extern long execve(const char *name, char **argv, char **envp)
1178  *
1179  * asm input arguments:
1180  *      rdi: name, rsi: argv, rdx: envp
1181  *
1182  * We want to fallback into:
1183  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1184  *
1185  * do_sys_execve asm fallback arguments:
1186  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1187  */
1188 ENTRY(kernel_execve)
1189         CFI_STARTPROC
1190         FAKE_STACK_FRAME $0
1191         SAVE_ALL
1192         movq %rsp,%rcx
1193         call sys_execve
1194         movq %rax, RAX(%rsp)
1195         RESTORE_REST
1196         testq %rax,%rax
1197         je int_ret_from_sys_call
1198         RESTORE_ARGS
1199         UNFAKE_STACK_FRAME
1200         ret
1201         CFI_ENDPROC
1202 END(kernel_execve)
1203
1204 /* Call softirq on interrupt stack. Interrupts are off. */
1205 ENTRY(call_softirq)
1206         CFI_STARTPROC
1207         pushq_cfi %rbp
1208         CFI_REL_OFFSET rbp,0
1209         mov  %rsp,%rbp
1210         CFI_DEF_CFA_REGISTER rbp
1211         incl PER_CPU_VAR(irq_count)
1212         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1213         push  %rbp                      # backlink for old unwinder
1214         call __do_softirq
1215         leaveq
1216         CFI_RESTORE             rbp
1217         CFI_DEF_CFA_REGISTER    rsp
1218         CFI_ADJUST_CFA_OFFSET   -8
1219         decl PER_CPU_VAR(irq_count)
1220         ret
1221         CFI_ENDPROC
1222 END(call_softirq)
1223
1224 #ifdef CONFIG_XEN
1225 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1226
1227 /*
1228  * A note on the "critical region" in our callback handler.
1229  * We want to avoid stacking callback handlers due to events occurring
1230  * during handling of the last event. To do this, we keep events disabled
1231  * until we've done all processing. HOWEVER, we must enable events before
1232  * popping the stack frame (can't be done atomically) and so it would still
1233  * be possible to get enough handler activations to overflow the stack.
1234  * Although unlikely, bugs of that kind are hard to track down, so we'd
1235  * like to avoid the possibility.
1236  * So, on entry to the handler we detect whether we interrupted an
1237  * existing activation in its critical region -- if so, we pop the current
1238  * activation and restart the handler using the previous one.
1239  */
1240 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1241         CFI_STARTPROC
1242 /*
1243  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1244  * see the correct pointer to the pt_regs
1245  */
1246         movq %rdi, %rsp            # we don't return, adjust the stack frame
1247         CFI_ENDPROC
1248         DEFAULT_FRAME
1249 11:     incl PER_CPU_VAR(irq_count)
1250         movq %rsp,%rbp
1251         CFI_DEF_CFA_REGISTER rbp
1252         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1253         pushq %rbp                      # backlink for old unwinder
1254         call xen_evtchn_do_upcall
1255         popq %rsp
1256         CFI_DEF_CFA_REGISTER rsp
1257         decl PER_CPU_VAR(irq_count)
1258         jmp  error_exit
1259         CFI_ENDPROC
1260 END(xen_do_hypervisor_callback)
1261
1262 /*
1263  * Hypervisor uses this for application faults while it executes.
1264  * We get here for two reasons:
1265  *  1. Fault while reloading DS, ES, FS or GS
1266  *  2. Fault while executing IRET
1267  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1268  * registers that could be reloaded and zeroed the others.
1269  * Category 2 we fix up by killing the current process. We cannot use the
1270  * normal Linux return path in this case because if we use the IRET hypercall
1271  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1272  * We distinguish between categories by comparing each saved segment register
1273  * with its current contents: any discrepancy means we in category 1.
1274  */
1275 ENTRY(xen_failsafe_callback)
1276         INTR_FRAME 1 (6*8)
1277         /*CFI_REL_OFFSET gs,GS*/
1278         /*CFI_REL_OFFSET fs,FS*/
1279         /*CFI_REL_OFFSET es,ES*/
1280         /*CFI_REL_OFFSET ds,DS*/
1281         CFI_REL_OFFSET r11,8
1282         CFI_REL_OFFSET rcx,0
1283         movw %ds,%cx
1284         cmpw %cx,0x10(%rsp)
1285         CFI_REMEMBER_STATE
1286         jne 1f
1287         movw %es,%cx
1288         cmpw %cx,0x18(%rsp)
1289         jne 1f
1290         movw %fs,%cx
1291         cmpw %cx,0x20(%rsp)
1292         jne 1f
1293         movw %gs,%cx
1294         cmpw %cx,0x28(%rsp)
1295         jne 1f
1296         /* All segments match their saved values => Category 2 (Bad IRET). */
1297         movq (%rsp),%rcx
1298         CFI_RESTORE rcx
1299         movq 8(%rsp),%r11
1300         CFI_RESTORE r11
1301         addq $0x30,%rsp
1302         CFI_ADJUST_CFA_OFFSET -0x30
1303         pushq_cfi $0    /* RIP */
1304         pushq_cfi %r11
1305         pushq_cfi %rcx
1306         jmp general_protection
1307         CFI_RESTORE_STATE
1308 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1309         movq (%rsp),%rcx
1310         CFI_RESTORE rcx
1311         movq 8(%rsp),%r11
1312         CFI_RESTORE r11
1313         addq $0x30,%rsp
1314         CFI_ADJUST_CFA_OFFSET -0x30
1315         pushq_cfi $0
1316         SAVE_ALL
1317         jmp error_exit
1318         CFI_ENDPROC
1319 END(xen_failsafe_callback)
1320
1321 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1322         xen_hvm_callback_vector xen_evtchn_do_upcall
1323
1324 #endif /* CONFIG_XEN */
1325
1326 /*
1327  * Some functions should be protected against kprobes
1328  */
1329         .pushsection .kprobes.text, "ax"
1330
1331 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1332 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1333 paranoiderrorentry stack_segment do_stack_segment
1334 #ifdef CONFIG_XEN
1335 zeroentry xen_debug do_debug
1336 zeroentry xen_int3 do_int3
1337 errorentry xen_stack_segment do_stack_segment
1338 #endif
1339 errorentry general_protection do_general_protection
1340 errorentry page_fault do_page_fault
1341 #ifdef CONFIG_KVM_GUEST
1342 errorentry async_page_fault do_async_page_fault
1343 #endif
1344 #ifdef CONFIG_X86_MCE
1345 paranoidzeroentry machine_check *machine_check_vector(%rip)
1346 #endif
1347
1348         /*
1349          * "Paranoid" exit path from exception stack.
1350          * Paranoid because this is used by NMIs and cannot take
1351          * any kernel state for granted.
1352          * We don't do kernel preemption checks here, because only
1353          * NMI should be common and it does not enable IRQs and
1354          * cannot get reschedule ticks.
1355          *
1356          * "trace" is 0 for the NMI handler only, because irq-tracing
1357          * is fundamentally NMI-unsafe. (we cannot change the soft and
1358          * hard flags at once, atomically)
1359          */
1360
1361         /* ebx: no swapgs flag */
1362 ENTRY(paranoid_exit)
1363         DEFAULT_FRAME
1364         DISABLE_INTERRUPTS(CLBR_NONE)
1365         TRACE_IRQS_OFF
1366         testl %ebx,%ebx                         /* swapgs needed? */
1367         jnz paranoid_restore
1368         testl $3,CS(%rsp)
1369         jnz   paranoid_userspace
1370 paranoid_swapgs:
1371         TRACE_IRQS_IRETQ 0
1372         SWAPGS_UNSAFE_STACK
1373         RESTORE_ALL 8
1374         jmp irq_return
1375 paranoid_restore:
1376         TRACE_IRQS_IRETQ 0
1377         RESTORE_ALL 8
1378         jmp irq_return
1379 paranoid_userspace:
1380         GET_THREAD_INFO(%rcx)
1381         movl TI_flags(%rcx),%ebx
1382         andl $_TIF_WORK_MASK,%ebx
1383         jz paranoid_swapgs
1384         movq %rsp,%rdi                  /* &pt_regs */
1385         call sync_regs
1386         movq %rax,%rsp                  /* switch stack for scheduling */
1387         testl $_TIF_NEED_RESCHED,%ebx
1388         jnz paranoid_schedule
1389         movl %ebx,%edx                  /* arg3: thread flags */
1390         TRACE_IRQS_ON
1391         ENABLE_INTERRUPTS(CLBR_NONE)
1392         xorl %esi,%esi                  /* arg2: oldset */
1393         movq %rsp,%rdi                  /* arg1: &pt_regs */
1394         call do_notify_resume
1395         DISABLE_INTERRUPTS(CLBR_NONE)
1396         TRACE_IRQS_OFF
1397         jmp paranoid_userspace
1398 paranoid_schedule:
1399         TRACE_IRQS_ON
1400         ENABLE_INTERRUPTS(CLBR_ANY)
1401         call schedule
1402         DISABLE_INTERRUPTS(CLBR_ANY)
1403         TRACE_IRQS_OFF
1404         jmp paranoid_userspace
1405         CFI_ENDPROC
1406 END(paranoid_exit)
1407
1408 /*
1409  * Exception entry point. This expects an error code/orig_rax on the stack.
1410  * returns in "no swapgs flag" in %ebx.
1411  */
1412 ENTRY(error_entry)
1413         XCPT_FRAME
1414         CFI_ADJUST_CFA_OFFSET 15*8
1415         /* oldrax contains error code */
1416         cld
1417         movq_cfi rdi, RDI+8
1418         movq_cfi rsi, RSI+8
1419         movq_cfi rdx, RDX+8
1420         movq_cfi rcx, RCX+8
1421         movq_cfi rax, RAX+8
1422         movq_cfi  r8,  R8+8
1423         movq_cfi  r9,  R9+8
1424         movq_cfi r10, R10+8
1425         movq_cfi r11, R11+8
1426         movq_cfi rbx, RBX+8
1427         movq_cfi rbp, RBP+8
1428         movq_cfi r12, R12+8
1429         movq_cfi r13, R13+8
1430         movq_cfi r14, R14+8
1431         movq_cfi r15, R15+8
1432         xorl %ebx,%ebx
1433         testl $3,CS+8(%rsp)
1434         je error_kernelspace
1435 error_swapgs:
1436         SWAPGS
1437 error_sti:
1438         TRACE_IRQS_OFF
1439         ret
1440
1441 /*
1442  * There are two places in the kernel that can potentially fault with
1443  * usergs. Handle them here. The exception handlers after iret run with
1444  * kernel gs again, so don't set the user space flag. B stepping K8s
1445  * sometimes report an truncated RIP for IRET exceptions returning to
1446  * compat mode. Check for these here too.
1447  */
1448 error_kernelspace:
1449         incl %ebx
1450         leaq irq_return(%rip),%rcx
1451         cmpq %rcx,RIP+8(%rsp)
1452         je error_swapgs
1453         movl %ecx,%eax  /* zero extend */
1454         cmpq %rax,RIP+8(%rsp)
1455         je bstep_iret
1456         cmpq $gs_change,RIP+8(%rsp)
1457         je error_swapgs
1458         jmp error_sti
1459
1460 bstep_iret:
1461         /* Fix truncated RIP */
1462         movq %rcx,RIP+8(%rsp)
1463         jmp error_swapgs
1464         CFI_ENDPROC
1465 END(error_entry)
1466
1467
1468 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1469 ENTRY(error_exit)
1470         DEFAULT_FRAME
1471         movl %ebx,%eax
1472         RESTORE_REST
1473         DISABLE_INTERRUPTS(CLBR_NONE)
1474         TRACE_IRQS_OFF
1475         GET_THREAD_INFO(%rcx)
1476         testl %eax,%eax
1477         jne retint_kernel
1478         LOCKDEP_SYS_EXIT_IRQ
1479         movl TI_flags(%rcx),%edx
1480         movl $_TIF_WORK_MASK,%edi
1481         andl %edi,%edx
1482         jnz retint_careful
1483         jmp retint_swapgs
1484         CFI_ENDPROC
1485 END(error_exit)
1486
1487
1488         /* runs on exception stack */
1489 ENTRY(nmi)
1490         INTR_FRAME
1491         PARAVIRT_ADJUST_EXCEPTION_FRAME
1492         pushq_cfi $-1
1493         subq $ORIG_RAX-R15, %rsp
1494         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1495         call save_paranoid
1496         DEFAULT_FRAME 0
1497         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1498         movq %rsp,%rdi
1499         movq $-1,%rsi
1500         call do_nmi
1501 #ifdef CONFIG_TRACE_IRQFLAGS
1502         /* paranoidexit; without TRACE_IRQS_OFF */
1503         /* ebx: no swapgs flag */
1504         DISABLE_INTERRUPTS(CLBR_NONE)
1505         testl %ebx,%ebx                         /* swapgs needed? */
1506         jnz nmi_restore
1507         testl $3,CS(%rsp)
1508         jnz nmi_userspace
1509 nmi_swapgs:
1510         SWAPGS_UNSAFE_STACK
1511 nmi_restore:
1512         RESTORE_ALL 8
1513         jmp irq_return
1514 nmi_userspace:
1515         GET_THREAD_INFO(%rcx)
1516         movl TI_flags(%rcx),%ebx
1517         andl $_TIF_WORK_MASK,%ebx
1518         jz nmi_swapgs
1519         movq %rsp,%rdi                  /* &pt_regs */
1520         call sync_regs
1521         movq %rax,%rsp                  /* switch stack for scheduling */
1522         testl $_TIF_NEED_RESCHED,%ebx
1523         jnz nmi_schedule
1524         movl %ebx,%edx                  /* arg3: thread flags */
1525         ENABLE_INTERRUPTS(CLBR_NONE)
1526         xorl %esi,%esi                  /* arg2: oldset */
1527         movq %rsp,%rdi                  /* arg1: &pt_regs */
1528         call do_notify_resume
1529         DISABLE_INTERRUPTS(CLBR_NONE)
1530         jmp nmi_userspace
1531 nmi_schedule:
1532         ENABLE_INTERRUPTS(CLBR_ANY)
1533         call schedule
1534         DISABLE_INTERRUPTS(CLBR_ANY)
1535         jmp nmi_userspace
1536         CFI_ENDPROC
1537 #else
1538         jmp paranoid_exit
1539         CFI_ENDPROC
1540 #endif
1541 END(nmi)
1542
1543 ENTRY(ignore_sysret)
1544         CFI_STARTPROC
1545         mov $-ENOSYS,%eax
1546         sysret
1547         CFI_ENDPROC
1548 END(ignore_sysret)
1549
1550 /*
1551  * End of kprobes section
1552  */
1553         .popsection