arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/pgtable_types.h>
  59
  60 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  61 #include <linux/elf-em.h>
  62 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  63 #define __AUDIT_ARCH_64BIT 0x80000000
  64 #define __AUDIT_ARCH_LE    0x40000000
  65
  66         .code64
  67         .section .entry.text, "ax"
  68
  69 #ifdef CONFIG_FUNCTION_TRACER
  70 #ifdef CONFIG_DYNAMIC_FTRACE
  71 ENTRY(mcount)
  72         retq
  73 END(mcount)
  74
  75 ENTRY(ftrace_caller)
  76         cmpl $0, function_trace_stop
  77         jne  ftrace_stub
  78
  79         MCOUNT_SAVE_FRAME
  80
  81         movq 0x38(%rsp), %rdi
  82         movq 8(%rbp), %rsi
  83         subq $MCOUNT_INSN_SIZE, %rdi
  84
  85 GLOBAL(ftrace_call)
  86         call ftrace_stub
  87
  88         MCOUNT_RESTORE_FRAME
  89
  90 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  91 GLOBAL(ftrace_graph_call)
  92         jmp ftrace_stub
  93 #endif
  94
  95 GLOBAL(ftrace_stub)
  96         retq
  97 END(ftrace_caller)
  98
  99 #else /* ! CONFIG_DYNAMIC_FTRACE */
 100 ENTRY(mcount)
 101         cmpl $0, function_trace_stop
 102         jne  ftrace_stub
 103
 104         cmpq $ftrace_stub, ftrace_trace_function
 105         jnz trace
 106
 107 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 108         cmpq $ftrace_stub, ftrace_graph_return
 109         jnz ftrace_graph_caller
 110
 111         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 112         jnz ftrace_graph_caller
 113 #endif
 114
 115 GLOBAL(ftrace_stub)
 116         retq
 117
 118 trace:
 119         MCOUNT_SAVE_FRAME
 120
 121         movq 0x38(%rsp), %rdi
 122         movq 8(%rbp), %rsi
 123         subq $MCOUNT_INSN_SIZE, %rdi
 124
 125         call   *ftrace_trace_function
 126
 127         MCOUNT_RESTORE_FRAME
 128
 129         jmp ftrace_stub
 130 END(mcount)
 131 #endif /* CONFIG_DYNAMIC_FTRACE */
 132 #endif /* CONFIG_FUNCTION_TRACER */
 133
 134 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 135 ENTRY(ftrace_graph_caller)
 136         cmpl $0, function_trace_stop
 137         jne ftrace_stub
 138
 139         MCOUNT_SAVE_FRAME
 140
 141         leaq 8(%rbp), %rdi
 142         movq 0x38(%rsp), %rsi
 143         movq (%rbp), %rdx
 144         subq $MCOUNT_INSN_SIZE, %rsi
 145
 146         call    prepare_ftrace_return
 147
 148         MCOUNT_RESTORE_FRAME
 149
 150         retq
 151 END(ftrace_graph_caller)
 152
 153 GLOBAL(return_to_handler)
 154         subq  $24, %rsp
 155
 156         /* Save the return values */
 157         movq %rax, (%rsp)
 158         movq %rdx, 8(%rsp)
 159         movq %rbp, %rdi
 160
 161         call ftrace_return_to_handler
 162
 163         movq %rax, %rdi
 164         movq 8(%rsp), %rdx
 165         movq (%rsp), %rax
 166         addq $24, %rsp
 167         jmp *%rdi
 168 #endif
 169
 170
 171 #ifndef CONFIG_PREEMPT
 172 #define retint_kernel retint_restore_args
 173 #endif
 174
 175 #ifdef CONFIG_PARAVIRT
 176 ENTRY(native_usergs_sysret64)
 177         swapgs
 178         sysretq
 179 ENDPROC(native_usergs_sysret64)
 180 #endif /* CONFIG_PARAVIRT */
 181
 182
 183 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 184 #ifdef CONFIG_TRACE_IRQFLAGS
 185         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 186         jnc  1f
 187         TRACE_IRQS_ON
 188 1:
 189 #endif
 190 .endm
 191
 192 /*
 193  * C code is not supposed to know about undefined top of stack. Every time
 194  * a C function with an pt_regs argument is called from the SYSCALL based
 195  * fast path FIXUP_TOP_OF_STACK is needed.
 196  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 197  * manipulation.
 198  */
 199
 200         /* %rsp:at FRAMEEND */
 201         .macro FIXUP_TOP_OF_STACK tmp offset=0
 202         movq PER_CPU_VAR(old_rsp),\tmp
 203         movq \tmp,RSP+\offset(%rsp)
 204         movq $__USER_DS,SS+\offset(%rsp)
 205         movq $__USER_CS,CS+\offset(%rsp)
 206         movq $-1,RCX+\offset(%rsp)
 207         movq R11+\offset(%rsp),\tmp  /* get eflags */
 208         movq \tmp,EFLAGS+\offset(%rsp)
 209         .endm
 210
 211         .macro RESTORE_TOP_OF_STACK tmp offset=0
 212         movq RSP+\offset(%rsp),\tmp
 213         movq \tmp,PER_CPU_VAR(old_rsp)
 214         movq EFLAGS+\offset(%rsp),\tmp
 215         movq \tmp,R11+\offset(%rsp)
 216         .endm
 217
 218         .macro FAKE_STACK_FRAME child_rip
 219         /* push in order ss, rsp, eflags, cs, rip */
 220         xorl %eax, %eax
 221         pushq_cfi $__KERNEL_DS /* ss */
 222         /*CFI_REL_OFFSET        ss,0*/
 223         pushq_cfi %rax /* rsp */
 224         CFI_REL_OFFSET  rsp,0
 225         pushq_cfi $X86_EFLAGS_IF /* eflags - interrupts on */
 226         /*CFI_REL_OFFSET        rflags,0*/
 227         pushq_cfi $__KERNEL_CS /* cs */
 228         /*CFI_REL_OFFSET        cs,0*/
 229         pushq_cfi \child_rip /* rip */
 230         CFI_REL_OFFSET  rip,0
 231         pushq_cfi %rax /* orig rax */
 232         .endm
 233
 234         .macro UNFAKE_STACK_FRAME
 235         addq $8*6, %rsp
 236         CFI_ADJUST_CFA_OFFSET   -(6*8)
 237         .endm
 238
 239 /*
 240  * initial frame state for interrupts (and exceptions without error code)
 241  */
 242         .macro EMPTY_FRAME start=1 offset=0
 243         .if \start
 244         CFI_STARTPROC simple
 245         CFI_SIGNAL_FRAME
 246         CFI_DEF_CFA rsp,8+\offset
 247         .else
 248         CFI_DEF_CFA_OFFSET 8+\offset
 249         .endif
 250         .endm
 251
 252 /*
 253  * initial frame state for interrupts (and exceptions without error code)
 254  */
 255         .macro INTR_FRAME start=1 offset=0
 256         EMPTY_FRAME \start, SS+8+\offset-RIP
 257         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 258         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 259         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 260         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 261         CFI_REL_OFFSET rip, RIP+\offset-RIP
 262         .endm
 263
 264 /*
 265  * initial frame state for exceptions with error code (and interrupts
 266  * with vector already pushed)
 267  */
 268         .macro XCPT_FRAME start=1 offset=0
 269         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 270         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 271         .endm
 272
 273 /*
 274  * frame that enables calling into C.
 275  */
 276         .macro PARTIAL_FRAME start=1 offset=0
 277         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 278         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 279         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 283         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 286         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 287         .endm
 288
 289 /*
 290  * frame that enables passing a complete pt_regs to a C function.
 291  */
 292         .macro DEFAULT_FRAME start=1 offset=0
 293         PARTIAL_FRAME \start, R11+\offset-R15
 294         CFI_REL_OFFSET rbx, RBX+\offset
 295         CFI_REL_OFFSET rbp, RBP+\offset
 296         CFI_REL_OFFSET r12, R12+\offset
 297         CFI_REL_OFFSET r13, R13+\offset
 298         CFI_REL_OFFSET r14, R14+\offset
 299         CFI_REL_OFFSET r15, R15+\offset
 300         .endm
 301
 302 /* save partial stack frame */
 303         .macro SAVE_ARGS_IRQ
 304         cld
 305         /* start from rbp in pt_regs and jump over */
 306         movq_cfi rdi, RDI-RBP
 307         movq_cfi rsi, RSI-RBP
 308         movq_cfi rdx, RDX-RBP
 309         movq_cfi rcx, RCX-RBP
 310         movq_cfi rax, RAX-RBP
 311         movq_cfi  r8,  R8-RBP
 312         movq_cfi  r9,  R9-RBP
 313         movq_cfi r10, R10-RBP
 314         movq_cfi r11, R11-RBP
 315
 316         /* Save rbp so that we can unwind from get_irq_regs() */
 317         movq_cfi rbp, 0
 318
 319         /* Save previous stack value */
 320         movq %rsp, %rsi
 321
 322         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 323         testl $3, CS(%rdi)
 324         je 1f
 325         SWAPGS
 326         /*
 327          * irq_count is used to check if a CPU is already on an interrupt stack
 328          * or not. While this is essentially redundant with preempt_count it is
 329          * a little cheaper to use a separate counter in the PDA (short of
 330          * moving irq_enter into assembly, which would be too much work)
 331          */
 332 1:      incl PER_CPU_VAR(irq_count)
 333         jne 2f
 334         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 335         CFI_DEF_CFA_REGISTER    rsi
 336
 337 2:      /* Store previous stack value */
 338         pushq %rsi
 339         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 340                         0x77 /* DW_OP_breg7 */, 0, \
 341                         0x06 /* DW_OP_deref */, \
 342                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 343                         0x22 /* DW_OP_plus */
 344         /* We entered an interrupt context - irqs are off: */
 345         TRACE_IRQS_OFF
 346         .endm
 347
 348 ENTRY(save_rest)
 349         PARTIAL_FRAME 1 REST_SKIP+8
 350         movq 5*8+16(%rsp), %r11 /* save return address */
 351         movq_cfi rbx, RBX+16
 352         movq_cfi rbp, RBP+16
 353         movq_cfi r12, R12+16
 354         movq_cfi r13, R13+16
 355         movq_cfi r14, R14+16
 356         movq_cfi r15, R15+16
 357         movq %r11, 8(%rsp)      /* return address */
 358         FIXUP_TOP_OF_STACK %r11, 16
 359         ret
 360         CFI_ENDPROC
 361 END(save_rest)
 362
 363 /* save complete stack frame */
 364         .pushsection .kprobes.text, "ax"
 365 ENTRY(save_paranoid)
 366         XCPT_FRAME 1 RDI+8
 367         cld
 368         movq_cfi rdi, RDI+8
 369         movq_cfi rsi, RSI+8
 370         movq_cfi rdx, RDX+8
 371         movq_cfi rcx, RCX+8
 372         movq_cfi rax, RAX+8
 373         movq_cfi r8, R8+8
 374         movq_cfi r9, R9+8
 375         movq_cfi r10, R10+8
 376         movq_cfi r11, R11+8
 377         movq_cfi rbx, RBX+8
 378         movq_cfi rbp, RBP+8
 379         movq_cfi r12, R12+8
 380         movq_cfi r13, R13+8
 381         movq_cfi r14, R14+8
 382         movq_cfi r15, R15+8
 383         movl $1,%ebx
 384         movl $MSR_GS_BASE,%ecx
 385         rdmsr
 386         testl %edx,%edx
 387         js 1f   /* negative -> in kernel */
 388         SWAPGS
 389         xorl %ebx,%ebx
 390 1:      ret
 391         CFI_ENDPROC
 392 END(save_paranoid)
 393         .popsection
 394
 395 /*
 396  * A newly forked process directly context switches into this address.
 397  *
 398  * rdi: prev task we switched from
 399  */
 400 ENTRY(ret_from_fork)
 401         DEFAULT_FRAME
 402
 403         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 404
 405         pushq_cfi kernel_eflags(%rip)
 406         popfq_cfi                               # reset kernel eflags
 407
 408         call schedule_tail                      # rdi: 'prev' task parameter
 409
 410         GET_THREAD_INFO(%rcx)
 411
 412         RESTORE_REST
 413
 414         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 415         je   int_ret_from_sys_call
 416
 417         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 418         jnz  int_ret_from_sys_call
 419
 420         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 421         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 422
 423         CFI_ENDPROC
 424 END(ret_from_fork)
 425
 426 /*
 427  * System call entry. Up to 6 arguments in registers are supported.
 428  *
 429  * SYSCALL does not save anything on the stack and does not change the
 430  * stack pointer.
 431  */
 432
 433 /*
 434  * Register setup:
 435  * rax  system call number
 436  * rdi  arg0
 437  * rcx  return address for syscall/sysret, C arg3
 438  * rsi  arg1
 439  * rdx  arg2
 440  * r10  arg3    (--> moved to rcx for C)
 441  * r8   arg4
 442  * r9   arg5
 443  * r11  eflags for syscall/sysret, temporary for C
 444  * r12-r15,rbp,rbx saved by C code, not touched.
 445  *
 446  * Interrupts are off on entry.
 447  * Only called from user space.
 448  *
 449  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 450  *      and report it properly in ps. Unfortunately we haven't.
 451  *
 452  * When user can change the frames always force IRET. That is because
 453  * it deals with uncanonical addresses better. SYSRET has trouble
 454  * with them due to bugs in both AMD and Intel CPUs.
 455  */
 456
 457 ENTRY(system_call)
 458         CFI_STARTPROC   simple
 459         CFI_SIGNAL_FRAME
 460         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 461         CFI_REGISTER    rip,rcx
 462         /*CFI_REGISTER  rflags,r11*/
 463         SWAPGS_UNSAFE_STACK
 464         /*
 465          * A hypervisor implementation might want to use a label
 466          * after the swapgs, so that it can do the swapgs
 467          * for the guest and jump here on syscall.
 468          */
 469 ENTRY(system_call_after_swapgs)
 470
 471         movq    %rsp,PER_CPU_VAR(old_rsp)
 472         movq    PER_CPU_VAR(kernel_stack),%rsp
 473         /*
 474          * No need to follow this irqs off/on section - it's straight
 475          * and short:
 476          */
 477         ENABLE_INTERRUPTS(CLBR_NONE)
 478         SAVE_ARGS 8,0
 479         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 480         movq  %rcx,RIP-ARGOFFSET(%rsp)
 481         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 482         GET_THREAD_INFO(%rcx)
 483         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags(%rcx)
 484         jnz tracesys
 485 system_call_fastpath:
 486         cmpq $__NR_syscall_max,%rax
 487         ja badsys
 488         movq %r10,%rcx
 489         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 490         movq %rax,RAX-ARGOFFSET(%rsp)
 491 /*
 492  * Syscall return path ending with SYSRET (fast path)
 493  * Has incomplete stack frame and undefined top of stack.
 494  */
 495 ret_from_sys_call:
 496         movl $_TIF_ALLWORK_MASK,%edi
 497         /* edi: flagmask */
 498 sysret_check:
 499         LOCKDEP_SYS_EXIT
 500         GET_THREAD_INFO(%rcx)
 501         DISABLE_INTERRUPTS(CLBR_NONE)
 502         TRACE_IRQS_OFF
 503         movl TI_flags(%rcx),%edx
 504         andl %edi,%edx
 505         jnz  sysret_careful
 506         CFI_REMEMBER_STATE
 507         /*
 508          * sysretq will re-enable interrupts:
 509          */
 510         TRACE_IRQS_ON
 511         movq RIP-ARGOFFSET(%rsp),%rcx
 512         CFI_REGISTER    rip,rcx
 513         RESTORE_ARGS 1,-ARG_SKIP,0
 514         /*CFI_REGISTER  rflags,r11*/
 515         movq    PER_CPU_VAR(old_rsp), %rsp
 516         USERGS_SYSRET64
 517
 518         CFI_RESTORE_STATE
 519         /* Handle reschedules */
 520         /* edx: work, edi: workmask */
 521 sysret_careful:
 522         bt $TIF_NEED_RESCHED,%edx
 523         jnc sysret_signal
 524         TRACE_IRQS_ON
 525         ENABLE_INTERRUPTS(CLBR_NONE)
 526         pushq_cfi %rdi
 527         call schedule
 528         popq_cfi %rdi
 529         jmp sysret_check
 530
 531         /* Handle a signal */
 532 sysret_signal:
 533         TRACE_IRQS_ON
 534         ENABLE_INTERRUPTS(CLBR_NONE)
 535 #ifdef CONFIG_AUDITSYSCALL
 536         bt $TIF_SYSCALL_AUDIT,%edx
 537         jc sysret_audit
 538 #endif
 539         /*
 540          * We have a signal, or exit tracing or single-step.
 541          * These all wind up with the iret return path anyway,
 542          * so just join that path right now.
 543          */
 544         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 545         jmp int_check_syscall_exit_work
 546
 547 badsys:
 548         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 549         jmp ret_from_sys_call
 550
 551 #ifdef CONFIG_AUDITSYSCALL
 552         /*
 553          * Fast path for syscall audit without full syscall trace.
 554          * We just call audit_syscall_entry() directly, and then
 555          * jump back to the normal fast path.
 556          */
 557 auditsys:
 558         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 559         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 560         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 561         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 562         movq %rax,%rsi                  /* 2nd arg: syscall number */
 563         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 564         call audit_syscall_entry
 565         LOAD_ARGS 0             /* reload call-clobbered registers */
 566         jmp system_call_fastpath
 567
 568         /*
 569          * Return fast path for syscall audit.  Call audit_syscall_exit()
 570          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 571          * masked off.
 572          */
 573 sysret_audit:
 574         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 575         cmpq $0,%rsi            /* is it < 0? */
 576         setl %al                /* 1 if so, 0 if not */
 577         movzbl %al,%edi         /* zero-extend that into %edi */
 578         inc %edi /* first arg, 0->1(AUDITSC_SUCCESS), 1->2(AUDITSC_FAILURE) */
 579         call audit_syscall_exit
 580         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 581         jmp sysret_check
 582 #endif  /* CONFIG_AUDITSYSCALL */
 583
 584         /* Do syscall tracing */
 585 tracesys:
 586 #ifdef CONFIG_AUDITSYSCALL
 587         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags(%rcx)
 588         jz auditsys
 589 #endif
 590         SAVE_REST
 591         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 592         FIXUP_TOP_OF_STACK %rdi
 593         movq %rsp,%rdi
 594         call syscall_trace_enter
 595         /*
 596          * Reload arg registers from stack in case ptrace changed them.
 597          * We don't reload %rax because syscall_trace_enter() returned
 598          * the value it wants us to use in the table lookup.
 599          */
 600         LOAD_ARGS ARGOFFSET, 1
 601         RESTORE_REST
 602         cmpq $__NR_syscall_max,%rax
 603         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 604         movq %r10,%rcx  /* fixup for C */
 605         call *sys_call_table(,%rax,8)
 606         movq %rax,RAX-ARGOFFSET(%rsp)
 607         /* Use IRET because user could have changed frame */
 608
 609 /*
 610  * Syscall return path ending with IRET.
 611  * Has correct top of stack, but partial stack frame.
 612  */
 613 GLOBAL(int_ret_from_sys_call)
 614         DISABLE_INTERRUPTS(CLBR_NONE)
 615         TRACE_IRQS_OFF
 616         testl $3,CS-ARGOFFSET(%rsp)
 617         je retint_restore_args
 618         movl $_TIF_ALLWORK_MASK,%edi
 619         /* edi: mask to check */
 620 GLOBAL(int_with_check)
 621         LOCKDEP_SYS_EXIT_IRQ
 622         GET_THREAD_INFO(%rcx)
 623         movl TI_flags(%rcx),%edx
 624         andl %edi,%edx
 625         jnz   int_careful
 626         andl    $~TS_COMPAT,TI_status(%rcx)
 627         jmp   retint_swapgs
 628
 629         /* Either reschedule or signal or syscall exit tracking needed. */
 630         /* First do a reschedule test. */
 631         /* edx: work, edi: workmask */
 632 int_careful:
 633         bt $TIF_NEED_RESCHED,%edx
 634         jnc  int_very_careful
 635         TRACE_IRQS_ON
 636         ENABLE_INTERRUPTS(CLBR_NONE)
 637         pushq_cfi %rdi
 638         call schedule
 639         popq_cfi %rdi
 640         DISABLE_INTERRUPTS(CLBR_NONE)
 641         TRACE_IRQS_OFF
 642         jmp int_with_check
 643
 644         /* handle signals and tracing -- both require a full stack frame */
 645 int_very_careful:
 646         TRACE_IRQS_ON
 647         ENABLE_INTERRUPTS(CLBR_NONE)
 648 int_check_syscall_exit_work:
 649         SAVE_REST
 650         /* Check for syscall exit trace */
 651         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 652         jz int_signal
 653         pushq_cfi %rdi
 654         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 655         call syscall_trace_leave
 656         popq_cfi %rdi
 657         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 658         jmp int_restore_rest
 659
 660 int_signal:
 661         testl $_TIF_DO_NOTIFY_MASK,%edx
 662         jz 1f
 663         movq %rsp,%rdi          # &ptregs -> arg1
 664         xorl %esi,%esi          # oldset -> arg2
 665         call do_notify_resume
 666 1:      movl $_TIF_WORK_MASK,%edi
 667 int_restore_rest:
 668         RESTORE_REST
 669         DISABLE_INTERRUPTS(CLBR_NONE)
 670         TRACE_IRQS_OFF
 671         jmp int_with_check
 672         CFI_ENDPROC
 673 END(system_call)
 674
 675 /*
 676  * Certain special system calls that need to save a complete full stack frame.
 677  */
 678         .macro PTREGSCALL label,func,arg
 679 ENTRY(\label)
 680         PARTIAL_FRAME 1 8               /* offset 8: return address */
 681         subq $REST_SKIP, %rsp
 682         CFI_ADJUST_CFA_OFFSET REST_SKIP
 683         call save_rest
 684         DEFAULT_FRAME 0 8               /* offset 8: return address */
 685         leaq 8(%rsp), \arg      /* pt_regs pointer */
 686         call \func
 687         jmp ptregscall_common
 688         CFI_ENDPROC
 689 END(\label)
 690         .endm
 691
 692         PTREGSCALL stub_clone, sys_clone, %r8
 693         PTREGSCALL stub_fork, sys_fork, %rdi
 694         PTREGSCALL stub_vfork, sys_vfork, %rdi
 695         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 696         PTREGSCALL stub_iopl, sys_iopl, %rsi
 697
 698 ENTRY(ptregscall_common)
 699         DEFAULT_FRAME 1 8       /* offset 8: return address */
 700         RESTORE_TOP_OF_STACK %r11, 8
 701         movq_cfi_restore R15+8, r15
 702         movq_cfi_restore R14+8, r14
 703         movq_cfi_restore R13+8, r13
 704         movq_cfi_restore R12+8, r12
 705         movq_cfi_restore RBP+8, rbp
 706         movq_cfi_restore RBX+8, rbx
 707         ret $REST_SKIP          /* pop extended registers */
 708         CFI_ENDPROC
 709 END(ptregscall_common)
 710
 711 ENTRY(stub_execve)
 712         CFI_STARTPROC
 713         addq $8, %rsp
 714         PARTIAL_FRAME 0
 715         SAVE_REST
 716         FIXUP_TOP_OF_STACK %r11
 717         movq %rsp, %rcx
 718         call sys_execve
 719         RESTORE_TOP_OF_STACK %r11
 720         movq %rax,RAX(%rsp)
 721         RESTORE_REST
 722         jmp int_ret_from_sys_call
 723         CFI_ENDPROC
 724 END(stub_execve)
 725
 726 /*
 727  * sigreturn is special because it needs to restore all registers on return.
 728  * This cannot be done with SYSRET, so use the IRET return path instead.
 729  */
 730 ENTRY(stub_rt_sigreturn)
 731         CFI_STARTPROC
 732         addq $8, %rsp
 733         PARTIAL_FRAME 0
 734         SAVE_REST
 735         movq %rsp,%rdi
 736         FIXUP_TOP_OF_STACK %r11
 737         call sys_rt_sigreturn
 738         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 739         RESTORE_REST
 740         jmp int_ret_from_sys_call
 741         CFI_ENDPROC
 742 END(stub_rt_sigreturn)
 743
 744 /*
 745  * Build the entry stubs and pointer table with some assembler magic.
 746  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 747  * single cache line on all modern x86 implementations.
 748  */
 749         .section .init.rodata,"a"
 750 ENTRY(interrupt)
 751         .section .entry.text
 752         .p2align 5
 753         .p2align CONFIG_X86_L1_CACHE_SHIFT
 754 ENTRY(irq_entries_start)
 755         INTR_FRAME
 756 vector=FIRST_EXTERNAL_VECTOR
 757 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 758         .balign 32
 759   .rept 7
 760     .if vector < NR_VECTORS
 761       .if vector <> FIRST_EXTERNAL_VECTOR
 762         CFI_ADJUST_CFA_OFFSET -8
 763       .endif
 764 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 765       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 766         jmp 2f
 767       .endif
 768       .previous
 769         .quad 1b
 770       .section .entry.text
 771 vector=vector+1
 772     .endif
 773   .endr
 774 2:      jmp common_interrupt
 775 .endr
 776         CFI_ENDPROC
 777 END(irq_entries_start)
 778
 779 .previous
 780 END(interrupt)
 781 .previous
 782
 783 /*
 784  * Interrupt entry/exit.
 785  *
 786  * Interrupt entry points save only callee clobbered registers in fast path.
 787  *
 788  * Entry runs with interrupts off.
 789  */
 790
 791 /* 0(%rsp): ~(interrupt number) */
 792         .macro interrupt func
 793         /* reserve pt_regs for scratch regs and rbp */
 794         subq $ORIG_RAX-RBP, %rsp
 795         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 796         SAVE_ARGS_IRQ
 797         call \func
 798         .endm
 799
 800 /*
 801  * Interrupt entry/exit should be protected against kprobes
 802  */
 803         .pushsection .kprobes.text, "ax"
 804         /*
 805          * The interrupt stubs push (~vector+0x80) onto the stack and
 806          * then jump to common_interrupt.
 807          */
 808         .p2align CONFIG_X86_L1_CACHE_SHIFT
 809 common_interrupt:
 810         XCPT_FRAME
 811         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 812         interrupt do_IRQ
 813         /* 0(%rsp): old_rsp-ARGOFFSET */
 814 ret_from_intr:
 815         DISABLE_INTERRUPTS(CLBR_NONE)
 816         TRACE_IRQS_OFF
 817         decl PER_CPU_VAR(irq_count)
 818
 819         /* Restore saved previous stack */
 820         popq %rsi
 821         CFI_DEF_CFA_REGISTER    rsi
 822         leaq ARGOFFSET-RBP(%rsi), %rsp
 823         CFI_DEF_CFA_REGISTER    rsp
 824         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 825
 826 exit_intr:
 827         GET_THREAD_INFO(%rcx)
 828         testl $3,CS-ARGOFFSET(%rsp)
 829         je retint_kernel
 830
 831         /* Interrupt came from user space */
 832         /*
 833          * Has a correct top of stack, but a partial stack frame
 834          * %rcx: thread info. Interrupts off.
 835          */
 836 retint_with_reschedule:
 837         movl $_TIF_WORK_MASK,%edi
 838 retint_check:
 839         LOCKDEP_SYS_EXIT_IRQ
 840         movl TI_flags(%rcx),%edx
 841         andl %edi,%edx
 842         CFI_REMEMBER_STATE
 843         jnz  retint_careful
 844
 845 retint_swapgs:          /* return to user-space */
 846         /*
 847          * The iretq could re-enable interrupts:
 848          */
 849         DISABLE_INTERRUPTS(CLBR_ANY)
 850         TRACE_IRQS_IRETQ
 851         SWAPGS
 852         jmp restore_args
 853
 854 retint_restore_args:    /* return to kernel space */
 855         DISABLE_INTERRUPTS(CLBR_ANY)
 856         /*
 857          * The iretq could re-enable interrupts:
 858          */
 859         TRACE_IRQS_IRETQ
 860 restore_args:
 861         RESTORE_ARGS 1,8,1
 862
 863 irq_return:
 864         INTERRUPT_RETURN
 865
 866 ENTRY(native_iret)
 867         /*
 868          * Are we returning to a stack segment from the LDT?  Note: in
 869          * 64-bit mode SS:RSP on the exception stack is always valid.
 870          */
 871 #ifdef CONFIG_X86_ESPFIX64
 872         testb $4,(SS-RIP)(%rsp)
 873         jnz native_irq_return_ldt
 874 #endif
 875
 876 .global native_irq_return_iret
 877 native_irq_return_iret:
 878         /*
 879          * This may fault.  Non-paranoid faults on return to userspace are
 880          * handled by fixup_bad_iret.  These include #SS, #GP, and #NP.
 881          * Double-faults due to espfix64 are handled in do_double_fault.
 882          * Other faults here are fatal.
 883          */
 884         iretq
 885
 886 #ifdef CONFIG_X86_ESPFIX64
 887 native_irq_return_ldt:
 888         pushq_cfi %rax
 889         pushq_cfi %rdi
 890         SWAPGS
 891         movq PER_CPU_VAR(espfix_waddr),%rdi
 892         movq %rax,(0*8)(%rdi)   /* RAX */
 893         movq (2*8)(%rsp),%rax   /* RIP */
 894         movq %rax,(1*8)(%rdi)
 895         movq (3*8)(%rsp),%rax   /* CS */
 896         movq %rax,(2*8)(%rdi)
 897         movq (4*8)(%rsp),%rax   /* RFLAGS */
 898         movq %rax,(3*8)(%rdi)
 899         movq (6*8)(%rsp),%rax   /* SS */
 900         movq %rax,(5*8)(%rdi)
 901         movq (5*8)(%rsp),%rax   /* RSP */
 902         movq %rax,(4*8)(%rdi)
 903         andl $0xffff0000,%eax
 904         popq_cfi %rdi
 905         orq PER_CPU_VAR(espfix_stack),%rax
 906         SWAPGS
 907         movq %rax,%rsp
 908         popq_cfi %rax
 909         jmp native_irq_return_iret
 910 #endif
 911
 912         /* edi: workmask, edx: work */
 913 retint_careful:
 914         CFI_RESTORE_STATE
 915         bt    $TIF_NEED_RESCHED,%edx
 916         jnc   retint_signal
 917         TRACE_IRQS_ON
 918         ENABLE_INTERRUPTS(CLBR_NONE)
 919         pushq_cfi %rdi
 920         call  schedule
 921         popq_cfi %rdi
 922         GET_THREAD_INFO(%rcx)
 923         DISABLE_INTERRUPTS(CLBR_NONE)
 924         TRACE_IRQS_OFF
 925         jmp retint_check
 926
 927 retint_signal:
 928         testl $_TIF_DO_NOTIFY_MASK,%edx
 929         jz    retint_swapgs
 930         TRACE_IRQS_ON
 931         ENABLE_INTERRUPTS(CLBR_NONE)
 932         SAVE_REST
 933         movq $-1,ORIG_RAX(%rsp)
 934         xorl %esi,%esi          # oldset
 935         movq %rsp,%rdi          # &pt_regs
 936         call do_notify_resume
 937         RESTORE_REST
 938         DISABLE_INTERRUPTS(CLBR_NONE)
 939         TRACE_IRQS_OFF
 940         GET_THREAD_INFO(%rcx)
 941         jmp retint_with_reschedule
 942
 943 #ifdef CONFIG_PREEMPT
 944         /* Returning to kernel space. Check if we need preemption */
 945         /* rcx:  threadinfo. interrupts off. */
 946 ENTRY(retint_kernel)
 947         cmpl $0,TI_preempt_count(%rcx)
 948         jnz  retint_restore_args
 949         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 950         jnc  retint_restore_args
 951         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 952         jnc  retint_restore_args
 953         call preempt_schedule_irq
 954         jmp exit_intr
 955 #endif
 956         CFI_ENDPROC
 957 END(common_interrupt)
 958
 959 /*
 960  * End of kprobes section
 961  */
 962        .popsection
 963
 964 /*
 965  * APIC interrupts.
 966  */
 967 .macro apicinterrupt num sym do_sym
 968 ENTRY(\sym)
 969         INTR_FRAME
 970         pushq_cfi $~(\num)
 971         interrupt \do_sym
 972         jmp ret_from_intr
 973         CFI_ENDPROC
 974 END(\sym)
 975 .endm
 976
 977 #ifdef CONFIG_SMP
 978 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 979         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 980 apicinterrupt REBOOT_VECTOR \
 981         reboot_interrupt smp_reboot_interrupt
 982 #endif
 983
 984 #ifdef CONFIG_X86_UV
 985 apicinterrupt UV_BAU_MESSAGE \
 986         uv_bau_message_intr1 uv_bau_message_interrupt
 987 #endif
 988 apicinterrupt LOCAL_TIMER_VECTOR \
 989         apic_timer_interrupt smp_apic_timer_interrupt
 990 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 991         x86_platform_ipi smp_x86_platform_ipi
 992
 993 #ifdef CONFIG_SMP
 994 .irp idx,0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
 995         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
 996 .if NUM_INVALIDATE_TLB_VECTORS > \idx
 997 apicinterrupt (INVALIDATE_TLB_VECTOR_START)+\idx \
 998         invalidate_interrupt\idx smp_invalidate_interrupt
 999 .endif
1000 .endr
1001 #endif
1002
1003 apicinterrupt THRESHOLD_APIC_VECTOR \
1004         threshold_interrupt smp_threshold_interrupt
1005 apicinterrupt THERMAL_APIC_VECTOR \
1006         thermal_interrupt smp_thermal_interrupt
1007
1008 #ifdef CONFIG_SMP
1009 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1010         call_function_single_interrupt smp_call_function_single_interrupt
1011 apicinterrupt CALL_FUNCTION_VECTOR \
1012         call_function_interrupt smp_call_function_interrupt
1013 apicinterrupt RESCHEDULE_VECTOR \
1014         reschedule_interrupt smp_reschedule_interrupt
1015 #endif
1016
1017 apicinterrupt ERROR_APIC_VECTOR \
1018         error_interrupt smp_error_interrupt
1019 apicinterrupt SPURIOUS_APIC_VECTOR \
1020         spurious_interrupt smp_spurious_interrupt
1021
1022 #ifdef CONFIG_IRQ_WORK
1023 apicinterrupt IRQ_WORK_VECTOR \
1024         irq_work_interrupt smp_irq_work_interrupt
1025 #endif
1026
1027 /*
1028  * Exception entry points.
1029  */
1030 .macro zeroentry sym do_sym
1031 ENTRY(\sym)
1032         INTR_FRAME
1033         PARAVIRT_ADJUST_EXCEPTION_FRAME
1034         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1035         subq $ORIG_RAX-R15, %rsp
1036         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1037         call error_entry
1038         DEFAULT_FRAME 0
1039         movq %rsp,%rdi          /* pt_regs pointer */
1040         xorl %esi,%esi          /* no error code */
1041         call \do_sym
1042         jmp error_exit          /* %ebx: no swapgs flag */
1043         CFI_ENDPROC
1044 END(\sym)
1045 .endm
1046
1047 .macro paranoidzeroentry sym do_sym
1048 ENTRY(\sym)
1049         INTR_FRAME
1050         PARAVIRT_ADJUST_EXCEPTION_FRAME
1051         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1052         subq $ORIG_RAX-R15, %rsp
1053         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1054         call save_paranoid
1055         TRACE_IRQS_OFF
1056         movq %rsp,%rdi          /* pt_regs pointer */
1057         xorl %esi,%esi          /* no error code */
1058         call \do_sym
1059         jmp paranoid_exit       /* %ebx: no swapgs flag */
1060         CFI_ENDPROC
1061 END(\sym)
1062 .endm
1063
1064 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1065 .macro paranoidzeroentry_ist sym do_sym ist
1066 ENTRY(\sym)
1067         INTR_FRAME
1068         PARAVIRT_ADJUST_EXCEPTION_FRAME
1069         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1070         subq $ORIG_RAX-R15, %rsp
1071         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1072         call save_paranoid
1073         TRACE_IRQS_OFF
1074         movq %rsp,%rdi          /* pt_regs pointer */
1075         xorl %esi,%esi          /* no error code */
1076         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1077         call \do_sym
1078         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1079         jmp paranoid_exit       /* %ebx: no swapgs flag */
1080         CFI_ENDPROC
1081 END(\sym)
1082 .endm
1083
1084 .macro errorentry sym do_sym
1085 ENTRY(\sym)
1086         XCPT_FRAME
1087         PARAVIRT_ADJUST_EXCEPTION_FRAME
1088         subq $ORIG_RAX-R15, %rsp
1089         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1090         call error_entry
1091         DEFAULT_FRAME 0
1092         movq %rsp,%rdi                  /* pt_regs pointer */
1093         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1094         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1095         call \do_sym
1096         jmp error_exit                  /* %ebx: no swapgs flag */
1097         CFI_ENDPROC
1098 END(\sym)
1099 .endm
1100
1101         /* error code is on the stack already */
1102 .macro paranoiderrorentry sym do_sym
1103 ENTRY(\sym)
1104         XCPT_FRAME
1105         PARAVIRT_ADJUST_EXCEPTION_FRAME
1106         subq $ORIG_RAX-R15, %rsp
1107         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1108         call save_paranoid
1109         DEFAULT_FRAME 0
1110         TRACE_IRQS_OFF
1111         movq %rsp,%rdi                  /* pt_regs pointer */
1112         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1113         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1114         call \do_sym
1115         jmp paranoid_exit               /* %ebx: no swapgs flag */
1116         CFI_ENDPROC
1117 END(\sym)
1118 .endm
1119
1120 zeroentry divide_error do_divide_error
1121 zeroentry overflow do_overflow
1122 zeroentry bounds do_bounds
1123 zeroentry invalid_op do_invalid_op
1124 zeroentry device_not_available do_device_not_available
1125 paranoiderrorentry double_fault do_double_fault
1126 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1127 errorentry invalid_TSS do_invalid_TSS
1128 errorentry segment_not_present do_segment_not_present
1129 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1130 zeroentry coprocessor_error do_coprocessor_error
1131 errorentry alignment_check do_alignment_check
1132 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1133
1134
1135         /* Reload gs selector with exception handling */
1136         /* edi:  new selector */
1137 ENTRY(native_load_gs_index)
1138         CFI_STARTPROC
1139         pushfq_cfi
1140         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1141         SWAPGS
1142 gs_change:
1143         movl %edi,%gs
1144 2:      mfence          /* workaround */
1145         SWAPGS
1146         popfq_cfi
1147         ret
1148         CFI_ENDPROC
1149 END(native_load_gs_index)
1150
1151         .section __ex_table,"a"
1152         .align 8
1153         .quad gs_change,bad_gs
1154         .previous
1155         .section .fixup,"ax"
1156         /* running with kernelgs */
1157 bad_gs:
1158         SWAPGS                  /* switch back to user gs */
1159         xorl %eax,%eax
1160         movl %eax,%gs
1161         jmp  2b
1162         .previous
1163
1164 ENTRY(kernel_thread_helper)
1165         pushq $0                # fake return address
1166         CFI_STARTPROC
1167         /*
1168          * Here we are in the child and the registers are set as they were
1169          * at kernel_thread() invocation in the parent.
1170          */
1171         call *%rsi
1172         # exit
1173         mov %eax, %edi
1174         call do_exit
1175         ud2                     # padding for call trace
1176         CFI_ENDPROC
1177 END(kernel_thread_helper)
1178
1179 /*
1180  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1181  *
1182  * C extern interface:
1183  *       extern long execve(const char *name, char **argv, char **envp)
1184  *
1185  * asm input arguments:
1186  *      rdi: name, rsi: argv, rdx: envp
1187  *
1188  * We want to fallback into:
1189  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1190  *
1191  * do_sys_execve asm fallback arguments:
1192  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1193  */
1194 ENTRY(kernel_execve)
1195         CFI_STARTPROC
1196         FAKE_STACK_FRAME $0
1197         SAVE_ALL
1198         movq %rsp,%rcx
1199         call sys_execve
1200         movq %rax, RAX(%rsp)
1201         RESTORE_REST
1202         testq %rax,%rax
1203         je int_ret_from_sys_call
1204         RESTORE_ARGS
1205         UNFAKE_STACK_FRAME
1206         ret
1207         CFI_ENDPROC
1208 END(kernel_execve)
1209
1210 /* Call softirq on interrupt stack. Interrupts are off. */
1211 ENTRY(call_softirq)
1212         CFI_STARTPROC
1213         pushq_cfi %rbp
1214         CFI_REL_OFFSET rbp,0
1215         mov  %rsp,%rbp
1216         CFI_DEF_CFA_REGISTER rbp
1217         incl PER_CPU_VAR(irq_count)
1218         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1219         push  %rbp                      # backlink for old unwinder
1220         call __do_softirq
1221         leaveq
1222         CFI_RESTORE             rbp
1223         CFI_DEF_CFA_REGISTER    rsp
1224         CFI_ADJUST_CFA_OFFSET   -8
1225         decl PER_CPU_VAR(irq_count)
1226         ret
1227         CFI_ENDPROC
1228 END(call_softirq)
1229
1230 #ifdef CONFIG_XEN
1231 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1232
1233 /*
1234  * A note on the "critical region" in our callback handler.
1235  * We want to avoid stacking callback handlers due to events occurring
1236  * during handling of the last event. To do this, we keep events disabled
1237  * until we've done all processing. HOWEVER, we must enable events before
1238  * popping the stack frame (can't be done atomically) and so it would still
1239  * be possible to get enough handler activations to overflow the stack.
1240  * Although unlikely, bugs of that kind are hard to track down, so we'd
1241  * like to avoid the possibility.
1242  * So, on entry to the handler we detect whether we interrupted an
1243  * existing activation in its critical region -- if so, we pop the current
1244  * activation and restart the handler using the previous one.
1245  */
1246 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1247         CFI_STARTPROC
1248 /*
1249  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1250  * see the correct pointer to the pt_regs
1251  */
1252         movq %rdi, %rsp            # we don't return, adjust the stack frame
1253         CFI_ENDPROC
1254         DEFAULT_FRAME
1255 11:     incl PER_CPU_VAR(irq_count)
1256         movq %rsp,%rbp
1257         CFI_DEF_CFA_REGISTER rbp
1258         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1259         pushq %rbp                      # backlink for old unwinder
1260         call xen_evtchn_do_upcall
1261         popq %rsp
1262         CFI_DEF_CFA_REGISTER rsp
1263         decl PER_CPU_VAR(irq_count)
1264         jmp  error_exit
1265         CFI_ENDPROC
1266 END(xen_do_hypervisor_callback)
1267
1268 /*
1269  * Hypervisor uses this for application faults while it executes.
1270  * We get here for two reasons:
1271  *  1. Fault while reloading DS, ES, FS or GS
1272  *  2. Fault while executing IRET
1273  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1274  * registers that could be reloaded and zeroed the others.
1275  * Category 2 we fix up by killing the current process. We cannot use the
1276  * normal Linux return path in this case because if we use the IRET hypercall
1277  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1278  * We distinguish between categories by comparing each saved segment register
1279  * with its current contents: any discrepancy means we in category 1.
1280  */
1281 ENTRY(xen_failsafe_callback)
1282         INTR_FRAME 1 (6*8)
1283         /*CFI_REL_OFFSET gs,GS*/
1284         /*CFI_REL_OFFSET fs,FS*/
1285         /*CFI_REL_OFFSET es,ES*/
1286         /*CFI_REL_OFFSET ds,DS*/
1287         CFI_REL_OFFSET r11,8
1288         CFI_REL_OFFSET rcx,0
1289         movw %ds,%cx
1290         cmpw %cx,0x10(%rsp)
1291         CFI_REMEMBER_STATE
1292         jne 1f
1293         movw %es,%cx
1294         cmpw %cx,0x18(%rsp)
1295         jne 1f
1296         movw %fs,%cx
1297         cmpw %cx,0x20(%rsp)
1298         jne 1f
1299         movw %gs,%cx
1300         cmpw %cx,0x28(%rsp)
1301         jne 1f
1302         /* All segments match their saved values => Category 2 (Bad IRET). */
1303         movq (%rsp),%rcx
1304         CFI_RESTORE rcx
1305         movq 8(%rsp),%r11
1306         CFI_RESTORE r11
1307         addq $0x30,%rsp
1308         CFI_ADJUST_CFA_OFFSET -0x30
1309         pushq_cfi $0    /* RIP */
1310         pushq_cfi %r11
1311         pushq_cfi %rcx
1312         jmp general_protection
1313         CFI_RESTORE_STATE
1314 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1315         movq (%rsp),%rcx
1316         CFI_RESTORE rcx
1317         movq 8(%rsp),%r11
1318         CFI_RESTORE r11
1319         addq $0x30,%rsp
1320         CFI_ADJUST_CFA_OFFSET -0x30
1321         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1322         SAVE_ALL
1323         jmp error_exit
1324         CFI_ENDPROC
1325 END(xen_failsafe_callback)
1326
1327 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1328         xen_hvm_callback_vector xen_evtchn_do_upcall
1329
1330 #endif /* CONFIG_XEN */
1331
1332 /*
1333  * Some functions should be protected against kprobes
1334  */
1335         .pushsection .kprobes.text, "ax"
1336
1337 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1338 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1339 errorentry stack_segment do_stack_segment
1340 #ifdef CONFIG_XEN
1341 zeroentry xen_debug do_debug
1342 zeroentry xen_int3 do_int3
1343 errorentry xen_stack_segment do_stack_segment
1344 #endif
1345 errorentry general_protection do_general_protection
1346 errorentry page_fault do_page_fault
1347 #ifdef CONFIG_KVM_GUEST
1348 errorentry async_page_fault do_async_page_fault
1349 #endif
1350 #ifdef CONFIG_X86_MCE
1351 paranoidzeroentry machine_check *machine_check_vector(%rip)
1352 #endif
1353
1354         /*
1355          * "Paranoid" exit path from exception stack.
1356          * Paranoid because this is used by NMIs and cannot take
1357          * any kernel state for granted.
1358          * We don't do kernel preemption checks here, because only
1359          * NMI should be common and it does not enable IRQs and
1360          * cannot get reschedule ticks.
1361          *
1362          * "trace" is 0 for the NMI handler only, because irq-tracing
1363          * is fundamentally NMI-unsafe. (we cannot change the soft and
1364          * hard flags at once, atomically)
1365          */
1366
1367         /* ebx: no swapgs flag */
1368 ENTRY(paranoid_exit)
1369         DEFAULT_FRAME
1370         DISABLE_INTERRUPTS(CLBR_NONE)
1371         TRACE_IRQS_OFF
1372         testl %ebx,%ebx                         /* swapgs needed? */
1373         jnz paranoid_restore
1374         testl $3,CS(%rsp)
1375         jnz   paranoid_userspace
1376 paranoid_swapgs:
1377         TRACE_IRQS_IRETQ 0
1378         SWAPGS_UNSAFE_STACK
1379         RESTORE_ALL 8
1380         jmp irq_return
1381 paranoid_restore:
1382         TRACE_IRQS_IRETQ 0
1383         RESTORE_ALL 8
1384         jmp irq_return
1385 paranoid_userspace:
1386         GET_THREAD_INFO(%rcx)
1387         movl TI_flags(%rcx),%ebx
1388         andl $_TIF_WORK_MASK,%ebx
1389         jz paranoid_swapgs
1390         movq %rsp,%rdi                  /* &pt_regs */
1391         call sync_regs
1392         movq %rax,%rsp                  /* switch stack for scheduling */
1393         testl $_TIF_NEED_RESCHED,%ebx
1394         jnz paranoid_schedule
1395         movl %ebx,%edx                  /* arg3: thread flags */
1396         TRACE_IRQS_ON
1397         ENABLE_INTERRUPTS(CLBR_NONE)
1398         xorl %esi,%esi                  /* arg2: oldset */
1399         movq %rsp,%rdi                  /* arg1: &pt_regs */
1400         call do_notify_resume
1401         DISABLE_INTERRUPTS(CLBR_NONE)
1402         TRACE_IRQS_OFF
1403         jmp paranoid_userspace
1404 paranoid_schedule:
1405         TRACE_IRQS_ON
1406         ENABLE_INTERRUPTS(CLBR_ANY)
1407         call schedule
1408         DISABLE_INTERRUPTS(CLBR_ANY)
1409         TRACE_IRQS_OFF
1410         jmp paranoid_userspace
1411         CFI_ENDPROC
1412 END(paranoid_exit)
1413
1414 /*
1415  * Exception entry point. This expects an error code/orig_rax on the stack.
1416  * returns in "no swapgs flag" in %ebx.
1417  */
1418 ENTRY(error_entry)
1419         XCPT_FRAME
1420         CFI_ADJUST_CFA_OFFSET 15*8
1421         /* oldrax contains error code */
1422         cld
1423         movq_cfi rdi, RDI+8
1424         movq_cfi rsi, RSI+8
1425         movq_cfi rdx, RDX+8
1426         movq_cfi rcx, RCX+8
1427         movq_cfi rax, RAX+8
1428         movq_cfi  r8,  R8+8
1429         movq_cfi  r9,  R9+8
1430         movq_cfi r10, R10+8
1431         movq_cfi r11, R11+8
1432         movq_cfi rbx, RBX+8
1433         movq_cfi rbp, RBP+8
1434         movq_cfi r12, R12+8
1435         movq_cfi r13, R13+8
1436         movq_cfi r14, R14+8
1437         movq_cfi r15, R15+8
1438         xorl %ebx,%ebx
1439         testl $3,CS+8(%rsp)
1440         je error_kernelspace
1441 error_swapgs:
1442         SWAPGS
1443 error_sti:
1444         TRACE_IRQS_OFF
1445         ret
1446
1447 /*
1448  * There are two places in the kernel that can potentially fault with
1449  * usergs. Handle them here.  B stepping K8s sometimes report a
1450  * truncated RIP for IRET exceptions returning to compat mode. Check
1451  * for these here too.
1452  */
1453 error_kernelspace:
1454         incl %ebx
1455         leaq native_irq_return_iret(%rip),%rcx
1456         cmpq %rcx,RIP+8(%rsp)
1457         je error_bad_iret
1458         movl %ecx,%eax  /* zero extend */
1459         cmpq %rax,RIP+8(%rsp)
1460         je bstep_iret
1461         cmpq $gs_change,RIP+8(%rsp)
1462         je error_swapgs
1463         jmp error_sti
1464
1465 bstep_iret:
1466         /* Fix truncated RIP */
1467         movq %rcx,RIP+8(%rsp)
1468         /* fall through */
1469
1470 error_bad_iret:
1471         SWAPGS
1472         mov %rsp,%rdi
1473         call fixup_bad_iret
1474         mov %rax,%rsp
1475         decl %ebx       /* Return to usergs */
1476         jmp error_sti
1477         CFI_ENDPROC
1478 END(error_entry)
1479
1480
1481 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1482 ENTRY(error_exit)
1483         DEFAULT_FRAME
1484         movl %ebx,%eax
1485         RESTORE_REST
1486         DISABLE_INTERRUPTS(CLBR_NONE)
1487         TRACE_IRQS_OFF
1488         GET_THREAD_INFO(%rcx)
1489         testl %eax,%eax
1490         jne retint_kernel
1491         LOCKDEP_SYS_EXIT_IRQ
1492         movl TI_flags(%rcx),%edx
1493         movl $_TIF_WORK_MASK,%edi
1494         andl %edi,%edx
1495         jnz retint_careful
1496         jmp retint_swapgs
1497         CFI_ENDPROC
1498 END(error_exit)
1499
1500
1501         /* runs on exception stack */
1502 ENTRY(nmi)
1503         INTR_FRAME
1504         PARAVIRT_ADJUST_EXCEPTION_FRAME
1505         pushq_cfi $-1
1506         subq $ORIG_RAX-R15, %rsp
1507         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1508         call save_paranoid
1509         DEFAULT_FRAME 0
1510         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1511         movq %rsp,%rdi
1512         movq $-1,%rsi
1513         call do_nmi
1514 #ifdef CONFIG_TRACE_IRQFLAGS
1515         /* paranoidexit; without TRACE_IRQS_OFF */
1516         /* ebx: no swapgs flag */
1517         DISABLE_INTERRUPTS(CLBR_NONE)
1518         testl %ebx,%ebx                         /* swapgs needed? */
1519         jnz nmi_restore
1520         testl $3,CS(%rsp)
1521         jnz nmi_userspace
1522 nmi_swapgs:
1523         SWAPGS_UNSAFE_STACK
1524 nmi_restore:
1525         RESTORE_ALL 8
1526         jmp irq_return
1527 nmi_userspace:
1528         GET_THREAD_INFO(%rcx)
1529         movl TI_flags(%rcx),%ebx
1530         andl $_TIF_WORK_MASK,%ebx
1531         jz nmi_swapgs
1532         movq %rsp,%rdi                  /* &pt_regs */
1533         call sync_regs
1534         movq %rax,%rsp                  /* switch stack for scheduling */
1535         testl $_TIF_NEED_RESCHED,%ebx
1536         jnz nmi_schedule
1537         movl %ebx,%edx                  /* arg3: thread flags */
1538         ENABLE_INTERRUPTS(CLBR_NONE)
1539         xorl %esi,%esi                  /* arg2: oldset */
1540         movq %rsp,%rdi                  /* arg1: &pt_regs */
1541         call do_notify_resume
1542         DISABLE_INTERRUPTS(CLBR_NONE)
1543         jmp nmi_userspace
1544 nmi_schedule:
1545         ENABLE_INTERRUPTS(CLBR_ANY)
1546         call schedule
1547         DISABLE_INTERRUPTS(CLBR_ANY)
1548         jmp nmi_userspace
1549         CFI_ENDPROC
1550 #else
1551         jmp paranoid_exit
1552         CFI_ENDPROC
1553 #endif
1554 END(nmi)
1555
1556 ENTRY(ignore_sysret)
1557         CFI_STARTPROC
1558         mov $-ENOSYS,%eax
1559         sysret
1560         CFI_ENDPROC
1561 END(ignore_sysret)
1562
1563 /*
1564  * End of kprobes section
1565  */
1566         .popsection