arch/x86/crypto/crc32c-pcl-intel-asm_64.S

   1 /*
   2  * Implement fast CRC32C with PCLMULQDQ instructions. (x86_64)
   3  *
   4  * The white papers on CRC32C calculations with PCLMULQDQ instruction can be
   5  * downloaded from:
   6  * http://www.intel.com/content/dam/www/public/us/en/documents/white-papers/crc-iscsi-polynomial-crc32-instruction-paper.pdf
   7  * http://www.intel.com/content/dam/www/public/us/en/documents/white-papers/fast-crc-computation-paper.pdf
   8  *
   9  * Copyright (C) 2012 Intel Corporation.
  10  *
  11  * Authors:
  12  *      Wajdi Feghali <wajdi.k.feghali@intel.com>
  13  *      James Guilford <james.guilford@intel.com>
  14  *      David Cote <david.m.cote@intel.com>
  15  *      Tim Chen <tim.c.chen@linux.intel.com>
  16  *
  17  * This software is available to you under a choice of one of two
  18  * licenses.  You may choose to be licensed under the terms of the GNU
  19  * General Public License (GPL) Version 2, available from the file
  20  * COPYING in the main directory of this source tree, or the
  21  * OpenIB.org BSD license below:
  22  *
  23  *     Redistribution and use in source and binary forms, with or
  24  *     without modification, are permitted provided that the following
  25  *     conditions are met:
  26  *
  27  *      - Redistributions of source code must retain the above
  28  *        copyright notice, this list of conditions and the following
  29  *        disclaimer.
  30  *
  31  *      - Redistributions in binary form must reproduce the above
  32  *        copyright notice, this list of conditions and the following
  33  *        disclaimer in the documentation and/or other materials
  34  *        provided with the distribution.
  35  *
  36  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  37  * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  38  * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  39  * NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS
  40  * BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
  41  * ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  42  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  43  * SOFTWARE.
  44  */
  45
  46 #include <linux/linkage.h>
  47
  48 ## ISCSI CRC 32 Implementation with crc32 and pclmulqdq Instruction
  49
  50 .macro LABEL prefix n
  51 \prefix\n\():
  52 .endm
  53
  54 .macro JMPTBL_ENTRY i
  55 .word crc_\i - crc_array
  56 .endm
  57
  58 .macro JNC_LESS_THAN j
  59         jnc less_than_\j
  60 .endm
  61
  62 # Define threshold where buffers are considered "small" and routed to more
  63 # efficient "by-1" code. This "by-1" code only handles up to 255 bytes, so
  64 # SMALL_SIZE can be no larger than 255.
  65
  66 #define SMALL_SIZE 200
  67
  68 .if (SMALL_SIZE > 255)
  69 .error "SMALL_ SIZE must be < 256"
  70 .endif
  71
  72 # unsigned int crc_pcl(u8 *buffer, int len, unsigned int crc_init);
  73
  74 ENTRY(crc_pcl)
  75 #define    bufp         %rdi
  76 #define    bufp_dw      %edi
  77 #define    bufp_w       %di
  78 #define    bufp_b       %dil
  79 #define    bufptmp      %rcx
  80 #define    block_0      %rcx
  81 #define    block_1      %rdx
  82 #define    block_2      %r11
  83 #define    len          %rsi
  84 #define    len_dw       %esi
  85 #define    len_w        %si
  86 #define    len_b        %sil
  87 #define    crc_init_arg %rdx
  88 #define    tmp          %rbx
  89 #define    crc_init     %r8
  90 #define    crc_init_dw  %r8d
  91 #define    crc1         %r9
  92 #define    crc2         %r10
  93
  94         pushq   %rbx
  95         pushq   %rdi
  96         pushq   %rsi
  97
  98         ## Move crc_init for Linux to a different
  99         mov     crc_init_arg, crc_init
 100
 101         ################################################################
 102         ## 1) ALIGN:
 103         ################################################################
 104
 105         mov     bufp, bufptmp           # rdi = *buf
 106         neg     bufp
 107         and     $7, bufp                # calculate the unalignment amount of
 108                                         # the address
 109         je      proc_block              # Skip if aligned
 110
 111         ## If len is less than 8 and we're unaligned, we need to jump
 112         ## to special code to avoid reading beyond the end of the buffer
 113         cmp     $8, len
 114         jae     do_align
 115         # less_than_8 expects length in upper 3 bits of len_dw
 116         # less_than_8_post_shl1 expects length = carryflag * 8 + len_dw[31:30]
 117         shl     $32-3+1, len_dw
 118         jmp     less_than_8_post_shl1
 119
 120 do_align:
 121         #### Calculate CRC of unaligned bytes of the buffer (if any)
 122         movq    (bufptmp), tmp          # load a quadward from the buffer
 123         add     bufp, bufptmp           # align buffer pointer for quadword
 124                                         # processing
 125         sub     bufp, len               # update buffer length
 126 align_loop:
 127         crc32b  %bl, crc_init_dw        # compute crc32 of 1-byte
 128         shr     $8, tmp                 # get next byte
 129         dec     bufp
 130         jne     align_loop
 131
 132 proc_block:
 133
 134         ################################################################
 135         ## 2) PROCESS  BLOCKS:
 136         ################################################################
 137
 138         ## compute num of bytes to be processed
 139         movq    len, tmp                # save num bytes in tmp
 140
 141         cmpq    $128*24, len
 142         jae     full_block
 143
 144 continue_block:
 145         cmpq    $SMALL_SIZE, len
 146         jb      small
 147
 148         ## len < 128*24
 149         movq    $2731, %rax             # 2731 = ceil(2^16 / 24)
 150         mul     len_dw
 151         shrq    $16, %rax
 152
 153         ## eax contains floor(bytes / 24) = num 24-byte chunks to do
 154
 155         ## process rax 24-byte chunks (128 >= rax >= 0)
 156
 157         ## compute end address of each block
 158         ## block 0 (base addr + RAX * 8)
 159         ## block 1 (base addr + RAX * 16)
 160         ## block 2 (base addr + RAX * 24)
 161         lea     (bufptmp, %rax, 8), block_0
 162         lea     (block_0, %rax, 8), block_1
 163         lea     (block_1, %rax, 8), block_2
 164
 165         xor     crc1, crc1
 166         xor     crc2, crc2
 167
 168         ## branch into array
 169         lea     jump_table(%rip), bufp
 170         movzxw  (bufp, %rax, 2), len
 171         offset=crc_array-jump_table
 172         lea     offset(bufp, len, 1), bufp
 173         jmp     *bufp
 174
 175         ################################################################
 176         ## 2a) PROCESS FULL BLOCKS:
 177         ################################################################
 178 full_block:
 179         movq    $128,%rax
 180         lea     128*8*2(block_0), block_1
 181         lea     128*8*3(block_0), block_2
 182         add     $128*8*1, block_0
 183
 184         xor     crc1,crc1
 185         xor     crc2,crc2
 186
 187         # Fall thruogh into top of crc array (crc_128)
 188
 189         ################################################################
 190         ## 3) CRC Array:
 191         ################################################################
 192
 193 crc_array:
 194         i=128
 195 .rept 128-1
 196 .altmacro
 197 LABEL crc_ %i
 198 .noaltmacro
 199         crc32q   -i*8(block_0), crc_init
 200         crc32q   -i*8(block_1), crc1
 201         crc32q   -i*8(block_2), crc2
 202         i=(i-1)
 203 .endr
 204
 205 .altmacro
 206 LABEL crc_ %i
 207 .noaltmacro
 208         crc32q   -i*8(block_0), crc_init
 209         crc32q   -i*8(block_1), crc1
 210 # SKIP  crc32  -i*8(block_2), crc2 ; Don't do this one yet
 211
 212         mov     block_2, block_0
 213
 214         ################################################################
 215         ## 4) Combine three results:
 216         ################################################################
 217
 218         lea     (K_table-16)(%rip), bufp        # first entry is for idx 1
 219         shlq    $3, %rax                        # rax *= 8
 220         subq    %rax, tmp                       # tmp -= rax*8
 221         shlq    $1, %rax
 222         subq    %rax, tmp                       # tmp -= rax*16
 223                                                 # (total tmp -= rax*24)
 224         addq    %rax, bufp
 225
 226         movdqa  (bufp), %xmm0                   # 2 consts: K1:K2
 227
 228         movq    crc_init, %xmm1                 # CRC for block 1
 229         pclmulqdq $0x00,%xmm0,%xmm1             # Multiply by K2
 230
 231         movq    crc1, %xmm2                     # CRC for block 2
 232         pclmulqdq $0x10, %xmm0, %xmm2           # Multiply by K1
 233
 234         pxor    %xmm2,%xmm1
 235         movq    %xmm1, %rax
 236         xor     -i*8(block_2), %rax
 237         mov     crc2, crc_init
 238         crc32   %rax, crc_init
 239
 240 ################################################################
 241 ## 5) Check for end:
 242 ################################################################
 243
 244 LABEL crc_ 0
 245         mov     tmp, len
 246         cmp     $128*24, tmp
 247         jae     full_block
 248         cmp     $24, tmp
 249         jae     continue_block
 250
 251 less_than_24:
 252         shl     $32-4, len_dw                   # less_than_16 expects length
 253                                                 # in upper 4 bits of len_dw
 254         jnc     less_than_16
 255         crc32q  (bufptmp), crc_init
 256         crc32q  8(bufptmp), crc_init
 257         jz      do_return
 258         add     $16, bufptmp
 259         # len is less than 8 if we got here
 260         # less_than_8 expects length in upper 3 bits of len_dw
 261         # less_than_8_post_shl1 expects length = carryflag * 8 + len_dw[31:30]
 262         shl     $2, len_dw
 263         jmp     less_than_8_post_shl1
 264
 265         #######################################################################
 266         ## 6) LESS THAN 256-bytes REMAIN AT THIS POINT (8-bits of len are full)
 267         #######################################################################
 268 small:
 269         shl $32-8, len_dw               # Prepare len_dw for less_than_256
 270         j=256
 271 .rept 5                                 # j = {256, 128, 64, 32, 16}
 272 .altmacro
 273 LABEL less_than_ %j                     # less_than_j: Length should be in
 274                                         # upper lg(j) bits of len_dw
 275         j=(j/2)
 276         shl     $1, len_dw              # Get next MSB
 277         JNC_LESS_THAN %j
 278 .noaltmacro
 279         i=0
 280 .rept (j/8)
 281         crc32q  i(bufptmp), crc_init    # Compute crc32 of 8-byte data
 282         i=i+8
 283 .endr
 284         jz      do_return               # Return if remaining length is zero
 285         add     $j, bufptmp             # Advance buf
 286 .endr
 287
 288 less_than_8:                            # Length should be stored in
 289                                         # upper 3 bits of len_dw
 290         shl     $1, len_dw
 291 less_than_8_post_shl1:
 292         jnc     less_than_4
 293         crc32l  (bufptmp), crc_init_dw  # CRC of 4 bytes
 294         jz      do_return               # return if remaining data is zero
 295         add     $4, bufptmp
 296 less_than_4:                            # Length should be stored in
 297                                         # upper 2 bits of len_dw
 298         shl     $1, len_dw
 299         jnc     less_than_2
 300         crc32w  (bufptmp), crc_init_dw  # CRC of 2 bytes
 301         jz      do_return               # return if remaining data is zero
 302         add     $2, bufptmp
 303 less_than_2:                            # Length should be stored in the MSB
 304                                         # of len_dw
 305         shl     $1, len_dw
 306         jnc     less_than_1
 307         crc32b  (bufptmp), crc_init_dw  # CRC of 1 byte
 308 less_than_1:                            # Length should be zero
 309 do_return:
 310         movq    crc_init, %rax
 311         popq    %rsi
 312         popq    %rdi
 313         popq    %rbx
 314         ret
 315
 316         ################################################################
 317         ## jump table        Table is 129 entries x 2 bytes each
 318         ################################################################
 319 .align 4
 320 jump_table:
 321         i=0
 322 .rept 129
 323 .altmacro
 324 JMPTBL_ENTRY %i
 325 .noaltmacro
 326         i=i+1
 327 .endr
 328
 329 ENDPROC(crc_pcl)
 330
 331         ################################################################
 332         ## PCLMULQDQ tables
 333         ## Table is 128 entries x 2 quad words each
 334         ################################################################
 335 .data
 336 .align 64
 337 K_table:
 338         .quad 0x14cd00bd6,0x105ec76f0
 339         .quad 0x0ba4fc28e,0x14cd00bd6
 340         .quad 0x1d82c63da,0x0f20c0dfe
 341         .quad 0x09e4addf8,0x0ba4fc28e
 342         .quad 0x039d3b296,0x1384aa63a
 343         .quad 0x102f9b8a2,0x1d82c63da
 344         .quad 0x14237f5e6,0x01c291d04
 345         .quad 0x00d3b6092,0x09e4addf8
 346         .quad 0x0c96cfdc0,0x0740eef02
 347         .quad 0x18266e456,0x039d3b296
 348         .quad 0x0daece73e,0x0083a6eec
 349         .quad 0x0ab7aff2a,0x102f9b8a2
 350         .quad 0x1248ea574,0x1c1733996
 351         .quad 0x083348832,0x14237f5e6
 352         .quad 0x12c743124,0x02ad91c30
 353         .quad 0x0b9e02b86,0x00d3b6092
 354         .quad 0x018b33a4e,0x06992cea2
 355         .quad 0x1b331e26a,0x0c96cfdc0
 356         .quad 0x17d35ba46,0x07e908048
 357         .quad 0x1bf2e8b8a,0x18266e456
 358         .quad 0x1a3e0968a,0x11ed1f9d8
 359         .quad 0x0ce7f39f4,0x0daece73e
 360         .quad 0x061d82e56,0x0f1d0f55e
 361         .quad 0x0d270f1a2,0x0ab7aff2a
 362         .quad 0x1c3f5f66c,0x0a87ab8a8
 363         .quad 0x12ed0daac,0x1248ea574
 364         .quad 0x065863b64,0x08462d800
 365         .quad 0x11eef4f8e,0x083348832
 366         .quad 0x1ee54f54c,0x071d111a8
 367         .quad 0x0b3e32c28,0x12c743124
 368         .quad 0x0064f7f26,0x0ffd852c6
 369         .quad 0x0dd7e3b0c,0x0b9e02b86
 370         .quad 0x0f285651c,0x0dcb17aa4
 371         .quad 0x010746f3c,0x018b33a4e
 372         .quad 0x1c24afea4,0x0f37c5aee
 373         .quad 0x0271d9844,0x1b331e26a
 374         .quad 0x08e766a0c,0x06051d5a2
 375         .quad 0x093a5f730,0x17d35ba46
 376         .quad 0x06cb08e5c,0x11d5ca20e
 377         .quad 0x06b749fb2,0x1bf2e8b8a
 378         .quad 0x1167f94f2,0x021f3d99c
 379         .quad 0x0cec3662e,0x1a3e0968a
 380         .quad 0x19329634a,0x08f158014
 381         .quad 0x0e6fc4e6a,0x0ce7f39f4
 382         .quad 0x08227bb8a,0x1a5e82106
 383         .quad 0x0b0cd4768,0x061d82e56
 384         .quad 0x13c2b89c4,0x188815ab2
 385         .quad 0x0d7a4825c,0x0d270f1a2
 386         .quad 0x10f5ff2ba,0x105405f3e
 387         .quad 0x00167d312,0x1c3f5f66c
 388         .quad 0x0f6076544,0x0e9adf796
 389         .quad 0x026f6a60a,0x12ed0daac
 390         .quad 0x1a2adb74e,0x096638b34
 391         .quad 0x19d34af3a,0x065863b64
 392         .quad 0x049c3cc9c,0x1e50585a0
 393         .quad 0x068bce87a,0x11eef4f8e
 394         .quad 0x1524fa6c6,0x19f1c69dc
 395         .quad 0x16cba8aca,0x1ee54f54c
 396         .quad 0x042d98888,0x12913343e
 397         .quad 0x1329d9f7e,0x0b3e32c28
 398         .quad 0x1b1c69528,0x088f25a3a
 399         .quad 0x02178513a,0x0064f7f26
 400         .quad 0x0e0ac139e,0x04e36f0b0
 401         .quad 0x0170076fa,0x0dd7e3b0c
 402         .quad 0x141a1a2e2,0x0bd6f81f8
 403         .quad 0x16ad828b4,0x0f285651c
 404         .quad 0x041d17b64,0x19425cbba
 405         .quad 0x1fae1cc66,0x010746f3c
 406         .quad 0x1a75b4b00,0x18db37e8a
 407         .quad 0x0f872e54c,0x1c24afea4
 408         .quad 0x01e41e9fc,0x04c144932
 409         .quad 0x086d8e4d2,0x0271d9844
 410         .quad 0x160f7af7a,0x052148f02
 411         .quad 0x05bb8f1bc,0x08e766a0c
 412         .quad 0x0a90fd27a,0x0a3c6f37a
 413         .quad 0x0b3af077a,0x093a5f730
 414         .quad 0x04984d782,0x1d22c238e
 415         .quad 0x0ca6ef3ac,0x06cb08e5c
 416         .quad 0x0234e0b26,0x063ded06a
 417         .quad 0x1d88abd4a,0x06b749fb2
 418         .quad 0x04597456a,0x04d56973c
 419         .quad 0x0e9e28eb4,0x1167f94f2
 420         .quad 0x07b3ff57a,0x19385bf2e
 421         .quad 0x0c9c8b782,0x0cec3662e
 422         .quad 0x13a9cba9e,0x0e417f38a
 423         .quad 0x093e106a4,0x19329634a
 424         .quad 0x167001a9c,0x14e727980
 425         .quad 0x1ddffc5d4,0x0e6fc4e6a
 426         .quad 0x00df04680,0x0d104b8fc
 427         .quad 0x02342001e,0x08227bb8a
 428         .quad 0x00a2a8d7e,0x05b397730
 429         .quad 0x168763fa6,0x0b0cd4768
 430         .quad 0x1ed5a407a,0x0e78eb416
 431         .quad 0x0d2c3ed1a,0x13c2b89c4
 432         .quad 0x0995a5724,0x1641378f0
 433         .quad 0x19b1afbc4,0x0d7a4825c
 434         .quad 0x109ffedc0,0x08d96551c
 435         .quad 0x0f2271e60,0x10f5ff2ba
 436         .quad 0x00b0bf8ca,0x00bf80dd2
 437         .quad 0x123888b7a,0x00167d312
 438         .quad 0x1e888f7dc,0x18dcddd1c
 439         .quad 0x002ee03b2,0x0f6076544
 440         .quad 0x183e8d8fe,0x06a45d2b2
 441         .quad 0x133d7a042,0x026f6a60a
 442         .quad 0x116b0f50c,0x1dd3e10e8
 443         .quad 0x05fabe670,0x1a2adb74e
 444         .quad 0x130004488,0x0de87806c
 445         .quad 0x000bcf5f6,0x19d34af3a
 446         .quad 0x18f0c7078,0x014338754
 447         .quad 0x017f27698,0x049c3cc9c
 448         .quad 0x058ca5f00,0x15e3e77ee
 449         .quad 0x1af900c24,0x068bce87a
 450         .quad 0x0b5cfca28,0x0dd07448e
 451         .quad 0x0ded288f8,0x1524fa6c6
 452         .quad 0x059f229bc,0x1d8048348
 453         .quad 0x06d390dec,0x16cba8aca
 454         .quad 0x037170390,0x0a3e3e02c
 455         .quad 0x06353c1cc,0x042d98888
 456         .quad 0x0c4584f5c,0x0d73c7bea
 457         .quad 0x1f16a3418,0x1329d9f7e
 458         .quad 0x0531377e2,0x185137662
 459         .quad 0x1d8d9ca7c,0x1b1c69528
 460         .quad 0x0b25b29f2,0x18a08b5bc
 461         .quad 0x19fb2a8b0,0x02178513a
 462         .quad 0x1a08fe6ac,0x1da758ae0
 463         .quad 0x045cddf4e,0x0e0ac139e
 464         .quad 0x1a91647f2,0x169cf9eb0
 465         .quad 0x1a0f717c4,0x0170076fa