recipes/linux/omap3-pandora-kernel2_3.2-pandora.bb

   1 DESCRIPTION = "3.2 Linux kernel for the Pandora handheld console"
   2 SECTION = "kernel"
   3 LICENSE = "GPLv2"
   4 COMPATIBLE_MACHINE = "omap3-pandora"
   5 PACKAGE_ARCH = "${MACHINE_ARCH}"
   6
   7 PR = "r19"
   8
   9 # we already build 2.6 kernel using OE infrastructure, and
  10 # as we don't know how to build another one into the same image
  11 # (especially out-of-tree modules), we just package manually prebuilt one
  12 # git://git.openpandora.org/pandora-kernel.git , branch pandora-3.2
  13 # commit: 7a86414d402959803aae2576377ce1b158bc41ef
  14 # out-of-tree modules are built from:
  15 # http://git.openpandora.org/cgi-bin/gitweb.cgi?p=sgx.git
  16 # http://notaz.gp2x.de/misc/pnd/oe_rootfs_extra_modules.tar.bz2
  17 SRC_URI = "http://notaz.gp2x.de/misc/pnd/oe_rootfs_extra_${PR}.tar.bz2"
  18
  19 S = "${WORKDIR}"
  20
  21 do_install() {
  22   cp -a ${S}/boot ${D}/
  23   cp -a ${S}/lib ${D}/
  24 }
  25
  26 FILES_${PN} = "boot lib"
  27
  28 pkg_postinst_${PN} () {
  29   # this will cause depmod to be run on next boot
  30   rm -f /lib/modules/`uname -r`/modules.dep
  31   sync
  32
  33   if ! grep -q '[[:blank:]]/[[:blank:]]*ubifs' /proc/mounts; then
  34     for dir in `ls -d /media/*boot* 2> /dev/null` `ls -d /media/*BOOT* 2> /dev/null`; do
  35       test -e $dir/uImage && oldkernel=$dir/uImage
  36       test -e $dir/uImage-3 && oldkernel=$dir/uImage-3
  37     done
  38
  39     if test -n "$oldkernel"; then
  40       cp /boot/uImage-3 $oldkernel
  41       msg="Updated kernel has beed copied to ${oldkernel}. \
  42 If this location is wrong, copy /boot/uImage-3 to the location \
  43 where your kernel is booted from (usually set in boot.txt / autoboot.txt)."
  44     else
  45       msg="The kernel in /boot/uImage-3 has been updated. You need to \
  46 copy it to the location where kernel is booted from (usually set in \
  47 boot.txt / autoboot.txt) or the system might not start after reboot."
  48     fi
  49     sync
  50     if test -n "$DISPLAY"; then
  51       zenity --info --text "$msg"
  52     else
  53       echo "=================================="
  54       echo "$msg"
  55       sleep 5
  56     fi
  57   fi
  58 }
  59
  60 PACKAGE_STRIP = "no"
  61 SRC_URI[md5sum] = "9d5d4438a5df7d300b8ede40896af5d5"
  62 SRC_URI[sha256sum] = "d25db14612257d115ce07c05ece3ca006f633171d80c49d0031592e9a46dc231"