recipes/python/python-pyqt_4.8.4.bb

   1 DESCRIPTION = "Python Qt4 Bindings"
   2 HOMEPAGE = "http://riverbankcomputing.co.uk"
   3 AUTHOR = "Phil Thomson @ riverbank.co.uk"
   4 SECTION = "devel/python"
   5 PRIORITY = "optional"
   6 LICENSE = "GPL"
   7 DEPENDS = "sip-native python-sip"
   8 RDEPENDS_${PN} = "python-core"
   9 SRCNAME = "pyqt"
  10 PR = "r0"
  11
  12 PYQT_OE_VERSION = "Qt_4_7_1"
  13
  14 SRC_URI = "\
  15   http://www.riverbankcomputing.co.uk/static/Downloads/PyQt4/PyQt-x11-gpl-${PV}.tar.gz \
  16   \
  17   file://fix_qthelp_ftbfs.diff;apply=yes \
  18   file://fix_the_QAssitant_ftbfs.diff;apply=yes \
  19   file://assistantclient-fix.patch;apply=yes \
  20 "
  21 SRC_URI[md5sum] = "97c5dc1042feb5b3fe20baabad055af1"
  22 SRC_URI[sha256sum] = "fcfa3ecc0b4fad6d93227751b36a6f81ea104ee19dd26905f52de59f060b3e98"
  23 S = "${WORKDIR}/PyQt-x11-gpl-${PV}"
  24
  25 # arm and mips machines need some extra patches
  26 SRC_URI_append_arm = "\
  27   file://qreal_float_support.diff;apply=yes \
  28 "
  29
  30 SRC_URI_append_mipsel = "\
  31   file://qreal_float_support.diff;apply=yes \
  32 "
  33
  34 inherit qt4x11 sip distutils-base
  35
  36 PARALLEL_MAKE = ""
  37
  38 QMAKE_PROFILES = "pyqt.pro"
  39 # NOTE: has to match with MIN(qt version we have in OE, last known Qt version by SIP/PyQt)
  40 EXTRA_SIPTAGS = "-tWS_X11 -t${PYQT_OE_VERSION} -xVendorID -xPyQt_SessionManager -xPyQt_Accessibility"
  41 EXTRA_OEMAKE = " MAKEFLAGS= "
  42
  43 # arm and mips need extra params for the qreal issue
  44 EXTRA_SIPTAGS_append_arm = " -x PyQt_qreal_double"
  45 EXTRA_SIPTAGS_append_mipsel = " -x PyQt_qreal_double"
  46
  47 SIP_MODULES = "QtCore QtDeclarative QtGui QtNetwork QtSql QtSvg QtXml QtWebKit"
  48 MAKE_MODULES = "qpy ${SIP_MODULES}"
  49
  50 EXTRA_QMAKEVARS_POST += "\
  51   INCLUDEPATH+=${OE_QMAKE_INCDIR_QT}/Qt \
  52   INCLUDEPATH+=${STAGING_INCDIR}/${PYTHON_DIR} \
  53   INCLUDEPATH+=../qpy/QtCore \
  54   INCLUDEPATH+=../qpy/QtGui \
  55   INCLUDEPATH+=../qpy/QtDeclarative \
  56   INCLUDEPATH+=${OE_QMAKE_INCDIR_QT}/QtCore \
  57   INCLUDEPATH+=${OE_QMAKE_INCDIR_QT}/QtGui \
  58   INCLUDEPATH+=${OE_QMAKE_INCDIR_QT}/QtDeclarative \
  59   INCLUDEPATH+=${OE_QMAKE_INCDIR_QT}/QtWebKit \
  60   INCLUDEPATH+=${OE_QMAKE_INCDIR_QT}/QtNetwork \
  61 "
  62 FIX_QREAL = "\
  63 "
  64
  65 do_generate_prepend() {
  66     for i in ${FIX_QREAL}; do
  67         sed -i -e s,qreal,float,g sip/$i
  68     done
  69 }
  70
  71 do_configure_prepend() {
  72     printf "TEMPLATE=subdirs\nSUBDIRS=${MAKE_MODULES}\n" >pyqt.pro
  73     printf "TEMPLATE=subdirs\nSUBDIRS=QtCore QtDeclarative QtGui\n" >qpy/qpy.pro
  74     ln -sf ./qpycore.pro qpy/QtCore/QtCore.pro
  75     ln -sf ./qpydeclarative.pro qpy/QtDeclarative/QtDeclarative.pro
  76     ln -sf ./qpygui.pro qpy/QtGui/QtGui.pro
  77     echo "INCLUDEPATH+=${S}/QtCore" >>qpy/QtCore/QtCore.pro
  78     echo "INCLUDEPATH+=${S}/QtGui" >>qpy/QtGui/QtGui.pro
  79     echo "INCLUDEPATH+=${S}/QtDeclarative" >>qpy/QtDeclarative/QtDeclarative.pro
  80     echo "LIBS+=-L../qpy/QtGui/ -lqpygui" >>QtGui/QtGui.pro
  81     echo "LIBS+=-L../qpy/QtCore/ -lqpycore" >>QtCore/QtCore.pro
  82     echo "LIBS+=-L../qpy/QtDeclarative/ -lqpydeclarative" >>QtDeclarative/QtDeclarative.pro
  83 }
  84
  85 do_stage() {
  86     install -d ${STAGING_SIPDIR}/qt/
  87     install -d ${STAGING_LIBDIR}/${PYTHON_DIR}/site-packages
  88     for module in ${SIP_MODULES}
  89     do
  90         install -m 0644 ${S}/sip/${module}/*.sip ${STAGING_SIPDIR}/qt/
  91         install -m 0755 ${module}/lib${module}.so ${STAGING_LIBDIR}/${PYTHON_DIR}/site-packages/${module}.so
  92     done
  93 }
  94
  95 do_install() {
  96     install -d ${D}${libdir}/${PYTHON_DIR}/site-packages/PyQt4
  97     for module in ${SIP_MODULES}
  98     do
  99                 echo "from PyQt4.${module} import *\n" >> ${D}${libdir}/${PYTHON_DIR}/site-packages/PyQt4/Qt.py
 100                 install -m 0755 ${module}/lib${module}.so ${D}${libdir}/${PYTHON_DIR}/site-packages/PyQt4/${module}.so
 101     done
 102         cp -pPR elementtree ${D}${libdir}/${PYTHON_DIR}/site-packages/PyQt4/
 103         cp __init__.py ${D}${libdir}/${PYTHON_DIR}/site-packages/PyQt4/
 104 }
 105
 106 FILES_${PN} = "${libdir}/${PYTHON_DIR}/site-packages"
 107