recipes/python/python-efl.inc

   1 DESCRIPTION = "${PN} bindings"
   2 LICENSE = "BSD"
   3 AUTHOR = "Gustavo Sverzut Barbieri <barbieri@gmail.com>"
   4 HOMEPAGE = "http://www.enlightenment.org"
   5 # NOTE: Due to a bug in distutils, even if we don't use pyrex but cython,
   6 # we need to build pyrex otherwise cython doesn't get called to build
   7 # the extension modules.
   8 DEPENDS = "python-cython-native python-pyrex-native python-numeric eina"
   9 RDEPENDS += "python-lang"
  10 PV = "0.3.1+svnr${SRCPV}"
  11 PR = "ml0"
  12
  13 inherit setuptools
  14
  15 SRC_URI = "svn://svn.enlightenment.org/svn/e/trunk/BINDINGS/python;module=${PN};proto=http"
  16 S = "${WORKDIR}/${PN}"
  17
  18 do_install_append() {
  19         if [ -e examples ]; then
  20                 for i in `find examples -name "*.edc"`; do
  21                         cd ${S}/`dirname $i`
  22                         echo "Generating .edj file for $i..."
  23                         edje_cc `basename $i`
  24                         echo "Removing sources in this directory..."
  25                         rm -f *.edc *.png *.ttf *.jpeg
  26                 done
  27                 cd ${S}
  28                 install -d ${D}${datadir}/${PN}/
  29                 cp -a examples ${D}${datadir}/${PN}/
  30                 find ${D}${datadir}/${PN}/examples -name "CVS" | xargs rm -rf
  31                 find ${D}${datadir}/${PN}/examples -name ".cvsignore" | xargs rm -f
  32         fi
  33 }
  34
  35 FILES_${PN}-dbg += "${libdir}/${PYTHON_DIR}/site-packages/*.egg/*/*/.debug"
  36
  37 PACKAGES += "${PN}-examples"
  38 FILES_${PN}-examples = "${datadir}/${PN}/examples"