recipes/linux/linux.inc

   1 DESCRIPTION = "Linux Kernel"
   2 SECTION = "kernel"
   3 LICENSE = "GPLv2"
   4
   5 inherit kernel siteinfo
   6
   7 RPSRC = "http://www.rpsys.net/openzaurus/patches/archive"
   8
   9 # Enable OABI compat for people stuck with obsolete userspace
  10 ARM_KEEP_OABI ?= "1"
  11
  12 # Quirk for udev greater or equal 141
  13 UDEV_GE_141 ?= "0"
  14
  15 # Specify the commandline for your device
  16
  17 # Boot from mmc
  18 CMDLINE_at91sam9263ek = "mem=64M console=ttyS0,115200 root=/dev/mmcblk0p1 rootfstype=ext2 rootdelay=5"
  19 # Boot from nfs
  20 #CMDLINE_at91sam9263ek = "mem=64M console=ttyS0,115200 root=301 root=/dev/nfs nfsroot=172.20.3.1:/data/at91 ip=172.20.0.5:::255.255.0.0"
  21
  22 # Set the verbosity of kernel messages during runtime
  23 # You can define CMDLINE_DEBUG in your local.conf or distro.conf to override this behaviour
  24 CMDLINE_DEBUG ?= '${@base_conditional("DISTRO_TYPE", "release", "quiet", "debug", d)}'
  25 CMDLINE_append = " ${CMDLINE_DEBUG} "
  26
  27 # Support for binary device tree generation
  28
  29 FILES_kernel-devicetree = "/boot/devicetree*"
  30
  31 KERNEL_DEVICETREE_boc01 = "${WORKDIR}/boc01.dts"
  32 KERNEL_DEVICETREE_calamari = "arch/${ARCH}/boot/dts/mpc8536ds.dts"
  33 KERNEL_DEVICETREE_canyonlands = "arch/${ARCH}/boot/dts/canyonlands.dts"
  34 KERNEL_DEVICETREE_kilauea = "arch/${ARCH}/boot/dts/kilauea.dts"
  35 KERNEL_DEVICETREE_lsppchd = "arch/${ARCH}/boot/dts/kuroboxHD.dts"
  36 KERNEL_DEVICETREE_lsppchg = "arch/${ARCH}/boot/dts/kuroboxHG.dts"
  37 KERNEL_DEVICETREE_mpc8313e-rdb = "arch/${ARCH}/boot/dts/mpc8313erdb.dts"
  38 KERNEL_DEVICETREE_mpc8315e-rdb = "arch/${ARCH}/boot/dts/mpc8315erdb.dts"
  39 KERNEL_DEVICETREE_mpc8323e-rdb = "arch/${ARCH}/boot/dts/mpc832x_rdb.dts"
  40 KERNEL_DEVICETREE_sequoia = "arch/${ARCH}/boot/dts/sequoia.dts"
  41 KERNEL_DEVICETREE_mpc8641-hpcn = "arch/${ARCH}/boot/dts/mpc8641_hpcn.dts"
  42 KERNEL_DEVICETREE_p2020ds = "arch/${ARCH}/boot/dts/p2020ds.dts"
  43 KERNEL_DEVICETREE_xilinx-ml507 = "arch/${ARCH}/boot/dts/virtex440-ml507.dts"
  44
  45 KERNEL_DEVICETREE_FLAGS = "-R 8 -S 0x3000"
  46
  47 python __anonymous () {
  48
  49     import bb
  50
  51     devicetree = bb.data.getVar('KERNEL_DEVICETREE', d, 1) or ''
  52     if devicetree:
  53         depends = bb.data.getVar("DEPENDS", d, 1)
  54         bb.data.setVar("DEPENDS", "%s dtc-native" % depends, d)
  55         packages = bb.data.getVar("PACKAGES", d, 1)
  56         bb.data.setVar("PACKAGES", "%s kernel-devicetree" % packages, d)
  57 }
  58
  59 do_configure_prepend() {
  60         echo "" > ${S}/.config
  61
  62         #
  63         # logo support, if you supply logo_linux_clut224.ppm in SRC_URI, then it's going to be used
  64         #
  65         if [ -e ${WORKDIR}/logo_linux_clut224.ppm ]; then
  66                 install -m 0644 ${WORKDIR}/logo_linux_clut224.ppm drivers/video/logo/logo_linux_clut224.ppm
  67                 echo "CONFIG_LOGO=y"                    >> ${S}/.config
  68                 echo "CONFIG_LOGO_LINUX_CLUT224=y"      >> ${S}/.config
  69         fi
  70
  71         #
  72         # oabi / eabi support
  73         #
  74         if [ "${TARGET_OS}" = "linux-gnueabi" -o  "${TARGET_OS}" = "linux-uclibceabi" ]; then
  75                 echo "CONFIG_AEABI=y"                   >> ${S}/.config
  76                 if [ "${ARM_KEEP_OABI}" = "1" ] ; then
  77                         echo "CONFIG_OABI_COMPAT=y"             >> ${S}/.config
  78                 else
  79                         echo "# CONFIG_OABI_COMPAT is not set"  >> ${S}/.config
  80                 fi
  81         else
  82                 echo "# CONFIG_AEABI is not set"        >> ${S}/.config
  83                 echo "# CONFIG_OABI_COMPAT is not set"  >> ${S}/.config
  84         fi
  85
  86         # When enabling thumb for userspace we also need thumb support in the kernel
  87         if [ "${ARM_INSTRUCTION_SET}" = "thumb" ] ; then
  88             sed -i -e /CONFIG_ARM_THUMB/d ${WORKDIR}/defconfig
  89             echo "CONFIG_ARM_THUMB=y" >> ${S}/.config
  90         fi
  91
  92         #
  93         # endian support
  94         #
  95         if [ "${SITEINFO_ENDIANESS}" = "be" ]; then
  96                 echo "CONFIG_CPU_BIG_ENDIAN=y"          >> ${S}/.config
  97         fi
  98
  99         echo "CONFIG_CMDLINE=\"${CMDLINE}\"" >> ${S}/.config
 100
 101         sed -e '/CONFIG_AEABI/d' \
 102             -e '/CONFIG_OABI_COMPAT=/d' \
 103             -e '/CONFIG_CMDLINE=/d' \
 104             -e '/CONFIG_CPU_BIG_ENDIAN/d' \
 105             -e '/CONFIG_LOGO=/d' \
 106             -e '/CONFIG_LOGO_LINUX_CLUT224=/d' \
 107             -e '/CONFIG_LOCALVERSION/d' \
 108             -e '/CONFIG_LOCALVERSION_AUTO/d' \
 109             < '${WORKDIR}/defconfig' >>'${S}/.config'
 110
 111         echo 'CONFIG_LOCALVERSION=""' >>${S}/.config
 112         echo '# CONFIG_LOCALVERSION_AUTO is not set' >>${S}/.config
 113
 114         #
 115         # Udev quirks
 116         #
 117
 118         # Newer versions of udev mandate that sysfs doesn't have deprecated entries
 119         if [ "${UDEV_GE_141}" = "1" ] ; then
 120             sed -e /CONFIG_SYSFS_DEPRECATED/d \
 121                 -e /CONFIG_SYSFS_DEPRECATED_V2/d \
 122                 -e /CONFIG_HOTPLUG/d \
 123                 -e /CONFIG_UEVENT_HELPER_PATH/d \
 124                 -e /CONFIG_UNIX/d \
 125                 -e /CONFIG_SYSFS/d \
 126                 -e /CONFIG_PROC_FS/d \
 127                 -e /CONFIG_TMPFS/d \
 128                 -e /CONFIG_INOTIFY_USER/d \
 129                 -e /CONFIG_SIGNALFD/d \
 130                 -e /CONFIG_TMPFS_POSIX_ACL/d \
 131                 -e /CONFIG_BLK_DEV_BSG/d \
 132                 -i '${S}/.config'
 133
 134             echo '# CONFIG_SYSFS_DEPRECATED is not set' >> ${S}/.config
 135             echo '# CONFIG_SYSFS_DEPRECATED_V2 is not set' >> ${S}/.config
 136             echo 'CONFIG_HOTPLUG=y' >> ${S}/.config
 137             echo 'CONFIG_UEVENT_HELPER_PATH=""' >> ${S}/.config
 138             echo 'CONFIG_UNIX=y' >> ${S}/.config
 139             echo 'CONFIG_SYSFS=y' >> ${S}/.config
 140             echo 'CONFIG_PROC_FS=y' >> ${S}/.config
 141             echo 'CONFIG_TMPFS=y' >> ${S}/.config
 142             echo 'CONFIG_INOTIFY_USER=y' >> ${S}/.config
 143             echo 'CONFIG_SIGNALFD=y' >> ${S}/.config
 144             echo 'CONFIG_TMPFS_POSIX_ACL=y' >> ${S}/.config
 145             echo 'CONFIG_BLK_DEV_BSG=y' >> ${S}/.config
 146             echo 'CONFIG_DEVTMPFS=y' >> ${S}/.config
 147             echo 'CONFIG_DEVTMPFS_MOUNT=y' >> ${S}/.config
 148         fi
 149
 150         #
 151         # root-over-nfs-over-usb-eth support. Limited, but should cover some cases.
 152         # Enable this by setting a proper CMDLINE_NFSROOT_USB.
 153         #
 154         if [ ! -z "${CMDLINE_NFSROOT_USB}" ]; then
 155                 oenote "Configuring the kernel for root-over-nfs-over-usb-eth with CMDLINE ${CMDLINE_NFSROOT_USB}"
 156                 sed -e '/CONFIG_INET/d' \
 157                     -e '/CONFIG_IP_PNP=/d' \
 158                     -e '/CONFIG_USB_GADGET=/d' \
 159                     -e '/CONFIG_USB_GADGET_SELECTED=/d' \
 160                     -e '/CONFIG_USB_ETH=/d' \
 161                     -e '/CONFIG_NFS_FS=/d' \
 162                     -e '/CONFIG_ROOT_NFS=/d' \
 163                     -e '/CONFIG_CMDLINE=/d' \
 164                     -i ${S}/.config
 165                 echo "CONFIG_INET=y"                     >> ${S}/.config
 166                 echo "CONFIG_IP_PNP=y"                   >> ${S}/.config
 167                 echo "CONFIG_USB_GADGET=y"               >> ${S}/.config
 168                 echo "CONFIG_USB_GADGET_SELECTED=y"      >> ${S}/.config
 169                 echo "CONFIG_USB_ETH=y"                  >> ${S}/.config
 170                 echo "CONFIG_NFS_FS=y"                   >> ${S}/.config
 171                 echo "CONFIG_ROOT_NFS=y"                 >> ${S}/.config
 172                 echo "CONFIG_CMDLINE=\"${CMDLINE_NFSROOT_USB}\"" >> ${S}/.config
 173         fi
 174                 yes '' | oe_runmake oldconfig
 175 }
 176
 177 do_configure_append_avr32() {
 178         sed -i -e s:-mno-pic::g arch/avr32/Makefile
 179 }
 180
 181 do_configure_append() {
 182         if test -e scripts/Makefile.fwinst ; then
 183                 sed -i -e "s:-m0644:-m 0644:g" scripts/Makefile.fwinst
 184         fi
 185 }
 186
 187 do_devicetree_image() {
 188     if test -n "${KERNEL_DEVICETREE}" ; then
 189         dtc -I dts -O dtb ${KERNEL_DEVICETREE_FLAGS} -o devicetree ${KERNEL_DEVICETREE}
 190         install -m 0644 devicetree ${D}/boot/devicetree-${KERNEL_VERSION}
 191         install -d ${DEPLOY_DIR_IMAGE}
 192         install -m 0644 devicetree ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.dtb
 193         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.dtb
 194         cd ${DEPLOY_DIR_IMAGE}
 195         rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.dtb
 196         ln -sf ${KERNEL_IMAGE_BASE_NAME}.dtb ${KERNEL_IMAGE_SYMLINK_NAME}.dtb
 197         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_SYMLINK_NAME}.dtb
 198     fi
 199 }
 200
 201 addtask devicetree_image after do_install before do_package do_deploy
 202
 203 pkg_postinst_kernel-devicetree () {
 204         cd /${KERNEL_IMAGEDEST}; update-alternatives --install /${KERNEL_IMAGEDEST}/devicetree devicetree devicetree-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 205 }
 206
 207 pkg_postrm_kernel-devicetree () {
 208         cd /${KERNEL_IMAGEDEST}; update-alternatives --remove devicetree devicetree-${KERNEL_VERSION} || true
 209 }
 210