recipes/gphoto2/libgphoto2_2.4.7.bb

   1 DESCRIPTION = "libgphoto2 allows you to access digital cameras"
   2 SECTION = "libs"
   3 LICENSE = "GPL"
   4 DEPENDS = "libtool jpeg virtual/libusb0 libexif"
   5
   6 # The .fdi and .rules files were generated with:
   7 #  libgphoto2-2.4.7/packaging/generic$ qemu-arm -s 1048576 -r 2.6.24 -L /OE/angstrom-dev/staging/armv5te-angstrom-linux-gnueabi/ .libs/print-camera-list
   8 # They are release specific, so please regen when adding new releases
   9
  10 SRC_URI = "${SOURCEFORGE_MIRROR}/gphoto/libgphoto2-${PV}.tar.bz2 \
  11            file://10-camera-libgphoto2-device.fdi \
  12            file://10-camera-libgphoto2.fdi \
  13            file://90-libgphoto2.rules \
  14 "
  15
  16 PR = "r1"
  17
  18 inherit autotools pkgconfig lib_package
  19
  20 OE_LT_RPATH_ALLOW=":${libdir}:"
  21 OE_LT_RPATH_ALLOW[export]="1"
  22
  23 EXTRA_OECONF = " --with-drivers=all ac_cv_lib_ltdl_lt_dlcaller_register=yes"
  24
  25 do_configure_append() {
  26         cd ${S}/libgphoto2_port/
  27         autoreconf -Wcross --verbose --install --force ${EXTRA_AUTORECONF} $acpaths
  28         cd ${S}
  29 }
  30
  31 do_install_append() {
  32     install -d ${D}${datadir}/hal/fdi/information/20thirdparty
  33     install -m 0644 ${WORKDIR}/*.fdi ${D}${datadir}/hal/fdi/information/20thirdparty/
  34
  35     install -d ${D}${sysconfdir}/udev/rules.d/
  36     install -m 0755 ${WORKDIR}/*.rules ${D}${sysconfdir}/udev/rules.d/
  37
  38     install -d ${D}${bindir}
  39     install -m 0755 ${S}/packaging/generic/check-ptp-camera ${D}${bindir}/
  40 }
  41
  42 PACKAGES =+ "libgphotoport libgphoto2-camlibs"
  43 FILES_libgphoto2-camlibs = "${libdir}/libgphoto2*/*/*.so*"
  44 RDEPENDS_${PN} = "libgphoto2-camlibs"
  45
  46 FILES_libgphotoport = "${libdir}/libgphoto2_port.so.*"
  47
  48 FILES_${PN} += "${libdir}/udev/* ${datadir}/hal"
  49 FILES_${PN}-dbg += "${libdir}/*/*/.debug"
  50
  51
  52