recipes/freesmartphone/frameworkd_git.bb

   1 DESCRIPTION = "The reference implementation of the freesmartphone.org framework APIs"
   2 HOMEPAGE = "http://www.freesmartphone.org"
   3 AUTHOR = "FreeSmartphone.Org Development Team"
   4 SECTION = "console/network"
   5 DEPENDS = "python-cython-native python-pyrex-native"
   6 LICENSE = "GPL"
   7 SRCREV = "f751f2724eea23d0ca050bdf2672f9011ae09517"
   8 PV = "0.9.5.9+gitr${SRCREV}"
   9 PR = "r3"
  10
  11 inherit distutils update-rc.d python-dir
  12
  13 INITSCRIPT_NAME = "frameworkd"
  14 INITSCRIPT_PARAMS = "defaults 29"
  15
  16 SRC_URI = "${FREESMARTPHONE_GIT}/framework.git;protocol=git;branch=master \
  17            file://frameworkd \
  18            file://frameworkd.conf \
  19            "
  20 SRC_URI_append_shr = "file://oeventsd-use-opimd-signals.patch;patch=1"
  21
  22 S = "${WORKDIR}/git"
  23
  24 do_configure_append() {
  25         echo "version=\"${PV}\"" >framework/__version__.py
  26 }
  27
  28 do_install_append() {
  29         install -d ${D}${sysconfdir}/init.d/
  30         install -m 0755 ${WORKDIR}/frameworkd ${D}${sysconfdir}/init.d/
  31         install -m 0644 ${WORKDIR}/frameworkd.conf ${D}${sysconfdir}
  32 }
  33
  34 pkg_postinst_${PN} () {
  35         echo "*IMPORTANT NOTICE*: There has been a change in internal opimd database structure as well as in the backend mechanism."
  36         echo "  This change is not backwards compatible so a conversion is needed, furthermore, since new opimd does not (and will not) support working with SIM, importing your SIM data is also required."
  37         echo "  In order to import SIM contacts, please use PISI."
  38         echo "  If you still have old contacts with 'tel:' prefix instead of field types (i.e you haven't upgraded since 26.1.2010) please run the 'remove-tel' script first."
  39         echo "  For the database conversion:"
  40         echo "    1) stop frameworkd '/etc/init.d/frameworkd stop'"
  41         echo "    2) use the conversion script, called: 'opimd_convert_db' which is already installed in your system"
  42         echo "    3) restart your device"
  43 }
  44
  45 RDEPENDS_${PN} += "\
  46   fsousaged \
  47 "
  48
  49 RDEPENDS_${PN} += "\
  50   python-ctypes \
  51   python-dbus \
  52   python-datetime \
  53   python-difflib \
  54   python-logging \
  55   python-pprint \
  56   python-pyalsaaudio \
  57   python-pygobject \
  58   python-pyrtc \
  59   python-pyserial \
  60   python-pyyaml \
  61   python-shell \
  62   python-subprocess \
  63   python-syslog \
  64   python-textutils \
  65   python-multiprocessing \
  66   ${PN}-config \
  67 "
  68
  69 RRECOMMENDS_${PN} += "\
  70   alsa-utils-amixer \
  71   python-gst \
  72   python-phoneutils \
  73   python-vobject \
  74   ppp \
  75 "
  76
  77 PACKAGES =+ "${PN}-config"
  78 PACKAGE_ARCH_${PN}-config = "${MACHINE_ARCH}"
  79
  80 # machine specific stuff, should ideally be elsewhere
  81 # - recommend MUXer on platforms that require one
  82 RDEPENDS_${PN}-config_append_om-gta01 = " fso-abyss"
  83 RDEPENDS_${PN}-config_append_om-gta02 = " fso-abyss"
  84 # - add wmiconfig for wireless configuration
  85 RDEPENDS_${PN}-config_append_om-gta02 = " wmiconfig"
  86
  87 FILES_${PN}-config = "\
  88   ${sysconfdir}/frameworkd.conf \
  89   ${sysconfdir}/freesmartphone \
  90   "
  91 CONFFILES_${PN}-config = "\
  92   ${sysconfdir}/frameworkd.conf \
  93   ${sysconfdir}/freesmartphone/opreferences/conf/phone/silent.yaml \
  94   ${sysconfdir}/freesmartphone/opreferences/conf/phone/default.yaml \
  95   ${sysconfdir}/freesmartphone/opreferences/conf/profiles/default.yaml \
  96   ${sysconfdir}/freesmartphone/opreferences/conf/rules/silent.yaml \
  97   ${sysconfdir}/freesmartphone/opreferences/conf/rules/default.yaml \
  98   ${sysconfdir}/freesmartphone/oevents/rules.yaml \
  99   ${sysconfdir}/freesmartphone/ogsmd/networks.tab \
 100   "
 101
 102 PACKAGE_ARCH_${PN} = "${BASE_PACKAGE_ARCH}"
 103 FILES_${PN} += "${sysconfdir}/dbus-1 ${sysconfdir}/freesmartphone ${sysconfdir}/init.d ${datadir}"
 104 FILES_${PN}-dbg += "${PYTHON_SITEPACKAGES_DIR}/framework/subsystems/*/.debug"