recipes/binutils/binutils_2.16.91.0.7.bb

   1 DESCRIPTION = "A GNU collection of binary utilities"
   2 HOMEPAGE = "http://www.gnu.org/software/binutils/"
   3 SECTION = "devel"
   4 LICENSE = "GPL"
   5 DEFAULT_PREFERENCE = "-1"
   6 PR = "r2"
   7
   8 inherit autotools gettext
   9
  10 PACKAGES = "${PN} ${PN}-dev ${PN}-doc ${PN}-symlinks"
  11
  12 FILES_${PN} = " \
  13         ${bindir}/${TARGET_PREFIX}* \
  14         ${libdir}/lib*-*.so \
  15         ${prefix}/${TARGET_SYS}/bin/*"
  16
  17 FILES_${PN}-dev = " \
  18         ${includedir} \
  19         ${libdir}/*.a \
  20         ${libdir}/*.la \
  21         ${libdir}/libbfd.so \
  22         ${libdir}/libopcodes.so"
  23
  24 FILES_${PN}-symlinks = " \
  25         ${bindir}/addr2line \
  26         ${bindir}/ar \
  27         ${bindir}/as \
  28         ${bindir}/c++filt \
  29         ${bindir}/gprof \
  30         ${bindir}/ld \
  31         ${bindir}/nm \
  32         ${bindir}/objcopy \
  33         ${bindir}/objdump \
  34         ${bindir}/ranlib \
  35         ${bindir}/readelf \
  36         ${bindir}/size \
  37         ${bindir}/strings \
  38         ${bindir}/strip"
  39
  40 SRC_URI = \
  41     "${KERNELORG_MIRROR}/pub/linux/devel/binutils/binutils-${PV}.tar.bz2 \
  42      file://binutils-2.16.91.0.6-objcopy-rename-errorcode.patch;patch=1 \
  43      file://binutils-uclibc-100-uclibc-conf.patch;patch=1 \
  44      file://binutils-uclibc-300-001_ld_makefile_patch.patch;patch=1 \
  45      file://binutils-uclibc-300-006_better_file_error.patch;patch=1 \
  46      file://binutils-uclibc-300-012_check_ldrunpath_length.patch;patch=1 \
  47      file://binutils-uclibc-400-mips-ELF_MAXPAGESIZE-4K.patch;patch=1 \
  48      file://binutils-uclibc-702-binutils-skip-comments.patch;patch=1"
  49
  50 S = "${WORKDIR}/binutils-${PV}"
  51 B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
  52
  53 EXTRA_OECONF = "--program-prefix=${TARGET_PREFIX} \
  54                 --enable-shared"
  55
  56 # This is necessary due to a bug in the binutils Makefiles
  57 EXTRA_OEMAKE = "configure-build-libiberty all"
  58
  59 export AR = "${HOST_PREFIX}ar"
  60 export AS = "${HOST_PREFIX}as"
  61 export LD = "${HOST_PREFIX}ld"
  62 export NM = "${HOST_PREFIX}nm"
  63 export RANLIB = "${HOST_PREFIX}ranlib"
  64 export OBJCOPY = "${HOST_PREFIX}objcopy"
  65 export OBJDUMP = "${HOST_PREFIX}objdump"
  66
  67 export AR_FOR_TARGET = "${TARGET_PREFIX}ar"
  68 export AS_FOR_TARGET = "${TARGET_PREFIX}as"
  69 export LD_FOR_TARGET = "${TARGET_PREFIX}ld"
  70 export NM_FOR_TARGET = "${TARGET_PREFIX}nm"
  71 export RANLIB_FOR_TARGET = "${TARGET_PREFIX}ranlib"
  72
  73 export CC_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc ${HOST_CC_ARCH}"
  74 export CXX_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc ${HOST_CC_ARCH}"
  75
  76 export CC_FOR_BUILD = "${BUILD_CC}"
  77 export CPP_FOR_BUILD = "${BUILD_CPP}"
  78 export CFLAGS_FOR_BUILD = "${BUILD_CFLAGS}"
  79
  80 export CC = "${CCACHE} ${HOST_PREFIX}gcc ${HOST_CC_ARCH}"
  81
  82 do_configure () {
  83         (cd ${S}; gnu-configize) || die "Failed to run gnu-configize"
  84         oe_runconf
  85 }
  86
  87 do_stage () {
  88         oe_libinstall -so -a -C opcodes libopcodes ${STAGING_LIBDIR}/
  89         oe_libinstall -a -C libiberty libiberty ${STAGING_LIBDIR}/
  90         oe_libinstall -so -a -C bfd libbfd ${STAGING_LIBDIR}/
  91         install -m 0644 ${S}/include/dis-asm.h ${STAGING_INCDIR}/
  92         install -m 0644 ${S}/include/symcat.h ${STAGING_INCDIR}/
  93         install -m 0644 ${S}/include/libiberty.h ${STAGING_INCDIR}/
  94         install -m 0644 ${S}/include/ansidecl.h ${STAGING_INCDIR}/
  95         install -m 0644 ${S}/include/bfdlink.h ${STAGING_INCDIR}/
  96         install -m 0644 bfd/bfd.h ${STAGING_INCDIR}/
  97 }
  98
  99 do_install () {
 100         autotools_do_install
 101
 102         # We don't really need these, so we'll remove them...
 103         rm -rf ${D}${libdir}/ldscripts
 104
 105         # Fix the /usr/${TARGET_SYS}/bin/* links
 106         for l in ${D}${prefix}/${TARGET_SYS}/bin/*; do
 107                 rm -f $l
 108                 ln -sf `echo ${prefix}/${TARGET_SYS}/bin \
 109                         | tr -s / \
 110                         | sed -e 's,^/,,' -e 's,[^/]*,..,g'`${bindir}/${TARGET_PREFIX}`basename $l` $l
 111         done
 112
 113         # Install the libiberty header
 114         install -d ${D}${includedir}
 115         install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
 116         install -m 644 ${S}/include/libiberty.h ${D}${includedir}
 117
 118         cd ${D}${bindir}
 119
 120         # Symlinks for ease of running these on the native target
 121         for p in ${TARGET_SYS}-* ; do
 122                 ln -sf $p `echo $p | sed -e s,${TARGET_SYS}-,,`
 123         done
 124 }