recipes/binutils/binutils_2.14.90.0.7.bb

   1 SECTION = "devel"
   2 inherit autotools gettext
   3
   4 DESCRIPTION = "A GNU collection of binary utilities"
   5 HOMEPAGE = "http://www.gnu.org/software/binutils/"
   6 LICENSE = "GPL"
   7 PR = "r6"
   8
   9 PACKAGES = "${PN} ${PN}-dev ${PN}-doc ${PN}-symlinks"
  10
  11 FILES_${PN} = " \
  12         ${bindir}/${TARGET_PREFIX}* \
  13         ${libdir}/lib*-*.so \
  14         ${prefix}/${TARGET_SYS}/bin/*"
  15
  16 FILES_${PN}-dev = " \
  17         ${includedir} \
  18         ${libdir}/*.a \
  19         ${libdir}/*.la \
  20         ${libdir}/libbfd.so \
  21         ${libdir}/libopcodes.so"
  22
  23 FILES_${PN}-symlinks = " \
  24         ${bindir}/addr2line \
  25         ${bindir}/ar \
  26         ${bindir}/as \
  27         ${bindir}/c++filt \
  28         ${bindir}/gprof \
  29         ${bindir}/ld \
  30         ${bindir}/nm \
  31         ${bindir}/objcopy \
  32         ${bindir}/objdump \
  33         ${bindir}/ranlib \
  34         ${bindir}/readelf \
  35         ${bindir}/size \
  36         ${bindir}/strings \
  37         ${bindir}/strip"
  38
  39 SRC_URI = \
  40     "${KERNELORG_MIRROR}/pub/linux/devel/binutils/binutils-${PV}.tar.bz2 \
  41      file://ld_makefile.patch;patch=1 \
  42      file://better_file_error.patch;patch=1 \
  43      file://signed_char_fix.patch;patch=1 \
  44      file://binutils-uclibc-001-debian.patch;patch=1 \
  45      file://binutils-uclibc-100-conf.patch;patch=1 \
  46      file://binutils-uclibc-200-build_modules.patch;patch=1 \
  47      file://binutils-uclibc-210-cflags.patch;patch=1 \
  48      file://binutils-100_cflags_for_build.patch;patch=1 \
  49      file://plt32trunc.patch;patch=1 \
  50      file://600-arm-textrel.patch;patch=1"
  51
  52 S = "${WORKDIR}/binutils-${PV}"
  53 B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
  54
  55 EXTRA_OECONF = "--with-sysroot=/ \
  56                 --program-prefix=${TARGET_PREFIX} \
  57                 --enable-shared"
  58
  59 # This is necessary due to a bug in the binutils Makefiles
  60 EXTRA_OEMAKE = "configure-build-libiberty all"
  61
  62 export AR = "${HOST_PREFIX}ar"
  63 export AS = "${HOST_PREFIX}as"
  64 export LD = "${HOST_PREFIX}ld"
  65 export NM = "${HOST_PREFIX}nm"
  66 export RANLIB = "${HOST_PREFIX}ranlib"
  67 export OBJCOPY = "${HOST_PREFIX}objcopy"
  68 export OBJDUMP = "${HOST_PREFIX}objdump"
  69
  70 export AR_FOR_TARGET = "${TARGET_PREFIX}ar"
  71 export AS_FOR_TARGET = "${TARGET_PREFIX}as"
  72 export LD_FOR_TARGET = "${TARGET_PREFIX}ld"
  73 export NM_FOR_TARGET = "${TARGET_PREFIX}nm"
  74 export RANLIB_FOR_TARGET = "${TARGET_PREFIX}ranlib"
  75
  76 export CC_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc"
  77 export CXX_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc"
  78
  79 export CC_FOR_BUILD = "${BUILD_CC}"
  80
  81 export CC = "${CCACHE} ${HOST_PREFIX}gcc"
  82
  83 do_configure () {
  84         (cd ${S}; gnu-configize) || die "Failed to run gnu-configize"
  85         oe_runconf
  86 }
  87
  88 do_stage () {
  89         oe_libinstall -so -a -C opcodes libopcodes ${STAGING_LIBDIR}/
  90         oe_libinstall -a -C libiberty libiberty ${STAGING_LIBDIR}/
  91         oe_libinstall -so -a -C bfd libbfd ${STAGING_LIBDIR}/
  92         install -m 0644 ${S}/include/dis-asm.h ${STAGING_INCDIR}/
  93         install -m 0644 ${S}/include/symcat.h ${STAGING_INCDIR}/
  94         install -m 0644 ${S}/include/libiberty.h ${STAGING_INCDIR}/
  95         install -m 0644 ${S}/include/ansidecl.h ${STAGING_INCDIR}/
  96         install -m 0644 ${S}/include/bfdlink.h ${STAGING_INCDIR}/
  97         install -m 0644 bfd/bfd.h ${STAGING_INCDIR}/
  98 }
  99
 100 do_install () {
 101         autotools_do_install
 102
 103         # We don't really need these, so we'll remove them...
 104         rm -rf ${D}${libdir}/ldscripts
 105
 106         # Fix the /usr/${TARGET_SYS}/bin/* links
 107         for l in ${D}${prefix}/${TARGET_SYS}/bin/*; do
 108                 rm -f $l
 109                 ln -sf `echo ${prefix}/${TARGET_SYS}/bin \
 110                         | tr -s / \
 111                         | sed -e 's,^/,,' -e 's,[^/]*,..,g'`${bindir}/${TARGET_PREFIX}`basename $l` $l
 112         done
 113
 114         # Install the libiberty header
 115         install -d ${D}${includedir}
 116         install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
 117         install -m 644 ${S}/include/libiberty.h ${D}${includedir}
 118
 119         cd ${D}${bindir}
 120
 121         # Symlinks for ease of running these on the native target
 122         for p in ${TARGET_SYS}-* ; do
 123                 ln -sf $p `echo $p | sed -e s,${TARGET_SYS}-,,`
 124         done
 125 }