recipes/binutils/binutils_2.14.90.0.7.bb

   1 SECTION = "devel"
   2 LICENSE = "GPL"
   3 inherit autotools gettext
   4
   5 DESCRIPTION = "A GNU collection of binary utilities"
   6 HOMEPAGE = "http://www.gnu.org/software/binutils/"
   7 LICENSE = "GPL"
   8 INC_PR = "r6"
   9 PR = "${INC_PR}.1"
  10
  11 PACKAGES = "${PN} ${PN}-dev ${PN}-doc ${PN}-symlinks"
  12
  13 FILES_${PN} = " \
  14         ${bindir}/${TARGET_PREFIX}* \
  15         ${libdir}/lib*-*.so \
  16         ${prefix}/${TARGET_SYS}/bin/*"
  17
  18 FILES_${PN}-dev = " \
  19         ${includedir} \
  20         ${libdir}/*.a \
  21         ${libdir}/*.la \
  22         ${libdir}/libbfd.so \
  23         ${libdir}/libopcodes.so"
  24
  25 FILES_${PN}-symlinks = " \
  26         ${bindir}/addr2line \
  27         ${bindir}/ar \
  28         ${bindir}/as \
  29         ${bindir}/c++filt \
  30         ${bindir}/gprof \
  31         ${bindir}/ld \
  32         ${bindir}/nm \
  33         ${bindir}/objcopy \
  34         ${bindir}/objdump \
  35         ${bindir}/ranlib \
  36         ${bindir}/readelf \
  37         ${bindir}/size \
  38         ${bindir}/strings \
  39         ${bindir}/strip"
  40
  41 SRC_URI = \
  42     "${KERNELORG_MIRROR}/pub/linux/devel/binutils/binutils-${PV}.tar.bz2 \
  43      file://ld_makefile.patch;patch=1 \
  44      file://better_file_error.patch;patch=1 \
  45      file://signed_char_fix.patch;patch=1 \
  46      file://binutils-uclibc-001-debian.patch;patch=1 \
  47      file://binutils-uclibc-100-conf.patch;patch=1 \
  48      file://binutils-uclibc-200-build_modules.patch;patch=1 \
  49      file://binutils-uclibc-210-cflags.patch;patch=1 \
  50      file://binutils-100_cflags_for_build.patch;patch=1 \
  51      file://plt32trunc.patch;patch=1 \
  52      file://600-arm-textrel.patch;patch=1 \
  53      file://binutils-2.14.90.0.7-fix-broken-configure.patch;patch=1"
  54
  55 S = "${WORKDIR}/binutils-${PV}"
  56 B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
  57
  58 EXTRA_OECONF = "--with-sysroot=/ \
  59                 --program-prefix=${TARGET_PREFIX} \
  60                 --enable-shared"
  61
  62 # This is necessary due to a bug in the binutils Makefiles
  63 EXTRA_OEMAKE = "configure-build-libiberty all"
  64
  65 export AR = "${HOST_PREFIX}ar"
  66 export AS = "${HOST_PREFIX}as"
  67 export LD = "${HOST_PREFIX}ld"
  68 export NM = "${HOST_PREFIX}nm"
  69 export RANLIB = "${HOST_PREFIX}ranlib"
  70 export OBJCOPY = "${HOST_PREFIX}objcopy"
  71 export OBJDUMP = "${HOST_PREFIX}objdump"
  72
  73 export AR_FOR_TARGET = "${TARGET_PREFIX}ar"
  74 export AS_FOR_TARGET = "${TARGET_PREFIX}as"
  75 export LD_FOR_TARGET = "${TARGET_PREFIX}ld"
  76 export NM_FOR_TARGET = "${TARGET_PREFIX}nm"
  77 export RANLIB_FOR_TARGET = "${TARGET_PREFIX}ranlib"
  78
  79 export CC_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc"
  80 export CXX_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc"
  81
  82 export CC_FOR_BUILD = "${BUILD_CC}"
  83
  84 export CC = "${CCACHE} ${HOST_PREFIX}gcc"
  85
  86 do_configure () {
  87         (cd ${S}; gnu-configize) || die "Failed to run gnu-configize"
  88         oe_runconf
  89 }
  90
  91 do_stage () {
  92         oe_libinstall -so -a -C opcodes libopcodes ${STAGING_LIBDIR}/
  93         oe_libinstall -a -C libiberty libiberty ${STAGING_LIBDIR}/
  94         oe_libinstall -so -a -C bfd libbfd ${STAGING_LIBDIR}/
  95         install -m 0644 ${S}/include/dis-asm.h ${STAGING_INCDIR}/
  96         install -m 0644 ${S}/include/symcat.h ${STAGING_INCDIR}/
  97         install -m 0644 ${S}/include/libiberty.h ${STAGING_INCDIR}/
  98         install -m 0644 ${S}/include/ansidecl.h ${STAGING_INCDIR}/
  99         install -m 0644 ${S}/include/bfdlink.h ${STAGING_INCDIR}/
 100         install -m 0644 bfd/bfd.h ${STAGING_INCDIR}/
 101 }
 102
 103 do_install () {
 104         autotools_do_install
 105
 106         # We don't really need these, so we'll remove them...
 107         rm -rf ${D}${libdir}/ldscripts
 108
 109         # Fix the /usr/${TARGET_SYS}/bin/* links
 110         for l in ${D}${prefix}/${TARGET_SYS}/bin/*; do
 111                 rm -f $l
 112                 ln -sf `echo ${prefix}/${TARGET_SYS}/bin \
 113                         | tr -s / \
 114                         | sed -e 's,^/,,' -e 's,[^/]*,..,g'`${bindir}/${TARGET_PREFIX}`basename $l` $l
 115         done
 116
 117         # Install the libiberty header
 118         install -d ${D}${includedir}
 119         install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
 120         install -m 644 ${S}/include/libiberty.h ${D}${includedir}
 121
 122         cd ${D}${bindir}
 123
 124         # Symlinks for ease of running these on the native target
 125         for p in ${TARGET_SYS}-* ; do
 126                 ln -sf $p `echo $p | sed -e s,${TARGET_SYS}-,,`
 127         done
 128 }