classes/rootfs_deb.bbclass

   1 #
   2 # Copyright 2006-2007 Openedhand Ltd.
   3 #
   4
   5 do_rootfs[depends] += "dpkg-native:do_populate_staging apt-native:do_populate_staging"
   6 do_rootfs[recrdeptask] += "do_package_write_deb"
   7
   8 fakeroot rootfs_deb_do_rootfs () {
   9         set +e
  10         mkdir -p ${IMAGE_ROOTFS}/var/dpkg/info
  11         mkdir -p ${IMAGE_ROOTFS}/var/dpkg/updates
  12
  13         rm -f ${STAGING_ETCDIR_NATIVE}/apt/sources.list.rev
  14         rm -f ${STAGING_ETCDIR_NATIVE}/apt/preferences
  15         > ${IMAGE_ROOTFS}/var/dpkg/status
  16         > ${IMAGE_ROOTFS}/var/dpkg/available
  17         # > ${STAGING_DIR}/var/dpkg/status
  18
  19         priority=1
  20         for arch in ${PACKAGE_ARCHS}; do
  21                 if [ ! -d ${DEPLOY_DIR_DEB}/$arch ]; then
  22                         continue;
  23                 fi
  24                 cd ${DEPLOY_DIR_DEB}/$arch
  25                 # if [ -z "${DEPLOY_KEEP_PACKAGES}" ]; then
  26                         rm -f Packages.gz Packages Packages.bz2
  27                 # fi
  28                 apt-ftparchive packages . | bzip2 > Packages.bz2
  29                 echo "Label: $arch" > Release
  30
  31                 echo "deb file:${DEPLOY_DIR_DEB}/$arch/ ./" >> ${STAGING_ETCDIR_NATIVE}/apt/sources.list.rev
  32                 (echo "Package: *"
  33                 echo "Pin: release l=$arch"
  34                 echo "Pin-Priority: $((800 + $priority))"
  35                 echo) >> ${STAGING_ETCDIR_NATIVE}/apt/preferences
  36                 priority=$(expr $priority + 5)
  37         done
  38
  39         tac ${STAGING_ETCDIR_NATIVE}/apt/sources.list.rev > ${STAGING_ETCDIR_NATIVE}/apt/sources.list
  40
  41         cat "${STAGING_ETCDIR_NATIVE}/apt/apt.conf.sample" \
  42                 | sed -e 's#Architecture ".*";#Architecture "${TARGET_ARCH}";#' \
  43                 > "${STAGING_ETCDIR_NATIVE}/apt/apt-rootfs.conf"
  44
  45         export APT_CONFIG="${STAGING_ETCDIR_NATIVE}/apt/apt-rootfs.conf"
  46         export D=${IMAGE_ROOTFS}
  47         export OFFLINE_ROOT=${IMAGE_ROOTFS}
  48         export IPKG_OFFLINE_ROOT=${IMAGE_ROOTFS}
  49
  50         mkdir -p ${IMAGE_ROOTFS}/var/lib/dpkg/alternatives
  51
  52         apt-get update
  53
  54         _flag () {
  55                 sed -i -e "/^Package: $2\$/{n; s/Status: install ok .*/Status: install ok $1/;}" ${IMAGE_ROOTFS}/var/dpkg/status
  56         }
  57         _getflag () {
  58                 cat ${IMAGE_ROOTFS}/var/dpkg/status | sed -n -e "/^Package: $2\$/{n; s/Status: install ok .*/$1/; p}"
  59         }
  60
  61         if [ x${TARGET_OS} = "xlinux" ] || [ x${TARGET_OS} = "xlinux-gnueabi" ] ; then
  62                 if [ ! -z "${LINGUAS_INSTALL}" ]; then
  63                         apt-get install glibc-localedata-i18n --force-yes --allow-unauthenticated
  64                         if [ $? -ne 0 ]; then
  65                                 exit 1
  66                         fi
  67                         for i in ${LINGUAS_INSTALL}; do
  68                                 apt-get install $i --force-yes --allow-unauthenticated
  69                                 if [ $? -ne 0 ]; then
  70                                         exit 1
  71                                 fi
  72                         done
  73                 fi
  74         fi
  75
  76         if [ ! -z "${PACKAGE_INSTALL}" ]; then
  77                 for i in ${PACKAGE_INSTALL}; do
  78                         apt-get install $i --force-yes --allow-unauthenticated
  79                         if [ $? -ne 0 ]; then
  80                                 exit 1
  81                         fi
  82                         find ${IMAGE_ROOTFS} -name \*.dpkg-new | for i in `cat`; do
  83                                 mv $i `echo $i | sed -e's,\.dpkg-new$,,'`
  84                         done
  85                 done
  86         fi
  87
  88         install -d ${IMAGE_ROOTFS}/${sysconfdir}
  89         echo ${BUILDNAME} > ${IMAGE_ROOTFS}/${sysconfdir}/version
  90
  91         # Mark all packages installed
  92         sed -i -e "s/Status: install ok unpacked/Status: install ok installed/;" ${IMAGE_ROOTFS}/var/dpkg/status
  93
  94         # Attempt to run preinsts
  95         # Mark packages with preinst failures as unpacked
  96         for i in ${IMAGE_ROOTFS}/var/dpkg/info/*.preinst; do
  97                 if [ -f $i ] && ! sh $i; then
  98                         _flag unpacked `basename $i .preinst`
  99                 fi
 100         done
 101
 102         # Attempt to run postinsts
 103         # Mark packages with postinst failures as unpacked
 104         for i in ${IMAGE_ROOTFS}/var/dpkg/info/*.postinst; do
 105                 if [ -f $i ] && ! sh $i configure; then
 106                         _flag unpacked `basename $i .postinst`
 107                 fi
 108         done
 109
 110         set -e
 111
 112         # Hacks to make dpkg/ipkg coexist for now
 113         mv ${IMAGE_ROOTFS}/var/dpkg ${IMAGE_ROOTFS}/usr/
 114         if [ -e ${IMAGE_ROOTFS}/usr/dpkg/alternatives ]; then
 115                 rmdir ${IMAGE_ROOTFS}/usr/dpkg/alternatives
 116         fi
 117         if [ ! -e ${IMAGE_ROOTFS}${libdir}/ipkg ] ; then
 118                 mkdir -p ${IMAGE_ROOTFS}${libdir}/ipkg
 119         fi
 120
 121         if [ ! -e ${IMAGE_ROOTFS}${sysconfdir}/ipkg ] ; then
 122                 mkdir -p ${IMAGE_ROOTFS}${sysconfdir}/ipkg
 123         fi
 124
 125         ln -sf ${libdir}/ipkg/alternatives ${IMAGE_ROOTFS}/usr/dpkg/alternatives
 126         ln -sf /usr/dpkg/info ${IMAGE_ROOTFS}${libdir}/ipkg/info
 127         ln -sf /usr/dpkg/status ${IMAGE_ROOTFS}${libdir}/ipkg/status
 128
 129         ${ROOTFS_POSTPROCESS_COMMAND}
 130
 131         log_check rootfs
 132 }
 133
 134 rootfs_deb_log_check() {
 135         target="$1"
 136         lf_path="$2"
 137
 138         lf_txt="`cat $lf_path`"
 139         for keyword_die in "E:"
 140         do
 141                 if (echo "$lf_txt" | grep -v log_check | grep "$keyword_die") >/dev/null 2>&1
 142                 then
 143                         echo "log_check: There were error messages in the logfile"
 144                         echo -e "log_check: Matched keyword: [$keyword_die]\n"
 145                         echo "$lf_txt" | grep -v log_check | grep -C 5 -i "$keyword_die"
 146                         echo ""
 147                         do_exit=1
 148                 fi
 149         done
 150         test "$do_exit" = 1 && exit 1
 151         true
 152 }
 153
 154 remove_packaging_data_files() {
 155         rm -rf ${IMAGE_ROOTFS}${libdir}/ipkg/
 156         rm -rf ${IMAGE_ROOTFS}/usr/dpkg/
 157 }