classes/kernel.bbclass

   1 inherit linux-kernel-base module_strip
   2
   3 PROVIDES += "virtual/kernel"
   4 DEPENDS += "virtual/${TARGET_PREFIX}depmod-${@get_kernelmajorversion('${PV}')} virtual/${TARGET_PREFIX}gcc${KERNEL_CCSUFFIX} update-modules"
   5
   6 KERNEL_IMAGETYPE ?= "zImage"
   7
   8 # Add dependency on mkimage for kernels that build a uImage
   9
  10 python __anonymous () {
  11
  12     import bb
  13
  14     kerneltype = bb.data.getVar('KERNEL_IMAGETYPE', d, 1) or ''
  15     if kerneltype == 'uImage':
  16         depends = bb.data.getVar("DEPENDS", d, 1)
  17         depends = "%s u-boot-mkimage-openmoko-native" % depends
  18         bb.data.setVar("DEPENDS", depends, d)
  19
  20     image = bb.data.getVar('INITRAMFS_IMAGE', d, True)
  21     if image != '' and image is not None:
  22         bb.data.setVar('INITRAMFS_TASK', '${INITRAMFS_IMAGE}:do_rootfs', d)
  23
  24     machine_kernel_pr = bb.data.getVar('MACHINE_KERNEL_PR', d, True)
  25
  26     if machine_kernel_pr:
  27        bb.data.setVar('PR', machine_kernel_pr, d)
  28 }
  29
  30 INITRAMFS_IMAGE ?= ""
  31 INITRAMFS_TASK ?= ""
  32
  33 inherit kernel-arch
  34
  35 PACKAGES_DYNAMIC += "kernel-module-*"
  36 PACKAGES_DYNAMIC += "kernel-image-*"
  37 PACKAGES_DYNAMIC += "kernel-firmware-*"
  38
  39 export OS = "${TARGET_OS}"
  40 export CROSS_COMPILE = "${TARGET_PREFIX}"
  41
  42 KERNEL_PRIORITY = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[-1]}"
  43
  44 KERNEL_RELEASE ?= "${KERNEL_VERSION}"
  45
  46 KERNEL_CCSUFFIX ?= ""
  47 KERNEL_LDSUFFIX ?= ""
  48
  49 # Set TARGET_??_KERNEL_ARCH in the machine .conf to set architecture
  50 # specific options necessary for building the kernel and modules.
  51 #FIXME: should be this: TARGET_CC_KERNEL_ARCH ?= "${TARGET_CC_ARCH}"
  52 TARGET_CC_KERNEL_ARCH ?= ""
  53 HOST_CC_KERNEL_ARCH ?= "${TARGET_CC_KERNEL_ARCH}"
  54 TARGET_LD_KERNEL_ARCH ?= ""
  55 HOST_LD_KERNEL_ARCH ?= "${TARGET_LD_KERNEL_ARCH}"
  56
  57 KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc${KERNEL_CCSUFFIX} ${HOST_CC_KERNEL_ARCH}"
  58 KERNEL_LD = "${LD}${KERNEL_LDSUFFIX} ${HOST_LD_KERNEL_ARCH}"
  59
  60 # Where built kernel lies in the kernel tree
  61 KERNEL_OUTPUT ?= "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
  62 KERNEL_IMAGEDEST = "boot"
  63
  64 #
  65 # configuration
  66 #
  67 export CMDLINE_CONSOLE = "console=${@bb.data.getVar("KERNEL_CONSOLE",d,1) or "ttyS0"}"
  68
  69 KERNEL_VERSION = "${@get_kernelversion('${S}')}"
  70 KERNEL_MAJOR_VERSION = "${@get_kernelmajorversion('${KERNEL_VERSION}')}"
  71
  72 KERNEL_LOCALVERSION ?= ""
  73
  74 # kernels are generally machine specific
  75 PACKAGE_ARCH = "${MACHINE_ARCH}"
  76
  77 # U-Boot support
  78 UBOOT_ENTRYPOINT ?= "20008000"
  79 UBOOT_LOADADDRESS ?= "${UBOOT_ENTRYPOINT}"
  80
  81 kernel_do_compile() {
  82         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
  83         oe_runmake include/linux/version.h CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  84         if [ "${KERNEL_MAJOR_VERSION}" != "2.6" ]; then
  85                 oe_runmake dep CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  86         fi
  87         oe_runmake ${KERNEL_IMAGETYPE} CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  88         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
  89                 oe_runmake modules  CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  90         else
  91                 oenote "no modules to compile"
  92         fi
  93 }
  94 kernel_do_compile[depends] = "${INITRAMFS_TASK}"
  95
  96 kernel_do_stage() {
  97         ASMDIR=`readlink include/asm`
  98
  99         mkdir -p ${STAGING_KERNEL_DIR}/include/$ASMDIR
 100         cp -fR include/$ASMDIR/* ${STAGING_KERNEL_DIR}/include/$ASMDIR/
 101         # Kernel 2.6.27 moved headers from includes/asm-${ARCH} to arch/${ARCH}/include/asm
 102         if [ -e arch/${ARCH}/include/asm/ ] ; then
 103                 cp -fR arch/${ARCH}/include/asm/* ${STAGING_KERNEL_DIR}/include/$ASMDIR/
 104                 install -d ${STAGING_KERNEL_DIR}/arch/${ARCH}/include
 105                 cp -fR arch/${ARCH}/* ${STAGING_KERNEL_DIR}/arch/${ARCH}/
 106         fi
 107         rm -f $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
 108         ln -sf $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
 109
 110         mkdir -p ${STAGING_KERNEL_DIR}/include/asm-generic
 111         cp -fR include/asm-generic/* ${STAGING_KERNEL_DIR}/include/asm-generic/
 112
 113         mkdir -p ${STAGING_KERNEL_DIR}/include/linux
 114         cp -fR include/linux/* ${STAGING_KERNEL_DIR}/include/linux/
 115
 116         mkdir -p ${STAGING_KERNEL_DIR}/include/net
 117         cp -fR include/net/* ${STAGING_KERNEL_DIR}/include/net/
 118
 119         mkdir -p ${STAGING_KERNEL_DIR}/include/pcmcia
 120         cp -fR include/pcmcia/* ${STAGING_KERNEL_DIR}/include/pcmcia/
 121
 122         for entry in drivers/crypto drivers/media include/media include/acpi include/sound include/video include/scsi include/trace; do
 123                 if [ -d $entry ]; then
 124                         mkdir -p ${STAGING_KERNEL_DIR}/$entry
 125                         cp -fR $entry/* ${STAGING_KERNEL_DIR}/$entry/
 126                 fi
 127         done
 128
 129         if [ -d drivers/sound ]; then
 130                 # 2.4 alsa needs some headers from this directory
 131                 mkdir -p ${STAGING_KERNEL_DIR}/include/drivers/sound
 132                 cp -fR drivers/sound/*.h ${STAGING_KERNEL_DIR}/include/drivers/sound/
 133         fi
 134
 135         install -m 0644 .config ${STAGING_KERNEL_DIR}/config-${KERNEL_VERSION}
 136         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/.config
 137         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/kernel-config
 138         echo "${KERNEL_VERSION}" >${STAGING_KERNEL_DIR}/kernel-abiversion
 139         echo "${S}" >${STAGING_KERNEL_DIR}/kernel-source
 140         echo "${KERNEL_CCSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ccsuffix
 141         echo "${KERNEL_LDSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ldsuffix
 142         [ -e Rules.make ] && install -m 0644 Rules.make ${STAGING_KERNEL_DIR}/
 143         [ -e Makefile ] && install -m 0644 Makefile ${STAGING_KERNEL_DIR}/
 144
 145         # Check if arch/${ARCH}/Makefile exists and install it
 146         if [ -e arch/${ARCH}/Makefile ]; then
 147                 install -d ${STAGING_KERNEL_DIR}/arch/${ARCH}
 148                 install -m 0644 arch/${ARCH}/Makefile* ${STAGING_KERNEL_DIR}/arch/${ARCH}
 149         # Otherwise check arch/x86/Makefile for i386 and x86_64 on kernels >= 2.6.24
 150         elif [ -e arch/x86/Makefile ]; then
 151                 install -d ${STAGING_KERNEL_DIR}/arch/x86
 152                 install -m 0644 arch/x86/Makefile* ${STAGING_KERNEL_DIR}/arch/x86
 153         fi
 154         cp -fR include/config* ${STAGING_KERNEL_DIR}/include/
 155         # Install kernel images and system.map to staging
 156         [ -e vmlinux ] && install -m 0644 vmlinux ${STAGING_KERNEL_DIR}/
 157         install -m 0644 ${KERNEL_OUTPUT} ${STAGING_KERNEL_DIR}/${KERNEL_IMAGETYPE}
 158         install -m 0644 System.map ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION}
 159         [ -e Module.symvers ] && install -m 0644 Module.symvers ${STAGING_KERNEL_DIR}/
 160
 161         cp -fR scripts ${STAGING_KERNEL_DIR}/
 162 }
 163
 164 kernel_do_install() {
 165         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
 166         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
 167                 oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" modules_install
 168         else
 169                 oenote "no modules to install"
 170         fi
 171
 172         install -d ${D}/${KERNEL_IMAGEDEST}
 173         install -d ${D}/boot
 174         install -m 0644 ${KERNEL_OUTPUT} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${KERNEL_VERSION}
 175         install -m 0644 System.map ${D}/boot/System.map-${KERNEL_VERSION}
 176         install -m 0644 .config ${D}/boot/config-${KERNEL_VERSION}
 177         install -m 0644 vmlinux ${D}/boot/vmlinux-${KERNEL_VERSION}
 178         install -d ${D}/etc/modutils
 179         if [ "${KERNEL_MAJOR_VERSION}" = "2.6" ]; then
 180                 install -d ${D}/etc/modprobe.d
 181         fi
 182
 183         # Check if scripts/genksyms exists and if so, build it
 184         if [ -e scripts/genksyms/ ]; then
 185                 oe_runmake SUBDIRS="scripts/genksyms"
 186         fi
 187
 188         install -d ${STAGING_KERNEL_DIR}
 189         cp -fR scripts ${STAGING_KERNEL_DIR}/
 190 }
 191
 192 kernel_do_configure() {
 193         yes '' | oe_runmake oldconfig
 194         if [ ! -z "${INITRAMFS_IMAGE}" ]; then
 195                 cp "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.cpio.gz" initramfs.cpio.gz
 196         fi
 197 }
 198
 199 do_menuconfig() {
 200         export TERMWINDOWTITLE="${PN} Kernel Configuration"
 201         export SHELLCMDS="make menuconfig"
 202         ${TERMCMDRUN}
 203         if [ $? -ne 0 ]; then
 204                 echo "Fatal: '${TERMCMD}' not found. Check TERMCMD variable."
 205                 exit 1
 206         fi
 207 }
 208 do_menuconfig[nostamp] = "1"
 209 addtask menuconfig after do_patch
 210
 211 pkg_postinst_kernel () {
 212         cd /${KERNEL_IMAGEDEST}; update-alternatives --install /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 213 }
 214
 215 pkg_postrm_kernel () {
 216         cd /${KERNEL_IMAGEDEST}; update-alternatives --remove ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} || true
 217 }
 218
 219 inherit cml1
 220
 221 EXPORT_FUNCTIONS do_compile do_install do_stage do_configure
 222
 223 # kernel-base becomes kernel-${KERNEL_VERSION}
 224 # kernel-image becomes kernel-image-${KERNEL_VERISON}
 225 PACKAGES = "kernel kernel-base kernel-image kernel-dev kernel-vmlinux"
 226 FILES = ""
 227 FILES_kernel-image = "/boot/${KERNEL_IMAGETYPE}*"
 228 FILES_kernel-dev = "/boot/System.map* /boot/config*"
 229 FILES_kernel-vmlinux = "/boot/vmlinux*"
 230 RDEPENDS_kernel = "kernel-base"
 231 RRECOMMENDS_kernel-module-hostap-cs += '${@base_version_less_or_equal("KERNEL_VERSION", "2.6.17", "", "apm-wifi-suspendfix", d)}'
 232 RRECOMMENDS_kernel-module-orinoco-cs += '${@base_version_less_or_equal("KERNEL_VERSION", "2.6.17", "", "apm-wifi-suspendfix", d)}'
 233 # Allow machines to override this dependency if kernel image files are
 234 # not wanted in images as standard
 235 RDEPENDS_kernel-base ?= "kernel-image"
 236 PKG_kernel-image = "kernel-image-${KERNEL_VERSION}"
 237 PKG_kernel-base = "kernel-${KERNEL_VERSION}"
 238 ALLOW_EMPTY_kernel = "1"
 239 ALLOW_EMPTY_kernel-base = "1"
 240 ALLOW_EMPTY_kernel-image = "1"
 241
 242 # Userspace workarounds for kernel modules issues
 243 # This is shame, fix the kernel instead!
 244 DEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 245 RDEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 246
 247 # renamed modules
 248 RPROVIDES_kernel-module-aes-generic = "kernel-module-aes"
 249
 250 pkg_postinst_kernel-image () {
 251 if [ ! -e "$D/lib/modules/${KERNEL_VERSION}" ]; then
 252         mkdir -p $D/lib/modules/${KERNEL_VERSION}
 253 fi
 254 if [ -n "$D" ]; then
 255         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 256 else
 257         depmod -a
 258 fi
 259 }
 260
 261 pkg_postinst_modules () {
 262 if [ -n "$D" ]; then
 263         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 264 else
 265         depmod -a
 266         update-modules || true
 267 fi
 268 }
 269
 270 pkg_postrm_modules () {
 271 update-modules || true
 272 }
 273
 274 autoload_postinst_fragment() {
 275 if [ x"$D" = "x" ]; then
 276         modprobe %s || true
 277 fi
 278 }
 279
 280 # autoload defaults (alphabetically sorted)
 281 module_autoload_hidp = "hidp"
 282 module_autoload_ipv6 = "ipv6"
 283 module_autoload_ipsec = "ipsec"
 284 module_autoload_ircomm-tty = "ircomm-tty"
 285 module_autoload_rfcomm = "rfcomm"
 286 module_autoload_sa1100-rtc = "sa1100-rtc"
 287 # sa1100-rtc was renamed in 2.6.23 onwards
 288 module_autoload_rtc-sa1100 = "rtc-sa1100"
 289
 290 # alias defaults (alphabetically sorted)
 291 module_conf_af_packet = "alias net-pf-17 af_packet"
 292 module_conf_bluez = "alias net-pf-31 bluez"
 293 module_conf_bnep = "alias bt-proto-4 bnep"
 294 module_conf_hci_uart = "alias tty-ldisc-15 hci_uart"
 295 module_conf_l2cap = "alias bt-proto-0 l2cap"
 296 module_conf_sco = "alias bt-proto-2 sco"
 297 module_conf_rfcomm = "alias bt-proto-3 rfcomm"
 298
 299 python populate_packages_prepend () {
 300         def extract_modinfo(file):
 301                 import tempfile, os, re
 302                 tempfile.tempdir = bb.data.getVar("WORKDIR", d, 1)
 303                 tf = tempfile.mkstemp()
 304                 tmpfile = tf[1]
 305                 cmd = "PATH=\"%s\" %sobjcopy -j .modinfo -O binary %s %s" % (bb.data.getVar("PATH", d, 1), bb.data.getVar("HOST_PREFIX", d, 1) or "", file, tmpfile)
 306                 os.system(cmd)
 307                 f = open(tmpfile)
 308                 l = f.read().split("\000")
 309                 f.close()
 310                 os.close(tf[0])
 311                 os.unlink(tmpfile)
 312                 exp = re.compile("([^=]+)=(.*)")
 313                 vals = {}
 314                 for i in l:
 315                         m = exp.match(i)
 316                         if not m:
 317                                 continue
 318                         vals[m.group(1)] = m.group(2)
 319                 return vals
 320
 321         def parse_depmod():
 322                 import os, re
 323
 324                 dvar = bb.data.getVar('D', d, 1)
 325                 if not dvar:
 326                         bb.error("D not defined")
 327                         return
 328
 329                 kernelver = bb.data.getVar('KERNEL_VERSION', d, 1)
 330                 kernelver_stripped = kernelver
 331                 m = re.match('^(.*-hh.*)[\.\+].*$', kernelver)
 332                 if m:
 333                         kernelver_stripped = m.group(1)
 334                 path = bb.data.getVar("PATH", d, 1)
 335                 host_prefix = bb.data.getVar("HOST_PREFIX", d, 1) or ""
 336                 major_version = bb.data.getVar('KERNEL_MAJOR_VERSION', d, 1)
 337
 338                 cmd = "PATH=\"%s\" %sdepmod-%s -n -a -r -b %s -F %s/boot/System.map-%s %s" % (path, host_prefix, major_version, dvar, dvar, kernelver, kernelver_stripped)
 339                 f = os.popen(cmd, 'r')
 340
 341                 deps = {}
 342                 pattern0 = "^(.*\.k?o):..*$"
 343                 pattern1 = "^(.*\.k?o):\s*(.*\.k?o)\s*$"
 344                 pattern2 = "^(.*\.k?o):\s*(.*\.k?o)\s*\\\$"
 345                 pattern3 = "^\t(.*\.k?o)\s*\\\$"
 346                 pattern4 = "^\t(.*\.k?o)\s*$"
 347
 348                 line = f.readline()
 349                 while line:
 350                         if not re.match(pattern0, line):
 351                                 line = f.readline()
 352                                 continue
 353                         m1 = re.match(pattern1, line)
 354                         if m1:
 355                                 deps[m1.group(1)] = m1.group(2).split()
 356                         else:
 357                                 m2 = re.match(pattern2, line)
 358                                 if m2:
 359                                         deps[m2.group(1)] = m2.group(2).split()
 360                                         line = f.readline()
 361                                         m3 = re.match(pattern3, line)
 362                                         while m3:
 363                                                 deps[m2.group(1)].extend(m3.group(1).split())
 364                                                 line = f.readline()
 365                                                 m3 = re.match(pattern3, line)
 366                                         m4 = re.match(pattern4, line)
 367                                         deps[m2.group(1)].extend(m4.group(1).split())
 368                         line = f.readline()
 369                 f.close()
 370                 return deps
 371
 372         def get_dependencies(file, pattern, format):
 373                 file = file.replace(bb.data.getVar('D', d, 1) or '', '', 1)
 374
 375                 if module_deps.has_key(file):
 376                         import os.path, re
 377                         dependencies = []
 378                         for i in module_deps[file]:
 379                                 m = re.match(pattern, os.path.basename(i))
 380                                 if not m:
 381                                         continue
 382                                 on = legitimize_package_name(m.group(1))
 383                                 dependency_pkg = format % on
 384                                 dependencies.append(dependency_pkg)
 385                         return dependencies
 386                 return []
 387
 388         def frob_metadata(file, pkg, pattern, format, basename):
 389                 import re
 390                 vals = extract_modinfo(file)
 391
 392                 dvar = bb.data.getVar('D', d, 1)
 393
 394                 # If autoloading is requested, output /etc/modutils/<name> and append
 395                 # appropriate modprobe commands to the postinst
 396                 autoload = bb.data.getVar('module_autoload_%s' % basename, d, 1)
 397                 if not autoload:
 398                     # Also, try canonical name with dashes
 399                     autoload = bb.data.getVar('module_autoload_%s' % basename.replace('_', '-'), d, 1)
 400                 if autoload:
 401                         name = '%s/etc/modutils/%s' % (dvar, basename)
 402                         f = open(name, 'w')
 403                         for m in autoload.split():
 404                                 f.write('%s\n' % m)
 405                         f.close()
 406                         postinst = bb.data.getVar('pkg_postinst_%s' % pkg, d, 1)
 407                         if not postinst:
 408                                 bb.fatal("pkg_postinst_%s not defined" % pkg)
 409                         postinst += bb.data.getVar('autoload_postinst_fragment', d, 1) % autoload
 410                         bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
 411
 412                 # Write out any modconf fragment
 413                 modconf = bb.data.getVar('module_conf_%s' % basename, d, 1)
 414                 if modconf:
 415                         if bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1) == "2.6":
 416                                 name = '%s/etc/modprobe.d/%s.conf' % (dvar, basename)
 417                         else:
 418                                 name = '%s/etc/modutils/%s.conf' % (dvar, basename)
 419                         f = open(name, 'w')
 420                         f.write("%s\n" % modconf)
 421                         f.close()
 422
 423                 files = bb.data.getVar('FILES_%s' % pkg, d, 1)
 424                 files = "%s /etc/modutils/%s /etc/modutils/%s.conf /etc/modprobe.d/%s.conf" % (files, basename, basename, basename)
 425                 bb.data.setVar('FILES_%s' % pkg, files, d)
 426
 427                 if vals.has_key("description"):
 428                         old_desc = bb.data.getVar('DESCRIPTION_' + pkg, d, 1) or ""
 429                         bb.data.setVar('DESCRIPTION_' + pkg, old_desc + "; " + vals["description"], d)
 430
 431                 rdepends_str = bb.data.getVar('RDEPENDS_' + pkg, d, 1)
 432                 if rdepends_str:
 433                         rdepends = rdepends_str.split()
 434                 else:
 435                         rdepends = []
 436                 rdepends.extend(get_dependencies(file, pattern, format))
 437                 bb.data.setVar('RDEPENDS_' + pkg, ' '.join(rdepends), d)
 438
 439         module_deps = parse_depmod()
 440         module_regex = '^(.*)\.k?o$'
 441         module_pattern = 'kernel-module-%s'
 442
 443         postinst = bb.data.getVar('pkg_postinst_modules', d, 1)
 444         postrm = bb.data.getVar('pkg_postrm_modules', d, 1)
 445
 446         maybe_update_modules = "update-modules "
 447         if bb.data.getVar("ONLINE_PACKAGE_MANAGEMENT", d) == "none":
 448                 maybe_update_modules = ""
 449
 450         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.bin$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 451         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.fw$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 452         do_split_packages(d, root='/lib/modules', file_regex=module_regex, output_pattern=module_pattern, description='%s kernel module', postinst=postinst, postrm=postrm, recursive=True, hook=frob_metadata, extra_depends='%skernel-%s' % (maybe_update_modules, bb.data.getVar("KERNEL_VERSION", d, 1)))
 453
 454         import re, os
 455         metapkg = "kernel-modules"
 456         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
 457         bb.data.setVar('FILES_' + metapkg, "", d)
 458         blacklist = [ 'kernel-dev', 'kernel-image', 'kernel-base', 'kernel-vmlinux' ]
 459         for l in module_deps.values():
 460                 for i in l:
 461                         pkg = module_pattern % legitimize_package_name(re.match(module_regex, os.path.basename(i)).group(1))
 462                         blacklist.append(pkg)
 463         metapkg_rdepends = []
 464         packages = bb.data.getVar('PACKAGES', d, 1).split()
 465         for pkg in packages[1:]:
 466                 if not pkg in blacklist and not pkg in metapkg_rdepends:
 467                         metapkg_rdepends.append(pkg)
 468         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
 469         bb.data.setVar('DESCRIPTION_' + metapkg, 'Kernel modules meta package', d)
 470         packages.append(metapkg)
 471         bb.data.setVar('PACKAGES', ' '.join(packages), d)
 472 }
 473
 474 # Support checking the kernel size since some kernels need to reside in partitions
 475 # with a fixed length or there is a limit in transferring the kernel to memory
 476 do_sizecheck() {
 477         if [ ! -z "${KERNEL_IMAGE_MAXSIZE}" -a -z "${DONT_CHECK_KERNELSIZE}" ]; then
 478                 size=`ls -l ${KERNEL_OUTPUT} | awk '{ print $5}'`
 479                 if [ $size -ge ${KERNEL_IMAGE_MAXSIZE} ]; then
 480                         rm ${KERNEL_OUTPUT}
 481                         die  "This kernel (size=$size > ${KERNEL_IMAGE_MAXSIZE}) is too big for your device. Please reduce the size of the kernel by making more of it modular."
 482                 fi
 483         fi
 484 }
 485
 486 addtask sizecheck before do_install after do_compile
 487
 488 do_uboot_mkimage() {
 489     if test "x${KERNEL_IMAGETYPE}" = "xuImage" ; then
 490         ENTRYPOINT=${UBOOT_ENTRYPOINT}
 491         if test -n "${UBOOT_ENTRYSYMBOL}"; then
 492             ENTRYPOINT=`${HOST_PREFIX}nm ${S}/vmlinux | \
 493                    awk '$3=="${UBOOT_ENTRYSYMBOL}" {print $1}'`
 494         fi
 495         if test -e arch/${ARCH}/boot/compressed/vmlinux ; then
 496             ${OBJCOPY} -O binary -R .note -R .comment -S arch/${ARCH}/boot/compressed/vmlinux linux.bin
 497             uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C none -a ${UBOOT_LOADADDRESS} -e $ENTRYPOINT -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin arch/${ARCH}/boot/uImage
 498             rm -f linux.bin
 499         else
 500             ${OBJCOPY} -O binary -R .note -R .comment -S vmlinux linux.bin
 501             rm -f linux.bin.gz
 502             gzip -9 linux.bin
 503             uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C gzip -a ${UBOOT_LOADADDRESS} -e $ENTRYPOINT -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin.gz arch/${ARCH}/boot/uImage
 504             rm -f linux.bin.gz
 505         fi
 506     fi
 507 }
 508
 509 addtask uboot_mkimage before do_install after do_compile
 510
 511 KERNEL_IMAGE_BASE_NAME ?= "${KERNEL_IMAGETYPE}-${PV}-${PR}-${MACHINE}"
 512 KERNEL_IMAGE_SYMLINK_NAME ?= "${KERNEL_IMAGETYPE}-${MACHINE}"
 513
 514 do_deploy() {
 515         install -d ${DEPLOY_DIR_IMAGE}
 516         install -m 0644 ${KERNEL_OUTPUT} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 517         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 518
 519         if [ -d "${D}/lib" ]; then
 520         tar -cvzf ${DEPLOY_DIR_IMAGE}/modules-${PV}-${PR}-${MACHINE}.tgz -C ${D} lib
 521         fi
 522
 523         cd ${DEPLOY_DIR_IMAGE}
 524         rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 525         ln -sf ${KERNEL_IMAGE_BASE_NAME}.bin ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 526         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_SYMLINK_NAME}.bin
 527 }
 528
 529 do_deploy[dirs] = "${S}"
 530
 531 addtask deploy before do_package after do_install